circ/circulation.pl

   1 #!/usr/bin/perl
   2
   3 # script to execute issuing of books
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # copyright 2010 BibLibre
   7 # Copyright 2011 PTFS-Europe Ltd.
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along
  21 # with Koha; if not, write to the Free Software Foundation, Inc.,
  22 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  23
  24 use strict;
  25 use warnings;
  26 use CGI;
  27 use C4::Output;
  28 use C4::Print;
  29 use C4::Auth qw/:DEFAULT get_session/;
  30 use C4::Dates qw/format_date/;
  31 use C4::Branch; # GetBranches
  32 use C4::Koha;   # GetPrinter
  33 use C4::Circulation;
  34 use C4::Overdues qw/CheckBorrowerDebarred/;
  35 use C4::Members;
  36 use C4::Biblio;
  37 use C4::Reserves;
  38 use C4::Context;
  39 use CGI::Session;
  40 use C4::Members::Attributes qw(GetBorrowerAttributes);
  41 use Koha::DateUtils;
  42
  43 use Date::Calc qw(
  44   Today
  45   Add_Delta_YM
  46   Add_Delta_Days
  47   Date_to_Days
  48 );
  49 use List::MoreUtils qw/uniq/;
  50
  51
  52 #
  53 # PARAMETERS READING
  54 #
  55 my $query = new CGI;
  56
  57 my $sessionID = $query->cookie("CGISESSID") ;
  58 my $session = get_session($sessionID);
  59
  60 # branch and printer are now defined by the userenv
  61 # but first we have to check if someone has tried to change them
  62
  63 my $branch = $query->param('branch');
  64 if ($branch){
  65     # update our session so the userenv is updated
  66     $session->param('branch', $branch);
  67     $session->param('branchname', GetBranchName($branch));
  68 }
  69
  70 my $printer = $query->param('printer');
  71 if ($printer){
  72     # update our session so the userenv is updated
  73     $session->param('branchprinter', $printer);
  74 }
  75
  76 if (!C4::Context->userenv && !$branch){
  77     if ($session->param('branch') eq 'NO_LIBRARY_SET'){
  78         # no branch set we can't issue
  79         print $query->redirect("/cgi-bin/koha/circ/selectbranchprinter.pl");
  80         exit;
  81     }
  82 }
  83
  84 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
  85     {
  86         template_name   => 'circ/circulation.tmpl',
  87         query           => $query,
  88         type            => "intranet",
  89         authnotrequired => 0,
  90         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
  91     }
  92 );
  93
  94 my $branches = GetBranches();
  95
  96 my @failedrenews = $query->param('failedrenew');    # expected to be itemnumbers
  97 our %renew_failed = ();
  98 for (@failedrenews) { $renew_failed{$_} = 1; }
  99
 100 my @failedreturns = $query->param('failedreturn');
 101 our %return_failed = ();
 102 for (@failedreturns) { $return_failed{$_} = 1; }
 103
 104 my $findborrower = $query->param('findborrower') || q{};
 105 $findborrower =~ s|,| |g;
 106 my $borrowernumber = $query->param('borrowernumber');
 107
 108 $branch  = C4::Context->userenv->{'branch'};
 109 $printer = C4::Context->userenv->{'branchprinter'};
 110
 111
 112 # If AutoLocation is not activated, we show the Circulation Parameters to chage settings of librarian
 113 if (C4::Context->preference("AutoLocation") != 1) {
 114     $template->param(ManualLocation => 1);
 115 }
 116
 117 if (C4::Context->preference("DisplayClearScreenButton")) {
 118     $template->param(DisplayClearScreenButton => 1);
 119 }
 120
 121 if (C4::Context->preference("UseTablesortForCirc")) {
 122     $template->param(UseTablesortForCirc => 1);
 123 }
 124
 125 my $barcode        = $query->param('barcode') || q{};
 126 $barcode =~  s/^\s*|\s*$//g; # remove leading/trailing whitespace
 127
 128 $barcode = barcodedecode($barcode) if( $barcode && C4::Context->preference('itemBarcodeInputFilter'));
 129 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
 130 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
 131 my $issueconfirmed = $query->param('issueconfirmed');
 132 my $cancelreserve  = $query->param('cancelreserve');
 133 my $organisation   = $query->param('organisations');
 134 my $print          = $query->param('print') || q{};
 135 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
 136 my $charges        = $query->param('charges') || q{};
 137
 138 # Check if stickyduedate is turned off
 139 if ( $barcode ) {
 140     # was stickyduedate loaded from session?
 141     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
 142         $session->clear( 'stickyduedate' );
 143         $stickyduedate  = $query->param('stickyduedate');
 144         $duedatespec    = $query->param('duedatespec');
 145     }
 146 }
 147
 148 my ($datedue,$invalidduedate);
 149
 150 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
 151 if($duedatespec_allow){
 152     if ($duedatespec) {
 153         if ($duedatespec =~ C4::Dates->regexp('syspref')) {
 154                 $datedue = dt_from_string($duedatespec);
 155         } else {
 156             $invalidduedate = 1;
 157             $template->param(IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec);
 158         }
 159     }
 160 }
 161
 162 our $todaysdate = C4::Dates->new->output('iso');
 163
 164 # check and see if we should print
 165 if ( $barcode eq '' && $print eq 'maybe' ) {
 166     $print = 'yes';
 167 }
 168
 169 my $inprocess = ($barcode eq '') ? '' : $query->param('inprocess');
 170 if ( $barcode eq '' && $charges eq 'yes' ) {
 171     $template->param(
 172         PAYCHARGES     => 'yes',
 173         borrowernumber => $borrowernumber
 174     );
 175 }
 176
 177 if ( $print eq 'yes' && $borrowernumber ne '' ) {
 178     if ( C4::Context->boolean_preference('printcirculationslips') ) {
 179         my $letter = IssueSlip($branch, $borrowernumber, "QUICK");
 180         NetworkPrint($letter->{content});
 181     }
 182     $query->param( 'borrowernumber', '' );
 183     $borrowernumber = '';
 184 }
 185
 186 #
 187 # STEP 2 : FIND BORROWER
 188 # if there is a list of find borrowers....
 189 #
 190 my $borrowerslist;
 191 my $message;
 192 if ($findborrower) {
 193     my $borrowers = Search($findborrower, 'cardnumber') || [];
 194     if (C4::Context->preference("AddPatronLists")) {
 195         $template->param(
 196             "AddPatronLists_".C4::Context->preference("AddPatronLists")=> "1",
 197         );
 198         if (C4::Context->preference("AddPatronLists")=~/code/){
 199             my $categories = GetBorrowercategoryList;
 200             $categories->[0]->{'first'} = 1;
 201             $template->param(categories=>$categories);
 202         }
 203     }
 204     if ( @$borrowers == 0 ) {
 205         $query->param( 'findborrower', '' );
 206         $message = "'$findborrower'";
 207     }
 208     elsif ( @$borrowers == 1 ) {
 209         $borrowernumber = $borrowers->[0]->{'borrowernumber'};
 210         $query->param( 'borrowernumber', $borrowernumber );
 211         $query->param( 'barcode',           '' );
 212     }
 213     else {
 214         $borrowerslist = $borrowers;
 215     }
 216 }
 217
 218 # get the borrower information.....
 219 my $borrower;
 220 if ($borrowernumber) {
 221     $borrower = GetMemberDetails( $borrowernumber, 0 );
 222     my ( $od, $issue, $fines ) = GetMemberIssuesAndFines( $borrowernumber );
 223
 224     # Warningdate is the date that the warning starts appearing
 225     my (  $today_year,   $today_month,   $today_day) = Today();
 226     my ($warning_year, $warning_month, $warning_day) = split /-/, $borrower->{'dateexpiry'};
 227     my (  $enrol_year,   $enrol_month,   $enrol_day) = split /-/, $borrower->{'dateenrolled'};
 228     # Renew day is calculated by adding the enrolment period to today
 229     my (  $renew_year,   $renew_month,   $renew_day);
 230     if ($enrol_year*$enrol_month*$enrol_day>0) {
 231         (  $renew_year,   $renew_month,   $renew_day) =
 232         Add_Delta_YM( $enrol_year, $enrol_month, $enrol_day,
 233             0 , $borrower->{'enrolmentperiod'});
 234     }
 235     # if the expiry date is before today ie they have expired
 236     if ( !$borrower->{'dateexpiry'} || $warning_year*$warning_month*$warning_day==0
 237         || Date_to_Days($today_year,     $today_month, $today_day  )
 238          > Date_to_Days($warning_year, $warning_month, $warning_day) )
 239     {
 240         #borrowercard expired, no issues
 241         $template->param(
 242             flagged  => "1",
 243             noissues => "1",
 244             expired => "1",
 245             renewaldate => format_date("$renew_year-$renew_month-$renew_day")
 246         );
 247     }
 248     # check for NotifyBorrowerDeparture
 249     elsif ( C4::Context->preference('NotifyBorrowerDeparture') &&
 250             Date_to_Days(Add_Delta_Days($warning_year,$warning_month,$warning_day,- C4::Context->preference('NotifyBorrowerDeparture'))) <
 251             Date_to_Days( $today_year, $today_month, $today_day ) )
 252     {
 253         # borrower card soon to expire warn librarian
 254         $template->param("warndeparture" => format_date($borrower->{dateexpiry}),
 255         flagged       => "1",);
 256         if (C4::Context->preference('ReturnBeforeExpiry')){
 257             $template->param("returnbeforeexpiry" => 1);
 258         }
 259     }
 260     $template->param(
 261         overduecount => $od,
 262         issuecount   => $issue,
 263         finetotal    => $fines
 264     );
 265
 266     my $debar = CheckBorrowerDebarred($borrowernumber);
 267     if ($debar) {
 268         $template->param( 'userdebarred'    => 1 );
 269         $template->param( 'debarredcomment' => $borrower->{debarredcomment} );
 270         if ( $debar ne "9999-12-31" ) {
 271             $template->param( 'userdebarreddate' => C4::Dates::format_date($debar) );
 272         }
 273     }
 274
 275 }
 276
 277 #
 278 # STEP 3 : ISSUING
 279 #
 280 #
 281 if ($barcode) {
 282     # always check for blockers on issuing
 283     my ( $error, $question, $alerts ) =
 284     CanBookBeIssued( $borrower, $barcode, $datedue , $inprocess );
 285     my $blocker = $invalidduedate ? 1 : 0;
 286
 287     $template->param( alert => $alerts );
 288
 289     #  Get the item title for more information
 290     my $getmessageiteminfo = GetBiblioFromItemNumber(undef,$barcode);
 291     $template->param(
 292         authvalcode_notforloan => C4::Koha::GetAuthValCode('items.notforloan', $getmessageiteminfo->{'frameworkcode'}),
 293     );
 294
 295     delete $question->{'DEBT'} if ($debt_confirmed);
 296     foreach my $impossible ( keys %$error ) {
 297         $template->param(
 298             $impossible => $$error{$impossible},
 299             IMPOSSIBLE  => 1
 300         );
 301         $blocker = 1;
 302     }
 303     if( !$blocker ){
 304         my $confirm_required = 0;
 305         unless($issueconfirmed){
 306             #  Get the item title for more information
 307             my $getmessageiteminfo  = GetBiblioFromItemNumber(undef,$barcode);
 308             $template->{VARS}->{'additional_materials'} = $getmessageiteminfo->{'materials'};
 309             $template->param( itemhomebranch => $getmessageiteminfo->{'homebranch'} );
 310
 311             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
 312             foreach my $needsconfirmation ( keys %$question ) {
 313                 $template->param(
 314                     $needsconfirmation => $$question{$needsconfirmation},
 315                     getTitleMessageIteminfo => $getmessageiteminfo->{'title'},
 316                     getBarcodeMessageIteminfo => $getmessageiteminfo->{'barcode'},
 317                     NEEDSCONFIRMATION  => 1
 318                 );
 319                 $confirm_required = 1;
 320             }
 321         }
 322         unless($confirm_required) {
 323             AddIssue( $borrower, $barcode, $datedue, $cancelreserve );
 324             $inprocess = 1;
 325         }
 326     }
 327
 328     # FIXME If the issue is confirmed, we launch another time GetMemberIssuesAndFines, now display the issue count after issue
 329     my ( $od, $issue, $fines ) = GetMemberIssuesAndFines( $borrowernumber );
 330     $template->param( issuecount   => $issue );
 331 }
 332
 333 # reload the borrower info for the sake of reseting the flags.....
 334 if ($borrowernumber) {
 335     $borrower = GetMemberDetails( $borrowernumber, 0 );
 336 }
 337
 338 ##################################################################################
 339 # BUILD HTML
 340 # show all reserves of this borrower, and the position of the reservation ....
 341 if ($borrowernumber) {
 342
 343     # new op dev
 344     # now we show the status of the borrower's reservations
 345     my @borrowerreserv = GetReservesFromBorrowernumber($borrowernumber );
 346     my @reservloop;
 347     my @WaitingReserveLoop;
 348
 349     foreach my $num_res (@borrowerreserv) {
 350         my %getreserv;
 351         my %getWaitingReserveInfo;
 352         my $getiteminfo  = GetBiblioFromItemNumber( $num_res->{'itemnumber'} );
 353         my $itemtypeinfo = getitemtypeinfo( (C4::Context->preference('item-level_itypes')) ? $getiteminfo->{'itype'} : $getiteminfo->{'itemtype'} );
 354         my ( $transfertwhen, $transfertfrom, $transfertto ) =
 355           GetTransfers( $num_res->{'itemnumber'} );
 356
 357         $getreserv{waiting}       = 0;
 358         $getreserv{transfered}    = 0;
 359         $getreserv{nottransfered} = 0;
 360
 361         $getreserv{reservedate}    = format_date( $num_res->{'reservedate'} );
 362         $getreserv{reservenumber}  = $num_res->{'reservenumber'};
 363         $getreserv{title}          = $getiteminfo->{'title'};
 364         $getreserv{itemtype}       = $itemtypeinfo->{'description'};
 365         $getreserv{author}         = $getiteminfo->{'author'};
 366         $getreserv{barcodereserv}  = $getiteminfo->{'barcode'};
 367         $getreserv{itemcallnumber} = $getiteminfo->{'itemcallnumber'};
 368         $getreserv{biblionumber}   = $getiteminfo->{'biblionumber'};
 369         $getreserv{waitingat}      = GetBranchName( $num_res->{'branchcode'} );
 370         $getreserv{suspend}        = $num_res->{'suspend'};
 371         $getreserv{suspend_until}  = $num_res->{'suspend_until'};
 372         #         check if we have a waiting status for reservations
 373         if ( $num_res->{'found'} && $num_res->{'found'} eq 'W' ) {
 374             $getreserv{color}   = 'reserved';
 375             $getreserv{waiting} = 1;
 376 #     genarate information displaying only waiting reserves
 377         $getWaitingReserveInfo{title}        = $getiteminfo->{'title'};
 378         $getWaitingReserveInfo{biblionumber} = $getiteminfo->{'biblionumber'};
 379         $getWaitingReserveInfo{itemtype}     = $itemtypeinfo->{'description'};
 380         $getWaitingReserveInfo{author}       = $getiteminfo->{'author'};
 381         $getWaitingReserveInfo{itemcallnumber} = $getiteminfo->{'itemcallnumber'};
 382         $getWaitingReserveInfo{reservedate}  = format_date( $num_res->{'reservedate'} );
 383         $getWaitingReserveInfo{waitingat}    = GetBranchName( $num_res->{'branchcode'} );
 384         $getWaitingReserveInfo{waitinghere}  = 1 if $num_res->{'branchcode'} eq $branch;
 385         }
 386         #         check transfers with the itemnumber foud in th reservation loop
 387         if ($transfertwhen) {
 388             $getreserv{color}      = 'transfered';
 389             $getreserv{transfered} = 1;
 390             $getreserv{datesent}   = format_date($transfertwhen);
 391             $getreserv{frombranch} = GetBranchName($transfertfrom);
 392         } elsif ($getiteminfo->{'holdingbranch'} ne $num_res->{'branchcode'}) {
 393             $getreserv{nottransfered}   = 1;
 394             $getreserv{nottransferedby} = GetBranchName( $getiteminfo->{'holdingbranch'} );
 395         }
 396
 397 #         if we don't have a reserv on item, we put the biblio infos and the waiting position
 398         if ( $getiteminfo->{'title'} eq '' ) {
 399             my $getbibinfo = GetBiblioData( $num_res->{'biblionumber'} );
 400
 401             $getreserv{color}           = 'inwait';
 402             $getreserv{title}           = $getbibinfo->{'title'};
 403             $getreserv{nottransfered}   = 0;
 404             $getreserv{itemtype}        = $itemtypeinfo->{'description'};
 405             $getreserv{author}          = $getbibinfo->{'author'};
 406             $getreserv{biblionumber}    = $num_res->{'biblionumber'};
 407         }
 408         $getreserv{waitingposition} = $num_res->{'priority'};
 409         push( @reservloop, \%getreserv );
 410
 411 #         if we have a reserve waiting, initiate waitingreserveloop
 412         if ($getreserv{waiting} == 1) {
 413         push (@WaitingReserveLoop, \%getWaitingReserveInfo)
 414         }
 415
 416     }
 417
 418     # return result to the template
 419     $template->param(
 420         countreserv => scalar @reservloop,
 421         reservloop  => \@reservloop ,
 422         WaitingReserveLoop  => \@WaitingReserveLoop,
 423     );
 424     $template->param( adultborrower => 1 ) if ( $borrower->{'category_type'} eq 'A' );
 425 }
 426
 427 # make the issued books table.
 428 my $todaysissues = '';
 429 my $previssues   = '';
 430 our @todaysissues   = ();
 431 our @previousissues = ();
 432 our @relissues      = ();
 433 our @relprevissues  = ();
 434 my $displayrelissues;
 435
 436 our $totalprice = 0;
 437
 438 sub build_issue_data {
 439     my $issueslist = shift;
 440     my $relatives = shift;
 441
 442     # split in 2 arrays for today & previous
 443     foreach my $it ( @$issueslist ) {
 444         my $itemtypeinfo = getitemtypeinfo( (C4::Context->preference('item-level_itypes')) ? $it->{'itype'} : $it->{'itemtype'} );
 445
 446         # set itemtype per item-level_itype syspref - FIXME this is an ugly hack
 447         $it->{'itemtype'} = ( C4::Context->preference( 'item-level_itypes' ) ) ? $it->{'itype'} : $it->{'itemtype'};
 448
 449         ($it->{'charge'}, $it->{'itemtype_charge'}) = GetIssuingCharges(
 450             $it->{'itemnumber'}, $it->{'borrowernumber'}
 451         );
 452         $it->{'charge'} = sprintf("%.2f", $it->{'charge'});
 453         my ($can_renew, $can_renew_error) = CanBookBeRenewed(
 454             $it->{'borrowernumber'},$it->{'itemnumber'}
 455         );
 456         $it->{"renew_error_${can_renew_error}"} = 1 if defined $can_renew_error;
 457         my $restype = C4::Reserves::GetReserveStatus( $it->{'itemnumber'} );
 458         $it->{'can_renew'} = $can_renew;
 459         $it->{'can_confirm'} = !$can_renew && !$restype;
 460         $it->{'renew_error'} = ( $restype eq "Waiting" or $restype eq "Reserved" ) ? 1 : 0;
 461         $it->{'checkoutdate'} = C4::Dates->new($it->{'issuedate'},'iso')->output('syspref');
 462         $it->{'issuingbranchname'} = GetBranchName($it->{'branchcode'});
 463
 464         $totalprice += $it->{'replacementprice'} || 0;
 465         $it->{'itemtype'} = $itemtypeinfo->{'description'};
 466         $it->{'itemtype_image'} = $itemtypeinfo->{'imageurl'};
 467         $it->{'dd_sort'} = $it->{'date_due'};
 468         $it->{'dd'} = output_pref($it->{'date_due'});
 469         $it->{'displaydate_sort'} = $it->{'issuedate'};
 470         $it->{'displaydate'} = output_pref($it->{'issuedate'});
 471         #$it->{'od'} = ( $it->{'date_due'} lt $todaysdate ) ? 1 : 0 ;
 472         $it->{'od'} = $it->{'overdue'};
 473         $it->{'author'} ||= ' ';
 474         $it->{'renew_failed'} = $renew_failed{$it->{'itemnumber'}};
 475         $it->{'return_failed'} = $return_failed{$it->{'barcode'}};
 476
 477         if ( ( $it->{'issuedate'} && $it->{'issuedate'} gt $todaysdate )
 478           || ( $it->{'lastreneweddate'} && $it->{'lastreneweddate'} gt $todaysdate ) ) {
 479             (!$relatives) ? push @todaysissues, $it : push @relissues, $it;
 480         } else {
 481             (!$relatives) ? push @previousissues, $it : push @relprevissues, $it;
 482         }
 483     }
 484 }
 485
 486 if ($borrower) {
 487
 488     # Getting borrower relatives
 489     my @relborrowernumbers = GetMemberRelatives($borrower->{'borrowernumber'});
 490     #push @borrowernumbers, $borrower->{'borrowernumber'};
 491
 492     # get each issue of the borrower & separate them in todayissues & previous issues
 493     my $issueslist = GetPendingIssues($borrower->{'borrowernumber'});
 494     my $relissueslist = [];
 495     if ( @relborrowernumbers ) {
 496         $relissueslist = GetPendingIssues(@relborrowernumbers);
 497     }
 498
 499     build_issue_data($issueslist, 0);
 500     build_issue_data($relissueslist, 1);
 501
 502     $displayrelissues = scalar($relissueslist);
 503
 504     if ( C4::Context->preference( "todaysIssuesDefaultSortOrder" ) eq 'asc' ) {
 505         @todaysissues   = sort { $a->{'timestamp'} cmp $b->{'timestamp'} } @todaysissues;
 506     }
 507     else {
 508         @todaysissues   = sort { $b->{'timestamp'} cmp $a->{'timestamp'} } @todaysissues;
 509     }
 510
 511     if ( C4::Context->preference( "previousIssuesDefaultSortOrder" ) eq 'asc' ){
 512         @previousissues = sort { $a->{'date_due'} cmp $b->{'date_due'} } @previousissues;
 513     }
 514     else {
 515         @previousissues = sort { $b->{'date_due'} cmp $a->{'date_due'} } @previousissues;
 516     }
 517 }
 518
 519
 520 my @values;
 521 my %labels;
 522 my $CGIselectborrower;
 523 if ($borrowerslist) {
 524     foreach (
 525         sort {(lc $a->{'surname'} cmp lc $b->{'surname'} || lc $a->{'firstname'} cmp lc $b->{'firstname'})
 526         } @$borrowerslist
 527       )
 528     {
 529         push @values, $_->{'borrowernumber'};
 530         $labels{ $_->{'borrowernumber'} } =
 531 "$_->{'surname'}, $_->{'firstname'} ... ($_->{'cardnumber'} - $_->{'categorycode'} - $_->{'branchcode'}) ...  $_->{'address'} ";
 532     }
 533     $CGIselectborrower = CGI::scrolling_list(
 534         -name     => 'borrowernumber',
 535         -class    => 'focus',
 536         -id       => 'borrowernumber',
 537         -values   => \@values,
 538         -labels   => \%labels,
 539         -ondblclick => 'document.forms[\'mainform\'].submit()',
 540         -size     => 7,
 541         -tabindex => '',
 542         -multiple => 0
 543     );
 544 }
 545
 546 #title
 547 my $flags = $borrower->{'flags'};
 548 foreach my $flag ( sort keys %$flags ) {
 549     $template->param( flagged=> 1);
 550     $flags->{$flag}->{'message'} =~ s#\n#<br />#g;
 551     if ( $flags->{$flag}->{'noissues'} ) {
 552         $template->param(
 553             noissues => 'true',
 554         );
 555         if ( $flag eq 'GNA' ) {
 556             $template->param( gna => 'true' );
 557         }
 558         elsif ( $flag eq 'LOST' ) {
 559             $template->param( lost => 'true' );
 560         }
 561         elsif ( $flag eq 'DBARRED' ) {
 562             $template->param( dbarred => 'true' );
 563         }
 564         elsif ( $flag eq 'CHARGES' ) {
 565             $template->param(
 566                 charges    => 'true',
 567                 chargesmsg => $flags->{'CHARGES'}->{'message'},
 568                 chargesamount => $flags->{'CHARGES'}->{'amount'},
 569                 charges_is_blocker => 1
 570             );
 571         }
 572         elsif ( $flag eq 'CREDITS' ) {
 573             $template->param(
 574                 credits    => 'true',
 575                 creditsmsg => $flags->{'CREDITS'}->{'message'},
 576                 creditsamount => sprintf("%.02f", -($flags->{'CREDITS'}->{'amount'})), # from patron's pov
 577             );
 578         }
 579     }
 580     else {
 581         if ( $flag eq 'CHARGES' ) {
 582             $template->param(
 583                 charges    => 'true',
 584                 chargesmsg => $flags->{'CHARGES'}->{'message'},
 585                 chargesamount => $flags->{'CHARGES'}->{'amount'},
 586             );
 587         }
 588         elsif ( $flag eq 'CREDITS' ) {
 589             $template->param(
 590                 credits    => 'true',
 591                 creditsmsg => $flags->{'CREDITS'}->{'message'},
 592                 creditsamount => sprintf("%.02f", -($flags->{'CREDITS'}->{'amount'})), # from patron's pov
 593             );
 594         }
 595         elsif ( $flag eq 'ODUES' ) {
 596             $template->param(
 597                 odues    => 'true',
 598                 oduesmsg => $flags->{'ODUES'}->{'message'}
 599             );
 600
 601             my $items = $flags->{$flag}->{'itemlist'};
 602             if ( ! $query->param('module') || $query->param('module') ne 'returns' ) {
 603                 $template->param( nonreturns => 'true' );
 604             }
 605         }
 606         elsif ( $flag eq 'NOTES' ) {
 607             $template->param(
 608                 notes    => 'true',
 609                 notesmsg => $flags->{'NOTES'}->{'message'}
 610             );
 611         }
 612     }
 613 }
 614
 615 my $amountold = $borrower->{flags}->{'CHARGES'}->{'message'} || 0;
 616 $amountold =~ s/^.*\$//;    # remove upto the $, if any
 617
 618 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 619
 620 if ( $borrower->{'category_type'} eq 'C') {
 621     my  ( $catcodes, $labels ) =  GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 622     my $cnt = scalar(@$catcodes);
 623     $template->param( 'CATCODE_MULTI' => 1) if $cnt > 1;
 624     $template->param( 'catcode' =>    $catcodes->[0])  if $cnt == 1;
 625 }
 626
 627 my $CGIorganisations;
 628 my $member_of_institution;
 629 if ( C4::Context->preference("memberofinstitution") ) {
 630     my $organisations = get_institutions();
 631     my @orgs;
 632     my %org_labels;
 633     foreach my $organisation ( keys %$organisations ) {
 634         push @orgs, $organisation;
 635         $org_labels{$organisation} = $organisations->{$organisation}->{'surname'};
 636     }
 637     $member_of_institution = 1;
 638     $CGIorganisations      = CGI::popup_menu(
 639         -id     => 'organisations',
 640         -name   => 'organisations',
 641         -labels => \%org_labels,
 642         -values => \@orgs,
 643     );
 644 }
 645
 646 my $lib_messages_loop = GetMessages( $borrowernumber, 'L', $branch );
 647 if($lib_messages_loop){ $template->param(flagged => 1 ); }
 648
 649 my $bor_messages_loop = GetMessages( $borrowernumber, 'B', $branch );
 650 if($bor_messages_loop){ $template->param(flagged => 1 ); }
 651
 652 # Computes full borrower address
 653 my @fulladdress;
 654 push @fulladdress, $borrower->{'streetnumber'} if ( $borrower->{'streetnumber'} );
 655 push @fulladdress, &GetRoadTypeDetails( $borrower->{'streettype'} ) if ( $borrower->{'streettype'} );
 656 push @fulladdress, $borrower->{'address'} if ( $borrower->{'address'} );
 657
 658 my $fast_cataloging = 0;
 659 if (defined getframeworkinfo('FA')) {
 660     $fast_cataloging = 1
 661 }
 662
 663 if (C4::Context->preference('ExtendedPatronAttributes')) {
 664     my $attributes = GetBorrowerAttributes($borrowernumber);
 665     $template->param(
 666         ExtendedPatronAttributes => 1,
 667         extendedattributes => $attributes
 668     );
 669 }
 670
 671 $template->param(
 672     lib_messages_loop => $lib_messages_loop,
 673     bor_messages_loop => $bor_messages_loop,
 674     all_messages_del  => C4::Context->preference('AllowAllMessageDeletion'),
 675     findborrower      => $findborrower,
 676     borrower          => $borrower,
 677     borrowernumber    => $borrowernumber,
 678     branch            => $branch,
 679     branchname        => GetBranchName($borrower->{'branchcode'}),
 680     printer           => $printer,
 681     printername       => $printer,
 682     firstname         => $borrower->{'firstname'},
 683     surname           => $borrower->{'surname'},
 684     showname          => $borrower->{'showname'},
 685     category_type     => $borrower->{'category_type'},
 686     was_renewed       => $query->param('was_renewed') ? 1 : 0,
 687     expiry            => format_date($borrower->{'dateexpiry'}),
 688     categorycode      => $borrower->{'categorycode'},
 689     categoryname      => $borrower->{description},
 690     address           => join(' ', @fulladdress),
 691     address2          => $borrower->{'address2'},
 692     email             => $borrower->{'email'},
 693     emailpro          => $borrower->{'emailpro'},
 694     borrowernotes     => $borrower->{'borrowernotes'},
 695     city              => $borrower->{'city'},
 696     state              => $borrower->{'state'},
 697     zipcode           => $borrower->{'zipcode'},
 698     country           => $borrower->{'country'},
 699     phone             => $borrower->{'phone'} || $borrower->{'mobile'},
 700     cardnumber        => $borrower->{'cardnumber'},
 701     othernames        => $borrower->{'othernames'},
 702     amountold         => $amountold,
 703     barcode           => $barcode,
 704     stickyduedate     => $stickyduedate,
 705     duedatespec       => $duedatespec,
 706     message           => $message,
 707     CGIselectborrower => $CGIselectborrower,
 708     totalprice        => sprintf('%.2f', $totalprice),
 709     totaldue          => sprintf('%.2f', $total),
 710     todayissues       => \@todaysissues,
 711     previssues        => \@previousissues,
 712     relissues                   => \@relissues,
 713     relprevissues               => \@relprevissues,
 714     displayrelissues            => $displayrelissues,
 715     inprocess         => $inprocess,
 716     memberofinstution => $member_of_institution,
 717     CGIorganisations  => $CGIorganisations,
 718     is_child          => ($borrower->{'category_type'} eq 'C'),
 719     circview => 1,
 720     soundon           => C4::Context->preference("SoundOn"),
 721     fast_cataloging   => $fast_cataloging,
 722     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
 723     activeBorrowerRelationship => (C4::Context->preference('borrowerRelationship') ne ''),
 724     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 725     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 726     RoutingSerials => C4::Context->preference('RoutingSerials'),
 727 );
 728
 729 # save stickyduedate to session
 730 if ($stickyduedate) {
 731     $session->param( 'stickyduedate', $duedatespec );
 732 }
 733
 734 my ($picture, $dberror) = GetPatronImage($borrower->{'cardnumber'});
 735 $template->param( picture => 1 ) if $picture;
 736
 737 # get authorised values with type of BOR_NOTES
 738
 739 my $canned_notes = GetAuthorisedValues("BOR_NOTES");
 740
 741 $template->param(
 742     debt_confirmed            => $debt_confirmed,
 743     SpecifyDueDate            => $duedatespec_allow,
 744     CircAutocompl             => C4::Context->preference("CircAutocompl"),
 745         AllowRenewalLimitOverride => C4::Context->preference("AllowRenewalLimitOverride"),
 746     export_remove_fields      => C4::Context->preference("ExportRemoveFields"),
 747     export_with_csv_profile   => C4::Context->preference("ExportWithCsvProfile"),
 748     canned_bor_notes_loop     => $canned_notes,
 749 );
 750
 751 output_html_with_http_headers $query, $cookie, $template->output;