C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use DateTime;
  25 use Koha::DateUtils;
  26 use C4::Context;
  27 use C4::Stats;
  28 use C4::Reserves;
  29 use C4::Biblio;
  30 use C4::Items;
  31 use C4::Members;
  32 use C4::Accounts;
  33 use C4::ItemCirculationAlertPreference;
  34 use C4::Message;
  35 use C4::Debug;
  36 use C4::Log; # logaction
  37 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  38 use C4::RotatingCollections qw(GetCollectionItemBranches);
  39 use Algorithm::CheckDigits;
  40
  41 use Data::Dumper;
  42 use Koha::Account;
  43 use Koha::AuthorisedValues;
  44 use Koha::Biblioitems;
  45 use Koha::DateUtils;
  46 use Koha::Calendar;
  47 use Koha::Checkouts;
  48 use Koha::IssuingRules;
  49 use Koha::Items;
  50 use Koha::Patrons;
  51 use Koha::Patron::Debarments;
  52 use Koha::Database;
  53 use Koha::Libraries;
  54 use Koha::Holds;
  55 use Koha::RefundLostItemFeeRule;
  56 use Koha::RefundLostItemFeeRules;
  57 use Carp;
  58 use List::MoreUtils qw( uniq );
  59 use Scalar::Util qw( looks_like_number );
  60 use Date::Calc qw(
  61   Today
  62   Today_and_Now
  63   Add_Delta_YM
  64   Add_Delta_DHMS
  65   Date_to_Days
  66   Day_of_Week
  67   Add_Delta_Days
  68 );
  69 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  70
  71 BEGIN {
  72         require Exporter;
  73         @ISA    = qw(Exporter);
  74
  75         # FIXME subs that should probably be elsewhere
  76         push @EXPORT, qw(
  77                 &barcodedecode
  78         &LostItem
  79         &ReturnLostItem
  80         &GetPendingOnSiteCheckouts
  81         );
  82
  83         # subs to deal with issuing a book
  84         push @EXPORT, qw(
  85                 &CanBookBeIssued
  86                 &CanBookBeRenewed
  87                 &AddIssue
  88                 &AddRenewal
  89                 &GetRenewCount
  90         &GetSoonestRenewDate
  91         &GetLatestAutoRenewDate
  92                 &GetItemIssue
  93                 &GetIssuingCharges
  94         &GetBranchBorrowerCircRule
  95         &GetBranchItemRule
  96                 &GetBiblioIssues
  97                 &GetOpenIssue
  98         &CheckIfIssuedToPatron
  99         &IsItemIssued
 100         GetTopIssues
 101         );
 102
 103         # subs to deal with returns
 104         push @EXPORT, qw(
 105                 &AddReturn
 106         &MarkIssueReturned
 107         );
 108
 109         # subs to deal with transfers
 110         push @EXPORT, qw(
 111                 &transferbook
 112                 &GetTransfers
 113                 &GetTransfersFromTo
 114                 &updateWrongTransfer
 115                 &DeleteTransfer
 116                 &IsBranchTransferAllowed
 117                 &CreateBranchTransferLimit
 118                 &DeleteBranchTransferLimits
 119         &TransferSlip
 120         );
 121
 122     # subs to deal with offline circulation
 123     push @EXPORT, qw(
 124       &GetOfflineOperations
 125       &GetOfflineOperation
 126       &AddOfflineOperation
 127       &DeleteOfflineOperation
 128       &ProcessOfflineOperation
 129     );
 130 }
 131
 132 =head1 NAME
 133
 134 C4::Circulation - Koha circulation module
 135
 136 =head1 SYNOPSIS
 137
 138 use C4::Circulation;
 139
 140 =head1 DESCRIPTION
 141
 142 The functions in this module deal with circulation, issues, and
 143 returns, as well as general information about the library.
 144 Also deals with inventory.
 145
 146 =head1 FUNCTIONS
 147
 148 =head2 barcodedecode
 149
 150   $str = &barcodedecode($barcode, [$filter]);
 151
 152 Generic filter function for barcode string.
 153 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 154 Will do some manipulation of the barcode for systems that deliver a barcode
 155 to circulation.pl that differs from the barcode stored for the item.
 156 For proper functioning of this filter, calling the function on the
 157 correct barcode string (items.barcode) should return an unaltered barcode.
 158
 159 The optional $filter argument is to allow for testing or explicit
 160 behavior that ignores the System Pref.  Valid values are the same as the
 161 System Pref options.
 162
 163 =cut
 164
 165 # FIXME -- the &decode fcn below should be wrapped into this one.
 166 # FIXME -- these plugins should be moved out of Circulation.pm
 167 #
 168 sub barcodedecode {
 169     my ($barcode, $filter) = @_;
 170     my $branch = C4::Context::mybranch();
 171     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 172     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 173         if ($filter eq 'whitespace') {
 174                 $barcode =~ s/\s//g;
 175         } elsif ($filter eq 'cuecat') {
 176                 chomp($barcode);
 177             my @fields = split( /\./, $barcode );
 178             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 179             ($#results == 2) and return $results[2];
 180         } elsif ($filter eq 'T-prefix') {
 181                 if ($barcode =~ /^[Tt](\d)/) {
 182                         (defined($1) and $1 eq '0') and return $barcode;
 183             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 184                 }
 185         return sprintf("T%07d", $barcode);
 186         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 187         # Why drop the nonzero digit after the T?
 188         # Why pass non-digits (or empty string) to "T%07d"?
 189         } elsif ($filter eq 'libsuite8') {
 190                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 191                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 192                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 193                         }else{
 194                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 195                         }
 196                 }
 197     } elsif ($filter eq 'EAN13') {
 198         my $ean = CheckDigits('ean');
 199         if ( $ean->is_valid($barcode) ) {
 200             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 201             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 202         } else {
 203             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 204         }
 205         }
 206     return $barcode;    # return barcode, modified or not
 207 }
 208
 209 =head2 decode
 210
 211   $str = &decode($chunk);
 212
 213 Decodes a segment of a string emitted by a CueCat barcode scanner and
 214 returns it.
 215
 216 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 217 or Javascript based decoding on the client side.
 218
 219 =cut
 220
 221 sub decode {
 222     my ($encoded) = @_;
 223     my $seq =
 224       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 225     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 226     my $l = ( $#s + 1 ) % 4;
 227     if ($l) {
 228         if ( $l == 1 ) {
 229             # warn "Error: Cuecat decode parsing failed!";
 230             return;
 231         }
 232         $l = 4 - $l;
 233         $#s += $l;
 234     }
 235     my $r = '';
 236     while ( $#s >= 0 ) {
 237         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 238         $r .=
 239             chr( ( $n >> 16 ) ^ 67 )
 240          .chr( ( $n >> 8 & 255 ) ^ 67 )
 241          .chr( ( $n & 255 ) ^ 67 );
 242         @s = @s[ 4 .. $#s ];
 243     }
 244     $r = substr( $r, 0, length($r) - $l );
 245     return $r;
 246 }
 247
 248 =head2 transferbook
 249
 250   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 251                                             $barcode, $ignore_reserves);
 252
 253 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 254
 255 C<$newbranch> is the code for the branch to which the item should be transferred.
 256
 257 C<$barcode> is the barcode of the item to be transferred.
 258
 259 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 260 Otherwise, if an item is reserved, the transfer fails.
 261
 262 Returns three values:
 263
 264 =over
 265
 266 =item $dotransfer
 267
 268 is true if the transfer was successful.
 269
 270 =item $messages
 271
 272 is a reference-to-hash which may have any of the following keys:
 273
 274 =over
 275
 276 =item C<BadBarcode>
 277
 278 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 279
 280 =item C<IsPermanent>
 281
 282 The item's home branch is permanent. This doesn't prevent the item from being transferred, though. The value is the code of the item's home branch.
 283
 284 =item C<DestinationEqualsHolding>
 285
 286 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 287
 288 =item C<WasReturned>
 289
 290 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 291
 292 =item C<ResFound>
 293
 294 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 295
 296 =item C<WasTransferred>
 297
 298 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 299
 300 =back
 301
 302 =back
 303
 304 =cut
 305
 306 sub transferbook {
 307     my ( $tbr, $barcode, $ignoreRs ) = @_;
 308     my $messages;
 309     my $dotransfer      = 1;
 310     my $itemnumber = GetItemnumberFromBarcode( $barcode );
 311     my $issue      = GetItemIssue($itemnumber);
 312     my $biblio = GetBiblioFromItemNumber($itemnumber);
 313
 314     # bad barcode..
 315     if ( not $itemnumber ) {
 316         $messages->{'BadBarcode'} = $barcode;
 317         $dotransfer = 0;
 318     }
 319
 320     # get branches of book...
 321     my $hbr = $biblio->{'homebranch'};
 322     my $fbr = $biblio->{'holdingbranch'};
 323
 324     # if using Branch Transfer Limits
 325     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 326         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 327             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $biblio->{'itype'} ) ) {
 328                 $messages->{'NotAllowed'} = $tbr . "::" . $biblio->{'itype'};
 329                 $dotransfer = 0;
 330             }
 331         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $biblio->{ C4::Context->preference("BranchTransferLimitsType") } ) ) {
 332             $messages->{'NotAllowed'} = $tbr . "::" . $biblio->{ C4::Context->preference("BranchTransferLimitsType") };
 333             $dotransfer = 0;
 334         }
 335     }
 336
 337     # if is permanent...
 338     # FIXME Is this still used by someone?
 339     # See other FIXME in AddReturn
 340     my $library = Koha::Libraries->find($hbr);
 341     if ( $library and $library->get_categories->search({'me.categorycode' => 'PE'})->count ) {
 342         $messages->{'IsPermanent'} = $hbr;
 343         $dotransfer = 0;
 344     }
 345
 346     # can't transfer book if is already there....
 347     if ( $fbr eq $tbr ) {
 348         $messages->{'DestinationEqualsHolding'} = 1;
 349         $dotransfer = 0;
 350     }
 351
 352     # check if it is still issued to someone, return it...
 353     if ($issue->{borrowernumber}) {
 354         AddReturn( $barcode, $fbr );
 355         $messages->{'WasReturned'} = $issue->{borrowernumber};
 356     }
 357
 358     # find reserves.....
 359     # That'll save a database query.
 360     my ( $resfound, $resrec, undef ) =
 361       CheckReserves( $itemnumber );
 362     if ( $resfound and not $ignoreRs ) {
 363         $resrec->{'ResFound'} = $resfound;
 364
 365         #         $messages->{'ResFound'} = $resrec;
 366         $dotransfer = 1;
 367     }
 368
 369     #actually do the transfer....
 370     if ($dotransfer) {
 371         ModItemTransfer( $itemnumber, $fbr, $tbr );
 372
 373         # don't need to update MARC anymore, we do it in batch now
 374         $messages->{'WasTransfered'} = 1;
 375
 376     }
 377     ModDateLastSeen( $itemnumber );
 378     return ( $dotransfer, $messages, $biblio );
 379 }
 380
 381
 382 sub TooMany {
 383     my $borrower        = shift;
 384     my $biblionumber = shift;
 385         my $item                = shift;
 386     my $params = shift;
 387     my $onsite_checkout = $params->{onsite_checkout} || 0;
 388     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 389     my $cat_borrower    = $borrower->{'categorycode'};
 390     my $dbh             = C4::Context->dbh;
 391         my $branch;
 392         # Get which branchcode we need
 393         $branch = _GetCircControlBranch($item,$borrower);
 394         my $type = (C4::Context->preference('item-level_itypes'))
 395                         ? $item->{'itype'}         # item-level
 396                         : $item->{'itemtype'};     # biblio-level
 397
 398     # given branch, patron category, and item type, determine
 399     # applicable issuing rule
 400     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
 401         {   categorycode => $cat_borrower,
 402             itemtype     => $type,
 403             branchcode   => $branch
 404         }
 405     );
 406
 407
 408     # if a rule is found and has a loan limit set, count
 409     # how many loans the patron already has that meet that
 410     # rule
 411     if (defined($issuing_rule) and defined($issuing_rule->maxissueqty)) {
 412         my @bind_params;
 413         my $count_query = q|
 414             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 415             FROM issues
 416             JOIN items USING (itemnumber)
 417         |;
 418
 419         my $rule_itemtype = $issuing_rule->itemtype;
 420         if ($rule_itemtype eq "*") {
 421             # matching rule has the default item type, so count only
 422             # those existing loans that don't fall under a more
 423             # specific rule
 424             if (C4::Context->preference('item-level_itypes')) {
 425                 $count_query .= " WHERE items.itype NOT IN (
 426                                     SELECT itemtype FROM issuingrules
 427                                     WHERE branchcode = ?
 428                                     AND   (categorycode = ? OR categorycode = ?)
 429                                     AND   itemtype <> '*'
 430                                   ) ";
 431             } else {
 432                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 433                                   WHERE biblioitems.itemtype NOT IN (
 434                                     SELECT itemtype FROM issuingrules
 435                                     WHERE branchcode = ?
 436                                     AND   (categorycode = ? OR categorycode = ?)
 437                                     AND   itemtype <> '*'
 438                                   ) ";
 439             }
 440             push @bind_params, $issuing_rule->branchcode;
 441             push @bind_params, $issuing_rule->categorycode;
 442             push @bind_params, $cat_borrower;
 443         } else {
 444             # rule has specific item type, so count loans of that
 445             # specific item type
 446             if (C4::Context->preference('item-level_itypes')) {
 447                 $count_query .= " WHERE items.itype = ? ";
 448             } else {
 449                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 450                                   WHERE biblioitems.itemtype= ? ";
 451             }
 452             push @bind_params, $type;
 453         }
 454
 455         $count_query .= " AND borrowernumber = ? ";
 456         push @bind_params, $borrower->{'borrowernumber'};
 457         my $rule_branch = $issuing_rule->branchcode;
 458         if ($rule_branch ne "*") {
 459             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 460                 $count_query .= " AND issues.branchcode = ? ";
 461                 push @bind_params, $branch;
 462             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 463                 ; # if branch is the patron's home branch, then count all loans by patron
 464             } else {
 465                 $count_query .= " AND items.homebranch = ? ";
 466                 push @bind_params, $branch;
 467             }
 468         }
 469
 470         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 471
 472         my $max_checkouts_allowed = $issuing_rule->maxissueqty;
 473         my $max_onsite_checkouts_allowed = $issuing_rule->maxonsiteissueqty;
 474
 475         if ( $onsite_checkout ) {
 476             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 477                 return {
 478                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 479                     count => $onsite_checkout_count,
 480                     max_allowed => $max_onsite_checkouts_allowed,
 481                 }
 482             }
 483         }
 484         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 485             my $delta = $switch_onsite_checkout ? 1 : 0;
 486             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 487                 return {
 488                     reason => 'TOO_MANY_CHECKOUTS',
 489                     count => $checkout_count,
 490                     max_allowed => $max_checkouts_allowed,
 491                 };
 492             }
 493         } elsif ( not $onsite_checkout ) {
 494             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 495                 return {
 496                     reason => 'TOO_MANY_CHECKOUTS',
 497                     count => $checkout_count - $onsite_checkout_count,
 498                     max_allowed => $max_checkouts_allowed,
 499                 };
 500             }
 501         }
 502     }
 503
 504     # Now count total loans against the limit for the branch
 505     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 506     if (defined($branch_borrower_circ_rule->{maxissueqty})) {
 507         my @bind_params = ();
 508         my $branch_count_query = q|
 509             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 510             FROM issues
 511             JOIN items USING (itemnumber)
 512             WHERE borrowernumber = ?
 513         |;
 514         push @bind_params, $borrower->{borrowernumber};
 515
 516         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 517             $branch_count_query .= " AND issues.branchcode = ? ";
 518             push @bind_params, $branch;
 519         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 520             ; # if branch is the patron's home branch, then count all loans by patron
 521         } else {
 522             $branch_count_query .= " AND items.homebranch = ? ";
 523             push @bind_params, $branch;
 524         }
 525         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 526         my $max_checkouts_allowed = $branch_borrower_circ_rule->{maxissueqty};
 527         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{maxonsiteissueqty};
 528
 529         if ( $onsite_checkout ) {
 530             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 531                 return {
 532                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 533                     count => $onsite_checkout_count,
 534                     max_allowed => $max_onsite_checkouts_allowed,
 535                 }
 536             }
 537         }
 538         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 539             my $delta = $switch_onsite_checkout ? 1 : 0;
 540             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 541                 return {
 542                     reason => 'TOO_MANY_CHECKOUTS',
 543                     count => $checkout_count,
 544                     max_allowed => $max_checkouts_allowed,
 545                 };
 546             }
 547         } elsif ( not $onsite_checkout ) {
 548             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 549                 return {
 550                     reason => 'TOO_MANY_CHECKOUTS',
 551                     count => $checkout_count - $onsite_checkout_count,
 552                     max_allowed => $max_checkouts_allowed,
 553                 };
 554             }
 555         }
 556     }
 557
 558     if ( not defined( $issuing_rule ) and not defined($branch_borrower_circ_rule->{maxissueqty}) ) {
 559         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 560     }
 561
 562     # OK, the patron can issue !!!
 563     return;
 564 }
 565
 566 =head2 CanBookBeIssued
 567
 568   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $borrower,
 569                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 570
 571 Check if a book can be issued.
 572
 573 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 574
 575 IMPORTANT: The assumption by users of this routine is that causes blocking
 576 the issue are keyed by uppercase labels and other returned
 577 data is keyed in lower case!
 578
 579 =over 4
 580
 581 =item C<$borrower> hash with borrower informations (from GetMember)
 582
 583 =item C<$barcode> is the bar code of the book being issued.
 584
 585 =item C<$duedates> is a DateTime object.
 586
 587 =item C<$inprocess> boolean switch
 588
 589 =item C<$ignore_reserves> boolean switch
 590
 591 =item C<$params> Hashref of additional parameters
 592
 593 Available keys:
 594     override_high_holds - Ignore high holds
 595     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 596
 597 =back
 598
 599 Returns :
 600
 601 =over 4
 602
 603 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 604 Possible values are :
 605
 606 =back
 607
 608 =head3 INVALID_DATE
 609
 610 sticky due date is invalid
 611
 612 =head3 GNA
 613
 614 borrower gone with no address
 615
 616 =head3 CARD_LOST
 617
 618 borrower declared it's card lost
 619
 620 =head3 DEBARRED
 621
 622 borrower debarred
 623
 624 =head3 UNKNOWN_BARCODE
 625
 626 barcode unknown
 627
 628 =head3 NOT_FOR_LOAN
 629
 630 item is not for loan
 631
 632 =head3 WTHDRAWN
 633
 634 item withdrawn.
 635
 636 =head3 RESTRICTED
 637
 638 item is restricted (set by ??)
 639
 640 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 641 could be prevented, but ones that can be overriden by the operator.
 642
 643 Possible values are :
 644
 645 =head3 DEBT
 646
 647 borrower has debts.
 648
 649 =head3 RENEW_ISSUE
 650
 651 renewing, not issuing
 652
 653 =head3 ISSUED_TO_ANOTHER
 654
 655 issued to someone else.
 656
 657 =head3 RESERVED
 658
 659 reserved for someone else.
 660
 661 =head3 INVALID_DATE
 662
 663 sticky due date is invalid or due date in the past
 664
 665 =head3 TOO_MANY
 666
 667 if the borrower borrows to much things
 668
 669 =cut
 670
 671 sub CanBookBeIssued {
 672     my ( $borrower, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 673     my %needsconfirmation;    # filled with problems that needs confirmations
 674     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 675     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 676     my %messages;             # filled with information messages that should be displayed.
 677
 678     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 679     my $override_high_holds = $params->{override_high_holds} || 0;
 680
 681     my $item = GetItem(GetItemnumberFromBarcode( $barcode ));
 682     my $issue = GetItemIssue($item->{itemnumber});
 683         my $biblioitem = GetBiblioItemData($item->{biblioitemnumber});
 684         $item->{'itemtype'}=$item->{'itype'};
 685     my $dbh             = C4::Context->dbh;
 686
 687     # MANDATORY CHECKS - unless item exists, nothing else matters
 688     unless ( $item->{barcode} ) {
 689         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 690     }
 691         return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 692
 693     #
 694     # DUE DATE is OK ? -- should already have checked.
 695     #
 696     if ($duedate && ref $duedate ne 'DateTime') {
 697         $duedate = dt_from_string($duedate);
 698     }
 699     my $now = DateTime->now( time_zone => C4::Context->tz() );
 700     unless ( $duedate ) {
 701         my $issuedate = $now->clone();
 702
 703         my $branch = _GetCircControlBranch($item,$borrower);
 704         my $itype = ( C4::Context->preference('item-level_itypes') ) ? $item->{'itype'} : $biblioitem->{'itemtype'};
 705         $duedate = CalcDateDue( $issuedate, $itype, $branch, $borrower );
 706
 707         # Offline circ calls AddIssue directly, doesn't run through here
 708         #  So issuingimpossible should be ok.
 709     }
 710     if ($duedate) {
 711         my $today = $now->clone();
 712         $today->truncate( to => 'minute');
 713         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 714             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 715         }
 716     } else {
 717             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 718     }
 719
 720     #
 721     # BORROWER STATUS
 722     #
 723     if ( $borrower->{'category_type'} eq 'X' && (  $item->{barcode}  )) {
 724         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 725         &UpdateStats({
 726                      branch => C4::Context->userenv->{'branch'},
 727                      type => 'localuse',
 728                      itemnumber => $item->{'itemnumber'},
 729                      itemtype => $item->{'itype'},
 730                      borrowernumber => $borrower->{'borrowernumber'},
 731                      ccode => $item->{'ccode'}}
 732                     );
 733         ModDateLastSeen( $item->{'itemnumber'} );
 734         return( { STATS => 1 }, {});
 735     }
 736
 737     my $flags = C4::Members::patronflags( $borrower );
 738     if ( ref $flags ) {
 739         if ( $flags->{GNA} ) {
 740             $issuingimpossible{GNA} = 1;
 741         }
 742         if ( $flags->{'LOST'} ) {
 743             $issuingimpossible{CARD_LOST} = 1;
 744         }
 745         if ( $flags->{'DBARRED'} ) {
 746             $issuingimpossible{DEBARRED} = 1;
 747         }
 748     }
 749     if ( !defined $borrower->{dateexpiry} || $borrower->{'dateexpiry'} eq '0000-00-00') {
 750         $issuingimpossible{EXPIRED} = 1;
 751     } else {
 752         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'sql', 'floating' );
 753         $expiry_dt->truncate( to => 'day');
 754         my $today = $now->clone()->truncate(to => 'day');
 755         $today->set_time_zone( 'floating' );
 756         if ( DateTime->compare($today, $expiry_dt) == 1 ) {
 757             $issuingimpossible{EXPIRED} = 1;
 758         }
 759     }
 760
 761     #
 762     # BORROWER STATUS
 763     #
 764
 765     # DEBTS
 766     my ($balance, $non_issue_charges, $other_charges) =
 767       C4::Members::GetMemberAccountBalance( $borrower->{'borrowernumber'} );
 768
 769     my $amountlimit = C4::Context->preference("noissuescharge");
 770     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 771     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 772
 773     # Check the debt of this patrons guarantees
 774     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 775     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 776     if ( defined $no_issues_charge_guarantees ) {
 777         my $p = Koha::Patrons->find( $borrower->{borrowernumber} );
 778         my @guarantees = $p->guarantees();
 779         my $guarantees_non_issues_charges;
 780         foreach my $g ( @guarantees ) {
 781             my ( $b, $n, $o ) = C4::Members::GetMemberAccountBalance( $g->id );
 782             $guarantees_non_issues_charges += $n;
 783         }
 784
 785         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 786             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 787         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 788             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 789         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 790             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 791         }
 792     }
 793
 794     if ( C4::Context->preference("IssuingInProcess") ) {
 795         if ( $non_issue_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 796             $issuingimpossible{DEBT} = sprintf( "%.2f", $non_issue_charges );
 797         } elsif ( $non_issue_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 798             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 799         } elsif ( $allfinesneedoverride && $non_issue_charges > 0 && $non_issue_charges <= $amountlimit && !$inprocess ) {
 800             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 801         }
 802     }
 803     else {
 804         if ( $non_issue_charges > $amountlimit && $allowfineoverride ) {
 805             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 806         } elsif ( $non_issue_charges > $amountlimit && !$allowfineoverride) {
 807             $issuingimpossible{DEBT} = sprintf( "%.2f", $non_issue_charges );
 808         } elsif ( $non_issue_charges > 0 && $allfinesneedoverride ) {
 809             $needsconfirmation{DEBT} = sprintf( "%.2f", $non_issue_charges );
 810         }
 811     }
 812
 813     if ($balance > 0 && $other_charges > 0) {
 814         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 815     }
 816
 817     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
 818     if ( my $debarred_date = $patron->is_debarred ) {
 819          # patron has accrued fine days or has a restriction. $count is a date
 820         if ($debarred_date eq '9999-12-31') {
 821             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 822         }
 823         else {
 824             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 825         }
 826     } elsif ( my $num_overdues = $patron->has_overdues ) {
 827         ## patron has outstanding overdue loans
 828         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 829             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 830         }
 831         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 832             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 833         }
 834     }
 835
 836     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 837     #
 838     my $switch_onsite_checkout = (
 839           C4::Context->preference('SwitchOnSiteCheckouts')
 840       and $issue->{onsite_checkout}
 841       and $issue
 842       and $issue->{borrowernumber} == $borrower->{'borrowernumber'} ? 1 : 0 );
 843     my $toomany = TooMany( $borrower, $item->{biblionumber}, $item, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 844     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 845     if ( $toomany ) {
 846         if ( $toomany->{max_allowed} == 0 ) {
 847             $needsconfirmation{PATRON_CANT} = 1;
 848         }
 849         if ( C4::Context->preference("AllowTooManyOverride") ) {
 850             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 851             $needsconfirmation{current_loan_count} = $toomany->{count};
 852             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 853         } else {
 854             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 855             $issuingimpossible{current_loan_count} = $toomany->{count};
 856             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 857         }
 858     }
 859
 860     #
 861     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 862     #
 863     $patron = Koha::Patrons->find($borrower->{borrowernumber});
 864     my $wants_check = $patron->wants_check_for_previous_checkout;
 865     $needsconfirmation{PREVISSUE} = 1
 866         if ($wants_check and $patron->do_check_for_previous_checkout($item));
 867
 868     #
 869     # ITEM CHECKING
 870     #
 871     if ( $item->{'notforloan'} )
 872     {
 873         if(!C4::Context->preference("AllowNotForLoanOverride")){
 874             $issuingimpossible{NOT_FOR_LOAN} = 1;
 875             $issuingimpossible{item_notforloan} = $item->{'notforloan'};
 876         }else{
 877             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 878             $needsconfirmation{item_notforloan} = $item->{'notforloan'};
 879         }
 880     }
 881     else {
 882         # we have to check itemtypes.notforloan also
 883         if (C4::Context->preference('item-level_itypes')){
 884             # this should probably be a subroutine
 885             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 886             $sth->execute($item->{'itemtype'});
 887             my $notforloan=$sth->fetchrow_hashref();
 888             if ($notforloan->{'notforloan'}) {
 889                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 890                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 891                     $issuingimpossible{itemtype_notforloan} = $item->{'itype'};
 892                 } else {
 893                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 894                     $needsconfirmation{itemtype_notforloan} = $item->{'itype'};
 895                 }
 896             }
 897         }
 898         elsif ($biblioitem->{'notforloan'} == 1){
 899             if (!C4::Context->preference("AllowNotForLoanOverride")) {
 900                 $issuingimpossible{NOT_FOR_LOAN} = 1;
 901                 $issuingimpossible{itemtype_notforloan} = $biblioitem->{'itemtype'};
 902             } else {
 903                 $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 904                 $needsconfirmation{itemtype_notforloan} = $biblioitem->{'itemtype'};
 905             }
 906         }
 907     }
 908     if ( $item->{'withdrawn'} && $item->{'withdrawn'} > 0 )
 909     {
 910         $issuingimpossible{WTHDRAWN} = 1;
 911     }
 912     if (   $item->{'restricted'}
 913         && $item->{'restricted'} == 1 )
 914     {
 915         $issuingimpossible{RESTRICTED} = 1;
 916     }
 917     if ( $item->{'itemlost'} && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 918         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item->{itemlost} });
 919         my $code = $av->count ? $av->next->lib : '';
 920         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 921         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 922     }
 923     if ( C4::Context->preference("IndependentBranches") ) {
 924         my $userenv = C4::Context->userenv;
 925         unless ( C4::Context->IsSuperLibrarian() ) {
 926             if ( $item->{C4::Context->preference("HomeOrHoldingBranch")} ne $userenv->{branch} ){
 927                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 928                 $issuingimpossible{'itemhomebranch'} = $item->{C4::Context->preference("HomeOrHoldingBranch")};
 929             }
 930             $needsconfirmation{BORRNOTSAMEBRANCH} = $borrower->{'branchcode'}
 931               if ( $borrower->{'branchcode'} ne $userenv->{branch} );
 932         }
 933     }
 934     #
 935     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
 936     #
 937     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
 938
 939     if ( $rentalConfirmation ){
 940         my ($rentalCharge) = GetIssuingCharges( $item->{'itemnumber'}, $borrower->{'borrowernumber'} );
 941         if ( $rentalCharge > 0 ){
 942             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
 943         }
 944     }
 945
 946     #
 947     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 948     #
 949     if ( $issue->{borrowernumber} && $issue->{borrowernumber} eq $borrower->{'borrowernumber'} ){
 950
 951         # Already issued to current borrower.
 952         # If it is an on-site checkout if it can be switched to a normal checkout
 953         # or ask whether the loan should be renewed
 954
 955         if ( $issue->{onsite_checkout}
 956                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 957             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 958         } else {
 959             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 960                 $borrower->{'borrowernumber'},
 961                 $item->{'itemnumber'},
 962             );
 963             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 964                 if ( $renewerror eq 'onsite_checkout' ) {
 965                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 966                 }
 967                 else {
 968                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 969                 }
 970             }
 971             else {
 972                 $needsconfirmation{RENEW_ISSUE} = 1;
 973             }
 974         }
 975     }
 976     elsif ($issue->{borrowernumber}) {
 977
 978         # issued to someone else
 979         my $currborinfo =    C4::Members::GetMember( borrowernumber => $issue->{borrowernumber} );
 980
 981
 982         my ( $can_be_returned, $message ) = CanBookBeReturned( $item, C4::Context->userenv->{branch} );
 983
 984         unless ( $can_be_returned ) {
 985             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 986             $issuingimpossible{branch_to_return} = $message;
 987         } else {
 988             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 989             $needsconfirmation{issued_firstname} = $currborinfo->{'firstname'};
 990             $needsconfirmation{issued_surname} = $currborinfo->{'surname'};
 991             $needsconfirmation{issued_cardnumber} = $currborinfo->{'cardnumber'};
 992             $needsconfirmation{issued_borrowernumber} = $currborinfo->{'borrowernumber'};
 993         }
 994     }
 995
 996     unless ( $ignore_reserves ) {
 997         # See if the item is on reserve.
 998         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item->{'itemnumber'} );
 999         if ($restype) {
1000             my $resbor = $res->{'borrowernumber'};
1001             if ( $resbor ne $borrower->{'borrowernumber'} ) {
1002                 my ( $resborrower ) = C4::Members::GetMember( borrowernumber => $resbor );
1003                 if ( $restype eq "Waiting" )
1004                 {
1005                     # The item is on reserve and waiting, but has been
1006                     # reserved by some other patron.
1007                     $needsconfirmation{RESERVE_WAITING} = 1;
1008                     $needsconfirmation{'resfirstname'} = $resborrower->{'firstname'};
1009                     $needsconfirmation{'ressurname'} = $resborrower->{'surname'};
1010                     $needsconfirmation{'rescardnumber'} = $resborrower->{'cardnumber'};
1011                     $needsconfirmation{'resborrowernumber'} = $resborrower->{'borrowernumber'};
1012                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1013                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1014                 }
1015                 elsif ( $restype eq "Reserved" ) {
1016                     # The item is on reserve for someone else.
1017                     $needsconfirmation{RESERVED} = 1;
1018                     $needsconfirmation{'resfirstname'} = $resborrower->{'firstname'};
1019                     $needsconfirmation{'ressurname'} = $resborrower->{'surname'};
1020                     $needsconfirmation{'rescardnumber'} = $resborrower->{'cardnumber'};
1021                     $needsconfirmation{'resborrowernumber'} = $resborrower->{'borrowernumber'};
1022                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1023                     $needsconfirmation{'resreservedate'} = $res->{'reservedate'};
1024                 }
1025             }
1026         }
1027     }
1028
1029     ## CHECK AGE RESTRICTION
1030     my $agerestriction  = $biblioitem->{'agerestriction'};
1031     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $borrower );
1032     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1033         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1034             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1035         }
1036         else {
1037             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1038         }
1039     }
1040
1041     ## check for high holds decreasing loan period
1042     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1043         my $check = checkHighHolds( $item, $borrower );
1044
1045         if ( $check->{exceeded} ) {
1046             if ($override_high_holds) {
1047                 $alerts{HIGHHOLDS} = {
1048                     num_holds  => $check->{outstanding},
1049                     duration   => $check->{duration},
1050                     returndate => output_pref( $check->{due_date} ),
1051                 };
1052             }
1053             else {
1054                 $needsconfirmation{HIGHHOLDS} = {
1055                     num_holds  => $check->{outstanding},
1056                     duration   => $check->{duration},
1057                     returndate => output_pref( $check->{due_date} ),
1058                 };
1059             }
1060         }
1061     }
1062
1063     if (
1064         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1065         # don't do the multiple loans per bib check if we've
1066         # already determined that we've got a loan on the same item
1067         !$issuingimpossible{NO_MORE_RENEWALS} &&
1068         !$needsconfirmation{RENEW_ISSUE}
1069     ) {
1070         # Check if borrower has already issued an item from the same biblio
1071         # Only if it's not a subscription
1072         my $biblionumber = $item->{biblionumber};
1073         require C4::Serials;
1074         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1075         unless ($is_a_subscription) {
1076             my $checkouts = Koha::Checkouts->search(
1077                 {
1078                     borrowernumber => $borrower->{borrowernumber},
1079                     biblionumber   => $biblionumber,
1080                 },
1081                 {
1082                     join => 'item',
1083                 }
1084             );
1085             # if we get here, we don't already have a loan on this item,
1086             # so if there are any loans on this bib, ask for confirmation
1087             if ( $checkouts->count ) {
1088                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1089             }
1090         }
1091     }
1092
1093     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1094 }
1095
1096 =head2 CanBookBeReturned
1097
1098   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1099
1100 Check whether the item can be returned to the provided branch
1101
1102 =over 4
1103
1104 =item C<$item> is a hash of item information as returned from GetItem
1105
1106 =item C<$branch> is the branchcode where the return is taking place
1107
1108 =back
1109
1110 Returns:
1111
1112 =over 4
1113
1114 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1115
1116 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1117
1118 =back
1119
1120 =cut
1121
1122 sub CanBookBeReturned {
1123   my ($item, $branch) = @_;
1124   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1125
1126   # assume return is allowed to start
1127   my $allowed = 1;
1128   my $message;
1129
1130   # identify all cases where return is forbidden
1131   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1132      $allowed = 0;
1133      $message = $item->{'homebranch'};
1134   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1135      $allowed = 0;
1136      $message = $item->{'holdingbranch'};
1137   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1138      $allowed = 0;
1139      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1140   }
1141
1142   return ($allowed, $message);
1143 }
1144
1145 =head2 CheckHighHolds
1146
1147     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1148     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1149     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1150
1151 =cut
1152
1153 sub checkHighHolds {
1154     my ( $item, $borrower ) = @_;
1155     my $biblio = GetBiblioFromItemNumber( $item->{itemnumber} );
1156     my $branch = _GetCircControlBranch( $item, $borrower );
1157
1158     my $return_data = {
1159         exceeded    => 0,
1160         outstanding => 0,
1161         duration    => 0,
1162         due_date    => undef,
1163     };
1164
1165     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1166
1167     if ( $holds->count() ) {
1168         $return_data->{outstanding} = $holds->count();
1169
1170         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1171         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1172         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1173
1174         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1175
1176         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1177
1178             # static means just more than a given number of holds on the record
1179
1180             # If the number of holds is less than the threshold, we can stop here
1181             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1182                 return $return_data;
1183             }
1184         }
1185         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1186
1187             # dynamic means X more than the number of holdable items on the record
1188
1189             # let's get the items
1190             my @items = $holds->next()->biblio()->items();
1191
1192             # Remove any items with status defined to be ignored even if the would not make item unholdable
1193             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1194                 @items = grep { !$_->$status } @items;
1195             }
1196
1197             # Remove any items that are not holdable for this patron
1198             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber ) eq 'OK' } @items;
1199
1200             my $items_count = scalar @items;
1201
1202             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1203
1204             # If the number of holds is less than the count of items we have
1205             # plus the number of holds allowed above that count, we can stop here
1206             if ( $holds->count() <= $threshold ) {
1207                 return $return_data;
1208             }
1209         }
1210
1211         my $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1212
1213         my $calendar = Koha::Calendar->new( branchcode => $branch );
1214
1215         my $itype =
1216           ( C4::Context->preference('item-level_itypes') )
1217           ? $biblio->{'itype'}
1218           : $biblio->{'itemtype'};
1219
1220         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branch, $borrower );
1221
1222         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1223
1224         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1225         $reduced_datedue->set_hour($orig_due->hour);
1226         $reduced_datedue->set_minute($orig_due->minute);
1227         $reduced_datedue->truncate( to => 'minute' );
1228
1229         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1230             $return_data->{exceeded} = 1;
1231             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1232             $return_data->{due_date} = $reduced_datedue;
1233         }
1234     }
1235
1236     return $return_data;
1237 }
1238
1239 =head2 AddIssue
1240
1241   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1242
1243 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1244
1245 =over 4
1246
1247 =item C<$borrower> is a hash with borrower informations (from GetMember).
1248
1249 =item C<$barcode> is the barcode of the item being issued.
1250
1251 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1252 Calculated if empty.
1253
1254 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1255
1256 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1257 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1258
1259 AddIssue does the following things :
1260
1261   - step 01: check that there is a borrowernumber & a barcode provided
1262   - check for RENEWAL (book issued & being issued to the same patron)
1263       - renewal YES = Calculate Charge & renew
1264       - renewal NO  =
1265           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1266           * RESERVE PLACED ?
1267               - fill reserve if reserve to this patron
1268               - cancel reserve or not, otherwise
1269           * TRANSFERT PENDING ?
1270               - complete the transfert
1271           * ISSUE THE BOOK
1272
1273 =back
1274
1275 =cut
1276
1277 sub AddIssue {
1278     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1279
1280     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1281     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1282     my $auto_renew = $params && $params->{auto_renew};
1283     my $dbh          = C4::Context->dbh;
1284     my $barcodecheck = CheckValidBarcode($barcode);
1285
1286     my $issue;
1287
1288     if ( $datedue && ref $datedue ne 'DateTime' ) {
1289         $datedue = dt_from_string($datedue);
1290     }
1291
1292     # $issuedate defaults to today.
1293     if ( !defined $issuedate ) {
1294         $issuedate = DateTime->now( time_zone => C4::Context->tz() );
1295     }
1296     else {
1297         if ( ref $issuedate ne 'DateTime' ) {
1298             $issuedate = dt_from_string($issuedate);
1299
1300         }
1301     }
1302
1303     # Stop here if the patron or barcode doesn't exist
1304     if ( $borrower && $barcode && $barcodecheck ) {
1305         # find which item we issue
1306         my $item = GetItem( '', $barcode )
1307           or return;    # if we don't get an Item, abort.
1308
1309         my $branch = _GetCircControlBranch( $item, $borrower );
1310
1311         # get actual issuing if there is one
1312         my $actualissue = GetItemIssue( $item->{itemnumber} );
1313
1314         # get biblioinformation for this item
1315         my $biblio = GetBiblioFromItemNumber( $item->{itemnumber} );
1316
1317         # check if we just renew the issue.
1318         if ( $actualissue->{borrowernumber} eq $borrower->{'borrowernumber'}
1319                 and not $switch_onsite_checkout ) {
1320             $datedue = AddRenewal(
1321                 $borrower->{'borrowernumber'},
1322                 $item->{'itemnumber'},
1323                 $branch,
1324                 $datedue,
1325                 $issuedate,    # here interpreted as the renewal date
1326             );
1327         }
1328         else {
1329             # it's NOT a renewal
1330             if ( $actualissue->{borrowernumber}
1331                     and not $switch_onsite_checkout ) {
1332                 # This book is currently on loan, but not to the person
1333                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1334                 my ( $allowed, $message ) = CanBookBeReturned( $item, C4::Context->userenv->{branch} );
1335                 return unless $allowed;
1336                 AddReturn( $item->{'barcode'}, C4::Context->userenv->{'branch'} );
1337             }
1338
1339             MoveReserve( $item->{'itemnumber'}, $borrower->{'borrowernumber'}, $cancelreserve );
1340
1341             # Starting process for transfer job (checking transfert and validate it if we have one)
1342             my ($datesent) = GetTransfers( $item->{'itemnumber'} );
1343             if ($datesent) {
1344                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1345                 my $sth = $dbh->prepare(
1346                     "UPDATE branchtransfers
1347                         SET datearrived = now(),
1348                         tobranch = ?,
1349                         comments = 'Forced branchtransfer'
1350                     WHERE itemnumber= ? AND datearrived IS NULL"
1351                 );
1352                 $sth->execute( C4::Context->userenv->{'branch'},
1353                     $item->{'itemnumber'} );
1354             }
1355
1356             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1357             unless ($auto_renew) {
1358                 my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1359                     {   categorycode => $borrower->{categorycode},
1360                         itemtype     => $item->{itype},
1361                         branchcode   => $branch
1362                     }
1363                 );
1364
1365                 $auto_renew = $issuing_rule->auto_renew if $issuing_rule;
1366             }
1367
1368             # Record in the database the fact that the book was issued.
1369             unless ($datedue) {
1370                 my $itype =
1371                   ( C4::Context->preference('item-level_itypes') )
1372                   ? $biblio->{'itype'}
1373                   : $biblio->{'itemtype'};
1374                 $datedue = CalcDateDue( $issuedate, $itype, $branch, $borrower );
1375
1376             }
1377             $datedue->truncate( to => 'minute' );
1378
1379             $issue = Koha::Database->new()->schema()->resultset('Issue')->update_or_create(
1380                 {
1381                     borrowernumber => $borrower->{'borrowernumber'},
1382                     itemnumber     => $item->{'itemnumber'},
1383                     issuedate      => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1384                     date_due       => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1385                     branchcode     => C4::Context->userenv->{'branch'},
1386                     onsite_checkout => $onsite_checkout,
1387                     auto_renew      => $auto_renew ? 1 : 0
1388                 }
1389               );
1390
1391             if ( C4::Context->preference('ReturnToShelvingCart') ) {
1392                 # ReturnToShelvingCart is on, anything issued should be taken off the cart.
1393                 CartToShelf( $item->{'itemnumber'} );
1394             }
1395             $item->{'issues'}++;
1396             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1397                 UpdateTotalIssues( $item->{'biblionumber'}, 1 );
1398             }
1399
1400             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1401             if ( $item->{'itemlost'} ) {
1402                 if (
1403                     Koha::RefundLostItemFeeRules->should_refund(
1404                         {
1405                             current_branch      => C4::Context->userenv->{branch},
1406                             item_home_branch    => $item->{homebranch},
1407                             item_holding_branch => $item->{holdingbranch}
1408                         }
1409                     )
1410                   )
1411                 {
1412                     _FixAccountForLostAndReturned( $item->{'itemnumber'}, undef,
1413                         $item->{'barcode'} );
1414                 }
1415             }
1416
1417             ModItem(
1418                 {
1419                     issues        => $item->{'issues'},
1420                     holdingbranch => C4::Context->userenv->{'branch'},
1421                     itemlost      => 0,
1422                     onloan        => $datedue->ymd(),
1423                     datelastborrowed => DateTime->now( time_zone => C4::Context->tz() )->ymd(),
1424                 },
1425                 $item->{'biblionumber'},
1426                 $item->{'itemnumber'}
1427             );
1428             ModDateLastSeen( $item->{'itemnumber'} );
1429
1430            # If it costs to borrow this book, charge it to the patron's account.
1431             my ( $charge, $itemtype ) = GetIssuingCharges( $item->{'itemnumber'}, $borrower->{'borrowernumber'} );
1432             if ( $charge > 0 ) {
1433                 AddIssuingCharge( $item->{'itemnumber'}, $borrower->{'borrowernumber'}, $charge );
1434                 $item->{'charge'} = $charge;
1435             }
1436
1437             # Record the fact that this book was issued.
1438             &UpdateStats(
1439                 {
1440                     branch => C4::Context->userenv->{'branch'},
1441                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1442                     amount         => $charge,
1443                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1444                     itemnumber     => $item->{'itemnumber'},
1445                     itemtype       => $item->{'itype'},
1446                     borrowernumber => $borrower->{'borrowernumber'},
1447                     ccode          => $item->{'ccode'}
1448                 }
1449             );
1450
1451             # Send a checkout slip.
1452             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1453             my %conditions        = (
1454                 branchcode   => $branch,
1455                 categorycode => $borrower->{categorycode},
1456                 item_type    => $item->{itype},
1457                 notification => 'CHECKOUT',
1458             );
1459             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1460                 SendCirculationAlert(
1461                     {
1462                         type     => 'CHECKOUT',
1463                         item     => $item,
1464                         borrower => $borrower,
1465                         branch   => $branch,
1466                     }
1467                 );
1468             }
1469             logaction(
1470                 "CIRCULATION", "ISSUE",
1471                 $borrower->{'borrowernumber'},
1472                 $biblio->{'itemnumber'}
1473             ) if C4::Context->preference("IssueLog");
1474         }
1475     }
1476     return $issue;
1477 }
1478
1479 =head2 GetLoanLength
1480
1481   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1482
1483 Get loan length for an itemtype, a borrower type and a branch
1484
1485 =cut
1486
1487 sub GetLoanLength {
1488     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1489     my $dbh = C4::Context->dbh;
1490     my $sth = $dbh->prepare(qq{
1491         SELECT issuelength, lengthunit, renewalperiod
1492         FROM issuingrules
1493         WHERE   categorycode=?
1494             AND itemtype=?
1495             AND branchcode=?
1496             AND issuelength IS NOT NULL
1497     });
1498
1499     # try to find issuelength & return the 1st available.
1500     # check with borrowertype, itemtype and branchcode, then without one of those parameters
1501     $sth->execute( $borrowertype, $itemtype, $branchcode );
1502     my $loanlength = $sth->fetchrow_hashref;
1503
1504     return $loanlength
1505       if defined($loanlength) && defined $loanlength->{issuelength};
1506
1507     $sth->execute( $borrowertype, '*', $branchcode );
1508     $loanlength = $sth->fetchrow_hashref;
1509     return $loanlength
1510       if defined($loanlength) && defined $loanlength->{issuelength};
1511
1512     $sth->execute( '*', $itemtype, $branchcode );
1513     $loanlength = $sth->fetchrow_hashref;
1514     return $loanlength
1515       if defined($loanlength) && defined $loanlength->{issuelength};
1516
1517     $sth->execute( '*', '*', $branchcode );
1518     $loanlength = $sth->fetchrow_hashref;
1519     return $loanlength
1520       if defined($loanlength) && defined $loanlength->{issuelength};
1521
1522     $sth->execute( $borrowertype, $itemtype, '*' );
1523     $loanlength = $sth->fetchrow_hashref;
1524     return $loanlength
1525       if defined($loanlength) && defined $loanlength->{issuelength};
1526
1527     $sth->execute( $borrowertype, '*', '*' );
1528     $loanlength = $sth->fetchrow_hashref;
1529     return $loanlength
1530       if defined($loanlength) && defined $loanlength->{issuelength};
1531
1532     $sth->execute( '*', $itemtype, '*' );
1533     $loanlength = $sth->fetchrow_hashref;
1534     return $loanlength
1535       if defined($loanlength) && defined $loanlength->{issuelength};
1536
1537     $sth->execute( '*', '*', '*' );
1538     $loanlength = $sth->fetchrow_hashref;
1539     return $loanlength
1540       if defined($loanlength) && defined $loanlength->{issuelength};
1541
1542     # if no rule is set => 0 day (hardcoded)
1543     return {
1544         issuelength => 0,
1545         renewalperiod => 0,
1546         lengthunit => 'days',
1547     };
1548
1549 }
1550
1551
1552 =head2 GetHardDueDate
1553
1554   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1555
1556 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1557
1558 =cut
1559
1560 sub GetHardDueDate {
1561     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1562
1563     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
1564         {   categorycode => $borrowertype,
1565             itemtype     => $itemtype,
1566             branchcode   => $branchcode
1567         }
1568     );
1569
1570
1571     if ( defined( $issuing_rule ) ) {
1572         if ( $issuing_rule->hardduedate ) {
1573             return (dt_from_string($issuing_rule->hardduedate, 'iso'),$issuing_rule->hardduedatecompare);
1574         } else {
1575             return (undef, undef);
1576         }
1577     }
1578 }
1579
1580 =head2 GetBranchBorrowerCircRule
1581
1582   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1583
1584 Retrieves circulation rule attributes that apply to the given
1585 branch and patron category, regardless of item type.
1586 The return value is a hashref containing the following key:
1587
1588 maxissueqty - maximum number of loans that a
1589 patron of the given category can have at the given
1590 branch.  If the value is undef, no limit.
1591
1592 maxonsiteissueqty - maximum of on-site checkouts that a
1593 patron of the given category can have at the given
1594 branch.  If the value is undef, no limit.
1595
1596 This will first check for a specific branch and
1597 category match from branch_borrower_circ_rules.
1598
1599 If no rule is found, it will then check default_branch_circ_rules
1600 (same branch, default category).  If no rule is found,
1601 it will then check default_borrower_circ_rules (default
1602 branch, same category), then failing that, default_circ_rules
1603 (default branch, default category).
1604
1605 If no rule has been found in the database, it will default to
1606 the buillt in rule:
1607
1608 maxissueqty - undef
1609 maxonsiteissueqty - undef
1610
1611 C<$branchcode> and C<$categorycode> should contain the
1612 literal branch code and patron category code, respectively - no
1613 wildcards.
1614
1615 =cut
1616
1617 sub GetBranchBorrowerCircRule {
1618     my ( $branchcode, $categorycode ) = @_;
1619
1620     my $rules;
1621     my $dbh = C4::Context->dbh();
1622     $rules = $dbh->selectrow_hashref( q|
1623         SELECT maxissueqty, maxonsiteissueqty
1624         FROM branch_borrower_circ_rules
1625         WHERE branchcode = ?
1626         AND   categorycode = ?
1627     |, {}, $branchcode, $categorycode ) ;
1628     return $rules if $rules;
1629
1630     # try same branch, default borrower category
1631     $rules = $dbh->selectrow_hashref( q|
1632         SELECT maxissueqty, maxonsiteissueqty
1633         FROM default_branch_circ_rules
1634         WHERE branchcode = ?
1635     |, {}, $branchcode ) ;
1636     return $rules if $rules;
1637
1638     # try default branch, same borrower category
1639     $rules = $dbh->selectrow_hashref( q|
1640         SELECT maxissueqty, maxonsiteissueqty
1641         FROM default_borrower_circ_rules
1642         WHERE categorycode = ?
1643     |, {}, $categorycode ) ;
1644     return $rules if $rules;
1645
1646     # try default branch, default borrower category
1647     $rules = $dbh->selectrow_hashref( q|
1648         SELECT maxissueqty, maxonsiteissueqty
1649         FROM default_circ_rules
1650     |, {} );
1651     return $rules if $rules;
1652
1653     # built-in default circulation rule
1654     return {
1655         maxissueqty => undef,
1656         maxonsiteissueqty => undef,
1657     };
1658 }
1659
1660 =head2 GetBranchItemRule
1661
1662   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1663
1664 Retrieves circulation rule attributes that apply to the given
1665 branch and item type, regardless of patron category.
1666
1667 The return value is a hashref containing the following keys:
1668
1669 holdallowed => Hold policy for this branch and itemtype. Possible values:
1670   0: No holds allowed.
1671   1: Holds allowed only by patrons that have the same homebranch as the item.
1672   2: Holds allowed from any patron.
1673
1674 returnbranch => branch to which to return item.  Possible values:
1675   noreturn: do not return, let item remain where checked in (floating collections)
1676   homebranch: return to item's home branch
1677   holdingbranch: return to issuer branch
1678
1679 This searches branchitemrules in the following order:
1680
1681   * Same branchcode and itemtype
1682   * Same branchcode, itemtype '*'
1683   * branchcode '*', same itemtype
1684   * branchcode and itemtype '*'
1685
1686 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1687
1688 =cut
1689
1690 sub GetBranchItemRule {
1691     my ( $branchcode, $itemtype ) = @_;
1692     my $dbh = C4::Context->dbh();
1693     my $result = {};
1694
1695     my @attempts = (
1696         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1697             FROM branch_item_rules
1698             WHERE branchcode = ?
1699               AND itemtype = ?', $branchcode, $itemtype],
1700         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1701             FROM default_branch_circ_rules
1702             WHERE branchcode = ?', $branchcode],
1703         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1704             FROM default_branch_item_rules
1705             WHERE itemtype = ?', $itemtype],
1706         ['SELECT holdallowed, returnbranch, hold_fulfillment_policy
1707             FROM default_circ_rules'],
1708     );
1709
1710     foreach my $attempt (@attempts) {
1711         my ($query, @bind_params) = @{$attempt};
1712         my $search_result = $dbh->selectrow_hashref ( $query , {}, @bind_params )
1713           or next;
1714
1715         # Since branch/category and branch/itemtype use the same per-branch
1716         # defaults tables, we have to check that the key we want is set, not
1717         # just that a row was returned
1718         $result->{'holdallowed'}  = $search_result->{'holdallowed'}  unless ( defined $result->{'holdallowed'} );
1719         $result->{'hold_fulfillment_policy'} = $search_result->{'hold_fulfillment_policy'} unless ( defined $result->{'hold_fulfillment_policy'} );
1720         $result->{'returnbranch'} = $search_result->{'returnbranch'} unless ( defined $result->{'returnbranch'} );
1721     }
1722
1723     # built-in default circulation rule
1724     $result->{'holdallowed'} = 2 unless ( defined $result->{'holdallowed'} );
1725     $result->{'hold_fulfillment_policy'} = 'any' unless ( defined $result->{'hold_fulfillment_policy'} );
1726     $result->{'returnbranch'} = 'homebranch' unless ( defined $result->{'returnbranch'} );
1727
1728     return $result;
1729 }
1730
1731 =head2 AddReturn
1732
1733   ($doreturn, $messages, $iteminformation, $borrower) =
1734       &AddReturn( $barcode, $branch [,$exemptfine] [,$dropbox] [,$returndate] );
1735
1736 Returns a book.
1737
1738 =over 4
1739
1740 =item C<$barcode> is the bar code of the book being returned.
1741
1742 =item C<$branch> is the code of the branch where the book is being returned.
1743
1744 =item C<$exemptfine> indicates that overdue charges for the item will be
1745 removed. Optional.
1746
1747 =item C<$dropbox> indicates that the check-in date is assumed to be
1748 yesterday, or the last non-holiday as defined in C4::Calendar .  If
1749 overdue charges are applied and C<$dropbox> is true, the last charge
1750 will be removed.  This assumes that the fines accrual script has run
1751 for _today_. Optional.
1752
1753 =item C<$return_date> allows the default return date to be overridden
1754 by the given return date. Optional.
1755
1756 =back
1757
1758 C<&AddReturn> returns a list of four items:
1759
1760 C<$doreturn> is true iff the return succeeded.
1761
1762 C<$messages> is a reference-to-hash giving feedback on the operation.
1763 The keys of the hash are:
1764
1765 =over 4
1766
1767 =item C<BadBarcode>
1768
1769 No item with this barcode exists. The value is C<$barcode>.
1770
1771 =item C<NotIssued>
1772
1773 The book is not currently on loan. The value is C<$barcode>.
1774
1775 =item C<IsPermanent>
1776
1777 The book's home branch is a permanent collection. If you have borrowed
1778 this book, you are not allowed to return it. The value is the code for
1779 the book's home branch.
1780
1781 =item C<withdrawn>
1782
1783 This book has been withdrawn/cancelled. The value should be ignored.
1784
1785 =item C<Wrongbranch>
1786
1787 This book has was returned to the wrong branch.  The value is a hashref
1788 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1789 contain the branchcode of the incorrect and correct return library, respectively.
1790
1791 =item C<ResFound>
1792
1793 The item was reserved. The value is a reference-to-hash whose keys are
1794 fields from the reserves table of the Koha database, and
1795 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1796 either C<Waiting>, C<Reserved>, or 0.
1797
1798 =item C<WasReturned>
1799
1800 Value 1 if return is successful.
1801
1802 =item C<NeedsTransfer>
1803
1804 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1805
1806 =back
1807
1808 C<$iteminformation> is a reference-to-hash, giving information about the
1809 returned item from the issues table.
1810
1811 C<$borrower> is a reference-to-hash, giving information about the
1812 patron who last borrowed the book.
1813
1814 =cut
1815
1816 sub AddReturn {
1817     my ( $barcode, $branch, $exemptfine, $dropbox, $return_date, $dropboxdate ) = @_;
1818
1819     if ($branch and not Koha::Libraries->find($branch)) {
1820         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1821         undef $branch;
1822     }
1823     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1824     my $messages;
1825     my $borrower;
1826     my $doreturn       = 1;
1827     my $validTransfert = 0;
1828     my $stat_type = 'return';
1829
1830     # get information on item
1831     my $item = GetItem( undef, $barcode );
1832     unless ($item) {
1833         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1834     }
1835
1836     my $itemnumber = $item->{ itemnumber };
1837     my $itemtype = $item->{itype}; # GetItem called effective_itemtype
1838
1839     my $issue  = GetItemIssue($itemnumber);
1840     if ($issue and $issue->{borrowernumber}) {
1841         $borrower = C4::Members::GetMember( borrowernumber => $issue->{borrowernumber} )
1842             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '$issue->{borrowernumber}'\n"
1843                 . Dumper($issue) . "\n";
1844     } else {
1845         $messages->{'NotIssued'} = $barcode;
1846         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1847         $doreturn = 0;
1848         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1849         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1850         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1851            $messages->{'LocalUse'} = 1;
1852            $stat_type = 'localuse';
1853         }
1854     }
1855
1856     if ( $item->{'location'} eq 'PROC' ) {
1857         if ( C4::Context->preference("InProcessingToShelvingCart") ) {
1858             $item->{'location'} = 'CART';
1859         }
1860         else {
1861             $item->{location} = $item->{permanent_location};
1862         }
1863
1864         ModItem( $item, $item->{'biblionumber'}, $item->{'itemnumber'} );
1865     }
1866
1867         # full item data, but no borrowernumber or checkout info (no issue)
1868         # we know GetItem should work because GetItemnumberFromBarcode worked
1869     my $hbr = GetBranchItemRule($item->{'homebranch'}, $item->{'itype'})->{'returnbranch'} || "homebranch";
1870         # get the proper branch to which to return the item
1871     my $returnbranch = $item->{$hbr} || $branch ;
1872         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1873
1874     my $borrowernumber = $borrower->{'borrowernumber'} || undef;    # we don't know if we had a borrower or not
1875
1876     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1877     if ($yaml) {
1878         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1879         my $rules;
1880         eval { $rules = YAML::Load($yaml); };
1881         if ($@) {
1882             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1883         }
1884         else {
1885             foreach my $key ( keys %$rules ) {
1886                 if ( $item->{notforloan} eq $key ) {
1887                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->{notforloan}, to => $rules->{$key} };
1888                     ModItem( { notforloan => $rules->{$key} }, undef, $itemnumber );
1889                     last;
1890                 }
1891             }
1892         }
1893     }
1894
1895
1896     # check if the book is in a permanent collection....
1897     # FIXME -- This 'PE' attribute is largely undocumented.  afaict, there's no user interface that reflects this functionality.
1898     if ( $returnbranch ) {
1899         my $library = Koha::Libraries->find($returnbranch);
1900         if ( $library and $library->get_categories->search({'me.categorycode' => 'PE'})->count ) {
1901             $messages->{'IsPermanent'} = $returnbranch;
1902         }
1903     }
1904
1905     # check if the return is allowed at this branch
1906     my ($returnallowed, $message) = CanBookBeReturned($item, $branch);
1907     unless ($returnallowed){
1908         $messages->{'Wrongbranch'} = {
1909             Wrongbranch => $branch,
1910             Rightbranch => $message
1911         };
1912         $doreturn = 0;
1913         return ( $doreturn, $messages, $issue, $borrower );
1914     }
1915
1916     if ( $item->{'withdrawn'} ) { # book has been cancelled
1917         $messages->{'withdrawn'} = 1;
1918         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1919     }
1920
1921     # case of a return of document (deal with issues and holdingbranch)
1922     my $today = DateTime->now( time_zone => C4::Context->tz() );
1923
1924     if ($doreturn) {
1925         my $datedue = $issue->{date_due};
1926         $borrower or warn "AddReturn without current borrower";
1927                 my $circControlBranch;
1928         if ($dropbox) {
1929             # define circControlBranch only if dropbox mode is set
1930             # don't allow dropbox mode to create an invalid entry in issues (issuedate > today)
1931             # FIXME: check issuedate > returndate, factoring in holidays
1932
1933             $circControlBranch = _GetCircControlBranch($item,$borrower);
1934             $issue->{'overdue'} = DateTime->compare($issue->{'date_due'}, $dropboxdate ) == -1 ? 1 : 0;
1935         }
1936
1937         if ($borrowernumber) {
1938             eval {
1939                 MarkIssueReturned( $borrowernumber, $item->{'itemnumber'},
1940                     $circControlBranch, $return_date, $borrower->{privacy} );
1941             };
1942             unless ( $@ ) {
1943                 if ( ( C4::Context->preference('CalculateFinesOnReturn') && $issue->{'overdue'} ) || $return_date ) {
1944                     _CalculateAndUpdateFine( { issue => $issue, item => $item, borrower => $borrower, return_date => $return_date } );
1945                 }
1946             } else {
1947                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue );
1948
1949                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $borrower );
1950             }
1951
1952             # FIXME is the "= 1" right?  This could be the borrower hash.
1953             $messages->{'WasReturned'} = 1;
1954
1955         }
1956
1957         ModItem({ onloan => undef }, $issue->{'biblionumber'}, $item->{'itemnumber'});
1958     }
1959
1960     # the holdingbranch is updated if the document is returned to another location.
1961     # this is always done regardless of whether the item was on loan or not
1962     my $item_holding_branch = $item->{ holdingbranch };
1963     if ($item->{'holdingbranch'} ne $branch) {
1964         UpdateHoldingbranch($branch, $item->{'itemnumber'});
1965         $item->{'holdingbranch'} = $branch; # update item data holdingbranch too
1966     }
1967     ModDateLastSeen( $item->{'itemnumber'} );
1968
1969     # check if we have a transfer for this document
1970     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->{'itemnumber'} );
1971
1972     # if we have a transfer to do, we update the line of transfers with the datearrived
1973     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->{'itemnumber'} );
1974     if ($datesent) {
1975         if ( $tobranch eq $branch ) {
1976             my $sth = C4::Context->dbh->prepare(
1977                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
1978             );
1979             $sth->execute( $item->{'itemnumber'} );
1980             # if we have a reservation with valid transfer, we can set it's status to 'W'
1981             ShelfToCart( $item->{'itemnumber'} ) if ( C4::Context->preference("ReturnToShelvingCart") );
1982             C4::Reserves::ModReserveStatus($item->{'itemnumber'}, 'W');
1983         } else {
1984             $messages->{'WrongTransfer'}     = $tobranch;
1985             $messages->{'WrongTransferItem'} = $item->{'itemnumber'};
1986         }
1987         $validTransfert = 1;
1988     } else {
1989         ShelfToCart( $item->{'itemnumber'} ) if ( C4::Context->preference("ReturnToShelvingCart") );
1990     }
1991
1992     # fix up the accounts.....
1993     if ( $item->{'itemlost'} ) {
1994         $messages->{'WasLost'} = 1;
1995
1996         if ( $item->{'itemlost'} ) {
1997             if (
1998                 Koha::RefundLostItemFeeRules->should_refund(
1999                     {
2000                         current_branch      => C4::Context->userenv->{branch},
2001                         item_home_branch    => $item->{homebranch},
2002                         item_holding_branch => $item_holding_branch
2003                     }
2004                 )
2005               )
2006             {
2007                 _FixAccountForLostAndReturned( $item->{'itemnumber'}, $borrowernumber, $barcode );
2008                 $messages->{'LostItemFeeRefunded'} = 1;
2009             }
2010         }
2011     }
2012
2013     # fix up the overdues in accounts...
2014     if ($borrowernumber) {
2015         my $fix = _FixOverduesOnReturn($borrowernumber, $item->{itemnumber}, $exemptfine, $dropbox);
2016         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $item->{itemnumber}...) failed!";  # zero is OK, check defined
2017
2018         if ( $issue->{overdue} && $issue->{date_due} ) {
2019         # fix fine days
2020             $today = $dropboxdate if $dropbox;
2021             my ($debardate,$reminder) = _debar_user_on_return( $borrower, $item, $issue->{date_due}, $today );
2022             if ($reminder){
2023                 $messages->{'PrevDebarred'} = $debardate;
2024             } else {
2025                 $messages->{'Debarred'} = $debardate if $debardate;
2026             }
2027         # there's no overdue on the item but borrower had been previously debarred
2028         } elsif ( $issue->{date_due} and $borrower->{'debarred'} ) {
2029              if ( $borrower->{debarred} eq "9999-12-31") {
2030                 $messages->{'ForeverDebarred'} = $borrower->{'debarred'};
2031              } else {
2032                   my $borrower_debar_dt = dt_from_string( $borrower->{debarred} );
2033                   $borrower_debar_dt->truncate(to => 'day');
2034                   my $today_dt = $today->clone()->truncate(to => 'day');
2035                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2036                       $messages->{'PrevDebarred'} = $borrower->{'debarred'};
2037                   }
2038              }
2039         }
2040     }
2041
2042     # find reserves.....
2043     # if we don't have a reserve with the status W, we launch the Checkreserves routine
2044     my ($resfound, $resrec);
2045     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2046     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->{'itemnumber'}, undef, $lookahead ) unless ( $item->{'withdrawn'} );
2047     if ($resfound) {
2048           $resrec->{'ResFound'} = $resfound;
2049         $messages->{'ResFound'} = $resrec;
2050     }
2051
2052     # Record the fact that this book was returned.
2053     UpdateStats({
2054         branch         => $branch,
2055         type           => $stat_type,
2056         itemnumber     => $itemnumber,
2057         itemtype       => $itemtype,
2058         borrowernumber => $borrowernumber,
2059         ccode          => $item->{ ccode }
2060     });
2061
2062     # Send a check-in slip. # NOTE: borrower may be undef.  probably shouldn't try to send messages then.
2063     my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2064     my %conditions = (
2065         branchcode   => $branch,
2066         categorycode => $borrower->{categorycode},
2067         item_type    => $item->{itype},
2068         notification => 'CHECKIN',
2069     );
2070     if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2071         SendCirculationAlert({
2072             type     => 'CHECKIN',
2073             item     => $item,
2074             borrower => $borrower,
2075             branch   => $branch,
2076         });
2077     }
2078
2079     logaction("CIRCULATION", "RETURN", $borrowernumber, $item->{'itemnumber'})
2080         if C4::Context->preference("ReturnLog");
2081
2082     # Remove any OVERDUES related debarment if the borrower has no overdues
2083     if ( $borrowernumber
2084       && $borrower->{'debarred'}
2085       && C4::Context->preference('AutoRemoveOverduesRestrictions')
2086       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2087       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2088     ) {
2089         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2090     }
2091
2092     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2093     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2094         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2095             (C4::Context->preference("UseBranchTransferLimits") and
2096              ! IsBranchTransferAllowed($branch, $returnbranch, $item->{C4::Context->preference("BranchTransferLimitsType")} )
2097            )) {
2098             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s)", $item->{'itemnumber'},$branch, $returnbranch;
2099             $debug and warn "item: " . Dumper($item);
2100             ModItemTransfer($item->{'itemnumber'}, $branch, $returnbranch);
2101             $messages->{'WasTransfered'} = 1;
2102         } else {
2103             $messages->{'NeedsTransfer'} = $returnbranch;
2104         }
2105     }
2106
2107     return ( $doreturn, $messages, $issue, $borrower );
2108 }
2109
2110 =head2 MarkIssueReturned
2111
2112   MarkIssueReturned($borrowernumber, $itemnumber, $dropbox_branch, $returndate, $privacy);
2113
2114 Unconditionally marks an issue as being returned by
2115 moving the C<issues> row to C<old_issues> and
2116 setting C<returndate> to the current date, or
2117 the last non-holiday date of the branccode specified in
2118 C<dropbox_branch> .  Assumes you've already checked that
2119 it's safe to do this, i.e. last non-holiday > issuedate.
2120
2121 if C<$returndate> is specified (in iso format), it is used as the date
2122 of the return. It is ignored when a dropbox_branch is passed in.
2123
2124 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2125 the old_issue is immediately anonymised
2126
2127 Ideally, this function would be internal to C<C4::Circulation>,
2128 not exported, but it is currently needed by one
2129 routine in C<C4::Accounts>.
2130
2131 =cut
2132
2133 sub MarkIssueReturned {
2134     my ( $borrowernumber, $itemnumber, $dropbox_branch, $returndate, $privacy ) = @_;
2135
2136     my $anonymouspatron;
2137     if ( $privacy == 2 ) {
2138         # The default of 0 will not work due to foreign key constraints
2139         # The anonymisation will fail if AnonymousPatron is not a valid entry
2140         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2141         # Note that a warning should appear on the about page (System information tab).
2142         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2143         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2144             unless C4::Members::GetMember( borrowernumber => $anonymouspatron );
2145     }
2146     my $database = Koha::Database->new();
2147     my $schema   = $database->schema;
2148     my $dbh   = C4::Context->dbh;
2149
2150     my $issue_id = $dbh->selectrow_array(
2151         q|SELECT issue_id FROM issues WHERE itemnumber = ?|,
2152         undef, $itemnumber
2153     );
2154
2155     my $query = 'UPDATE issues SET returndate=';
2156     my @bind;
2157     if ($dropbox_branch) {
2158         my $calendar = Koha::Calendar->new( branchcode => $dropbox_branch );
2159         my $dropboxdate = $calendar->addDate( DateTime->now( time_zone => C4::Context->tz), -1 );
2160         $query .= ' ? ';
2161         push @bind, $dropboxdate->strftime('%Y-%m-%d %H:%M');
2162     } elsif ($returndate) {
2163         $query .= ' ? ';
2164         push @bind, $returndate;
2165     } else {
2166         $query .= ' now() ';
2167     }
2168     $query .= ' WHERE issue_id = ?';
2169     push @bind, $issue_id;
2170
2171     # FIXME Improve the return value and handle it from callers
2172     $schema->txn_do(sub {
2173
2174         # Update the returndate
2175         $dbh->do( $query, undef, @bind );
2176
2177         # Retrieve the issue
2178         my $issue = Koha::Checkouts->find( $issue_id ); # FIXME should be fetched earlier
2179
2180         # Create the old_issues entry
2181         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2182
2183         # Update the fines
2184         $dbh->do(q|UPDATE accountlines SET issue_id = ? WHERE issue_id = ?|, undef, $old_checkout->issue_id, $issue->issue_id);
2185
2186         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2187         if ( $privacy == 2) {
2188             $dbh->do(q|UPDATE old_issues SET borrowernumber=? WHERE issue_id = ?|, undef, $anonymouspatron, $old_checkout->issue_id);
2189         }
2190
2191         # And finally delete the issue
2192         $issue->delete;
2193
2194         ModItem( { 'onloan' => undef }, undef, $itemnumber );
2195
2196         if ( C4::Context->preference('StoreLastBorrower') ) {
2197             my $item = Koha::Items->find( $itemnumber );
2198             my $patron = Koha::Patrons->find( $borrowernumber );
2199             $item->last_returned_by( $patron );
2200         }
2201     });
2202
2203     return $issue_id;
2204 }
2205
2206 =head2 _debar_user_on_return
2207
2208     _debar_user_on_return($borrower, $item, $datedue, today);
2209
2210 C<$borrower> borrower hashref
2211
2212 C<$item> item hashref
2213
2214 C<$datedue> date due DateTime object
2215
2216 C<$return_date> DateTime object representing the return time
2217
2218 Internal function, called only by AddReturn that calculates and updates
2219  the user fine days, and debars them if necessary.
2220
2221 Should only be called for overdue returns
2222
2223 =cut
2224
2225 sub _debar_user_on_return {
2226     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2227
2228     my $branchcode = _GetCircControlBranch( $item, $borrower );
2229
2230     my $circcontrol = C4::Context->preference('CircControl');
2231     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2232         {   categorycode => $borrower->{categorycode},
2233             itemtype     => $item->{itype},
2234             branchcode   => $branchcode
2235         }
2236     );
2237     my $finedays = $issuing_rule ? $issuing_rule->finedays : undef;
2238     my $unit     = $issuing_rule ? $issuing_rule->lengthunit : undef;
2239     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2240
2241     if ($finedays) {
2242
2243         # finedays is in days, so hourly loans must multiply by 24
2244         # thus 1 hour late equals 1 day suspension * finedays rate
2245         $finedays = $finedays * 24 if ( $unit eq 'hours' );
2246
2247         # grace period is measured in the same units as the loan
2248         my $grace =
2249           DateTime::Duration->new( $unit => $issuing_rule->firstremind );
2250
2251         my $deltadays = DateTime::Duration->new(
2252             days => $chargeable_units
2253         );
2254         if ( $deltadays->subtract($grace)->is_positive() ) {
2255             my $suspension_days = $deltadays * $finedays;
2256
2257             # If the max suspension days is < than the suspension days
2258             # the suspension days is limited to this maximum period.
2259             my $max_sd = $issuing_rule->maxsuspensiondays;
2260             if ( defined $max_sd ) {
2261                 $max_sd = DateTime::Duration->new( days => $max_sd );
2262                 $suspension_days = $max_sd
2263                   if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2264             }
2265
2266             my ( $has_been_extended, $is_a_reminder );
2267             if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2268                 my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2269                 if ( $debarment ) {
2270                     $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2271                     $has_been_extended = 1;
2272                 }
2273             }
2274
2275             my $new_debar_dt =
2276               $return_date->clone()->add_duration( $suspension_days );
2277
2278             Koha::Patron::Debarments::AddUniqueDebarment({
2279                 borrowernumber => $borrower->{borrowernumber},
2280                 expiration     => $new_debar_dt->ymd(),
2281                 type           => 'SUSPENSION',
2282             });
2283             # if borrower was already debarred but does not get an extra debarment
2284             my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2285             my $new_debarment_str;
2286             if ( $borrower->{debarred} eq $patron->is_debarred ) {
2287                 $is_a_reminder = 1;
2288                 $new_debarment_str = $borrower->{debarred};
2289             } else {
2290                 $new_debarment_str = $new_debar_dt->ymd();
2291             }
2292             # FIXME Should return a DateTime object
2293             return $new_debarment_str, $is_a_reminder;
2294         }
2295     }
2296     return;
2297 }
2298
2299 =head2 _FixOverduesOnReturn
2300
2301    &_FixOverduesOnReturn($brn,$itm, $exemptfine, $dropboxmode);
2302
2303 C<$brn> borrowernumber
2304
2305 C<$itm> itemnumber
2306
2307 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2308 C<$dropboxmode> BOOL -- remove lastincrement on overdue charge associated with this issue.
2309
2310 Internal function, called only by AddReturn
2311
2312 =cut
2313
2314 sub _FixOverduesOnReturn {
2315     my ($borrowernumber, $item);
2316     unless ($borrowernumber = shift) {
2317         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2318         return;
2319     }
2320     unless ($item = shift) {
2321         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2322         return;
2323     }
2324     my ($exemptfine, $dropbox) = @_;
2325     my $dbh = C4::Context->dbh;
2326
2327     # check for overdue fine
2328     my $sth = $dbh->prepare(
2329 "SELECT * FROM accountlines WHERE (borrowernumber = ?) AND (itemnumber = ?) AND (accounttype='FU' OR accounttype='O')"
2330     );
2331     $sth->execute( $borrowernumber, $item );
2332
2333     # alter fine to show that the book has been returned
2334     my $data = $sth->fetchrow_hashref;
2335     return 0 unless $data;    # no warning, there's just nothing to fix
2336
2337     my $uquery;
2338     my @bind = ($data->{'accountlines_id'});
2339     if ($exemptfine) {
2340         $uquery = "update accountlines set accounttype='FFOR', amountoutstanding=0";
2341         if (C4::Context->preference("FinesLog")) {
2342             &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2343         }
2344     } elsif ($dropbox && $data->{lastincrement}) {
2345         my $outstanding = $data->{amountoutstanding} - $data->{lastincrement} ;
2346         my $amt = $data->{amount} - $data->{lastincrement} ;
2347         if (C4::Context->preference("FinesLog")) {
2348             &logaction("FINES", 'MODIFY',$borrowernumber,"Dropbox adjustment $amt, item $item");
2349         }
2350          $uquery = "update accountlines set accounttype='F' ";
2351          if($outstanding  >= 0 && $amt >=0) {
2352             $uquery .= ", amount = ? , amountoutstanding=? ";
2353             unshift @bind, ($amt, $outstanding) ;
2354         }
2355     } else {
2356         $uquery = "update accountlines set accounttype='F' ";
2357     }
2358     $uquery .= " where (accountlines_id = ?)";
2359     my $usth = $dbh->prepare($uquery);
2360     return $usth->execute(@bind);
2361 }
2362
2363 =head2 _FixAccountForLostAndReturned
2364
2365   &_FixAccountForLostAndReturned($itemnumber, [$borrowernumber, $barcode]);
2366
2367 Calculates the charge for a book lost and returned.
2368
2369 Internal function, not exported, called only by AddReturn.
2370
2371 FIXME: This function reflects how inscrutable fines logic is.  Fix both.
2372 FIXME: Give a positive return value on success.  It might be the $borrowernumber who received credit, or the amount forgiven.
2373
2374 =cut
2375
2376 sub _FixAccountForLostAndReturned {
2377     my $itemnumber     = shift or return;
2378     my $borrowernumber = @_ ? shift : undef;
2379     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2380     my $dbh = C4::Context->dbh;
2381     # check for charge made for lost book
2382     my $sth = $dbh->prepare("SELECT * FROM accountlines WHERE itemnumber = ? AND accounttype IN ('L', 'Rep', 'W') ORDER BY date DESC, accountno DESC");
2383     $sth->execute($itemnumber);
2384     my $data = $sth->fetchrow_hashref;
2385     $data or return;    # bail if there is nothing to do
2386     $data->{accounttype} eq 'W' and return;    # Written off
2387
2388     # writeoff this amount
2389     my $offset;
2390     my $amount = $data->{'amount'};
2391     my $acctno = $data->{'accountno'};
2392     my $amountleft;                                             # Starts off undef/zero.
2393     if ($data->{'amountoutstanding'} == $amount) {
2394         $offset     = $data->{'amount'};
2395         $amountleft = 0;                                        # Hey, it's zero here, too.
2396     } else {
2397         $offset     = $amount - $data->{'amountoutstanding'};   # Um, isn't this the same as ZERO?  We just tested those two things are ==
2398         $amountleft = $data->{'amountoutstanding'} - $amount;   # Um, isn't this the same as ZERO?  We just tested those two things are ==
2399     }
2400     my $usth = $dbh->prepare("UPDATE accountlines SET accounttype = 'LR',amountoutstanding='0'
2401         WHERE (accountlines_id = ?)");
2402     $usth->execute($data->{'accountlines_id'});      # We might be adjusting an account for some OTHER borrowernumber now.  Not the one we passed in.
2403     #check if any credit is left if so writeoff other accounts
2404     my $nextaccntno = getnextacctno($data->{'borrowernumber'});
2405     $amountleft *= -1 if ($amountleft < 0);
2406     if ($amountleft > 0) {
2407         my $msth = $dbh->prepare("SELECT * FROM accountlines WHERE (borrowernumber = ?)
2408                             AND (amountoutstanding >0) ORDER BY date");     # might want to order by amountoustanding ASC (pay smallest first)
2409         $msth->execute($data->{'borrowernumber'});
2410         # offset transactions
2411         my $newamtos;
2412         my $accdata;
2413         while (($accdata=$msth->fetchrow_hashref) and ($amountleft>0)){
2414             if ($accdata->{'amountoutstanding'} < $amountleft) {
2415                 $newamtos = 0;
2416                 $amountleft -= $accdata->{'amountoutstanding'};
2417             }  else {
2418                 $newamtos = $accdata->{'amountoutstanding'} - $amountleft;
2419                 $amountleft = 0;
2420             }
2421             my $thisacct = $accdata->{'accountlines_id'};
2422             # FIXME: move prepares outside while loop!
2423             my $usth = $dbh->prepare("UPDATE accountlines SET amountoutstanding= ?
2424                     WHERE (accountlines_id = ?)");
2425             $usth->execute($newamtos,$thisacct);
2426             $usth = $dbh->prepare("INSERT INTO accountoffsets
2427                 (borrowernumber, accountno, offsetaccount,  offsetamount)
2428                 VALUES
2429                 (?,?,?,?)");
2430             $usth->execute($data->{'borrowernumber'},$accdata->{'accountno'},$nextaccntno,$newamtos);
2431         }
2432     }
2433     $amountleft *= -1 if ($amountleft > 0);
2434     my $desc = "Item Returned " . $item_id;
2435     $usth = $dbh->prepare("INSERT INTO accountlines
2436         (borrowernumber,accountno,date,amount,description,accounttype,amountoutstanding)
2437         VALUES (?,?,now(),?,?,'CR',?)");
2438     $usth->execute($data->{'borrowernumber'},$nextaccntno,0-$amount,$desc,$amountleft);
2439     if ($borrowernumber) {
2440         # FIXME: same as query above.  use 1 sth for both
2441         $usth = $dbh->prepare("INSERT INTO accountoffsets
2442             (borrowernumber, accountno, offsetaccount,  offsetamount)
2443             VALUES (?,?,?,?)");
2444         $usth->execute($borrowernumber, $data->{'accountno'}, $nextaccntno, $offset);
2445     }
2446     ModItem({ paidfor => '' }, undef, $itemnumber);
2447     return;
2448 }
2449
2450 =head2 _GetCircControlBranch
2451
2452    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2453
2454 Internal function :
2455
2456 Return the library code to be used to determine which circulation
2457 policy applies to a transaction.  Looks up the CircControl and
2458 HomeOrHoldingBranch system preferences.
2459
2460 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2461
2462 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2463
2464 =cut
2465
2466 sub _GetCircControlBranch {
2467     my ($item, $borrower) = @_;
2468     my $circcontrol = C4::Context->preference('CircControl');
2469     my $branch;
2470
2471     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2472         $branch= C4::Context->userenv->{'branch'};
2473     } elsif ($circcontrol eq 'PatronLibrary') {
2474         $branch=$borrower->{branchcode};
2475     } else {
2476         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2477         $branch = $item->{$branchfield};
2478         # default to item home branch if holdingbranch is used
2479         # and is not defined
2480         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2481             $branch = $item->{homebranch};
2482         }
2483     }
2484     return $branch;
2485 }
2486
2487
2488
2489
2490
2491
2492 =head2 GetItemIssue
2493
2494   $issue = &GetItemIssue($itemnumber);
2495
2496 Returns patron currently having a book, or undef if not checked out.
2497
2498 C<$itemnumber> is the itemnumber.
2499
2500 C<$issue> is a hashref of the row from the issues table.
2501
2502 =cut
2503
2504 sub GetItemIssue {
2505     my ($itemnumber) = @_;
2506     return unless $itemnumber;
2507     my $sth = C4::Context->dbh->prepare(
2508         "SELECT items.*, issues.*
2509         FROM issues
2510         LEFT JOIN items ON issues.itemnumber=items.itemnumber
2511         WHERE issues.itemnumber=?");
2512     $sth->execute($itemnumber);
2513     my $data = $sth->fetchrow_hashref;
2514     return unless $data;
2515     $data->{issuedate_sql} = $data->{issuedate};
2516     $data->{date_due_sql} = $data->{date_due};
2517     $data->{issuedate} = dt_from_string($data->{issuedate}, 'sql');
2518     $data->{issuedate}->truncate(to => 'minute');
2519     $data->{date_due} = dt_from_string($data->{date_due}, 'sql');
2520     $data->{date_due}->truncate(to => 'minute');
2521     my $dt = DateTime->now( time_zone => C4::Context->tz)->truncate( to => 'minute');
2522     $data->{'overdue'} = DateTime->compare($data->{'date_due'}, $dt ) == -1 ? 1 : 0;
2523     return $data;
2524 }
2525
2526 =head2 GetOpenIssue
2527
2528   $issue = GetOpenIssue( $itemnumber );
2529
2530 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2531
2532 C<$itemnumber> is the item's itemnumber
2533
2534 Returns a hashref
2535
2536 =cut
2537
2538 sub GetOpenIssue {
2539   my ( $itemnumber ) = @_;
2540   return unless $itemnumber;
2541   my $dbh = C4::Context->dbh;
2542   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2543   $sth->execute( $itemnumber );
2544   return $sth->fetchrow_hashref();
2545
2546 }
2547
2548 =head2 GetBiblioIssues
2549
2550   $issues = GetBiblioIssues($biblionumber);
2551
2552 this function get all issues from a biblionumber.
2553
2554 Return:
2555 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash containts all column from
2556 tables issues and the firstname,surname & cardnumber from borrowers.
2557
2558 =cut
2559
2560 sub GetBiblioIssues {
2561     my $biblionumber = shift;
2562     return unless $biblionumber;
2563     my $dbh   = C4::Context->dbh;
2564     my $query = "
2565         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2566         FROM issues
2567             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2568             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2569             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2570             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2571         WHERE biblio.biblionumber = ?
2572         UNION ALL
2573         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2574         FROM old_issues
2575             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2576             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2577             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2578             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2579         WHERE biblio.biblionumber = ?
2580         ORDER BY timestamp
2581     ";
2582     my $sth = $dbh->prepare($query);
2583     $sth->execute($biblionumber, $biblionumber);
2584
2585     my @issues;
2586     while ( my $data = $sth->fetchrow_hashref ) {
2587         push @issues, $data;
2588     }
2589     return \@issues;
2590 }
2591
2592 =head2 GetUpcomingDueIssues
2593
2594   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2595
2596 =cut
2597
2598 sub GetUpcomingDueIssues {
2599     my $params = shift;
2600
2601     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2602     my $dbh = C4::Context->dbh;
2603
2604     my $statement = <<END_SQL;
2605 SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2606 FROM issues
2607 LEFT JOIN items USING (itemnumber)
2608 LEFT OUTER JOIN branches USING (branchcode)
2609 WHERE returndate is NULL
2610 HAVING days_until_due >= 0 AND days_until_due <= ?
2611 END_SQL
2612
2613     my @bind_parameters = ( $params->{'days_in_advance'} );
2614
2615     my $sth = $dbh->prepare( $statement );
2616     $sth->execute( @bind_parameters );
2617     my $upcoming_dues = $sth->fetchall_arrayref({});
2618
2619     return $upcoming_dues;
2620 }
2621
2622 =head2 CanBookBeRenewed
2623
2624   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2625
2626 Find out whether a borrowed item may be renewed.
2627
2628 C<$borrowernumber> is the borrower number of the patron who currently
2629 has the item on loan.
2630
2631 C<$itemnumber> is the number of the item to renew.
2632
2633 C<$override_limit>, if supplied with a true value, causes
2634 the limit on the number of times that the loan can be renewed
2635 (as controlled by the item type) to be ignored. Overriding also allows
2636 to renew sooner than "No renewal before" and to manually renew loans
2637 that are automatically renewed.
2638
2639 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2640 item must currently be on loan to the specified borrower; renewals
2641 must be allowed for the item's type; and the borrower must not have
2642 already renewed the loan. $error will contain the reason the renewal can not proceed
2643
2644 =cut
2645
2646 sub CanBookBeRenewed {
2647     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2648
2649     my $dbh    = C4::Context->dbh;
2650     my $renews = 1;
2651
2652     my $item      = GetItem($itemnumber)      or return ( 0, 'no_item' );
2653     my $itemissue = GetItemIssue($itemnumber) or return ( 0, 'no_checkout' );
2654     return ( 0, 'onsite_checkout' ) if $itemissue->{onsite_checkout};
2655
2656     $borrowernumber ||= $itemissue->{borrowernumber};
2657     my $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber )
2658       or return;
2659
2660     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2661
2662     # This item can fill one or more unfilled reserve, can those unfilled reserves
2663     # all be filled by other available items?
2664     if ( $resfound
2665         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2666     {
2667         my $schema = Koha::Database->new()->schema();
2668
2669         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2670         if ($item_holds) {
2671             # There is an item level hold on this item, no other item can fill the hold
2672             $resfound = 1;
2673         }
2674         else {
2675
2676             # Get all other items that could possibly fill reserves
2677             my @itemnumbers = $schema->resultset('Item')->search(
2678                 {
2679                     biblionumber => $resrec->{biblionumber},
2680                     onloan       => undef,
2681                     notforloan   => 0,
2682                     -not         => { itemnumber => $itemnumber }
2683                 },
2684                 { columns => 'itemnumber' }
2685             )->get_column('itemnumber')->all();
2686
2687             # Get all other reserves that could have been filled by this item
2688             my @borrowernumbers;
2689             while (1) {
2690                 my ( $reserve_found, $reserve, undef ) =
2691                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2692
2693                 if ($reserve_found) {
2694                     push( @borrowernumbers, $reserve->{borrowernumber} );
2695                 }
2696                 else {
2697                     last;
2698                 }
2699             }
2700
2701             # If the count of the union of the lists of reservable items for each borrower
2702             # is equal or greater than the number of borrowers, we know that all reserves
2703             # can be filled with available items. We can get the union of the sets simply
2704             # by pushing all the elements onto an array and removing the duplicates.
2705             my @reservable;
2706             my %borrowers;
2707             ITEM: foreach my $i (@itemnumbers) {
2708                 my $item = GetItem($i);
2709                 next if IsItemOnHoldAndFound($i);
2710                 for my $b (@borrowernumbers) {
2711                     my $borr = $borrowers{$b}//= C4::Members::GetMember(borrowernumber => $b);
2712                     next unless IsAvailableForItemLevelRequest($item, $borr);
2713                     next unless CanItemBeReserved($b,$i);
2714
2715                     push @reservable, $i;
2716                     if (@reservable >= @borrowernumbers) {
2717                         $resfound = 0;
2718                         last ITEM;
2719                     }
2720                     last;
2721                 }
2722             }
2723         }
2724     }
2725     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2726
2727     return ( 1, undef ) if $override_limit;
2728
2729     my $branchcode = _GetCircControlBranch( $item, $borrower );
2730     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
2731         {   categorycode => $borrower->{categorycode},
2732             itemtype     => $item->{itype},
2733             branchcode   => $branchcode
2734         }
2735     );
2736
2737     return ( 0, "too_many" )
2738       if not $issuing_rule or $issuing_rule->renewalsallowed <= $itemissue->{renewals};
2739
2740     my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2741     my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2742     my $patron      = Koha::Patrons->find($borrowernumber);
2743     my $restricted  = $patron->is_debarred;
2744     my $hasoverdues = $patron->has_overdues;
2745
2746     if ( $restricted and $restrictionblockrenewing ) {
2747         return ( 0, 'restriction');
2748     } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($itemissue->{overdue} and $overduesblockrenewing eq 'blockitem') ) {
2749         return ( 0, 'overdue');
2750     }
2751
2752     if ( $itemissue->{auto_renew} ) {
2753         if ( defined $issuing_rule->no_auto_renewal_after
2754                 and $issuing_rule->no_auto_renewal_after ne "" ) {
2755             # Get issue_date and add no_auto_renewal_after
2756             # If this is greater than today, it's too late for renewal.
2757             my $maximum_renewal_date = dt_from_string($itemissue->{issuedate});
2758             $maximum_renewal_date->add(
2759                 $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
2760             );
2761             my $now = dt_from_string;
2762             if ( $now >= $maximum_renewal_date ) {
2763                 return ( 0, "auto_too_late" );
2764             }
2765         }
2766         if ( defined $issuing_rule->no_auto_renewal_after_hard_limit
2767                       and $issuing_rule->no_auto_renewal_after_hard_limit ne "" ) {
2768             # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2769             if ( dt_from_string >= dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit ) ) {
2770                 return ( 0, "auto_too_late" );
2771             }
2772         }
2773
2774         if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2775             my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2776             my ( $amountoutstanding ) = C4::Members::GetMemberAccountRecords($borrower->{borrowernumber});
2777             if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2778                 return ( 0, "auto_too_much_oweing" );
2779             }
2780         }
2781     }
2782
2783     if ( defined $issuing_rule->norenewalbefore
2784         and $issuing_rule->norenewalbefore ne "" )
2785     {
2786
2787         # Calculate soonest renewal by subtracting 'No renewal before' from due date
2788         my $soonestrenewal =
2789           $itemissue->{date_due}->clone()
2790           ->subtract(
2791             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
2792
2793         # Depending on syspref reset the exact time, only check the date
2794         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2795             and $issuing_rule->lengthunit eq 'days' )
2796         {
2797             $soonestrenewal->truncate( to => 'day' );
2798         }
2799
2800         if ( $soonestrenewal > DateTime->now( time_zone => C4::Context->tz() ) )
2801         {
2802             return ( 0, "auto_too_soon" ) if $itemissue->{auto_renew};
2803             return ( 0, "too_soon" );
2804         }
2805         elsif ( $itemissue->{auto_renew} ) {
2806             return ( 0, "auto_renew" );
2807         }
2808     }
2809
2810     # Fallback for automatic renewals:
2811     # If norenewalbefore is undef, don't renew before due date.
2812     if ( $itemissue->{auto_renew} ) {
2813         my $now = dt_from_string;
2814         return ( 0, "auto_renew" )
2815           if $now >= $itemissue->{date_due};
2816         return ( 0, "auto_too_soon" );
2817     }
2818
2819     return ( 1, undef );
2820 }
2821
2822 =head2 AddRenewal
2823
2824   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2825
2826 Renews a loan.
2827
2828 C<$borrowernumber> is the borrower number of the patron who currently
2829 has the item.
2830
2831 C<$itemnumber> is the number of the item to renew.
2832
2833 C<$branch> is the library where the renewal took place (if any).
2834            The library that controls the circ policies for the renewal is retrieved from the issues record.
2835
2836 C<$datedue> can be a DateTime object used to set the due date.
2837
2838 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2839 this parameter is not supplied, lastreneweddate is set to the current date.
2840
2841 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2842 from the book's item type.
2843
2844 =cut
2845
2846 sub AddRenewal {
2847     my $borrowernumber  = shift;
2848     my $itemnumber      = shift or return;
2849     my $branch          = shift;
2850     my $datedue         = shift;
2851     my $lastreneweddate = shift || DateTime->now(time_zone => C4::Context->tz)->ymd();
2852
2853     my $item   = GetItem($itemnumber) or return;
2854     my $biblio = GetBiblioFromItemNumber($itemnumber) or return;
2855
2856     my $dbh = C4::Context->dbh;
2857
2858     # Find the issues record for this book
2859     my $issuedata  = GetItemIssue($itemnumber);
2860
2861     return unless ( $issuedata );
2862
2863     $borrowernumber ||= $issuedata->{borrowernumber};
2864
2865     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2866         carp 'Invalid date passed to AddRenewal.';
2867         return;
2868     }
2869
2870     my $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber ) or return;
2871
2872     if ( C4::Context->preference('CalculateFinesOnReturn') && $issuedata->{overdue} ) {
2873         _CalculateAndUpdateFine( { issue => $issuedata, item => $item, borrower => $borrower } );
2874     }
2875     _FixOverduesOnReturn( $borrowernumber, $itemnumber );
2876
2877     # If the due date wasn't specified, calculate it by adding the
2878     # book's loan length to today's date or the current due date
2879     # based on the value of the RenewalPeriodBase syspref.
2880     unless ($datedue) {
2881
2882         my $itemtype = (C4::Context->preference('item-level_itypes')) ? $biblio->{'itype'} : $biblio->{'itemtype'};
2883
2884         $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
2885                                         dt_from_string( $issuedata->{date_due} ) :
2886                                         DateTime->now( time_zone => C4::Context->tz());
2887         $datedue =  CalcDateDue($datedue, $itemtype, _GetCircControlBranch($item, $borrower), $borrower, 'is a renewal');
2888     }
2889
2890     # Update the issues record to have the new due date, and a new count
2891     # of how many times it has been renewed.
2892     my $renews = $issuedata->{'renewals'} + 1;
2893     my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
2894                             WHERE borrowernumber=?
2895                             AND itemnumber=?"
2896     );
2897
2898     $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
2899
2900     # Update the renewal count on the item, and tell zebra to reindex
2901     $renews = $biblio->{'renewals'} + 1;
2902     ModItem({ renewals => $renews, onloan => $datedue->strftime('%Y-%m-%d %H:%M')}, $biblio->{'biblionumber'}, $itemnumber);
2903
2904     # Charge a new rental fee, if applicable?
2905     my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
2906     if ( $charge > 0 ) {
2907         my $accountno = getnextacctno( $borrowernumber );
2908         my $item = GetBiblioFromItemNumber($itemnumber);
2909         my $manager_id = 0;
2910         $manager_id = C4::Context->userenv->{'number'} if C4::Context->userenv;
2911         $sth = $dbh->prepare(
2912                 "INSERT INTO accountlines
2913                     (date, borrowernumber, accountno, amount, manager_id,
2914                     description,accounttype, amountoutstanding, itemnumber)
2915                     VALUES (now(),?,?,?,?,?,?,?,?)"
2916         );
2917         $sth->execute( $borrowernumber, $accountno, $charge, $manager_id,
2918             "Renewal of Rental Item $item->{'title'} $item->{'barcode'}",
2919             'Rent', $charge, $itemnumber );
2920     }
2921
2922     # Send a renewal slip according to checkout alert preferencei
2923     if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
2924         $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber );
2925         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2926         my %conditions        = (
2927             branchcode   => $branch,
2928             categorycode => $borrower->{categorycode},
2929             item_type    => $item->{itype},
2930             notification => 'CHECKOUT',
2931         );
2932         if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
2933             SendCirculationAlert(
2934                 {
2935                     type     => 'RENEWAL',
2936                     item     => $item,
2937                     borrower => $borrower,
2938                     branch   => $branch,
2939                 }
2940             );
2941         }
2942     }
2943
2944     # Remove any OVERDUES related debarment if the borrower has no overdues
2945     $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber );
2946     if ( $borrowernumber
2947       && $borrower->{'debarred'}
2948       && !Koha::Patrons->find( $borrowernumber )->has_overdues
2949       && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2950     ) {
2951         DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2952     }
2953
2954     unless ( C4::Context->interface eq 'opac' ) { #if from opac we are obeying OpacRenewalBranch as calculated in opac-renew.pl
2955         $branch = C4::Context->userenv ? C4::Context->userenv->{branch} : $branch;
2956     }
2957
2958     # Add the renewal to stats
2959     UpdateStats(
2960         {
2961             branch         => $branch,
2962             type           => 'renew',
2963             amount         => $charge,
2964             itemnumber     => $itemnumber,
2965             itemtype       => $item->{itype},
2966             borrowernumber => $borrowernumber,
2967             ccode          => $item->{'ccode'}
2968         }
2969     );
2970
2971     #Log the renewal
2972     logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
2973     return $datedue;
2974 }
2975
2976 sub GetRenewCount {
2977     # check renewal status
2978     my ( $bornum, $itemno ) = @_;
2979     my $dbh           = C4::Context->dbh;
2980     my $renewcount    = 0;
2981     my $renewsallowed = 0;
2982     my $renewsleft    = 0;
2983
2984     my $borrower = C4::Members::GetMember( borrowernumber => $bornum);
2985     my $item     = GetItem($itemno);
2986
2987     # Look in the issues table for this item, lent to this borrower,
2988     # and not yet returned.
2989
2990     # FIXME - I think this function could be redone to use only one SQL call.
2991     my $sth = $dbh->prepare(
2992         "select * from issues
2993                                 where (borrowernumber = ?)
2994                                 and (itemnumber = ?)"
2995     );
2996     $sth->execute( $bornum, $itemno );
2997     my $data = $sth->fetchrow_hashref;
2998     $renewcount = $data->{'renewals'} if $data->{'renewals'};
2999     # $item and $borrower should be calculated
3000     my $branchcode = _GetCircControlBranch($item, $borrower);
3001
3002     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3003         {   categorycode => $borrower->{categorycode},
3004             itemtype     => $item->{itype},
3005             branchcode   => $branchcode
3006         }
3007     );
3008
3009     $renewsallowed = $issuing_rule ? $issuing_rule->renewalsallowed : undef; # FIXME Just replace undef with 0 to get what we expected. But what about the side-effects? TODO LATER
3010     $renewsleft    = $renewsallowed - $renewcount;
3011     if($renewsleft < 0){ $renewsleft = 0; }
3012     return ( $renewcount, $renewsallowed, $renewsleft );
3013 }
3014
3015 =head2 GetSoonestRenewDate
3016
3017   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3018
3019 Find out the soonest possible renew date of a borrowed item.
3020
3021 C<$borrowernumber> is the borrower number of the patron who currently
3022 has the item on loan.
3023
3024 C<$itemnumber> is the number of the item to renew.
3025
3026 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3027 renew date, based on the value "No renewal before" of the applicable
3028 issuing rule. Returns the current date if the item can already be
3029 renewed, and returns undefined if the borrower, loan, or item
3030 cannot be found.
3031
3032 =cut
3033
3034 sub GetSoonestRenewDate {
3035     my ( $borrowernumber, $itemnumber ) = @_;
3036
3037     my $dbh = C4::Context->dbh;
3038
3039     my $item      = GetItem($itemnumber)      or return;
3040     my $itemissue = GetItemIssue($itemnumber) or return;
3041
3042     $borrowernumber ||= $itemissue->{borrowernumber};
3043     my $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber )
3044       or return;
3045
3046     my $branchcode = _GetCircControlBranch( $item, $borrower );
3047     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3048         {   categorycode => $borrower->{categorycode},
3049             itemtype     => $item->{itype},
3050             branchcode   => $branchcode
3051         }
3052     );
3053
3054     my $now = dt_from_string;
3055     return $now unless $issuing_rule;
3056
3057     if ( defined $issuing_rule->norenewalbefore
3058         and $issuing_rule->norenewalbefore ne "" )
3059     {
3060         my $soonestrenewal =
3061           $itemissue->{date_due}->clone()
3062           ->subtract(
3063             $issuing_rule->lengthunit => $issuing_rule->norenewalbefore );
3064
3065         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3066             and $issuing_rule->lengthunit eq 'days' )
3067         {
3068             $soonestrenewal->truncate( to => 'day' );
3069         }
3070         return $soonestrenewal if $now < $soonestrenewal;
3071     }
3072     return $now;
3073 }
3074
3075 =head2 GetLatestAutoRenewDate
3076
3077   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3078
3079 Find out the latest possible auto renew date of a borrowed item.
3080
3081 C<$borrowernumber> is the borrower number of the patron who currently
3082 has the item on loan.
3083
3084 C<$itemnumber> is the number of the item to renew.
3085
3086 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3087 auto renew date, based on the value "No auto renewal after" and the "No auto
3088 renewal after (hard limit) of the applicable issuing rule.
3089 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3090 or item cannot be found.
3091
3092 =cut
3093
3094 sub GetLatestAutoRenewDate {
3095     my ( $borrowernumber, $itemnumber ) = @_;
3096
3097     my $dbh = C4::Context->dbh;
3098
3099     my $item      = GetItem($itemnumber)      or return;
3100     my $itemissue = GetItemIssue($itemnumber) or return;
3101
3102     $borrowernumber ||= $itemissue->{borrowernumber};
3103     my $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber )
3104       or return;
3105
3106     my $branchcode = _GetCircControlBranch( $item, $borrower );
3107     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule(
3108         {   categorycode => $borrower->{categorycode},
3109             itemtype     => $item->{itype},
3110             branchcode   => $branchcode
3111         }
3112     );
3113
3114     return unless $issuing_rule;
3115     return
3116       if ( not $issuing_rule->no_auto_renewal_after
3117             or $issuing_rule->no_auto_renewal_after eq '' )
3118       and ( not $issuing_rule->no_auto_renewal_after_hard_limit
3119              or $issuing_rule->no_auto_renewal_after_hard_limit eq '' );
3120
3121     my $maximum_renewal_date;
3122     if ( $issuing_rule->no_auto_renewal_after ) {
3123         $maximum_renewal_date = dt_from_string($itemissue->{issuedate});
3124         $maximum_renewal_date->add(
3125             $issuing_rule->lengthunit => $issuing_rule->no_auto_renewal_after
3126         );
3127     }
3128
3129     if ( $issuing_rule->no_auto_renewal_after_hard_limit ) {
3130         my $dt = dt_from_string( $issuing_rule->no_auto_renewal_after_hard_limit );
3131         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3132     }
3133     return $maximum_renewal_date;
3134 }
3135
3136
3137 =head2 GetIssuingCharges
3138
3139   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3140
3141 Calculate how much it would cost for a given patron to borrow a given
3142 item, including any applicable discounts.
3143
3144 C<$itemnumber> is the item number of item the patron wishes to borrow.
3145
3146 C<$borrowernumber> is the patron's borrower number.
3147
3148 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3149 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3150 if it's a video).
3151
3152 =cut
3153
3154 sub GetIssuingCharges {
3155
3156     # calculate charges due
3157     my ( $itemnumber, $borrowernumber ) = @_;
3158     my $charge = 0;
3159     my $dbh    = C4::Context->dbh;
3160     my $item_type;
3161
3162     # Get the book's item type and rental charge (via its biblioitem).
3163     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3164         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3165     $charge_query .= (C4::Context->preference('item-level_itypes'))
3166         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3167         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3168
3169     $charge_query .= ' WHERE items.itemnumber =?';
3170
3171     my $sth = $dbh->prepare($charge_query);
3172     $sth->execute($itemnumber);
3173     if ( my $item_data = $sth->fetchrow_hashref ) {
3174         $item_type = $item_data->{itemtype};
3175         $charge    = $item_data->{rentalcharge};
3176         my $branch = C4::Context::mybranch();
3177         my $discount_query = q|SELECT rentaldiscount,
3178             issuingrules.itemtype, issuingrules.branchcode
3179             FROM borrowers
3180             LEFT JOIN issuingrules ON borrowers.categorycode = issuingrules.categorycode
3181             WHERE borrowers.borrowernumber = ?
3182             AND (issuingrules.itemtype = ? OR issuingrules.itemtype = '*')
3183             AND (issuingrules.branchcode = ? OR issuingrules.branchcode = '*')|;
3184         my $discount_sth = $dbh->prepare($discount_query);
3185         $discount_sth->execute( $borrowernumber, $item_type, $branch );
3186         my $discount_rules = $discount_sth->fetchall_arrayref({});
3187         if (@{$discount_rules}) {
3188             # We may have multiple rules so get the most specific
3189             my $discount = _get_discount_from_rule($discount_rules, $branch, $item_type);
3190             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3191         }
3192         if ($charge) {
3193             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3194         }
3195     }
3196
3197     return ( $charge, $item_type );
3198 }
3199
3200 # Select most appropriate discount rule from those returned
3201 sub _get_discount_from_rule {
3202     my ($rules_ref, $branch, $itemtype) = @_;
3203     my $discount;
3204
3205     if (@{$rules_ref} == 1) { # only 1 applicable rule use it
3206         $discount = $rules_ref->[0]->{rentaldiscount};
3207         return (defined $discount) ? $discount : 0;
3208     }
3209     # could have up to 4 does one match $branch and $itemtype
3210     my @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq $itemtype } @{$rules_ref};
3211     if (@d) {
3212         $discount = $d[0]->{rentaldiscount};
3213         return (defined $discount) ? $discount : 0;
3214     }
3215     # do we have item type + all branches
3216     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq $itemtype } @{$rules_ref};
3217     if (@d) {
3218         $discount = $d[0]->{rentaldiscount};
3219         return (defined $discount) ? $discount : 0;
3220     }
3221     # do we all item types + this branch
3222     @d = grep { $_->{branchcode} eq $branch && $_->{itemtype} eq q{*} } @{$rules_ref};
3223     if (@d) {
3224         $discount = $d[0]->{rentaldiscount};
3225         return (defined $discount) ? $discount : 0;
3226     }
3227     # so all and all (surely we wont get here)
3228     @d = grep { $_->{branchcode} eq q{*} && $_->{itemtype} eq q{*} } @{$rules_ref};
3229     if (@d) {
3230         $discount = $d[0]->{rentaldiscount};
3231         return (defined $discount) ? $discount : 0;
3232     }
3233     # none of the above
3234     return 0;
3235 }
3236
3237 =head2 AddIssuingCharge
3238
3239   &AddIssuingCharge( $itemno, $borrowernumber, $charge )
3240
3241 =cut
3242
3243 sub AddIssuingCharge {
3244     my ( $itemnumber, $borrowernumber, $charge ) = @_;
3245     my $dbh = C4::Context->dbh;
3246     my $nextaccntno = getnextacctno( $borrowernumber );
3247     my $manager_id = 0;
3248     $manager_id = C4::Context->userenv->{'number'} if C4::Context->userenv;
3249     my $query ="
3250         INSERT INTO accountlines
3251             (borrowernumber, itemnumber, accountno,
3252             date, amount, description, accounttype,
3253             amountoutstanding, manager_id)
3254         VALUES (?, ?, ?,now(), ?, 'Rental', 'Rent',?,?)
3255     ";
3256     my $sth = $dbh->prepare($query);
3257     $sth->execute( $borrowernumber, $itemnumber, $nextaccntno, $charge, $charge, $manager_id );
3258 }
3259
3260 =head2 GetTransfers
3261
3262   GetTransfers($itemnumber);
3263
3264 =cut
3265
3266 sub GetTransfers {
3267     my ($itemnumber) = @_;
3268
3269     my $dbh = C4::Context->dbh;
3270
3271     my $query = '
3272         SELECT datesent,
3273                frombranch,
3274                tobranch,
3275                branchtransfer_id
3276         FROM branchtransfers
3277         WHERE itemnumber = ?
3278           AND datearrived IS NULL
3279         ';
3280     my $sth = $dbh->prepare($query);
3281     $sth->execute($itemnumber);
3282     my @row = $sth->fetchrow_array();
3283     return @row;
3284 }
3285
3286 =head2 GetTransfersFromTo
3287
3288   @results = GetTransfersFromTo($frombranch,$tobranch);
3289
3290 Returns the list of pending transfers between $from and $to branch
3291
3292 =cut
3293
3294 sub GetTransfersFromTo {
3295     my ( $frombranch, $tobranch ) = @_;
3296     return unless ( $frombranch && $tobranch );
3297     my $dbh   = C4::Context->dbh;
3298     my $query = "
3299         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3300         FROM   branchtransfers
3301         WHERE  frombranch=?
3302           AND  tobranch=?
3303           AND datearrived IS NULL
3304     ";
3305     my $sth = $dbh->prepare($query);
3306     $sth->execute( $frombranch, $tobranch );
3307     my @gettransfers;
3308
3309     while ( my $data = $sth->fetchrow_hashref ) {
3310         push @gettransfers, $data;
3311     }
3312     return (@gettransfers);
3313 }
3314
3315 =head2 DeleteTransfer
3316
3317   &DeleteTransfer($itemnumber);
3318
3319 =cut
3320
3321 sub DeleteTransfer {
3322     my ($itemnumber) = @_;
3323     return unless $itemnumber;
3324     my $dbh          = C4::Context->dbh;
3325     my $sth          = $dbh->prepare(
3326         "DELETE FROM branchtransfers
3327          WHERE itemnumber=?
3328          AND datearrived IS NULL "
3329     );
3330     return $sth->execute($itemnumber);
3331 }
3332
3333 =head2 SendCirculationAlert
3334
3335 Send out a C<check-in> or C<checkout> alert using the messaging system.
3336
3337 B<Parameters>:
3338
3339 =over 4
3340
3341 =item type
3342
3343 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3344
3345 =item item
3346
3347 Hashref of information about the item being checked in or out.
3348
3349 =item borrower
3350
3351 Hashref of information about the borrower of the item.
3352
3353 =item branch
3354
3355 The branchcode from where the checkout or check-in took place.
3356
3357 =back
3358
3359 B<Example>:
3360
3361     SendCirculationAlert({
3362         type     => 'CHECKOUT',
3363         item     => $item,
3364         borrower => $borrower,
3365         branch   => $branch,
3366     });
3367
3368 =cut
3369
3370 sub SendCirculationAlert {
3371     my ($opts) = @_;
3372     my ($type, $item, $borrower, $branch) =
3373         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3374     my %message_name = (
3375         CHECKIN  => 'Item_Check_in',
3376         CHECKOUT => 'Item_Checkout',
3377         RENEWAL  => 'Item_Checkout',
3378     );
3379     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3380         borrowernumber => $borrower->{borrowernumber},
3381         message_name   => $message_name{$type},
3382     });
3383     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3384
3385     my $schema = Koha::Database->new->schema;
3386     my @transports = keys %{ $borrower_preferences->{transports} };
3387
3388     # From the MySQL doc:
3389     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3390     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3391     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3392     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_NO_TABLE_LOCKS};
3393
3394     for my $mtt (@transports) {
3395         my $letter =  C4::Letters::GetPreparedLetter (
3396             module => 'circulation',
3397             letter_code => $type,
3398             branchcode => $branch,
3399             message_transport_type => $mtt,
3400             lang => $borrower->{lang},
3401             tables => {
3402                 $issues_table => $item->{itemnumber},
3403                 'items'       => $item->{itemnumber},
3404                 'biblio'      => $item->{biblionumber},
3405                 'biblioitems' => $item->{biblionumber},
3406                 'borrowers'   => $borrower,
3407                 'branches'    => $branch,
3408             }
3409         ) or next;
3410
3411         $schema->storage->txn_begin;
3412         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3413         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3414         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3415         unless ( $message ) {
3416             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3417             C4::Message->enqueue($letter, $borrower, $mtt);
3418         } else {
3419             $message->append($letter);
3420             $message->update;
3421         }
3422         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3423         $schema->storage->txn_commit;
3424     }
3425
3426     return;
3427 }
3428
3429 =head2 updateWrongTransfer
3430
3431   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3432
3433 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3434
3435 =cut
3436
3437 sub updateWrongTransfer {
3438         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3439         my $dbh = C4::Context->dbh;
3440 # first step validate the actual line of transfert .
3441         my $sth =
3442                 $dbh->prepare(
3443                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3444                 );
3445                 $sth->execute($FromLibrary,$itemNumber);
3446
3447 # second step create a new line of branchtransfer to the right location .
3448         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3449
3450 #third step changing holdingbranch of item
3451         UpdateHoldingbranch($FromLibrary,$itemNumber);
3452 }
3453
3454 =head2 UpdateHoldingbranch
3455
3456   $items = UpdateHoldingbranch($branch,$itmenumber);
3457
3458 Simple methode for updating hodlingbranch in items BDD line
3459
3460 =cut
3461
3462 sub UpdateHoldingbranch {
3463         my ( $branch,$itemnumber ) = @_;
3464     ModItem({ holdingbranch => $branch }, undef, $itemnumber);
3465 }
3466
3467 =head2 CalcDateDue
3468
3469 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3470
3471 this function calculates the due date given the start date and configured circulation rules,
3472 checking against the holidays calendar as per the 'useDaysMode' syspref.
3473 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3474 C<$itemtype>  = itemtype code of item in question
3475 C<$branch>  = location whose calendar to use
3476 C<$borrower> = Borrower object
3477 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3478
3479 =cut
3480
3481 sub CalcDateDue {
3482     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3483
3484     $isrenewal ||= 0;
3485
3486     # loanlength now a href
3487     my $loanlength =
3488             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3489
3490     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3491             ? qq{renewalperiod}
3492             : qq{issuelength};
3493
3494     my $datedue;
3495     if ( $startdate ) {
3496         if (ref $startdate ne 'DateTime' ) {
3497             $datedue = dt_from_string($datedue);
3498         } else {
3499             $datedue = $startdate->clone;
3500         }
3501     } else {
3502         $datedue =
3503           DateTime->now( time_zone => C4::Context->tz() )
3504           ->truncate( to => 'minute' );
3505     }
3506
3507
3508     # calculate the datedue as normal
3509     if ( C4::Context->preference('useDaysMode') eq 'Days' )
3510     {    # ignoring calendar
3511         if ( $loanlength->{lengthunit} eq 'hours' ) {
3512             $datedue->add( hours => $loanlength->{$length_key} );
3513         } else {    # days
3514             $datedue->add( days => $loanlength->{$length_key} );
3515             $datedue->set_hour(23);
3516             $datedue->set_minute(59);
3517         }
3518     } else {
3519         my $dur;
3520         if ($loanlength->{lengthunit} eq 'hours') {
3521             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3522         }
3523         else { # days
3524             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3525         }
3526         my $calendar = Koha::Calendar->new( branchcode => $branch );
3527         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3528         if ($loanlength->{lengthunit} eq 'days') {
3529             $datedue->set_hour(23);
3530             $datedue->set_minute(59);
3531         }
3532     }
3533
3534     # if Hard Due Dates are used, retrieve them and apply as necessary
3535     my ( $hardduedate, $hardduedatecompare ) =
3536       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3537     if ($hardduedate) {    # hardduedates are currently dates
3538         $hardduedate->truncate( to => 'minute' );
3539         $hardduedate->set_hour(23);
3540         $hardduedate->set_minute(59);
3541         my $cmp = DateTime->compare( $hardduedate, $datedue );
3542
3543 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3544 # if the calculated date is before the 'after' Hard Due Date (floor), override
3545 # if the hard due date is set to 'exactly', overrride
3546         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3547             $datedue = $hardduedate->clone;
3548         }
3549
3550         # in all other cases, keep the date due as it is
3551
3552     }
3553
3554     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3555     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3556         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3557         if( $expiry_dt ) { #skip empty expiry date..
3558             $expiry_dt->set( hour => 23, minute => 59);
3559             my $d1= $datedue->clone->set_time_zone('floating');
3560             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3561                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3562             }
3563         }
3564     }
3565
3566     return $datedue;
3567 }
3568
3569
3570 sub CheckValidBarcode{
3571 my ($barcode) = @_;
3572 my $dbh = C4::Context->dbh;
3573 my $query=qq|SELECT count(*)
3574              FROM items
3575              WHERE barcode=?
3576             |;
3577 my $sth = $dbh->prepare($query);
3578 $sth->execute($barcode);
3579 my $exist=$sth->fetchrow ;
3580 return $exist;
3581 }
3582
3583 =head2 IsBranchTransferAllowed
3584
3585   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3586
3587 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3588
3589 =cut
3590
3591 sub IsBranchTransferAllowed {
3592         my ( $toBranch, $fromBranch, $code ) = @_;
3593
3594         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3595
3596         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3597         my $dbh = C4::Context->dbh;
3598
3599         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3600         $sth->execute( $toBranch, $fromBranch, $code );
3601         my $limit = $sth->fetchrow_hashref();
3602
3603         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3604         if ( $limit->{'limitId'} ) {
3605                 return 0;
3606         } else {
3607                 return 1;
3608         }
3609 }
3610
3611 =head2 CreateBranchTransferLimit
3612
3613   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3614
3615 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3616
3617 =cut
3618
3619 sub CreateBranchTransferLimit {
3620    my ( $toBranch, $fromBranch, $code ) = @_;
3621    return unless defined($toBranch) && defined($fromBranch);
3622    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3623
3624    my $dbh = C4::Context->dbh;
3625
3626    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3627    return $sth->execute( $code, $toBranch, $fromBranch );
3628 }
3629
3630 =head2 DeleteBranchTransferLimits
3631
3632     my $result = DeleteBranchTransferLimits($frombranch);
3633
3634 Deletes all the library transfer limits for one library.  Returns the
3635 number of limits deleted, 0e0 if no limits were deleted, or undef if
3636 no arguments are supplied.
3637
3638 =cut
3639
3640 sub DeleteBranchTransferLimits {
3641     my $branch = shift;
3642     return unless defined $branch;
3643     my $dbh    = C4::Context->dbh;
3644     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3645     return $sth->execute($branch);
3646 }
3647
3648 sub ReturnLostItem{
3649     my ( $borrowernumber, $itemnum ) = @_;
3650
3651     MarkIssueReturned( $borrowernumber, $itemnum );
3652     my $borrower = C4::Members::GetMember( 'borrowernumber'=>$borrowernumber );
3653     my $item = C4::Items::GetItem( $itemnum );
3654     my $old_note = ($item->{'paidfor'} && ($item->{'paidfor'} ne q{})) ? $item->{'paidfor'}.' / ' : q{};
3655     my @datearr = localtime(time);
3656     my $date = ( 1900 + $datearr[5] ) . "-" . ( $datearr[4] + 1 ) . "-" . $datearr[3];
3657     my $bor = "$borrower->{'firstname'} $borrower->{'surname'} $borrower->{'cardnumber'}";
3658     ModItem({ paidfor =>  $old_note."Paid for by $bor $date" }, undef, $itemnum);
3659 }
3660
3661
3662 sub LostItem{
3663     my ($itemnumber, $mark_returned) = @_;
3664
3665     my $dbh = C4::Context->dbh();
3666     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3667                            FROM issues
3668                            JOIN items USING (itemnumber)
3669                            JOIN biblio USING (biblionumber)
3670                            WHERE issues.itemnumber=?");
3671     $sth->execute($itemnumber);
3672     my $issues=$sth->fetchrow_hashref();
3673
3674     # If a borrower lost the item, add a replacement cost to the their record
3675     if ( my $borrowernumber = $issues->{borrowernumber} ){
3676         my $borrower = C4::Members::GetMember( borrowernumber => $borrowernumber );
3677
3678         if (C4::Context->preference('WhenLostForgiveFine')){
3679             my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, 1, 0); # 1, 0 = exemptfine, no-dropbox
3680             defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3681         }
3682         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3683             C4::Accounts::chargelostitem($borrowernumber, $itemnumber, $issues->{'replacementprice'}, "Lost Item $issues->{'title'} $issues->{'barcode'}");
3684             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3685             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3686         }
3687
3688         MarkIssueReturned($borrowernumber,$itemnumber,undef,undef,$borrower->{'privacy'}) if $mark_returned;
3689     }
3690 }
3691
3692 sub GetOfflineOperations {
3693     my $dbh = C4::Context->dbh;
3694     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3695     $sth->execute(C4::Context->userenv->{'branch'});
3696     my $results = $sth->fetchall_arrayref({});
3697     return $results;
3698 }
3699
3700 sub GetOfflineOperation {
3701     my $operationid = shift;
3702     return unless $operationid;
3703     my $dbh = C4::Context->dbh;
3704     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3705     $sth->execute( $operationid );
3706     return $sth->fetchrow_hashref;
3707 }
3708
3709 sub AddOfflineOperation {
3710     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3711     my $dbh = C4::Context->dbh;
3712     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3713     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3714     return "Added.";
3715 }
3716
3717 sub DeleteOfflineOperation {
3718     my $dbh = C4::Context->dbh;
3719     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3720     $sth->execute( shift );
3721     return "Deleted.";
3722 }
3723
3724 sub ProcessOfflineOperation {
3725     my $operation = shift;
3726
3727     my $report;
3728     if ( $operation->{action} eq 'return' ) {
3729         $report = ProcessOfflineReturn( $operation );
3730     } elsif ( $operation->{action} eq 'issue' ) {
3731         $report = ProcessOfflineIssue( $operation );
3732     } elsif ( $operation->{action} eq 'payment' ) {
3733         $report = ProcessOfflinePayment( $operation );
3734     }
3735
3736     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3737
3738     return $report;
3739 }
3740
3741 sub ProcessOfflineReturn {
3742     my $operation = shift;
3743
3744     my $itemnumber = C4::Items::GetItemnumberFromBarcode( $operation->{barcode} );
3745
3746     if ( $itemnumber ) {
3747         my $issue = GetOpenIssue( $itemnumber );
3748         if ( $issue ) {
3749             MarkIssueReturned(
3750                 $issue->{borrowernumber},
3751                 $itemnumber,
3752                 undef,
3753                 $operation->{timestamp},
3754             );
3755             ModItem(
3756                 { renewals => 0, onloan => undef },
3757                 $issue->{'biblionumber'},
3758                 $itemnumber
3759             );
3760             return "Success.";
3761         } else {
3762             return "Item not issued.";
3763         }
3764     } else {
3765         return "Item not found.";
3766     }
3767 }
3768
3769 sub ProcessOfflineIssue {
3770     my $operation = shift;
3771
3772     my $borrower = C4::Members::GetMember( cardnumber => $operation->{cardnumber} );
3773
3774     if ( $borrower->{borrowernumber} ) {
3775         my $itemnumber = C4::Items::GetItemnumberFromBarcode( $operation->{barcode} );
3776         unless ($itemnumber) {
3777             return "Barcode not found.";
3778         }
3779         my $issue = GetOpenIssue( $itemnumber );
3780
3781         if ( $issue and ( $issue->{borrowernumber} ne $borrower->{borrowernumber} ) ) { # Item already issued to another borrower, mark it returned
3782             MarkIssueReturned(
3783                 $issue->{borrowernumber},
3784                 $itemnumber,
3785                 undef,
3786                 $operation->{timestamp},
3787             );
3788         }
3789         AddIssue(
3790             $borrower,
3791             $operation->{'barcode'},
3792             undef,
3793             1,
3794             $operation->{timestamp},
3795             undef,
3796         );
3797         return "Success.";
3798     } else {
3799         return "Borrower not found.";
3800     }
3801 }
3802
3803 sub ProcessOfflinePayment {
3804     my $operation = shift;
3805
3806     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} });
3807     my $amount = $operation->{amount};
3808
3809     Koha::Account->new( { patron_id => $patron->id } )->pay( { amount => $amount } );
3810
3811     return "Success."
3812 }
3813
3814
3815 =head2 TransferSlip
3816
3817   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
3818
3819   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
3820
3821 =cut
3822
3823 sub TransferSlip {
3824     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
3825
3826     my $item =  GetItem( $itemnumber, $barcode )
3827       or return;
3828
3829     return C4::Letters::GetPreparedLetter (
3830         module => 'circulation',
3831         letter_code => 'TRANSFERSLIP',
3832         branchcode => $branch,
3833         tables => {
3834             'branches'    => $to_branch,
3835             'biblio'      => $item->{biblionumber},
3836             'items'       => $item,
3837         },
3838     );
3839 }
3840
3841 =head2 CheckIfIssuedToPatron
3842
3843   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
3844
3845   Return 1 if any record item is issued to patron, otherwise return 0
3846
3847 =cut
3848
3849 sub CheckIfIssuedToPatron {
3850     my ($borrowernumber, $biblionumber) = @_;
3851
3852     my $dbh = C4::Context->dbh;
3853     my $query = q|
3854         SELECT COUNT(*) FROM issues
3855         LEFT JOIN items ON items.itemnumber = issues.itemnumber
3856         WHERE items.biblionumber = ?
3857         AND issues.borrowernumber = ?
3858     |;
3859     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
3860     return 1 if $is_issued;
3861     return;
3862 }
3863
3864 =head2 IsItemIssued
3865
3866   IsItemIssued( $itemnumber )
3867
3868   Return 1 if the item is on loan, otherwise return 0
3869
3870 =cut
3871
3872 sub IsItemIssued {
3873     my $itemnumber = shift;
3874     my $dbh = C4::Context->dbh;
3875     my $sth = $dbh->prepare(q{
3876         SELECT COUNT(*)
3877         FROM issues
3878         WHERE itemnumber = ?
3879     });
3880     $sth->execute($itemnumber);
3881     return $sth->fetchrow;
3882 }
3883
3884 =head2 GetAgeRestriction
3885
3886   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
3887   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
3888
3889   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
3890   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
3891
3892 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
3893 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
3894 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
3895          Negative days mean the borrower has gone past the age restriction age.
3896
3897 =cut
3898
3899 sub GetAgeRestriction {
3900     my ($record_restrictions, $borrower) = @_;
3901     my $markers = C4::Context->preference('AgeRestrictionMarker');
3902
3903     # Split $record_restrictions to something like FSK 16 or PEGI 6
3904     my @values = split ' ', uc($record_restrictions);
3905     return unless @values;
3906
3907     # Search first occurrence of one of the markers
3908     my @markers = split /\|/, uc($markers);
3909     return unless @markers;
3910
3911     my $index            = 0;
3912     my $restriction_year = 0;
3913     for my $value (@values) {
3914         $index++;
3915         for my $marker (@markers) {
3916             $marker =~ s/^\s+//;    #remove leading spaces
3917             $marker =~ s/\s+$//;    #remove trailing spaces
3918             if ( $marker eq $value ) {
3919                 if ( $index <= $#values ) {
3920                     $restriction_year += $values[$index];
3921                 }
3922                 last;
3923             }
3924             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
3925
3926                 # Perhaps it is something like "K16" (as in Finland)
3927                 $restriction_year += $1;
3928                 last;
3929             }
3930         }
3931         last if ( $restriction_year > 0 );
3932     }
3933
3934     #Check if the borrower is age restricted for this material and for how long.
3935     if ($restriction_year && $borrower) {
3936         if ( $borrower->{'dateofbirth'} ) {
3937             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
3938             $alloweddate[0] += $restriction_year;
3939
3940             #Prevent runime eror on leap year (invalid date)
3941             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
3942                 $alloweddate[2] = 28;
3943             }
3944
3945             #Get how many days the borrower has to reach the age restriction
3946             my @Today = split /-/, DateTime->today->ymd();
3947             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
3948             #Negative days means the borrower went past the age restriction age
3949             return ($restriction_year, $daysToAgeRestriction);
3950         }
3951     }
3952
3953     return ($restriction_year);
3954 }
3955
3956
3957 =head2 GetPendingOnSiteCheckouts
3958
3959 =cut
3960
3961 sub GetPendingOnSiteCheckouts {
3962     my $dbh = C4::Context->dbh;
3963     return $dbh->selectall_arrayref(q|
3964         SELECT
3965           items.barcode,
3966           items.biblionumber,
3967           items.itemnumber,
3968           items.itemnotes,
3969           items.itemcallnumber,
3970           items.location,
3971           issues.date_due,
3972           issues.branchcode,
3973           issues.date_due < NOW() AS is_overdue,
3974           biblio.author,
3975           biblio.title,
3976           borrowers.firstname,
3977           borrowers.surname,
3978           borrowers.cardnumber,
3979           borrowers.borrowernumber
3980         FROM items
3981         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
3982         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
3983         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
3984         WHERE issues.onsite_checkout = 1
3985     |, { Slice => {} } );
3986 }
3987
3988 sub GetTopIssues {
3989     my ($params) = @_;
3990
3991     my ($count, $branch, $itemtype, $ccode, $newness)
3992         = @$params{qw(count branch itemtype ccode newness)};
3993
3994     my $dbh = C4::Context->dbh;
3995     my $query = q{
3996         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
3997           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
3998           i.ccode, SUM(i.issues) AS count
3999         FROM biblio b
4000         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4001         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4002     };
4003
4004     my (@where_strs, @where_args);
4005
4006     if ($branch) {
4007         push @where_strs, 'i.homebranch = ?';
4008         push @where_args, $branch;
4009     }
4010     if ($itemtype) {
4011         if (C4::Context->preference('item-level_itypes')){
4012             push @where_strs, 'i.itype = ?';
4013             push @where_args, $itemtype;
4014         } else {
4015             push @where_strs, 'bi.itemtype = ?';
4016             push @where_args, $itemtype;
4017         }
4018     }
4019     if ($ccode) {
4020         push @where_strs, 'i.ccode = ?';
4021         push @where_args, $ccode;
4022     }
4023     if ($newness) {
4024         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4025         push @where_args, $newness;
4026     }
4027
4028     if (@where_strs) {
4029         $query .= 'WHERE ' . join(' AND ', @where_strs);
4030     }
4031
4032     $query .= q{
4033         GROUP BY b.biblionumber
4034         HAVING count > 0
4035         ORDER BY count DESC
4036     };
4037
4038     $count = int($count);
4039     if ($count > 0) {
4040         $query .= "LIMIT $count";
4041     }
4042
4043     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4044
4045     return @$rows;
4046 }
4047
4048 sub _CalculateAndUpdateFine {
4049     my ($params) = @_;
4050
4051     my $borrower    = $params->{borrower};
4052     my $item        = $params->{item};
4053     my $issue       = $params->{issue};
4054     my $return_date = $params->{return_date};
4055
4056     unless ($borrower) { carp "No borrower passed in!" && return; }
4057     unless ($item)     { carp "No item passed in!"     && return; }
4058     unless ($issue)    { carp "No issue passed in!"    && return; }
4059
4060     my $datedue = $issue->{date_due};
4061
4062     # we only need to calculate and change the fines if we want to do that on return
4063     # Should be on for hourly loans
4064     my $control = C4::Context->preference('CircControl');
4065     my $control_branchcode =
4066         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4067       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4068       :                                     $issue->{branchcode};
4069
4070     my $date_returned = $return_date ? dt_from_string($return_date) : dt_from_string();
4071
4072     my ( $amount, $type, $unitcounttotal ) =
4073       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4074
4075     $type ||= q{};
4076
4077     if ( C4::Context->preference('finesMode') eq 'production' ) {
4078         if ( $amount > 0 ) {
4079             C4::Overdues::UpdateFine({
4080                 issue_id       => $issue->{issue_id},
4081                 itemnumber     => $issue->{itemnumber},
4082                 borrowernumber => $issue->{borrowernumber},
4083                 amount         => $amount,
4084                 type           => $type,
4085                 due            => output_pref($datedue),
4086             });
4087         }
4088         elsif ($return_date) {
4089
4090             # Backdated returns may have fines that shouldn't exist,
4091             # so in this case, we need to drop those fines to 0
4092
4093             C4::Overdues::UpdateFine({
4094                 issue_id       => $issue->{issue_id},
4095                 itemnumber     => $issue->{itemnumber},
4096                 borrowernumber => $issue->{borrowernumber},
4097                 amount         => 0,
4098                 type           => $type,
4099                 due            => output_pref($datedue),
4100             });
4101         }
4102     }
4103 }
4104
4105 1;
4106
4107 __END__
4108
4109 =head1 AUTHOR
4110
4111 Koha Development Team <http://koha-community.org/>
4112
4113 =cut