Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use base 'Exporter';
  25
  26 our @EXPORT = (
  27     qw( dt_from_string output_pref format_sqldatetime )
  28 );
  29
  30 =head1 DateUtils
  31
  32 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  33
  34 =head1 DESCRIPTION
  35
  36 Koha has historically only used dates not datetimes and been content to
  37 handle these as strings. It also has confused formatting with actual dates
  38 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  39
  40 =cut
  41
  42 =head2 dt_ftom_string
  43
  44 $dt = dt_from_string($date_string, [$format, $timezone ]);
  45
  46 Passed a date string returns a DateTime object format and timezone default
  47 to the system preferences. If the date string is empty DateTime->now is returned
  48
  49 =cut
  50
  51 sub dt_from_string {
  52     my ( $date_string, $date_format, $tz ) = @_;
  53
  54     return if $date_string and $date_string =~ m|^0000-0|;
  55
  56     $tz = C4::Context->tz unless $tz;;
  57
  58     return DateTime->now( time_zone => $tz ) unless $date_string;
  59
  60     $date_format = C4::Context->preference('dateformat') unless $date_format;
  61
  62     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  63         return $date_string;
  64     }
  65
  66     my $regex;
  67
  68     # The fallback format is sql/iso
  69     my $fallback_re = qr|
  70         (?<year>\d{4})
  71         -
  72         (?<month>\d{2})
  73         -
  74         (?<day>\d{2})
  75     |xms;
  76
  77     if ( $date_format eq 'metric' ) {
  78         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  79         $regex = qr|
  80             (?<day>\d{2})
  81             /
  82             (?<month>\d{2})
  83             /
  84             (?<year>\d{4})
  85         |xms;
  86     }
  87     elsif ( $date_format eq 'dmydot' ) {
  88         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  89         $regex = qr|
  90             (?<day>\d{2})
  91             .
  92             (?<month>\d{2})
  93             .
  94             (?<year>\d{4})
  95         |xms;
  96     }
  97     elsif ( $date_format eq 'us' ) {
  98         # us format is "mm/dd/yyyy[ hh:mm:ss]"
  99         $regex = qr|
 100             (?<month>\d{2})
 101             /
 102             (?<day>\d{2})
 103             /
 104             (?<year>\d{4})
 105         |xms;
 106     }
 107     elsif ( $date_format eq 'rfc3339' ) {
 108         $regex = qr/
 109             (?<year>\d{4})
 110             -
 111             (?<month>\d{2})
 112             -
 113             (?<day>\d{2})
 114             ([Tt\s])
 115             (?<hour>\d{2})
 116             :
 117             (?<minute>\d{2})
 118             :
 119             (?<second>\d{2})
 120             (\.\d{1,3})?(([Zz])|([\+|\-]([01][0-9]|2[0-3]):[0-5][0-9]))
 121         /xms;
 122     }
 123     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 124         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 125         $regex = $fallback_re;
 126     }
 127     else {
 128         die "Invalid dateformat parameter ($date_format)";
 129     }
 130
 131     # Add the faculative time part [hh:mm[:ss]]
 132     my $time_re .= qr|
 133             (
 134                 \s*
 135                 (?<hour>\d{2})
 136                 :
 137                 (?<minute>\d{2})
 138                 (
 139                     :
 140                     (?<second>\d{2})
 141                 )?
 142             )?
 143     |xms;
 144     $regex .= $time_re;
 145     $fallback_re .= $time_re;
 146
 147     my %dt_params;
 148     if ( $date_string =~ $regex ) {
 149         %dt_params = (
 150             year   => $+{year},
 151             month  => $+{month},
 152             day    => $+{day},
 153             hour   => $+{hour},
 154             minute => $+{minute},
 155             second => $+{second},
 156         );
 157     } elsif ( $date_string =~ $fallback_re ) {
 158         %dt_params = (
 159             year   => $+{year},
 160             month  => $+{month},
 161             day    => $+{day},
 162             hour   => $+{hour},
 163             minute => $+{minute},
 164             second => $+{second},
 165         );
 166     }
 167     else {
 168         die "The given date ($date_string) does not match the date format ($date_format)";
 169     }
 170
 171     # system allows the 0th of the month
 172     $dt_params{day} = '01' if $dt_params{day} eq '00';
 173
 174     # Set default hh:mm:ss to 00:00:00
 175     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 176     $dt_params{minute} = 00 unless defined $dt_params{minute};
 177     $dt_params{second} = 00 unless defined $dt_params{second};
 178
 179     my $dt = eval {
 180         DateTime->new(
 181             %dt_params,
 182             # No TZ for dates 'infinite' => see bug 13242
 183             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 184         );
 185     };
 186     if ($@) {
 187         $tz = DateTime::TimeZone->new( name => 'floating' );
 188         $dt = DateTime->new(
 189             %dt_params,
 190             # No TZ for dates 'infinite' => see bug 13242
 191             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 192         );
 193     }
 194     return $dt;
 195 }
 196
 197 =head2 output_pref
 198
 199 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 200 $date_string = output_pref( $dt );
 201
 202 Returns a string containing the time & date formatted as per the C4::Context setting,
 203 or C<undef> if C<undef> was provided.
 204
 205 This routine can either be passed a DateTime object or or a hashref.  If it is
 206 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 207 an optional 'dateformat' to override the dateformat system preference, an
 208 optional 'timeformat' to override the TimeFormat system preference value,
 209 and an optional 'dateonly' to specify that only the formatted date string
 210 should be returned without the time.
 211
 212 =cut
 213
 214 sub output_pref {
 215     my $params = shift;
 216     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 217     if ( ref $params eq 'HASH' ) {
 218         $dt         = $params->{dt};
 219         $str        = $params->{str};
 220         $force_pref = $params->{dateformat};         # if testing we want to override Context
 221         $force_time = $params->{timeformat};
 222         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 223         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 224     } else {
 225         $dt = $params;
 226     }
 227
 228     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 229
 230     if ( $str ) {
 231         local $@;
 232         $dt = eval { dt_from_string( $str ) };
 233         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 234     }
 235
 236     return if !defined $dt; # NULL date
 237     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 238
 239     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 240     if ( $dt->ymd !~ /^9999/ ) {
 241         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 242         $dt->set_time_zone( $tz );
 243     }
 244
 245     my $pref =
 246       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 247
 248     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 249     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 250     my $date;
 251     if ( $pref =~ m/^iso/ ) {
 252         $date = $dateonly
 253           ? $dt->strftime("%Y-%m-%d")
 254           : $dt->strftime("%Y-%m-%d $time");
 255     }
 256     elsif ( $pref =~ m/^rfc3339/ ) {
 257         if (!$dateonly) {
 258             $date = $dt->strftime('%FT%T%z');
 259             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 260         }
 261         else {
 262             $date = $dt->strftime("%Y-%m-%d");
 263         }
 264     }
 265     elsif ( $pref =~ m/^metric/ ) {
 266         $date = $dateonly
 267           ? $dt->strftime("%d/%m/%Y")
 268           : $dt->strftime("%d/%m/%Y $time");
 269     }
 270     elsif ( $pref =~ m/^dmydot/ ) {
 271         $date = $dateonly
 272           ? $dt->strftime("%d.%m.%Y")
 273           : $dt->strftime("%d.%m.%Y $time");
 274     }
 275
 276     elsif ( $pref =~ m/^us/ ) {
 277         $date = $dateonly
 278           ? $dt->strftime("%m/%d/%Y")
 279           : $dt->strftime("%m/%d/%Y $time");
 280     }
 281     else {
 282         $date = $dateonly
 283           ? $dt->strftime("%Y-%m-%d")
 284           : $dt->strftime("%Y-%m-%d $time");
 285     }
 286
 287     if ( $as_due_date ) {
 288         $time_format eq '12hr'
 289             ? $date =~ s| 11:59 PM$||
 290             : $date =~ s| 23:59$||;
 291     }
 292
 293     return $date;
 294 }
 295
 296 =head2 format_sqldatetime
 297
 298 $string = format_sqldatetime( $string_as_returned_from_db );
 299
 300 a convenience routine for calling dt_from_string and formatting the result
 301 with output_pref as it is a frequent activity in scripts
 302
 303 =cut
 304
 305 sub format_sqldatetime {
 306     my $str        = shift;
 307     my $force_pref = shift;    # if testing we want to override Context
 308     my $force_time = shift;
 309     my $dateonly   = shift;
 310
 311     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 312         my $dt = dt_from_string( $str, 'sql' );
 313         return q{} unless $dt;
 314         $dt->truncate( to => 'minute' );
 315         return output_pref({
 316             dt => $dt,
 317             dateformat => $force_pref,
 318             timeformat => $force_time,
 319             dateonly => $dateonly
 320         });
 321     }
 322     return q{};
 323 }
 324
 325 1;