Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use List::MoreUtils qw( any uniq );
  25 use JSON qw( to_json );
  26 use Unicode::Normalize;
  27
  28 use C4::Context;
  29 use C4::Log;
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use Koha::AuthUtils;
  33 use Koha::Checkouts;
  34 use Koha::Club::Enrollments;
  35 use Koha::Database;
  36 use Koha::DateUtils;
  37 use Koha::Exceptions::Password;
  38 use Koha::Holds;
  39 use Koha::Old::Checkouts;
  40 use Koha::Patron::Attributes;
  41 use Koha::Patron::Categories;
  42 use Koha::Patron::Debarments;
  43 use Koha::Patron::HouseboundProfile;
  44 use Koha::Patron::HouseboundRole;
  45 use Koha::Patron::Images;
  46 use Koha::Patron::Modifications;
  47 use Koha::Patron::Relationships;
  48 use Koha::Patrons;
  49 use Koha::Plugins;
  50 use Koha::Subscription::Routinglists;
  51 use Koha::Token;
  52 use Koha::Virtualshelves;
  53
  54 use base qw(Koha::Object);
  55
  56 use constant ADMINISTRATIVE_LOCKOUT => -1;
  57
  58 our $RESULTSET_PATRON_ID_MAPPING = {
  59     Accountline          => 'borrowernumber',
  60     Aqbasketuser         => 'borrowernumber',
  61     Aqbudget             => 'budget_owner_id',
  62     Aqbudgetborrower     => 'borrowernumber',
  63     ArticleRequest       => 'borrowernumber',
  64     BorrowerAttribute    => 'borrowernumber',
  65     BorrowerDebarment    => 'borrowernumber',
  66     BorrowerFile         => 'borrowernumber',
  67     BorrowerModification => 'borrowernumber',
  68     ClubEnrollment       => 'borrowernumber',
  69     Issue                => 'borrowernumber',
  70     ItemsLastBorrower    => 'borrowernumber',
  71     Linktracker          => 'borrowernumber',
  72     Message              => 'borrowernumber',
  73     MessageQueue         => 'borrowernumber',
  74     OldIssue             => 'borrowernumber',
  75     OldReserve           => 'borrowernumber',
  76     Rating               => 'borrowernumber',
  77     Reserve              => 'borrowernumber',
  78     Review               => 'borrowernumber',
  79     SearchHistory        => 'userid',
  80     Statistic            => 'borrowernumber',
  81     Suggestion           => 'suggestedby',
  82     TagAll               => 'borrowernumber',
  83     Virtualshelfcontent  => 'borrowernumber',
  84     Virtualshelfshare    => 'borrowernumber',
  85     Virtualshelve        => 'owner',
  86 };
  87
  88 =head1 NAME
  89
  90 Koha::Patron - Koha Patron Object class
  91
  92 =head1 API
  93
  94 =head2 Class Methods
  95
  96 =head3 new
  97
  98 =cut
  99
 100 sub new {
 101     my ( $class, $params ) = @_;
 102
 103     return $class->SUPER::new($params);
 104 }
 105
 106 =head3 fixup_cardnumber
 107
 108 Autogenerate next cardnumber from highest value found in database
 109
 110 =cut
 111
 112 sub fixup_cardnumber {
 113     my ( $self ) = @_;
 114     my $max = Koha::Patrons->search({
 115         cardnumber => {-regexp => '^-?[0-9]+$'}
 116     }, {
 117         select => \'CAST(cardnumber AS SIGNED)',
 118         as => ['cast_cardnumber']
 119     })->_resultset->get_column('cast_cardnumber')->max;
 120     $self->cardnumber(($max || 0) +1);
 121 }
 122
 123 =head3 trim_whitespace
 124
 125 trim whitespace from data which has some non-whitespace in it.
 126 Could be moved to Koha::Object if need to be reused
 127
 128 =cut
 129
 130 sub trim_whitespaces {
 131     my( $self ) = @_;
 132
 133     my $schema  = Koha::Database->new->schema;
 134     my @columns = $schema->source($self->_type)->columns;
 135
 136     for my $column( @columns ) {
 137         my $value = $self->$column;
 138         if ( defined $value ) {
 139             $value =~ s/^\s*|\s*$//g;
 140             $self->$column($value);
 141         }
 142     }
 143     return $self;
 144 }
 145
 146 =head3 plain_text_password
 147
 148 $patron->plain_text_password( $password );
 149
 150 stores a copy of the unencrypted password in the object
 151 for use in code before encrypting for db
 152
 153 =cut
 154
 155 sub plain_text_password {
 156     my ( $self, $password ) = @_;
 157     if ( $password ) {
 158         $self->{_plain_text_password} = $password;
 159         return $self;
 160     }
 161     return $self->{_plain_text_password}
 162         if $self->{_plain_text_password};
 163
 164     return;
 165 }
 166
 167 =head3 store
 168
 169 Patron specific store method to cleanup record
 170 and do other necessary things before saving
 171 to db
 172
 173 =cut
 174
 175 sub store {
 176     my ($self) = @_;
 177
 178     $self->_result->result_source->schema->txn_do(
 179         sub {
 180             if (
 181                 C4::Context->preference("autoMemberNum")
 182                 and ( not defined $self->cardnumber
 183                     or $self->cardnumber eq '' )
 184               )
 185             {
 186                 # Warning: The caller is responsible for locking the members table in write
 187                 # mode, to avoid database corruption.
 188                 # We are in a transaction but the table is not locked
 189                 $self->fixup_cardnumber;
 190             }
 191
 192             unless( $self->category->in_storage ) {
 193                 Koha::Exceptions::Object::FKConstraint->throw(
 194                     broken_fk => 'categorycode',
 195                     value     => $self->categorycode,
 196                 );
 197             }
 198
 199             $self->trim_whitespaces;
 200
 201             # Set surname to uppercase if uppercasesurname is true
 202             $self->surname( uc($self->surname) )
 203                 if C4::Context->preference("uppercasesurnames");
 204
 205             $self->relationship(undef) # We do not want to store an empty string in this field
 206               if defined $self->relationship
 207                      and $self->relationship eq "";
 208
 209             unless ( $self->in_storage ) {    #AddMember
 210
 211                 # Generate a valid userid/login if needed
 212                 $self->generate_userid
 213                   if not $self->userid or not $self->has_valid_userid;
 214
 215                 # Add expiration date if it isn't already there
 216                 unless ( $self->dateexpiry ) {
 217                     $self->dateexpiry( $self->category->get_expiry_date );
 218                 }
 219
 220                 # Add enrollment date if it isn't already there
 221                 unless ( $self->dateenrolled ) {
 222                     $self->dateenrolled(dt_from_string);
 223                 }
 224
 225                 # Set the privacy depending on the patron's category
 226                 my $default_privacy = $self->category->default_privacy || q{};
 227                 $default_privacy =
 228                     $default_privacy eq 'default' ? 1
 229                   : $default_privacy eq 'never'   ? 2
 230                   : $default_privacy eq 'forever' ? 0
 231                   :                                                   undef;
 232                 $self->privacy($default_privacy);
 233
 234                 # Call any check_password plugins if password is passed
 235                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 236                     my @plugins = Koha::Plugins->new()->GetPlugins({
 237                         method => 'check_password',
 238                     });
 239                     foreach my $plugin ( @plugins ) {
 240                         # This plugin hook will also be used by a plugin for the Norwegian national
 241                         # patron database. This is why we need to pass both the password and the
 242                         # borrowernumber to the plugin.
 243                         my $ret = $plugin->check_password(
 244                             {
 245                                 password       => $self->password,
 246                                 borrowernumber => $self->borrowernumber
 247                             }
 248                         );
 249                         if ( $ret->{'error'} == 1 ) {
 250                             Koha::Exceptions::Password::Plugin->throw();
 251                         }
 252                     }
 253                 }
 254
 255                 # Make a copy of the plain text password for later use
 256                 $self->plain_text_password( $self->password );
 257
 258                 # Create a disabled account if no password provided
 259                 $self->password( $self->password
 260                     ? Koha::AuthUtils::hash_password( $self->password )
 261                     : '!' );
 262
 263                 $self->borrowernumber(undef);
 264
 265                 $self = $self->SUPER::store;
 266
 267                 $self->add_enrolment_fee_if_needed(0);
 268
 269                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 270                   if C4::Context->preference("BorrowersLog");
 271             }
 272             else {    #ModMember
 273
 274                 my $self_from_storage = $self->get_from_storage;
 275                 # FIXME We should not deal with that here, callers have to do this job
 276                 # Moved from ModMember to prevent regressions
 277                 unless ( $self->userid ) {
 278                     my $stored_userid = $self_from_storage->userid;
 279                     $self->userid($stored_userid);
 280                 }
 281
 282                 # Password must be updated using $self->set_password
 283                 $self->password($self_from_storage->password);
 284
 285                 if ( $self->category->categorycode ne
 286                     $self_from_storage->category->categorycode )
 287                 {
 288                     # Add enrolement fee on category change if required
 289                     $self->add_enrolment_fee_if_needed(1)
 290                       if C4::Context->preference('FeeOnChangePatronCategory');
 291
 292                     # Clean up guarantors on category change if required
 293                     $self->guarantor_relationships->delete
 294                       if ( $self->category->category_type ne 'C'
 295                         && $self->category->category_type ne 'P' );
 296
 297                 }
 298
 299                 # Actionlogs
 300                 if ( C4::Context->preference("BorrowersLog") ) {
 301                     my $info;
 302                     my $from_storage = $self_from_storage->unblessed;
 303                     my $from_object  = $self->unblessed;
 304                     my @skip_fields  = (qw/lastseen updated_on/);
 305                     for my $key ( keys %{$from_storage} ) {
 306                         next if any { /$key/ } @skip_fields;
 307                         if (
 308                             (
 309                                   !defined( $from_storage->{$key} )
 310                                 && defined( $from_object->{$key} )
 311                             )
 312                             || ( defined( $from_storage->{$key} )
 313                                 && !defined( $from_object->{$key} ) )
 314                             || (
 315                                    defined( $from_storage->{$key} )
 316                                 && defined( $from_object->{$key} )
 317                                 && ( $from_storage->{$key} ne
 318                                     $from_object->{$key} )
 319                             )
 320                           )
 321                         {
 322                             $info->{$key} = {
 323                                 before => $from_storage->{$key},
 324                                 after  => $from_object->{$key}
 325                             };
 326                         }
 327                     }
 328
 329                     if ( defined($info) ) {
 330                         logaction(
 331                             "MEMBERS",
 332                             "MODIFY",
 333                             $self->borrowernumber,
 334                             to_json(
 335                                 $info,
 336                                 { utf8 => 1, pretty => 1, canonical => 1 }
 337                             )
 338                         );
 339                     }
 340                 }
 341
 342                 # Final store
 343                 $self = $self->SUPER::store;
 344             }
 345         }
 346     );
 347     return $self;
 348 }
 349
 350 =head3 delete
 351
 352 $patron->delete
 353
 354 Delete patron's holds, lists and finally the patron.
 355
 356 Lists owned by the borrower are deleted, but entries from the borrower to
 357 other lists are kept.
 358
 359 =cut
 360
 361 sub delete {
 362     my ($self) = @_;
 363
 364     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 365     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 366
 367     $self->_result->result_source->schema->txn_do(
 368         sub {
 369             # Cancel Patron's holds
 370             my $holds = $self->holds;
 371             while( my $hold = $holds->next ){
 372                 $hold->cancel;
 373             }
 374
 375             # Delete all lists and all shares of this borrower
 376             # Consistent with the approach Koha uses on deleting individual lists
 377             # Note that entries in virtualshelfcontents added by this borrower to
 378             # lists of others will be handled by a table constraint: the borrower
 379             # is set to NULL in those entries.
 380             # NOTE:
 381             # We could handle the above deletes via a constraint too.
 382             # But a new BZ report 11889 has been opened to discuss another approach.
 383             # Instead of deleting we could also disown lists (based on a pref).
 384             # In that way we could save shared and public lists.
 385             # The current table constraints support that idea now.
 386             # This pref should then govern the results of other routines/methods such as
 387             # Koha::Virtualshelf->new->delete too.
 388             # FIXME Could be $patron->get_lists
 389             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } );
 390
 391             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 392             # for patron selfreg
 393             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } );
 394
 395             $self->SUPER::delete;
 396
 397             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 398         }
 399     );
 400     return $self;
 401 }
 402
 403
 404 =head3 category
 405
 406 my $patron_category = $patron->category
 407
 408 Return the patron category for this patron
 409
 410 =cut
 411
 412 sub category {
 413     my ( $self ) = @_;
 414     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 415 }
 416
 417 =head3 image
 418
 419 =cut
 420
 421 sub image {
 422     my ( $self ) = @_;
 423
 424     return Koha::Patron::Images->find( $self->borrowernumber );
 425 }
 426
 427 =head3 library
 428
 429 Returns a Koha::Library object representing the patron's home library.
 430
 431 =cut
 432
 433 sub library {
 434     my ( $self ) = @_;
 435     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 436 }
 437
 438 =head3 sms_provider
 439
 440 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 441
 442 =cut
 443
 444 sub sms_provider {
 445     my ( $self ) = @_;
 446     my $sms_provider_rs = $self->_result->sms_provider;
 447     return unless $sms_provider_rs;
 448     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 449 }
 450
 451 =head3 guarantor_relationships
 452
 453 Returns Koha::Patron::Relationships object for this patron's guarantors
 454
 455 Returns the set of relationships for the patrons that are guarantors for this patron.
 456
 457 This is returned instead of a Koha::Patron object because the guarantor
 458 may not exist as a patron in Koha. If this is true, the guarantors name
 459 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 460
 461 =cut
 462
 463 sub guarantor_relationships {
 464     my ($self) = @_;
 465
 466     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 467 }
 468
 469 =head3 guarantee_relationships
 470
 471 Returns Koha::Patron::Relationships object for this patron's guarantors
 472
 473 Returns the set of relationships for the patrons that are guarantees for this patron.
 474
 475 The method returns Koha::Patron::Relationship objects for the sake
 476 of consistency with the guantors method.
 477 A guarantee by definition must exist as a patron in Koha.
 478
 479 =cut
 480
 481 sub guarantee_relationships {
 482     my ($self) = @_;
 483
 484     return Koha::Patron::Relationships->search(
 485         { guarantor_id => $self->id },
 486         {
 487             prefetch => 'guarantee',
 488             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 489         }
 490     );
 491 }
 492
 493 =head3 relationships_debt
 494
 495 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 496
 497 =cut
 498
 499 sub relationships_debt {
 500     my ($self, $params) = @_;
 501
 502     my $include_guarantors  = $params->{include_guarantors};
 503     my $only_this_guarantor = $params->{only_this_guarantor};
 504     my $include_this_patron = $params->{include_this_patron};
 505
 506     my @guarantors;
 507     if ( $only_this_guarantor ) {
 508         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 509         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 510     } elsif ( $self->guarantor_relationships->count ) {
 511         # I am a guarantee, just get all my guarantors
 512         @guarantors = $self->guarantor_relationships->guarantors;
 513     } else {
 514         # I am a guarantor, I need to get all the guarantors of all my guarantees
 515         @guarantors = map { $_->guarantor_relationships->guarantors } $self->guarantee_relationships->guarantees;
 516     }
 517
 518     my $non_issues_charges = 0;
 519     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 520     foreach my $guarantor (@guarantors) {
 521         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 522
 523         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 524         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships();
 525         my $guarantees_non_issues_charges = 0;
 526         foreach my $guarantee (@guarantees) {
 527             next if $seen->{ $guarantee->id };
 528             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 529             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 530             $seen->{ $guarantee->id } = 1;
 531         }
 532
 533         $non_issues_charges += $guarantees_non_issues_charges;
 534         $seen->{ $guarantor->id } = 1;
 535     }
 536
 537     return $non_issues_charges;
 538 }
 539
 540 =head3 housebound_profile
 541
 542 Returns the HouseboundProfile associated with this patron.
 543
 544 =cut
 545
 546 sub housebound_profile {
 547     my ( $self ) = @_;
 548     my $profile = $self->_result->housebound_profile;
 549     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 550         if ( $profile );
 551     return;
 552 }
 553
 554 =head3 housebound_role
 555
 556 Returns the HouseboundRole associated with this patron.
 557
 558 =cut
 559
 560 sub housebound_role {
 561     my ( $self ) = @_;
 562
 563     my $role = $self->_result->housebound_role;
 564     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 565     return;
 566 }
 567
 568 =head3 siblings
 569
 570 Returns the siblings of this patron.
 571
 572 =cut
 573
 574 sub siblings {
 575     my ($self) = @_;
 576
 577     my @guarantors = $self->guarantor_relationships()->guarantors();
 578
 579     return unless @guarantors;
 580
 581     my @siblings =
 582       map { $_->guarantee_relationships()->guarantees() } @guarantors;
 583
 584     return unless @siblings;
 585
 586     my %seen;
 587     @siblings =
 588       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 589
 590     return wantarray ? @siblings : Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 591 }
 592
 593 =head3 merge_with
 594
 595     my $patron = Koha::Patrons->find($id);
 596     $patron->merge_with( \@patron_ids );
 597
 598     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 599     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 600     of the keeper patron.
 601
 602 =cut
 603
 604 sub merge_with {
 605     my ( $self, $patron_ids ) = @_;
 606
 607     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 608     return if $anonymous_patron && $self->id eq $anonymous_patron;
 609
 610     my @patron_ids = @{ $patron_ids };
 611
 612     # Ensure the keeper isn't in the list of patrons to merge
 613     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 614
 615     my $schema = Koha::Database->new()->schema();
 616
 617     my $results;
 618
 619     $self->_result->result_source->schema->txn_do( sub {
 620         foreach my $patron_id (@patron_ids) {
 621
 622             next if $patron_id eq $anonymous_patron;
 623
 624             my $patron = Koha::Patrons->find( $patron_id );
 625
 626             next unless $patron;
 627
 628             # Unbless for safety, the patron will end up being deleted
 629             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 630
 631             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 632                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 633                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 634                 $rs->update({ $field => $self->id });
 635                 if ( $r eq 'BorrowerDebarment' ) {
 636                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 637                 }
 638             }
 639
 640             $patron->move_to_deleted();
 641             $patron->delete();
 642         }
 643     });
 644
 645     return $results;
 646 }
 647
 648
 649
 650 =head3 wants_check_for_previous_checkout
 651
 652     $wants_check = $patron->wants_check_for_previous_checkout;
 653
 654 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 655
 656 =cut
 657
 658 sub wants_check_for_previous_checkout {
 659     my ( $self ) = @_;
 660     my $syspref = C4::Context->preference("checkPrevCheckout");
 661
 662     # Simple cases
 663     ## Hard syspref trumps all
 664     return 1 if ($syspref eq 'hardyes');
 665     return 0 if ($syspref eq 'hardno');
 666     ## Now, patron pref trumps all
 667     return 1 if ($self->checkprevcheckout eq 'yes');
 668     return 0 if ($self->checkprevcheckout eq 'no');
 669
 670     # More complex: patron inherits -> determine category preference
 671     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 672     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 673     return 0 if ($checkPrevCheckoutByCat eq 'no');
 674
 675     # Finally: category preference is inherit, default to 0
 676     if ($syspref eq 'softyes') {
 677         return 1;
 678     } else {
 679         return 0;
 680     }
 681 }
 682
 683 =head3 do_check_for_previous_checkout
 684
 685     $do_check = $patron->do_check_for_previous_checkout($item);
 686
 687 Return 1 if the bib associated with $ITEM has previously been checked out to
 688 $PATRON, 0 otherwise.
 689
 690 =cut
 691
 692 sub do_check_for_previous_checkout {
 693     my ( $self, $item ) = @_;
 694
 695     my @item_nos;
 696     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 697     if ( $biblio->is_serial ) {
 698         push @item_nos, $item->{itemnumber};
 699     } else {
 700         # Get all itemnumbers for given bibliographic record.
 701         @item_nos = $biblio->items->get_column( 'itemnumber' );
 702     }
 703
 704     # Create (old)issues search criteria
 705     my $criteria = {
 706         borrowernumber => $self->borrowernumber,
 707         itemnumber => \@item_nos,
 708     };
 709
 710     # Check current issues table
 711     my $issues = Koha::Checkouts->search($criteria);
 712     return 1 if $issues->count; # 0 || N
 713
 714     # Check old issues table
 715     my $old_issues = Koha::Old::Checkouts->search($criteria);
 716     return $old_issues->count;  # 0 || N
 717 }
 718
 719 =head3 is_debarred
 720
 721 my $debarment_expiration = $patron->is_debarred;
 722
 723 Returns the date a patron debarment will expire, or undef if the patron is not
 724 debarred
 725
 726 =cut
 727
 728 sub is_debarred {
 729     my ($self) = @_;
 730
 731     return unless $self->debarred;
 732     return $self->debarred
 733       if $self->debarred =~ '^9999'
 734       or dt_from_string( $self->debarred ) > dt_from_string;
 735     return;
 736 }
 737
 738 =head3 is_expired
 739
 740 my $is_expired = $patron->is_expired;
 741
 742 Returns 1 if the patron is expired or 0;
 743
 744 =cut
 745
 746 sub is_expired {
 747     my ($self) = @_;
 748     return 0 unless $self->dateexpiry;
 749     return 0 if $self->dateexpiry =~ '^9999';
 750     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 751     return 0;
 752 }
 753
 754 =head3 is_going_to_expire
 755
 756 my $is_going_to_expire = $patron->is_going_to_expire;
 757
 758 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 759
 760 =cut
 761
 762 sub is_going_to_expire {
 763     my ($self) = @_;
 764
 765     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 766
 767     return 0 unless $delay;
 768     return 0 unless $self->dateexpiry;
 769     return 0 if $self->dateexpiry =~ '^9999';
 770     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 771     return 0;
 772 }
 773
 774 =head3 set_password
 775
 776     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 777
 778 Set the patron's password.
 779
 780 =head4 Exceptions
 781
 782 The passed string is validated against the current password enforcement policy.
 783 Validation can be skipped by passing the I<skip_validation> parameter.
 784
 785 Exceptions are thrown if the password is not good enough.
 786
 787 =over 4
 788
 789 =item Koha::Exceptions::Password::TooShort
 790
 791 =item Koha::Exceptions::Password::WhitespaceCharacters
 792
 793 =item Koha::Exceptions::Password::TooWeak
 794
 795 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 796
 797 =back
 798
 799 =cut
 800
 801 sub set_password {
 802     my ( $self, $args ) = @_;
 803
 804     my $password = $args->{password};
 805
 806     unless ( $args->{skip_validation} ) {
 807         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 808
 809         if ( !$is_valid ) {
 810             if ( $error eq 'too_short' ) {
 811                 my $min_length = $self->category->effective_min_password_length;
 812                 $min_length = 3 if not $min_length or $min_length < 3;
 813
 814                 my $password_length = length($password);
 815                 Koha::Exceptions::Password::TooShort->throw(
 816                     length => $password_length, min_length => $min_length );
 817             }
 818             elsif ( $error eq 'has_whitespaces' ) {
 819                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 820             }
 821             elsif ( $error eq 'too_weak' ) {
 822                 Koha::Exceptions::Password::TooWeak->throw();
 823             }
 824         }
 825     }
 826
 827     if ( C4::Context->config("enable_plugins") ) {
 828         # Call any check_password plugins
 829         my @plugins = Koha::Plugins->new()->GetPlugins({
 830             method => 'check_password',
 831         });
 832         foreach my $plugin ( @plugins ) {
 833             # This plugin hook will also be used by a plugin for the Norwegian national
 834             # patron database. This is why we need to pass both the password and the
 835             # borrowernumber to the plugin.
 836             my $ret = $plugin->check_password(
 837                 {
 838                     password       => $password,
 839                     borrowernumber => $self->borrowernumber
 840                 }
 841             );
 842             # This plugin hook will also be used by a plugin for the Norwegian national
 843             # patron database. This is why we need to call the actual plugins and then
 844             # check skip_validation afterwards.
 845             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 846                 Koha::Exceptions::Password::Plugin->throw();
 847             }
 848         }
 849     }
 850
 851     my $digest = Koha::AuthUtils::hash_password($password);
 852
 853     # We do not want to call $self->store and retrieve password from DB
 854     $self->password($digest);
 855     $self->login_attempts(0);
 856     $self->SUPER::store;
 857
 858     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 859         if C4::Context->preference("BorrowersLog");
 860
 861     return $self;
 862 }
 863
 864
 865 =head3 renew_account
 866
 867 my $new_expiry_date = $patron->renew_account
 868
 869 Extending the subscription to the expiry date.
 870
 871 =cut
 872
 873 sub renew_account {
 874     my ($self) = @_;
 875     my $date;
 876     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 877         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 878     } else {
 879         $date =
 880             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 881             ? dt_from_string( $self->dateexpiry )
 882             : dt_from_string;
 883     }
 884     my $expiry_date = $self->category->get_expiry_date($date);
 885
 886     $self->dateexpiry($expiry_date);
 887     $self->date_renewed( dt_from_string() );
 888     $self->store();
 889
 890     $self->add_enrolment_fee_if_needed(1);
 891
 892     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 893     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 894 }
 895
 896 =head3 has_overdues
 897
 898 my $has_overdues = $patron->has_overdues;
 899
 900 Returns the number of patron's overdues
 901
 902 =cut
 903
 904 sub has_overdues {
 905     my ($self) = @_;
 906     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 907     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 908 }
 909
 910 =head3 track_login
 911
 912     $patron->track_login;
 913     $patron->track_login({ force => 1 });
 914
 915     Tracks a (successful) login attempt.
 916     The preference TrackLastPatronActivity must be enabled. Or you
 917     should pass the force parameter.
 918
 919 =cut
 920
 921 sub track_login {
 922     my ( $self, $params ) = @_;
 923     return if
 924         !$params->{force} &&
 925         !C4::Context->preference('TrackLastPatronActivity');
 926     $self->lastseen( dt_from_string() )->store;
 927 }
 928
 929 =head3 move_to_deleted
 930
 931 my $is_moved = $patron->move_to_deleted;
 932
 933 Move a patron to the deletedborrowers table.
 934 This can be done before deleting a patron, to make sure the data are not completely deleted.
 935
 936 =cut
 937
 938 sub move_to_deleted {
 939     my ($self) = @_;
 940     my $patron_infos = $self->unblessed;
 941     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 942     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 943 }
 944
 945 =head3 article_requests
 946
 947 my @requests = $borrower->article_requests();
 948 my $requests = $borrower->article_requests();
 949
 950 Returns either a list of ArticleRequests objects,
 951 or an ArtitleRequests object, depending on the
 952 calling context.
 953
 954 =cut
 955
 956 sub article_requests {
 957     my ( $self ) = @_;
 958
 959     $self->{_article_requests} ||= Koha::ArticleRequests->search({ borrowernumber => $self->borrowernumber() });
 960
 961     return $self->{_article_requests};
 962 }
 963
 964 =head3 article_requests_current
 965
 966 my @requests = $patron->article_requests_current
 967
 968 Returns the article requests associated with this patron that are incomplete
 969
 970 =cut
 971
 972 sub article_requests_current {
 973     my ( $self ) = @_;
 974
 975     $self->{_article_requests_current} ||= Koha::ArticleRequests->search(
 976         {
 977             borrowernumber => $self->id(),
 978             -or          => [
 979                 { status => Koha::ArticleRequest::Status::Pending },
 980                 { status => Koha::ArticleRequest::Status::Processing }
 981             ]
 982         }
 983     );
 984
 985     return $self->{_article_requests_current};
 986 }
 987
 988 =head3 article_requests_finished
 989
 990 my @requests = $biblio->article_requests_finished
 991
 992 Returns the article requests associated with this patron that are completed
 993
 994 =cut
 995
 996 sub article_requests_finished {
 997     my ( $self, $borrower ) = @_;
 998
 999     $self->{_article_requests_finished} ||= Koha::ArticleRequests->search(
1000         {
1001             borrowernumber => $self->id(),
1002             -or          => [
1003                 { status => Koha::ArticleRequest::Status::Completed },
1004                 { status => Koha::ArticleRequest::Status::Canceled }
1005             ]
1006         }
1007     );
1008
1009     return $self->{_article_requests_finished};
1010 }
1011
1012 =head3 add_enrolment_fee_if_needed
1013
1014 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1015
1016 Add enrolment fee for a patron if needed.
1017
1018 $renewal - boolean denoting whether this is an account renewal or not
1019
1020 =cut
1021
1022 sub add_enrolment_fee_if_needed {
1023     my ($self, $renewal) = @_;
1024     my $enrolment_fee = $self->category->enrolmentfee;
1025     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1026         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1027         $self->account->add_debit(
1028             {
1029                 amount     => $enrolment_fee,
1030                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1031                 interface  => C4::Context->interface,
1032                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1033                 type       => $type
1034             }
1035         );
1036     }
1037     return $enrolment_fee || 0;
1038 }
1039
1040 =head3 checkouts
1041
1042 my $checkouts = $patron->checkouts
1043
1044 =cut
1045
1046 sub checkouts {
1047     my ($self) = @_;
1048     my $checkouts = $self->_result->issues;
1049     return Koha::Checkouts->_new_from_dbic( $checkouts );
1050 }
1051
1052 =head3 pending_checkouts
1053
1054 my $pending_checkouts = $patron->pending_checkouts
1055
1056 This method will return the same as $self->checkouts, but with a prefetch on
1057 items, biblio and biblioitems.
1058
1059 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1060
1061 It should not be used directly, prefer to access fields you need instead of
1062 retrieving all these fields in one go.
1063
1064 =cut
1065
1066 sub pending_checkouts {
1067     my( $self ) = @_;
1068     my $checkouts = $self->_result->issues->search(
1069         {},
1070         {
1071             order_by => [
1072                 { -desc => 'me.timestamp' },
1073                 { -desc => 'issuedate' },
1074                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1075             ],
1076             prefetch => { item => { biblio => 'biblioitems' } },
1077         }
1078     );
1079     return Koha::Checkouts->_new_from_dbic( $checkouts );
1080 }
1081
1082 =head3 old_checkouts
1083
1084 my $old_checkouts = $patron->old_checkouts
1085
1086 =cut
1087
1088 sub old_checkouts {
1089     my ($self) = @_;
1090     my $old_checkouts = $self->_result->old_issues;
1091     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1092 }
1093
1094 =head3 get_overdues
1095
1096 my $overdue_items = $patron->get_overdues
1097
1098 Return the overdue items
1099
1100 =cut
1101
1102 sub get_overdues {
1103     my ($self) = @_;
1104     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1105     return $self->checkouts->search(
1106         {
1107             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1108         },
1109         {
1110             prefetch => { item => { biblio => 'biblioitems' } },
1111         }
1112     );
1113 }
1114
1115 =head3 get_routing_lists
1116
1117 my @routinglists = $patron->get_routing_lists
1118
1119 Returns the routing lists a patron is subscribed to.
1120
1121 =cut
1122
1123 sub get_routing_lists {
1124     my ($self) = @_;
1125     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1126     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1127 }
1128
1129 =head3 get_age
1130
1131 my $age = $patron->get_age
1132
1133 Return the age of the patron
1134
1135 =cut
1136
1137 sub get_age {
1138     my ($self)    = @_;
1139     my $today_str = dt_from_string->strftime("%Y-%m-%d");
1140     return unless $self->dateofbirth;
1141     my $dob_str   = dt_from_string( $self->dateofbirth )->strftime("%Y-%m-%d");
1142
1143     my ( $dob_y,   $dob_m,   $dob_d )   = split /-/, $dob_str;
1144     my ( $today_y, $today_m, $today_d ) = split /-/, $today_str;
1145
1146     my $age = $today_y - $dob_y;
1147     if ( $dob_m . $dob_d > $today_m . $today_d ) {
1148         $age--;
1149     }
1150
1151     return $age;
1152 }
1153
1154 =head3 is_valid_age
1155
1156 my $is_valid = $patron->is_valid_age
1157
1158 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1159
1160 =cut
1161
1162 sub is_valid_age {
1163     my ($self) = @_;
1164     my $age = $self->get_age;
1165
1166     my $patroncategory = $self->category;
1167     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1168
1169     return (defined($age) && (($high && ($age > $high)) or ($age < $low))) ? 0 : 1;
1170 }
1171
1172 =head3 account
1173
1174 my $account = $patron->account
1175
1176 =cut
1177
1178 sub account {
1179     my ($self) = @_;
1180     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1181 }
1182
1183 =head3 holds
1184
1185 my $holds = $patron->holds
1186
1187 Return all the holds placed by this patron
1188
1189 =cut
1190
1191 sub holds {
1192     my ($self) = @_;
1193     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1194     return Koha::Holds->_new_from_dbic($holds_rs);
1195 }
1196
1197 =head3 old_holds
1198
1199 my $old_holds = $patron->old_holds
1200
1201 Return all the historical holds for this patron
1202
1203 =cut
1204
1205 sub old_holds {
1206     my ($self) = @_;
1207     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1208     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1209 }
1210
1211 =head3 return_claims
1212
1213 my $return_claims = $patron->return_claims
1214
1215 =cut
1216
1217 sub return_claims {
1218     my ($self) = @_;
1219     my $return_claims = $self->_result->return_claims_borrowernumbers;
1220     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1221 }
1222
1223 =head3 notice_email_address
1224
1225   my $email = $patron->notice_email_address;
1226
1227 Return the email address of patron used for notices.
1228 Returns the empty string if no email address.
1229
1230 =cut
1231
1232 sub notice_email_address{
1233     my ( $self ) = @_;
1234
1235     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1236     # if syspref is set to 'first valid' (value == OFF), look up email address
1237     if ( $which_address eq 'OFF' ) {
1238         return $self->first_valid_email_address;
1239     }
1240
1241     return $self->$which_address || '';
1242 }
1243
1244 =head3 first_valid_email_address
1245
1246 my $first_valid_email_address = $patron->first_valid_email_address
1247
1248 Return the first valid email address for a patron.
1249 For now, the order  is defined as email, emailpro, B_email.
1250 Returns the empty string if the borrower has no email addresses.
1251
1252 =cut
1253
1254 sub first_valid_email_address {
1255     my ($self) = @_;
1256
1257     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1258 }
1259
1260 =head3 get_club_enrollments
1261
1262 =cut
1263
1264 sub get_club_enrollments {
1265     my ( $self, $return_scalar ) = @_;
1266
1267     my $e = Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1268
1269     return $e if $return_scalar;
1270
1271     return wantarray ? $e->as_list : $e;
1272 }
1273
1274 =head3 get_enrollable_clubs
1275
1276 =cut
1277
1278 sub get_enrollable_clubs {
1279     my ( $self, $is_enrollable_from_opac, $return_scalar ) = @_;
1280
1281     my $params;
1282     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1283       if $is_enrollable_from_opac;
1284     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1285
1286     $params->{borrower} = $self;
1287
1288     my $e = Koha::Clubs->get_enrollable($params);
1289
1290     return $e if $return_scalar;
1291
1292     return wantarray ? $e->as_list : $e;
1293 }
1294
1295 =head3 account_locked
1296
1297 my $is_locked = $patron->account_locked
1298
1299 Return true if the patron has reached the maximum number of login attempts
1300 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1301 as an administrative lockout (independent of FailedLoginAttempts; see also
1302 Koha::Patron->lock).
1303 Otherwise return false.
1304 If the pref is not set (empty string, null or 0), the feature is considered as
1305 disabled.
1306
1307 =cut
1308
1309 sub account_locked {
1310     my ($self) = @_;
1311     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1312     return 1 if $FailedLoginAttempts
1313           and $self->login_attempts
1314           and $self->login_attempts >= $FailedLoginAttempts;
1315     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1316     return 0;
1317 }
1318
1319 =head3 can_see_patron_infos
1320
1321 my $can_see = $patron->can_see_patron_infos( $patron );
1322
1323 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1324
1325 =cut
1326
1327 sub can_see_patron_infos {
1328     my ( $self, $patron ) = @_;
1329     return unless $patron;
1330     return $self->can_see_patrons_from( $patron->library->branchcode );
1331 }
1332
1333 =head3 can_see_patrons_from
1334
1335 my $can_see = $patron->can_see_patrons_from( $branchcode );
1336
1337 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1338
1339 =cut
1340
1341 sub can_see_patrons_from {
1342     my ( $self, $branchcode ) = @_;
1343     my $can = 0;
1344     if ( $self->branchcode eq $branchcode ) {
1345         $can = 1;
1346     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1347         $can = 1;
1348     } elsif ( my $library_groups = $self->library->library_groups ) {
1349         while ( my $library_group = $library_groups->next ) {
1350             if ( $library_group->parent->has_child( $branchcode ) ) {
1351                 $can = 1;
1352                 last;
1353             }
1354         }
1355     }
1356     return $can;
1357 }
1358
1359 =head3 libraries_where_can_see_patrons
1360
1361 my $libraries = $patron-libraries_where_can_see_patrons;
1362
1363 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1364 The branchcodes are arbitrarily returned sorted.
1365 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1366
1367 An empty array means no restriction, the patron can see patron's infos from any libraries.
1368
1369 =cut
1370
1371 sub libraries_where_can_see_patrons {
1372     my ( $self ) = @_;
1373     my $userenv = C4::Context->userenv;
1374
1375     return () unless $userenv; # For tests, but userenv should be defined in tests...
1376
1377     my @restricted_branchcodes;
1378     if (C4::Context::only_my_library) {
1379         push @restricted_branchcodes, $self->branchcode;
1380     }
1381     else {
1382         unless (
1383             $self->has_permission(
1384                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1385             )
1386           )
1387         {
1388             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1389             if ( $library_groups->count )
1390             {
1391                 while ( my $library_group = $library_groups->next ) {
1392                     my $parent = $library_group->parent;
1393                     if ( $parent->has_child( $self->branchcode ) ) {
1394                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1395                     }
1396                 }
1397             }
1398
1399             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1400         }
1401     }
1402
1403     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1404     @restricted_branchcodes = uniq(@restricted_branchcodes);
1405     @restricted_branchcodes = sort(@restricted_branchcodes);
1406     return @restricted_branchcodes;
1407 }
1408
1409 =head3 has_permission
1410
1411 my $permission = $patron->has_permission($required);
1412
1413 See C4::Auth::haspermission for details of syntax for $required
1414
1415 =cut
1416
1417 sub has_permission {
1418     my ( $self, $flagsrequired ) = @_;
1419     return unless $self->userid;
1420     # TODO code from haspermission needs to be moved here!
1421     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1422 }
1423
1424 =head3 is_superlibrarian
1425
1426   my $is_superlibrarian = $patron->is_superlibrarian;
1427
1428 Return true if the patron is a superlibrarian.
1429
1430 =cut
1431
1432 sub is_superlibrarian {
1433     my ($self) = @_;
1434     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1435 }
1436
1437 =head3 is_adult
1438
1439 my $is_adult = $patron->is_adult
1440
1441 Return true if the patron has a category with a type Adult (A) or Organization (I)
1442
1443 =cut
1444
1445 sub is_adult {
1446     my ( $self ) = @_;
1447     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1448 }
1449
1450 =head3 is_child
1451
1452 my $is_child = $patron->is_child
1453
1454 Return true if the patron has a category with a type Child (C)
1455
1456 =cut
1457
1458 sub is_child {
1459     my( $self ) = @_;
1460     return $self->category->category_type eq 'C' ? 1 : 0;
1461 }
1462
1463 =head3 has_valid_userid
1464
1465 my $patron = Koha::Patrons->find(42);
1466 $patron->userid( $new_userid );
1467 my $has_a_valid_userid = $patron->has_valid_userid
1468
1469 my $patron = Koha::Patron->new( $params );
1470 my $has_a_valid_userid = $patron->has_valid_userid
1471
1472 Return true if the current userid of this patron is valid/unique, otherwise false.
1473
1474 Note that this should be done in $self->store instead and raise an exception if needed.
1475
1476 =cut
1477
1478 sub has_valid_userid {
1479     my ($self) = @_;
1480
1481     return 0 unless $self->userid;
1482
1483     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1484
1485     my $already_exists = Koha::Patrons->search(
1486         {
1487             userid => $self->userid,
1488             (
1489                 $self->in_storage
1490                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1491                 : ()
1492             ),
1493         }
1494     )->count;
1495     return $already_exists ? 0 : 1;
1496 }
1497
1498 =head3 generate_userid
1499
1500 my $patron = Koha::Patron->new( $params );
1501 $patron->generate_userid
1502
1503 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1504
1505 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1506
1507 =cut
1508
1509 sub generate_userid {
1510     my ($self) = @_;
1511     my $offset = 0;
1512     my $firstname = $self->firstname // q{};
1513     my $surname = $self->surname // q{};
1514     #The script will "do" the following code and increment the $offset until the generated userid is unique
1515     do {
1516       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1517       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1518       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1519       $userid = NFKD( $userid );
1520       $userid =~ s/\p{NonspacingMark}//g;
1521       $userid .= $offset unless $offset == 0;
1522       $self->userid( $userid );
1523       $offset++;
1524      } while (! $self->has_valid_userid );
1525
1526      return $self;
1527 }
1528
1529 =head3 add_extended_attribute
1530
1531 =cut
1532
1533 sub add_extended_attribute {
1534     my ($self, $attribute) = @_;
1535     $attribute->{borrowernumber} = $self->borrowernumber;
1536     return Koha::Patron::Attribute->new($attribute)->store;
1537 }
1538
1539 =head3 extended_attributes
1540
1541 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1542
1543 Or setter FIXME
1544
1545 =cut
1546
1547 sub extended_attributes {
1548     my ( $self, $attributes ) = @_;
1549     if ($attributes) {    # setter
1550         my $schema = $self->_result->result_source->schema;
1551         $schema->txn_do(
1552             sub {
1553                 # Remove the existing one
1554                 $self->extended_attributes->filter_by_branch_limitations->delete;
1555
1556                 # Insert the new ones
1557                 for my $attribute (@$attributes) {
1558                     eval {
1559                         $self->_result->create_related('borrower_attributes', $attribute);
1560                     };
1561                     # FIXME We should:
1562                     # 1 - Raise an exception
1563                     # 2 - Execute in a transaction and don't save
1564                     #  or Insert anyway but display a message on the UI
1565                     warn $@ if $@;
1566                 }
1567             }
1568         );
1569     }
1570
1571     my $rs = $self->_result->borrower_attributes;
1572     # We call search to use the filters in Koha::Patron::Attributes->search
1573     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1574 }
1575
1576 =head3 lock
1577
1578     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1579
1580     Lock and optionally expire a patron account.
1581     Remove holds and article requests if remove flag set.
1582     In order to distinguish from locking by entering a wrong password, let's
1583     call this an administrative lockout.
1584
1585 =cut
1586
1587 sub lock {
1588     my ( $self, $params ) = @_;
1589     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1590     if( $params->{expire} ) {
1591         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1592     }
1593     $self->store;
1594     if( $params->{remove} ) {
1595         $self->holds->delete;
1596         $self->article_requests->delete;
1597     }
1598     return $self;
1599 }
1600
1601 =head3 anonymize
1602
1603     Koha::Patrons->find($id)->anonymize;
1604
1605     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1606     are randomized, other personal data is cleared too.
1607     Patrons with issues are skipped.
1608
1609 =cut
1610
1611 sub anonymize {
1612     my ( $self ) = @_;
1613     if( $self->_result->issues->count ) {
1614         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1615         return;
1616     }
1617     # Mandatory fields come from the corresponding pref, but email fields
1618     # are removed since scrambled email addresses only generate errors
1619     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1620         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1621     $mandatory->{userid} = 1; # needed since sub store does not clear field
1622     my @columns = $self->_result->result_source->columns;
1623     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized/ } @columns;
1624     push @columns, 'dateofbirth'; # add this date back in
1625     foreach my $col (@columns) {
1626         $self->_anonymize_column($col, $mandatory->{lc $col} );
1627     }
1628     $self->anonymized(1)->store;
1629 }
1630
1631 sub _anonymize_column {
1632     my ( $self, $col, $mandatory ) = @_;
1633     my $col_info = $self->_result->result_source->column_info($col);
1634     my $type = $col_info->{data_type};
1635     my $nullable = $col_info->{is_nullable};
1636     my $val;
1637     if( $type =~ /char|text/ ) {
1638         $val = $mandatory
1639             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1640             : $nullable
1641             ? undef
1642             : q{};
1643     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1644         $val = $nullable ? undef : 0;
1645     } elsif( $type =~ /date|time/ ) {
1646         $val = $nullable ? undef : dt_from_string;
1647     }
1648     $self->$col($val);
1649 }
1650
1651 =head3 add_guarantor
1652
1653     my @relationships = $patron->add_guarantor(
1654         {
1655             borrowernumber => $borrowernumber,
1656             relationships  => $relationship,
1657         }
1658     );
1659
1660     Adds a new guarantor to a patron.
1661
1662 =cut
1663
1664 sub add_guarantor {
1665     my ( $self, $params ) = @_;
1666
1667     my $guarantor_id = $params->{guarantor_id};
1668     my $relationship = $params->{relationship};
1669
1670     return Koha::Patron::Relationship->new(
1671         {
1672             guarantee_id => $self->id,
1673             guarantor_id => $guarantor_id,
1674             relationship => $relationship
1675         }
1676     )->store();
1677 }
1678
1679 =head3 get_extended_attribute
1680
1681 my $attribute_value = $patron->get_extended_attribute( $code );
1682
1683 Return the attribute for the code passed in parameter.
1684
1685 It not exist it returns undef
1686
1687 Note that this will not work for repeatable attribute types.
1688
1689 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1690 (which should be a real patron's attribute (not extended)
1691
1692 =cut
1693
1694 sub get_extended_attribute {
1695     my ( $self, $code, $value ) = @_;
1696     my $rs = $self->_result->borrower_attributes;
1697     return unless $rs;
1698     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1699     return unless $attribute->count;
1700     return $attribute->next;
1701 }
1702
1703 =head3 to_api
1704
1705     my $json = $patron->to_api;
1706
1707 Overloaded method that returns a JSON representation of the Koha::Patron object,
1708 suitable for API output.
1709
1710 =cut
1711
1712 sub to_api {
1713     my ( $self, $params ) = @_;
1714
1715     my $json_patron = $self->SUPER::to_api( $params );
1716
1717     $json_patron->{restricted} = ( $self->is_debarred )
1718                                     ? Mojo::JSON->true
1719                                     : Mojo::JSON->false;
1720
1721     return $json_patron;
1722 }
1723
1724 =head3 to_api_mapping
1725
1726 This method returns the mapping for representing a Koha::Patron object
1727 on the API.
1728
1729 =cut
1730
1731 sub to_api_mapping {
1732     return {
1733         borrowernotes       => 'staff_notes',
1734         borrowernumber      => 'patron_id',
1735         branchcode          => 'library_id',
1736         categorycode        => 'category_id',
1737         checkprevcheckout   => 'check_previous_checkout',
1738         contactfirstname    => undef,                     # Unused
1739         contactname         => undef,                     # Unused
1740         contactnote         => 'altaddress_notes',
1741         contacttitle        => undef,                     # Unused
1742         dateenrolled        => 'date_enrolled',
1743         dateexpiry          => 'expiry_date',
1744         dateofbirth         => 'date_of_birth',
1745         debarred            => undef,                     # replaced by 'restricted'
1746         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1747         emailpro            => 'secondary_email',
1748         flags               => undef,    # permissions manipulation handled in /permissions
1749         gonenoaddress       => 'incorrect_address',
1750         guarantorid         => 'guarantor_id',
1751         lastseen            => 'last_seen',
1752         lost                => 'patron_card_lost',
1753         opacnote            => 'opac_notes',
1754         othernames          => 'other_name',
1755         password            => undef,            # password manipulation handled in /password
1756         phonepro            => 'secondary_phone',
1757         relationship        => 'relationship_type',
1758         sex                 => 'gender',
1759         smsalertnumber      => 'sms_number',
1760         sort1               => 'statistics_1',
1761         sort2               => 'statistics_2',
1762         autorenew_checkouts => 'autorenew_checkouts',
1763         streetnumber        => 'street_number',
1764         streettype          => 'street_type',
1765         zipcode             => 'postal_code',
1766         B_address           => 'altaddress_address',
1767         B_address2          => 'altaddress_address2',
1768         B_city              => 'altaddress_city',
1769         B_country           => 'altaddress_country',
1770         B_email             => 'altaddress_email',
1771         B_phone             => 'altaddress_phone',
1772         B_state             => 'altaddress_state',
1773         B_streetnumber      => 'altaddress_street_number',
1774         B_streettype        => 'altaddress_street_type',
1775         B_zipcode           => 'altaddress_postal_code',
1776         altcontactaddress1  => 'altcontact_address',
1777         altcontactaddress2  => 'altcontact_address2',
1778         altcontactaddress3  => 'altcontact_city',
1779         altcontactcountry   => 'altcontact_country',
1780         altcontactfirstname => 'altcontact_firstname',
1781         altcontactphone     => 'altcontact_phone',
1782         altcontactsurname   => 'altcontact_surname',
1783         altcontactstate     => 'altcontact_state',
1784         altcontactzipcode   => 'altcontact_postal_code'
1785     };
1786 }
1787
1788 =head2 Internal methods
1789
1790 =head3 _type
1791
1792 =cut
1793
1794 sub _type {
1795     return 'Borrower';
1796 }
1797
1798 =head1 AUTHORS
1799
1800 Kyle M Hall <kyle@bywatersolutions.com>
1801 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
1802 Martin Renvoize <martin.renvoize@ptfs-europe.com>
1803
1804 =cut
1805
1806 1;