opac/opac-reserve.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Katipo Communications 2002
   4 # Copyright Koha Development team 2012
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24 use C4::Auth;    # checkauth, getborrowernumber.
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Output;
  31 use C4::Context;
  32 use C4::Members;
  33 use C4::Overdues;
  34 use C4::Debug;
  35
  36 use Koha::AuthorisedValues;
  37 use Koha::Biblios;
  38 use Koha::DateUtils;
  39 use Koha::IssuingRules;
  40 use Koha::Items;
  41 use Koha::ItemTypes;
  42 use Koha::Checkouts;
  43 use Koha::Libraries;
  44 use Koha::Patrons;
  45 use Date::Calc qw/Today Date_to_Days/;
  46 use List::MoreUtils qw/uniq/;
  47
  48 my $maxreserves = C4::Context->preference("maxreserves");
  49
  50 my $query = new CGI;
  51
  52 # if RequestOnOpac (for placing holds) is disabled, leave immediately
  53 if ( ! C4::Context->preference('RequestOnOpac') ) {
  54     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  55     exit;
  56 }
  57
  58 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  59     {
  60         template_name   => "opac-reserve.tt",
  61         query           => $query,
  62         type            => "opac",
  63         authnotrequired => 0,
  64         debug           => 1,
  65     }
  66 );
  67
  68 my ($show_holds_count, $show_priority);
  69 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  70     m/holds/o and $show_holds_count = 1;
  71     m/priority/ and $show_priority = 1;
  72 }
  73
  74 sub get_out {
  75         output_html_with_http_headers(shift,shift,shift); # $query, $cookie, $template->output;
  76         exit;
  77 }
  78
  79 my $patron = Koha::Patrons->find( $borrowernumber );
  80
  81 my $can_place_hold_if_available_at_pickup = C4::Context->preference('OPACHoldsIfAvailableAtPickup');
  82 unless ( $can_place_hold_if_available_at_pickup ) {
  83     my @patron_categories = split '\|', C4::Context->preference('OPACHoldsIfAvailableAtPickupExceptions');
  84     if ( @patron_categories ) {
  85         my $categorycode = $patron->categorycode;
  86         $can_place_hold_if_available_at_pickup = grep /^$categorycode$/, @patron_categories;
  87     }
  88 }
  89
  90 # check if this user can place a reserve, -1 means use sys pref, 0 means dont block, 1 means block
  91 if ( $patron->category->effective_BlockExpiredPatronOpacActions ) {
  92
  93     if ( $patron->is_expired ) {
  94
  95         # cannot reserve, their card has expired and the rules set mean this is not allowed
  96         $template->param( message => 1, expired_patron => 1 );
  97         get_out( $query, $cookie, $template->output );
  98     }
  99 }
 100
 101 # Pass through any reserve charge
 102 my $reservefee = $patron->category->reservefee;
 103 if ( $reservefee > 0){
 104     $template->param( RESERVE_CHARGE => sprintf("%.2f",$reservefee));
 105 }
 106
 107 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 108
 109 # There are two ways of calling this script, with a single biblio num
 110 # or multiple biblio nums.
 111 my $biblionumbers = $query->param('biblionumbers');
 112 my $reserveMode = $query->param('reserve_mode');
 113 if ($reserveMode && ($reserveMode eq 'single')) {
 114     my $bib = $query->param('single_bib');
 115     $biblionumbers = "$bib/";
 116 }
 117 if (! $biblionumbers) {
 118     $biblionumbers = $query->param('biblionumber');
 119 }
 120
 121 if ((! $biblionumbers) && (! $query->param('place_reserve'))) {
 122     $template->param(message=>1, no_biblionumber=>1);
 123     &get_out($query, $cookie, $template->output);
 124 }
 125
 126 # Pass the numbers to the page so they can be fed back
 127 # when the hold is confirmed. TODO: Not necessary?
 128 $template->param( biblionumbers => $biblionumbers );
 129
 130 # Each biblio number is suffixed with '/', e.g. "1/2/3/"
 131 my @biblionumbers = split /\//, $biblionumbers;
 132 if (($#biblionumbers < 0) && (! $query->param('place_reserve'))) {
 133     # TODO: New message?
 134     $template->param(message=>1, no_biblionumber=>1);
 135     &get_out($query, $cookie, $template->output);
 136 }
 137
 138
 139 # pass the pickup branch along....
 140 my $branch = $query->param('branch') || $patron->branchcode || C4::Context->userenv->{branch} || '' ;
 141 $template->param( branch => $branch );
 142
 143 #
 144 #
 145 # Build hashes of the requested biblio(item)s and items.
 146 #
 147 #
 148
 149 my %biblioDataHash; # Hash of biblionumber to biblio/biblioitems record.
 150 my %itemInfoHash; # Hash of itemnumber to item info.
 151 foreach my $biblioNumber (@biblionumbers) {
 152
 153     my $biblioData = GetBiblioData($biblioNumber);
 154     $biblioDataHash{$biblioNumber} = $biblioData;
 155
 156     my @itemInfos = GetItemsInfo($biblioNumber);
 157
 158     my $marcrecord= GetMarcBiblio({ biblionumber => $biblioNumber });
 159
 160     # flag indicating existence of at least one item linked via a host record
 161     my $hostitemsflag;
 162     # adding items linked via host biblios
 163     my @hostitemInfos = GetHostItemsInfo($marcrecord);
 164     if (@hostitemInfos){
 165         $hostitemsflag =1;
 166         push (@itemInfos,@hostitemInfos);
 167     }
 168
 169     $biblioData->{itemInfos} = \@itemInfos;
 170     foreach my $itemInfo (@itemInfos) {
 171         $itemInfoHash{$itemInfo->{itemnumber}} = $itemInfo;
 172     }
 173
 174     # Compute the priority rank.
 175     my $biblio = Koha::Biblios->find( $biblioNumber );
 176     my $holds = $biblio->holds;
 177     my $rank = $holds->count;
 178     $biblioData->{reservecount} = 1;    # new reserve
 179     while ( my $hold = $holds->next ) {
 180         if ( $hold->is_waiting ) {
 181             $rank--;
 182         }
 183         else {
 184             $biblioData->{reservecount}++;
 185         }
 186     }
 187     $biblioData->{rank} = $rank + 1;
 188 }
 189
 190 #
 191 #
 192 # If this is the second time through this script, it
 193 # means we are carrying out the hold request, possibly
 194 # with a specific item for each biblionumber.
 195 #
 196 #
 197 if ( $query->param('place_reserve') ) {
 198     my $reserve_cnt = 0;
 199     if ($maxreserves) {
 200         $reserve_cnt = $patron->holds->count;
 201     }
 202
 203     # List is composed of alternating biblio/item/branch
 204     my $selectedItems = $query->param('selecteditems');
 205
 206     if ($query->param('reserve_mode') eq 'single') {
 207         # This indicates non-JavaScript mode, so there was
 208         # only a single biblio number selected.
 209         my $bib = $query->param('single_bib');
 210         my $item = $query->param("checkitem_$bib");
 211         if ($item eq 'any') {
 212             $item = '';
 213         }
 214         my $branch = $query->param('branch');
 215         $selectedItems = "$bib/$item/$branch/";
 216     }
 217
 218     $selectedItems =~ s!/$!!;
 219     my @selectedItems = split /\//, $selectedItems, -1;
 220
 221     # Make sure there is a biblionum/itemnum/branch triplet for each item.
 222     # The itemnum can be 'any', meaning next available.
 223     my $selectionCount = @selectedItems;
 224     if (($selectionCount == 0) || (($selectionCount % 3) != 0)) {
 225         $template->param(message=>1, bad_data=>1);
 226         &get_out($query, $cookie, $template->output);
 227     }
 228
 229     my $failed_holds = 0;
 230     while (@selectedItems) {
 231         my $biblioNum = shift(@selectedItems);
 232         my $itemNum   = shift(@selectedItems);
 233         my $branch    = shift(@selectedItems);    # i.e., branch code, not name
 234
 235         my $canreserve = 0;
 236
 237         my $singleBranchMode = Koha::Libraries->search->count == 1;
 238         if ( $singleBranchMode || ! C4::Context->preference("OPACAllowUserToChooseBranch") )
 239         {    # single branch mode or disabled user choosing
 240             $branch = $patron->branchcode;
 241         }
 242
 243 #item may belong to a host biblio, if yes change biblioNum to hosts bilbionumber
 244         if ( $itemNum ne '' ) {
 245             my $item = Koha::Items->find( $itemNum );
 246             my $hostbiblioNum = $item->biblio->biblionumber;
 247             if ( $hostbiblioNum ne $biblioNum ) {
 248                 $biblioNum = $hostbiblioNum;
 249             }
 250         }
 251
 252         my $biblioData = $biblioDataHash{$biblioNum};
 253         my $found;
 254
 255         # Check for user supplied reserve date
 256         my $startdate;
 257         if (   C4::Context->preference('AllowHoldDateInFuture')
 258             && C4::Context->preference('OPACAllowHoldDateInFuture') )
 259         {
 260             $startdate = $query->param("reserve_date_$biblioNum");
 261         }
 262
 263         my $expiration_date = $query->param("expiration_date_$biblioNum");
 264
 265         my $rank = $biblioData->{rank};
 266         if ( $itemNum ne '' ) {
 267             $canreserve = 1 if CanItemBeReserved( $borrowernumber, $itemNum )->{status} eq 'OK';
 268         }
 269         else {
 270             $canreserve = 1 if CanBookBeReserved( $borrowernumber, $biblioNum )->{status} eq 'OK';
 271
 272             # Inserts a null into the 'itemnumber' field of 'reserves' table.
 273             $itemNum = undef;
 274         }
 275         my $notes = $query->param('notes_'.$biblioNum)||'';
 276
 277         if (   $maxreserves
 278             && $reserve_cnt >= $maxreserves )
 279         {
 280             $canreserve = 0;
 281         }
 282
 283         unless ( $can_place_hold_if_available_at_pickup ) {
 284             my $items_in_this_library = Koha::Items->search({ biblionumber => $biblioNum, holdingbranch => $branch });
 285             my $nb_of_items_issued = $items_in_this_library->search({ 'issue.itemnumber' => { not => undef }}, { join => 'issue' })->count;
 286             my $nb_of_items_unavailable = $items_in_this_library->search({ -or => { lost => { '!=' => 0 }, damaged => { '!=' => 0 }, } });
 287             if ( $items_in_this_library->count > $nb_of_items_issued + $nb_of_items_unavailable ) {
 288                 $canreserve = 0
 289             }
 290         }
 291
 292         my $itemtype = $query->param('itemtype') || undef;
 293         $itemtype = undef if $itemNum;
 294
 295         # Here we actually do the reserveration. Stage 3.
 296         if ($canreserve) {
 297             my $reserve_id = AddReserve(
 298                 $branch,          $borrowernumber, $biblioNum,
 299                 [$biblioNum],     $rank,           $startdate,
 300                 $expiration_date, $notes,          $biblioData->{title},
 301                 $itemNum,         $found,          $itemtype,
 302             );
 303             $failed_holds++ unless $reserve_id;
 304             ++$reserve_cnt;
 305         }
 306     }
 307
 308     print $query->redirect("/cgi-bin/koha/opac-user.pl?" . ( $failed_holds ? "failed_holds=$failed_holds" : q|| ) . "#opac-user-holds");
 309     exit;
 310 }
 311
 312 #
 313 #
 314 # Here we check that the borrower can actually make reserves Stage 1.
 315 #
 316 #
 317 my $noreserves     = 0;
 318 my $maxoutstanding = C4::Context->preference("maxoutstanding");
 319 $template->param( noreserve => 1 ) unless $maxoutstanding;
 320 my $amountoutstanding = $patron->account->balance;
 321 if ( $amountoutstanding && ($amountoutstanding > $maxoutstanding) ) {
 322     my $amount = sprintf "%.02f", $amountoutstanding;
 323     $template->param( message => 1 );
 324     $noreserves = 1;
 325     $template->param( too_much_oweing => $amount );
 326 }
 327
 328 if ( $patron->gonenoaddress && ($patron->gonenoaddress == 1) ) {
 329     $noreserves = 1;
 330     $template->param(
 331         message => 1,
 332         GNA     => 1
 333     );
 334 }
 335
 336 if ( $patron->lost && ($patron->lost == 1) ) {
 337     $noreserves = 1;
 338     $template->param(
 339         message => 1,
 340         lost    => 1
 341     );
 342 }
 343
 344 if ( $patron->is_debarred ) {
 345     $noreserves = 1;
 346     $template->param(
 347         message          => 1,
 348         debarred         => 1,
 349         debarred_comment => $patron->debarredcomment,
 350         debarred_date    => $patron->debarred,
 351     );
 352 }
 353
 354 my $holds = $patron->holds;
 355 my $reserves_count = $holds->count;
 356 $template->param( RESERVES => $holds->unblessed );
 357 if ( $maxreserves && ( $reserves_count >= $maxreserves ) ) {
 358     $template->param( message => 1 );
 359     $noreserves = 1;
 360     $template->param( too_many_reserves => $holds->count );
 361 }
 362
 363 unless ( $noreserves ) {
 364     my $requested_reserves_count = scalar( @biblionumbers );
 365     if ( $maxreserves && ( $reserves_count + $requested_reserves_count > $maxreserves ) ) {
 366         $template->param( new_reserves_allowed => $maxreserves - $reserves_count );
 367     }
 368 }
 369
 370 unless ($noreserves) {
 371     $template->param( select_item_types => 1 );
 372 }
 373
 374
 375 #
 376 #
 377 # Build the template parameters that will show the info
 378 # and items for each biblionumber.
 379 #
 380 #
 381
 382 my $biblioLoop = [];
 383 my $numBibsAvailable = 0;
 384 my $itemdata_enumchron = 0;
 385 my $itemdata_ccode = 0;
 386 my $anyholdable = 0;
 387 my $itemLevelTypes = C4::Context->preference('item-level_itypes');
 388 $template->param('item_level_itypes' => $itemLevelTypes);
 389
 390 foreach my $biblioNum (@biblionumbers) {
 391
 392     my @not_available_at = ();
 393     my $record = GetMarcBiblio({ biblionumber => $biblioNum });
 394     # Init the bib item with the choices for branch pickup
 395     my %biblioLoopIter;
 396
 397     # Get relevant biblio data.
 398     my $biblioData = $biblioDataHash{$biblioNum};
 399     if (! $biblioData) {
 400         $template->param(message=>1, bad_biblionumber=>$biblioNum);
 401         &get_out($query, $cookie, $template->output);
 402     }
 403
 404     my $frameworkcode = GetFrameworkCode( $biblioData->{biblionumber} );
 405     $biblioLoopIter{biblionumber} = $biblioData->{biblionumber};
 406     $biblioLoopIter{title} = $biblioData->{title};
 407     $biblioLoopIter{subtitle} = GetRecordValue('subtitle', $record, $frameworkcode);
 408     $biblioLoopIter{author} = $biblioData->{author};
 409     $biblioLoopIter{rank} = $biblioData->{rank};
 410     $biblioLoopIter{reservecount} = $biblioData->{reservecount};
 411     $biblioLoopIter{already_reserved} = $biblioData->{already_reserved};
 412     $biblioLoopIter{reqholdnotes}=0; #TODO: For future use
 413
 414     if (!$itemLevelTypes && $biblioData->{itemtype}) {
 415         $biblioLoopIter{translated_description} = $itemtypes->{$biblioData->{itemtype}}{translated_description};
 416         $biblioLoopIter{imageurl} = getitemtypeimagesrc() . "/". $itemtypes->{$biblioData->{itemtype}}{imageurl};
 417     }
 418
 419     foreach my $itemInfo (@{$biblioData->{itemInfos}}) {
 420         if ($itemLevelTypes && $itemInfo->{itype}) {
 421             $itemInfo->{translated_description} = $itemtypes->{$itemInfo->{itype}}{translated_description};
 422             $itemInfo->{imageurl} = getitemtypeimagesrc() . "/". $itemtypes->{$itemInfo->{itype}}{imageurl};
 423         }
 424
 425         if (!$itemInfo->{'notforloan'} && !($itemInfo->{'itemnotforloan'} > 0)) {
 426             $biblioLoopIter{forloan} = 1;
 427         }
 428     }
 429
 430     my @notforloan_avs = Koha::AuthorisedValues->search_by_koha_field({ kohafield => 'items.notforloan', frameworkcode => $frameworkcode });
 431     my $notforloan_label_of = { map { $_->authorised_value => $_->opac_description } @notforloan_avs };
 432
 433     $biblioLoopIter{itemLoop} = [];
 434     my $numCopiesAvailable = 0;
 435     my $numCopiesOPACAvailable = 0;
 436     foreach my $itemInfo (@{$biblioData->{itemInfos}}) {
 437         my $itemNum = $itemInfo->{itemnumber};
 438         my $item = Koha::Items->find( $itemNum );
 439         my $itemLoopIter = {};
 440
 441         $itemLoopIter->{itemnumber} = $itemNum;
 442         $itemLoopIter->{barcode} = $itemInfo->{barcode};
 443         $itemLoopIter->{homeBranchName} = $itemInfo->{homebranch};
 444         $itemLoopIter->{callNumber} = $itemInfo->{itemcallnumber};
 445         $itemLoopIter->{enumchron} = $itemInfo->{enumchron};
 446         $itemLoopIter->{ccode} = $itemInfo->{ccode};
 447         $itemLoopIter->{copynumber} = $itemInfo->{copynumber};
 448         if ($itemLevelTypes) {
 449             $itemLoopIter->{translated_description} = $itemInfo->{translated_description};
 450             $itemLoopIter->{itype} = $itemInfo->{itype};
 451             $itemLoopIter->{imageurl} = $itemInfo->{imageurl};
 452         }
 453
 454         # If the holdingbranch is different than the homebranch, we show the
 455         # holdingbranch of the document too.
 456         if ( $itemInfo->{homebranch} ne $itemInfo->{holdingbranch} ) {
 457             $itemLoopIter->{holdingBranchName} = $itemInfo->{holdingbranch};
 458         }
 459
 460         # If the item is currently on loan, we display its return date and
 461         # change the background color.
 462         my $issue = Koha::Checkouts->find( { itemnumber => $itemNum } );
 463         if ( $issue ) {
 464             $itemLoopIter->{dateDue} = output_pref({ dt => dt_from_string($issue->date_due, 'sql'), as_due_date => 1 });
 465             $itemLoopIter->{backgroundcolor} = 'onloan';
 466         }
 467
 468         # checking reserve
 469         my $holds = $item->current_holds;
 470
 471         if ( my $first_hold = $holds->next ) {
 472             $itemLoopIter->{backgroundcolor} = 'reserved';
 473             $itemLoopIter->{reservedate}     = output_pref({ dt => dt_from_string($first_hold->reservedate), dateonly => 1 }); # FIXME Should be formatted in the template
 474             $itemLoopIter->{ExpectedAtLibrary}         = $first_hold->branchcode;
 475             $itemLoopIter->{waitingdate} = $first_hold->waitingdate;
 476         }
 477
 478         $itemLoopIter->{notforloan} = $itemInfo->{notforloan};
 479         $itemLoopIter->{itemnotforloan} = $itemInfo->{itemnotforloan};
 480
 481         # Management of the notforloan document
 482         if ( $itemLoopIter->{notforloan} || $itemLoopIter->{itemnotforloan}) {
 483             $itemLoopIter->{backgroundcolor} = 'other';
 484             $itemLoopIter->{notforloanvalue} =
 485               $notforloan_label_of->{ $itemLoopIter->{notforloan} };
 486         }
 487
 488         # Management of lost or long overdue items
 489         if ( $itemInfo->{itemlost} ) {
 490
 491             # FIXME localized strings should never be in Perl code
 492             $itemLoopIter->{message} =
 493                 $itemInfo->{itemlost} == 1 ? "(lost)"
 494               : $itemInfo->{itemlost} == 2 ? "(long overdue)"
 495               : "";
 496             $itemInfo->{backgroundcolor} = 'other';
 497         }
 498
 499         # Check of the transferred documents
 500         my ( $transfertwhen, $transfertfrom, $transfertto ) =
 501           GetTransfers($itemNum);
 502         if ( $transfertwhen && ($transfertwhen ne '') ) {
 503             $itemLoopIter->{transfertwhen} = output_pref({ dt => dt_from_string($transfertwhen), dateonly => 1 });
 504             $itemLoopIter->{transfertfrom} = $transfertfrom;
 505             $itemLoopIter->{transfertto} = $transfertto;
 506             $itemLoopIter->{nocancel} = 1;
 507         }
 508
 509         # if the items belongs to a host record, show link to host record
 510         if ( $itemInfo->{biblionumber} ne $biblioNum ) {
 511             $biblioLoopIter{hostitemsflag}    = 1;
 512             $itemLoopIter->{hostbiblionumber} = $itemInfo->{biblionumber};
 513             $itemLoopIter->{hosttitle}        = Koha::Biblios->find( $itemInfo->{biblionumber} )->title;
 514         }
 515
 516         # If there is no loan, return and transfer, we show a checkbox.
 517         $itemLoopIter->{notforloan} = $itemLoopIter->{notforloan} || 0;
 518
 519         my $patron_unblessed = $patron->unblessed;
 520         my $branch = GetReservesControlBranch( $itemInfo, $patron_unblessed );
 521
 522         my $policy_holdallowed = !$itemLoopIter->{already_reserved};
 523         $policy_holdallowed &&=
 524             IsAvailableForItemLevelRequest($itemInfo,$patron_unblessed) &&
 525             CanItemBeReserved( $borrowernumber, $itemNum )->{status} eq 'OK';
 526
 527         if ($policy_holdallowed) {
 528             my $opac_hold_policy = Koha::IssuingRules->get_opacitemholds_policy( { item => $item, patron => $patron } );
 529             if ( $opac_hold_policy ne 'N' ) { # If Y or F
 530                 $itemLoopIter->{available} = 1;
 531                 $numCopiesOPACAvailable++;
 532                 $biblioLoopIter{force_hold} = 1 if $opac_hold_policy eq 'F';
 533             }
 534             $numCopiesAvailable++;
 535
 536             unless ( $can_place_hold_if_available_at_pickup ) {
 537                 my $items_in_this_library = Koha::Items->search({ biblionumber => $itemInfo->{biblionumber}, holdingbranch => $itemInfo->{holdingbranch} });
 538                 my $nb_of_items_issued = $items_in_this_library->search({ 'issue.itemnumber' => { not => undef }}, { join => 'issue' })->count;
 539                 if ( $items_in_this_library->count > $nb_of_items_issued ) {
 540                     push @not_available_at, $itemInfo->{holdingbranch};
 541                 }
 542             }
 543         }
 544
 545         $itemLoopIter->{imageurl} = getitemtypeimagelocation( 'opac', $itemtypes->{ $itemInfo->{itype} }{imageurl} );
 546
 547     # Show serial enumeration when needed
 548         if ($itemLoopIter->{enumchron}) {
 549             $itemdata_enumchron = 1;
 550         }
 551     # Show collection when needed
 552         if ($itemLoopIter->{ccode}) {
 553             $itemdata_ccode = 1;
 554         }
 555
 556         push @{$biblioLoopIter{itemLoop}}, $itemLoopIter;
 557     }
 558     $template->param(
 559         itemdata_enumchron => $itemdata_enumchron,
 560         itemdata_ccode     => $itemdata_ccode,
 561     );
 562
 563     if ($numCopiesAvailable > 0) {
 564         $numBibsAvailable++;
 565         $biblioLoopIter{bib_available} = 1;
 566         $biblioLoopIter{holdable} = 1;
 567         $biblioLoopIter{itemholdable} = 1 if $numCopiesOPACAvailable;
 568     }
 569     if ($biblioLoopIter{already_reserved}) {
 570         $biblioLoopIter{holdable} = undef;
 571         $biblioLoopIter{itemholdable} = undef;
 572     }
 573     if(not C4::Context->preference('AllowHoldsOnPatronsPossessions') and CheckIfIssuedToPatron($borrowernumber,$biblioNum)) {
 574         $biblioLoopIter{holdable} = undef;
 575         $biblioLoopIter{already_patron_possession} = 1;
 576     }
 577
 578     if ( $biblioLoopIter{holdable} ) {
 579         @not_available_at = uniq @not_available_at;
 580         $biblioLoopIter{not_available_at} = \@not_available_at ;
 581     }
 582
 583     unless ( $can_place_hold_if_available_at_pickup ) {
 584         @not_available_at = uniq @not_available_at;
 585         $biblioLoopIter{not_available_at} = \@not_available_at ;
 586         # The record is not holdable is not available at any of the libraries
 587         if ( Koha::Libraries->search->count == @not_available_at ) {
 588             $biblioLoopIter{holdable} = 0;
 589         }
 590     }
 591
 592     $biblioLoopIter{holdable} &&= CanBookBeReserved( $borrowernumber, $biblioNum )->{status} eq 'OK';
 593
 594     # For multiple holds per record, if a patron has previously placed a hold,
 595     # the patron can only place more holds of the same type. That is, if the
 596     # patron placed a record level hold, all the holds the patron places must
 597     # be record level. If the patron placed an item level hold, all holds
 598     # the patron places must be item level
 599     my $forced_hold_level = Koha::Holds->search(
 600         {
 601             borrowernumber => $borrowernumber,
 602             biblionumber   => $biblioNum,
 603             found          => undef,
 604         }
 605     )->forced_hold_level();
 606     if ($forced_hold_level) {
 607         $biblioLoopIter{force_hold}   = 1 if $forced_hold_level eq 'item';
 608         $biblioLoopIter{itemholdable} = 0 if $forced_hold_level eq 'record';
 609     }
 610
 611
 612     push @$biblioLoop, \%biblioLoopIter;
 613
 614     $anyholdable = 1 if $biblioLoopIter{holdable};
 615 }
 616
 617
 618 if ( $numBibsAvailable == 0 || $anyholdable == 0) {
 619     $template->param( none_available => 1 );
 620 }
 621
 622 if (scalar @biblionumbers > 1) {
 623     $template->param( multi_hold => 1);
 624 }
 625
 626 my $show_notes=C4::Context->preference('OpacHoldNotes');
 627 $template->param(OpacHoldNotes=>$show_notes);
 628
 629 # display infos
 630 $template->param(bibitemloop => $biblioLoop);
 631 # can set reserve date in future
 632 if (
 633     C4::Context->preference( 'AllowHoldDateInFuture' ) &&
 634     C4::Context->preference( 'OPACAllowHoldDateInFuture' )
 635     ) {
 636     $template->param(
 637             reserve_in_future         => 1,
 638     );
 639 }
 640
 641 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };