catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to acomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use strict;            # always use
 136 #use warnings; FIXME - Bug 2505
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth qw(:DEFAULT get_session);
 146 use C4::Search;
 147 use C4::Languages qw(getLanguages);
 148 use C4::Koha;
 149 use C4::Members qw(GetMember);
 150 use URI::Escape;
 151 use POSIX qw(ceil floor);
 152 use C4::Branch; # GetBranches
 153 use C4::Search::History;
 154
 155 use Koha::Virtualshelves;
 156
 157 use URI::Escape;
 158
 159 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 160 # create a new CGI object
 161 # FIXME: no_undef_params needs to be tested
 162 use CGI qw('-no_undef_params' -utf8 );
 163 my $cgi = new CGI;
 164
 165 # decide which template to use
 166 my $template_name;
 167 my $template_type;
 168 my @params = $cgi->param("limit");
 169 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 170     $template_name = 'catalogue/results.tt';
 171 }
 172 else {
 173     $template_name = 'catalogue/advsearch.tt';
 174     $template_type = 'advsearch';
 175 }
 176 # load the template
 177 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 178     template_name => $template_name,
 179     query => $cgi,
 180     type => "intranet",
 181     authnotrequired => 0,
 182     flagsrequired   => { catalogue => 1 },
 183     }
 184 );
 185
 186 my $lang = C4::Languages::getlanguage($cgi);
 187
 188 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 189     $template->param('UNIMARC' => 1);
 190 }
 191 if (C4::Context->preference("IntranetNumbersPreferPhrase")) {
 192     $template->param('numbersphr' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = GetMember('borrowernumber' => $cgi->cookie("holdfor"));
 197     $template->param(
 198         holdfor => $cgi->cookie("holdfor"),
 199         holdfor_surname => $holdfor_patron->{'surname'},
 200         holdfor_firstname => $holdfor_patron->{'firstname'},
 201         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
 202     );
 203 }
 204
 205 ## URI Re-Writing
 206 # Deprecated, but preserved because it's interesting :-)
 207 # The same thing can be accomplished with mod_rewrite in
 208 # a more elegant way
 209 #
 210 #my $rewrite_flag;
 211 #my $uri = $cgi->url(-base => 1);
 212 #my $relative_url = $cgi->url(-relative=>1);
 213 #$uri.="/".$relative_url."?";
 214 #warn "URI:$uri";
 215 #my @cgi_params_list = $cgi->param();
 216 #my $url_params = $cgi->Vars;
 217 #
 218 #for my $each_param_set (@cgi_params_list) {
 219 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 220 #}
 221 #warn "New URI:$uri";
 222 # Only re-write a URI if there are params or if it already hasn't been re-written
 223 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 224 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 225 #                            -cookie => $cookie);
 226 #    exit;
 227 #}
 228
 229 # load the branches
 230 my $branches = GetBranches();
 231
 232 # Populate branch_loop with all branches sorted by their name.  If
 233 # IndependentBranches is activated, set the default branch to the borrower
 234 # branch, except for superlibrarian who need to search all libraries.
 235 my $user = C4::Context->userenv;
 236 my @branch_loop = map {
 237      {
 238         value      => $_,
 239         branchname => $branches->{$_}->{branchname},
 240         selected   => $user->{branch} eq $_ && C4::Branch::onlymine(),
 241      }
 242 } sort {
 243     $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname}
 244 } keys %$branches;
 245
 246 my $categories = GetBranchCategories('searchdomain');
 247
 248 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 249
 250 # load the Type stuff
 251 my $itemtypes = GetItemTypes;
 252 # the index parameter is different for item-level itemtypes
 253 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 254 my @advancedsearchesloop;
 255 my $cnt;
 256 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 257 my @advanced_search_types = split(/\|/, $advanced_search_types);
 258
 259 foreach my $advanced_srch_type (@advanced_search_types) {
 260     $advanced_srch_type =~ s/^\s*//;
 261     $advanced_srch_type =~ s/\s*$//;
 262    if ($advanced_srch_type eq 'itemtypes') {
 263    # itemtype is a special case, since it's not defined in authorized values
 264         my @itypesloop;
 265         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 266             my %row =(  number=>$cnt++,
 267                 ccl => "$itype_or_itemtype,phr",
 268                 code => $thisitemtype,
 269                 description => $itemtypes->{$thisitemtype}->{translated_description},
 270                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 271             );
 272             push @itypesloop, \%row;
 273         }
 274         my %search_code = (  advanced_search_type => $advanced_srch_type,
 275                              code_loop => \@itypesloop );
 276         push @advancedsearchesloop, \%search_code;
 277     } else {
 278     # covers all the other cases: non-itemtype authorized values
 279        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 280         my @authvalueloop;
 281         for my $thisitemtype (@$advsearchtypes) {
 282                 my %row =(
 283                                 number=>$cnt++,
 284                                 ccl => $advanced_srch_type,
 285                 code => $thisitemtype->{authorised_value},
 286                 description => $thisitemtype->{'lib'},
 287                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 288                 );
 289                 push @authvalueloop, \%row;
 290         }
 291         my %search_code = (  advanced_search_type => $advanced_srch_type,
 292                              code_loop => \@authvalueloop );
 293         push @advancedsearchesloop, \%search_code;
 294     }
 295 }
 296 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 297
 298 # The following should only be loaded if we're bringing up the advanced search template
 299 if ( $template_type eq 'advsearch' ) {
 300
 301     # load the servers (used for searching -- to do federated searching, etc.)
 302     my $primary_servers_loop;# = displayPrimaryServers();
 303     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 304
 305     my $secondary_servers_loop;
 306     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 307
 308     # set the default sorting
 309     if (   C4::Context->preference('OPACdefaultSortField')
 310         && C4::Context->preference('OPACdefaultSortOrder') ) {
 311         my $default_sort_by =
 312             C4::Context->preference('defaultSortField') . '_'
 313           . C4::Context->preference('defaultSortOrder');
 314         $template->param( sort_by => $default_sort_by  );
 315     }
 316
 317     # determine what to display next to the search boxes (ie, boolean option
 318     # shouldn't appear on the first one, scan indexes should, adding a new
 319     # box should only appear on the last, etc.
 320     my @search_boxes_array;
 321     my $search_boxes_count = 3; # begin whith 3 boxes
 322     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 323     for (my $i=1;$i<=$search_boxes_count;$i++) {
 324         # if it's the first one, don't display boolean option, but show scan indexes
 325         if ($i==1) {
 326             push @search_boxes_array, {scan_index => 1};
 327         }
 328         # if it's the last one, show the 'add field' box
 329         elsif ($i==$search_boxes_count) {
 330             push @search_boxes_array,
 331                 {
 332                 boolean => 1,
 333                 add_field => 1,
 334                 };
 335         }
 336         else {
 337             push @search_boxes_array,
 338                 {
 339                 boolean => 1,
 340                 };
 341         }
 342
 343     }
 344     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 345                       search_boxes_loop => \@search_boxes_array);
 346
 347     # load the language limits (for search)
 348     my $languages_limit_loop = getLanguages($lang, 1);
 349     $template->param(search_languages_loop => $languages_limit_loop,);
 350
 351     # Expanded search options in advanced search:
 352     # use the global setting by default, but let the user override it
 353     {
 354         my $expanded = $cgi->param('expanded_options');
 355         $expanded = C4::Context->preference("expandedSearchOption") || 0
 356             if !defined($expanded) || $expanded !~ /^0|1$/;
 357         $template->param( expanded_options => $expanded );
 358     }
 359
 360     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 361
 362     output_html_with_http_headers $cgi, $cookie, $template->output;
 363     exit;
 364 }
 365
 366 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 367
 368 # Fetch the paramater list as a hash in scalar context:
 369 #  * returns paramater list as tied hash ref
 370 #  * we can edit the values by changing the key
 371 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 372 my $params = $cgi->Vars;
 373
 374 # Params that can have more than one value
 375 # sort by is used to sort the query
 376 # in theory can have more than one but generally there's just one
 377 my @sort_by;
 378 my $default_sort_by;
 379 if (   C4::Context->preference('defaultSortField')
 380     && C4::Context->preference('defaultSortOrder') ) {
 381     $default_sort_by =
 382         C4::Context->preference('defaultSortField') . '_'
 383       . C4::Context->preference('defaultSortOrder');
 384 }
 385
 386 @sort_by = $cgi->param('sort_by');
 387 $sort_by[0] = $default_sort_by unless $sort_by[0];
 388 foreach my $sort (@sort_by) {
 389     $template->param($sort => 1) if $sort;
 390 }
 391 $template->param('sort_by' => $sort_by[0]);
 392
 393 # Use the servers defined, or just search our local catalog(default)
 394 my @servers = $cgi->param('server');
 395 unless (@servers) {
 396     #FIXME: this should be handled using Context.pm
 397     @servers = ("biblioserver");
 398     # @servers = C4::Context->config("biblioserver");
 399 }
 400 # operators include boolean and proximity operators and are used
 401 # to evaluate multiple operands
 402 my @operators = map uri_unescape($_), $cgi->param('op');
 403
 404 # indexes are query qualifiers, like 'title', 'author', etc. They
 405 # can be single or multiple parameters separated by comma: kw,right-Truncation
 406 my @indexes = map uri_unescape($_), $cgi->param('idx');
 407
 408 # if a simple index (only one)  display the index used in the top search box
 409 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 410     my $idx = "ms_".$indexes[0];
 411     $idx =~ s/\,/comma/g;  # template toolkit doesnt like variables with a , in it
 412     $template->param($idx => 1);
 413 }
 414
 415 # an operand can be a single term, a phrase, or a complete ccl query
 416 my @operands = map uri_unescape($_), $cgi->param('q');
 417
 418 # limits are use to limit to results to a pre-defined category such as branch or language
 419 my @limits = map uri_unescape($_), $cgi->param('limit');
 420 my @nolimits = map uri_unescape($_), $cgi->param('nolimit');
 421 my %is_nolimit = map { $_ => 1 } @nolimits;
 422 @limits = grep { not $is_nolimit{$_} } @limits;
 423
 424 if($params->{'multibranchlimit'}) {
 425     my $multibranch = '('.join( " or ", map { "branch: $_ " } @{ GetBranchesInCategory( $params->{'multibranchlimit'} ) } ).')';
 426     push @limits, $multibranch if ($multibranch ne  '()');
 427 }
 428
 429 my $available;
 430 foreach my $limit(@limits) {
 431     if ($limit =~/available/) {
 432         $available = 1;
 433     }
 434 }
 435 $template->param(available => $available);
 436
 437 # append year limits if they exist
 438 my $limit_yr;
 439 my $limit_yr_value;
 440 if ($params->{'limit-yr'}) {
 441     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 442         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 443         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 444         $limit_yr_value = "$yr1-$yr2";
 445     }
 446     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 447         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 448         $limit_yr_value = $params->{'limit-yr'};
 449     }
 450     push @limits,$limit_yr;
 451     #FIXME: Should return a error to the user, incorect date format specified
 452 }
 453
 454 # convert indexes and operands to corresponding parameter names for the z3950 search
 455 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 456 my $z3950par;
 457 my $indexes2z3950 = {
 458     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 459     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 460     ti=>'title', 'ti,phr'=>'title', se=>'title'
 461 };
 462 for (my $ii = 0; $ii < @operands; ++$ii)
 463 {
 464     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 465     if (defined $name && defined $operands[$ii])
 466     {
 467         $z3950par ||= {};
 468         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 469     }
 470 }
 471
 472
 473 # Params that can only have one value
 474 my $scan = $params->{'scan'};
 475 my $count = C4::Context->preference('numSearchResults') || 20;
 476 my $results_per_page = $params->{'count'} || $count;
 477 my $offset = $params->{'offset'} || 0;
 478 my $page = $cgi->param('page') || 1;
 479 #my $offset = ($page-1)*$results_per_page;
 480 my $hits;
 481 my $expanded_facet = $params->{'expand'};
 482
 483 # Define some global variables
 484 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 485
 486 ## I. BUILD THE QUERY
 487 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan,$lang);
 488
 489 ## parse the query_cgi string and put it into a form suitable for <input>s
 490 my @query_inputs;
 491 my $scan_index_to_use;
 492
 493 for my $this_cgi ( split('&',$query_cgi) ) {
 494     next unless $this_cgi;
 495     $this_cgi =~ m/(.*?)=(.*)/;
 496     my $input_name = $1;
 497     my $input_value = $2;
 498     push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 499     if ($input_name eq 'idx') {
 500         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 501     }
 502 }
 503 $template->param ( QUERY_INPUTS => \@query_inputs,
 504                    scan_index_to_use => $scan_index_to_use );
 505
 506 ## parse the limit_cgi string and put it into a form suitable for <input>s
 507 my @limit_inputs;
 508 for my $this_cgi ( split('&',$limit_cgi) ) {
 509     next unless $this_cgi;
 510     # handle special case limit-yr
 511     if ($this_cgi =~ /yr,st-numeric/) {
 512         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 513         next;
 514     }
 515     $this_cgi =~ m/(.*=)(.*)/;
 516     my $input_name = $1;
 517     my $input_value = $2;
 518     $input_name =~ s/=$//;
 519     push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 520 }
 521 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 522
 523 ## II. DO THE SEARCH AND GET THE RESULTS
 524 my $total; # the total results for the whole set
 525 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 526 my $results_hashref;
 527
 528 eval {
 529     ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$itemtypes,$query_type,$scan);
 530 };
 531
 532 # This sorts the facets into alphabetical order
 533 if ($facets) {
 534     foreach my $f (@$facets) {
 535         $f->{facets} = [ sort { uc($a->{facet_label_value}) cmp uc($b->{facet_label_value}) } @{ $f->{facets} } ];
 536     }
 537 }
 538 if ($@ || $error) {
 539     $template->param(query_error => $error.$@);
 540     output_html_with_http_headers $cgi, $cookie, $template->output;
 541     exit;
 542 }
 543
 544 # At this point, each server has given us a result set
 545 # now we build that set for template display
 546 my @sup_results_array;
 547 for (my $i=0;$i<@servers;$i++) {
 548     my $server = $servers[$i];
 549     if ($server =~/biblioserver/) { # this is the local bibliographic server
 550         $hits = $results_hashref->{$server}->{"hits"};
 551         my $page = $cgi->param('page') || 0;
 552         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 553                                        $results_hashref->{$server}->{"RECORDS"});
 554         $total = $total + $results_hashref->{$server}->{"hits"};
 555
 556         # Search history
 557         if (C4::Context->preference('EnableSearchHistory')) {
 558             unless ( $offset ) {
 559                 my $path_info = $cgi->url(-path_info=>1);
 560                 my $query_cgi_history = $cgi->url(-query=>1);
 561                 $query_cgi_history =~ s/^$path_info\?//;
 562                 $query_cgi_history =~ s/;/&/g;
 563                 my $query_desc_history = $query_desc;
 564                 $query_desc_history .= ", $limit_desc"
 565                     if $limit_desc;
 566
 567                 C4::Search::History::add({
 568                     userid => $borrowernumber,
 569                     sessionid => $cgi->cookie("CGISESSID"),
 570                     query_desc => $query_desc_history,
 571                     query_cgi => $query_cgi_history,
 572                     total => $total,
 573                     type => "biblio",
 574                 });
 575             }
 576             $template->param( EnableSearchHistory => 1 );
 577         }
 578
 579         ## If there's just one result, redirect to the detail page
 580         if ($total == 1) {
 581             my $biblionumber = $newresults[0]->{biblionumber};
 582             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 583             my $views = { C4::Search::enabled_staff_search_views };
 584             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 585                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 586             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 587                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 588             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 589                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 590             } else {
 591                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 592             }
 593             exit;
 594         }
 595
 596         # set up parameters if user wishes to re-run the search
 597         # as a Z39.50 search
 598         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 599
 600         if ($hits) {
 601             $template->param(total => $hits);
 602             my $limit_cgi_not_availablity = $limit_cgi;
 603             $limit_cgi_not_availablity =~ s/&limit=available//g;
 604             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 605             $template->param(limit_cgi => $limit_cgi);
 606             $template->param(query_cgi => $query_cgi);
 607             $template->param(query_desc => $query_desc);
 608             $template->param(limit_desc => $limit_desc);
 609             $template->param(offset     => $offset);
 610             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 611             if ($query_desc || $limit_desc) {
 612                 $template->param(searchdesc => 1);
 613             }
 614             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 615             $template->param(results_per_page =>  $results_per_page);
 616             # must define a value for size if not present in DB
 617             # in order to avoid problems generated by the default size value in TT
 618             foreach my $line (@newresults) {
 619                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 620             }
 621             $template->param(SEARCH_RESULTS => \@newresults);
 622             ## FIXME: add a global function for this, it's better than the current global one
 623             ## Build the page numbers on the bottom of the page
 624             my @page_numbers;
 625             # total number of pages there will be
 626             my $pages = ceil($hits / $results_per_page);
 627             # default page number
 628             my $current_page_number = 1;
 629             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 630             my $previous_page_offset;
 631             if ( $offset >= $results_per_page ) {
 632                 $previous_page_offset = $offset - $results_per_page;
 633             }
 634             my $next_page_offset = $offset + $results_per_page;
 635             # If we're within the first 10 pages, keep it simple
 636             #warn "current page:".$current_page_number;
 637             if ($current_page_number < 10) {
 638                 # just show the first 10 pages
 639                 # Loop through the pages
 640                 my $pages_to_show = 10;
 641                 $pages_to_show = $pages if $pages<10;
 642                 for (my $i=1; $i<=$pages_to_show;$i++) {
 643                     # the offset for this page
 644                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 645                     # the page number for this page
 646                     my $this_page_number = $i;
 647                     # put it in the array
 648                     push @page_numbers,
 649                       { offset    => $this_offset,
 650                         pg        => $this_page_number,
 651                         # it should only be highlighted if it's the current page
 652                         highlight => $this_page_number == $current_page_number,
 653                         sort_by   => join ' ', @sort_by
 654                       };
 655
 656                 }
 657
 658             }
 659
 660             # now, show twenty pages, with the current one smack in the middle
 661             else {
 662                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 663                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 664                     my $this_page_number = $i-9;
 665                     if ( $this_page_number <= $pages ) {
 666                         push @page_numbers,
 667                           { offset    => $this_offset,
 668                             pg        => $this_page_number,
 669                             highlight => $this_page_number == $current_page_number,
 670                             sort_by   => join ' ', @sort_by
 671                           };
 672                     }
 673                 }
 674             }
 675             # FIXME: no previous_page_offset when pages < 2
 676             $template->param(   PAGE_NUMBERS => \@page_numbers,
 677                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 678             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 679         }
 680
 681
 682         # no hits
 683         else {
 684             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 685         }
 686
 687     } # end of the if local
 688
 689     # asynchronously search the authority server
 690     elsif ($server =~/authorityserver/) { # this is the local authority server
 691         my @inner_sup_results_array;
 692         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 693             my $marc_record_object = C4::Search::new_record_from_zebra(
 694                 'authorityserver',
 695                 $sup_record
 696             );
 697             # warn "Authority Found: ".$marc_record_object->as_formatted();
 698             push @inner_sup_results_array, {
 699                 'title' => $marc_record_object->field(100)->subfield('a'),
 700                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 701             };
 702         }
 703         push @sup_results_array, {  servername => $server,
 704                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 705     }
 706     # FIXME: can add support for other targets as needed here
 707     $template->param(           outer_sup_results_loop => \@sup_results_array);
 708 } #/end of the for loop
 709 #$template->param(FEDERATED_RESULTS => \@results_array);
 710
 711 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 712
 713 my $gotonumber = $cgi->param('gotoNumber');
 714 if ($gotonumber eq 'last' || $gotonumber eq 'first') {
 715     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 716 }
 717 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 718 my $gotopage = $cgi->param('gotoPage');
 719 $template->{'VARS'}->{'gotoPage'} = $gotopage
 720   if $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 721
 722 for my $facet ( @$facets ) {
 723     for my $entry ( @{ $facet->{facets} } ) {
 724         my $index = $entry->{type_link_value};
 725         my $value = $entry->{facet_link_value};
 726         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 727     }
 728 }
 729
 730 $template->param(
 731             #classlist => $classlist,
 732             total => $total,
 733             opacfacets => 1,
 734             facets_loop => $facets,
 735             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 736             scan => $scan,
 737             search_error => $error,
 738 );
 739
 740 if ($query_desc || $limit_desc) {
 741     $template->param(searchdesc => 1);
 742 }
 743
 744 # VI. BUILD THE TEMPLATE
 745
 746 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 747     {
 748         borrowernumber => $borrowernumber,
 749         add_allowed    => 1,
 750         category       => 1,
 751     }
 752 );
 753 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 754     {
 755         borrowernumber => $borrowernumber,
 756         add_allowed    => 1,
 757         category       => 2,
 758     }
 759 );
 760
 761
 762 $template->param(
 763     add_to_some_private_shelves => $some_private_shelves,
 764     add_to_some_public_shelves  => $some_public_shelves,
 765 );
 766
 767 output_html_with_http_headers $cgi, $cookie, $template->output;