Koha/REST/V1.pm

   1 package Koha::REST::V1;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious';
  21
  22 use C4::Context;
  23 use Koha::Logger;
  24
  25 use JSON::Validator::OpenAPI::Mojolicious;
  26 use Try::Tiny;
  27
  28 =head1 NAME
  29
  30 Koha::REST::V1 - Main v.1 REST api class
  31
  32 =head1 API
  33
  34 =head2 Class Methods
  35
  36 =head3 startup
  37
  38 Overloaded Mojolicious->startup method. It is called at application startup.
  39
  40 =cut
  41
  42 sub startup {
  43     my $self = shift;
  44
  45     $self->hook(
  46         before_dispatch => sub {
  47             my $c = shift;
  48
  49             # Remove /api/v1/app.pl/ from the path
  50             $c->req->url->base->path('/');
  51
  52             # Handle CORS
  53             $c->res->headers->header( 'Access-Control-Allow-Origin' =>
  54                   C4::Context->preference('AccessControlAllowOrigin') )
  55               if C4::Context->preference('AccessControlAllowOrigin');
  56         }
  57     );
  58
  59     # Force charset=utf8 in Content-Type header for JSON responses
  60     $self->types->type( json    => 'application/json; charset=utf8' );
  61     # MARC-related types
  62     $self->types->type( marcxml => 'application/marcxml+xml' );
  63     $self->types->type( mij     => 'application/marc-in-json' );
  64     $self->types->type( marc    => 'application/marc' );
  65
  66     my $secret_passphrase = C4::Context->config('api_secret_passphrase');
  67     if ($secret_passphrase) {
  68         $self->secrets([$secret_passphrase]);
  69     }
  70
  71     my $validator = JSON::Validator::OpenAPI::Mojolicious->new;
  72
  73     push @{$self->routes->namespaces}, 'Koha::Plugin';
  74
  75     # Try to load and merge all schemas first and validate the result just once.
  76     my $spec;
  77     my $swagger_schema = $self->home->rel_file("api/swagger-v2-schema.json");
  78     try {
  79         $spec = $validator->bundle(
  80             {
  81                 replace => 1,
  82                 schema => $self->home->rel_file("api/v1/swagger/swagger.json")
  83             }
  84         );
  85
  86         $self->plugin(
  87             'Koha::REST::Plugin::PluginRoutes' => {
  88                 spec               => $spec,
  89                 validator          => undef
  90             }
  91         ) unless C4::Context->needs_install; # load only if Koha is installed
  92
  93         $self->plugin(
  94             OpenAPI => {
  95                 spec  => $spec,
  96                 route => $self->routes->under('/api/v1')->to('Auth#under'),
  97                 schema => ( $swagger_schema ) ? $swagger_schema : undef,
  98                 allow_invalid_ref =>
  99                 1,    # required by our spec because $ref directly under
 100                         # Paths-, Parameters-, Definitions- & Info-object
 101                         # is not allowed by the OpenAPI specification.
 102             }
 103         );
 104     }
 105     catch {
 106         # Validation of the complete spec failed. Resort to validation one-by-one
 107         # to catch bad ones.
 108
 109         # JSON::Validator uses confess, so trim call stack from the message.
 110         my $logger = Koha::Logger->get({ interface => 'api' });
 111         $logger->error("Warning: Could not load REST API spec bundle: " . $_);
 112
 113         try {
 114             $validator->load_and_validate_schema(
 115                 $self->home->rel_file("api/v1/swagger/swagger.json"),
 116                 {
 117                     allow_invalid_ref  => 1,
 118                     schema => ( $swagger_schema ) ? $swagger_schema : undef,
 119                 }
 120             );
 121
 122             $spec = $validator->schema->data;
 123             $self->plugin(
 124                 'Koha::REST::Plugin::PluginRoutes' => {
 125                     spec      => $spec,
 126                     validator => $validator
 127                 }
 128             )  unless C4::Context->needs_install; # load only if Koha is installed
 129
 130             $self->plugin(
 131                 OpenAPI => {
 132                     spec  => $spec,
 133                     route => $self->routes->under('/api/v1')->to('Auth#under'),
 134                     allow_invalid_ref =>
 135                     1,    # required by our spec because $ref directly under
 136                             # Paths-, Parameters-, Definitions- & Info-object
 137                             # is not allowed by the OpenAPI specification.
 138                 }
 139             );
 140         }
 141         catch {
 142             # JSON::Validator uses confess, so trim call stack from the message.
 143             $logger->error("Warning: Could not load REST API spec bundle: " . $_);
 144         };
 145     };
 146
 147     $self->plugin( 'Koha::REST::Plugin::Pagination' );
 148     $self->plugin( 'Koha::REST::Plugin::Query' );
 149     $self->plugin( 'Koha::REST::Plugin::Objects' );
 150     $self->plugin( 'Koha::REST::Plugin::Exceptions' );
 151 }
 152
 153 1;