C4/SIP/Sip.pm

   1 #
   2 # Sip.pm: General Sip utility functions
   3 #
   4
   5 package C4::SIP::Sip;
   6
   7 use strict;
   8 use warnings;
   9 use Exporter;
  10 use Encode;
  11 use Sys::Syslog qw(syslog);
  12 use POSIX qw(strftime);
  13 use Socket qw(:crlf);
  14 use IO::Handle;
  15
  16 use C4::SIP::Sip::Constants qw(SIP_DATETIME FID_SCREEN_MSG);
  17 use C4::SIP::Sip::Checksum qw(checksum);
  18
  19 use vars qw($VERSION @ISA @EXPORT_OK %EXPORT_TAGS);
  20
  21 BEGIN {
  22     $VERSION = 3.07.00.049;
  23         @ISA = qw(Exporter);
  24
  25         @EXPORT_OK = qw(y_or_n timestamp add_field maybe_add add_count
  26                     denied sipbool boolspace write_msg read_SIP_packet
  27                     $error_detection $protocol_version $field_delimiter
  28                     $last_response);
  29
  30         %EXPORT_TAGS = (
  31                     all => [qw(y_or_n timestamp add_field maybe_add
  32                                add_count denied sipbool boolspace write_msg
  33                                read_SIP_packet
  34                                $error_detection $protocol_version
  35                                $field_delimiter $last_response)]);
  36 }
  37
  38 our $error_detection = 0;
  39 our $protocol_version = 1;
  40 our $field_delimiter = '|'; # Protocol Default
  41
  42 # We need to keep a copy of the last message we sent to the SC,
  43 # in case there's a transmission error and the SC sends us a
  44 # REQUEST_ACS_RESEND.  If we receive a REQUEST_ACS_RESEND before
  45 # we've ever sent anything, then we are to respond with a
  46 # REQUEST_SC_RESEND (p.16)
  47
  48 our $last_response = '';
  49
  50 sub timestamp {
  51     my $time = $_[0] || time();
  52     if ( ref $time eq 'DateTime') {
  53         return $time->strftime(SIP_DATETIME);
  54     } elsif ($time=~m/^(\d{4})\-(\d{2})\-(\d{2})/) {
  55         # passing a db returned date as is + bogus time
  56         return sprintf( '%04d%02d%02d    235900', $1, $2, $3);
  57     }
  58     return strftime(SIP_DATETIME, localtime($time));
  59 }
  60
  61 #
  62 # add_field(field_id, value)
  63 #    return constructed field value
  64 #
  65 sub add_field {
  66     my ($field_id, $value) = @_;
  67     my ($i, $ent);
  68
  69     if (!defined($value)) {
  70         syslog("LOG_DEBUG", "add_field: Undefined value being added to '%s'",
  71                $field_id);
  72                 $value = '';
  73     }
  74     $value=~s/\r/ /g; # CR terminates a sip message
  75                       # Protect against them in sip text fields
  76
  77     # Replace any occurences of the field delimiter in the
  78     # field value with the HTML character entity
  79     $ent = sprintf("&#%d;", ord($field_delimiter));
  80
  81     while (($i = index($value, $field_delimiter)) != ($[-1)) {
  82                 substr($value, $i, 1) = $ent;
  83     }
  84
  85     return $field_id . $value . $field_delimiter;
  86 }
  87 #
  88 # maybe_add(field_id, value):
  89 #    If value is defined and non-empty, then return the
  90 #    constructed field value, otherwise return the empty string.
  91 #    NOTE: if zero is a valid value for your field, don't use maybe_add!
  92 #
  93 sub maybe_add {
  94     my ($fid, $value, $server) = @_;
  95
  96     if ( $fid eq FID_SCREEN_MSG && $server->{account}->{screen_msg_regex} ) {
  97         foreach my $regex (
  98             ref $server->{account}->{screen_msg_regex} eq "ARRAY"
  99             ? @{ $server->{account}->{screen_msg_regex} }
 100             : $server->{account}->{screen_msg_regex} )
 101         {
 102             $value =~ s/$regex->{find}/$regex->{replace}/g;
 103         }
 104     }
 105
 106     return (defined($value) && $value) ? add_field($fid, $value) : '';
 107 }
 108
 109 #
 110 # add_count()  produce fixed four-character count field,
 111 # or a string of four spaces if the count is invalid for some
 112 # reason
 113 #
 114 sub add_count {
 115     my ($label, $count) = @_;
 116
 117     # If the field is unsupported, it will be undef, return blanks
 118     # as per the spec.
 119     if (!defined($count)) {
 120                 return ' ' x 4;
 121     }
 122
 123     $count = sprintf("%04d", $count);
 124     if (length($count) != 4) {
 125                 syslog("LOG_WARNING", "handle_patron_info: %s wrong size: '%s'",
 126                $label, $count);
 127                 $count = ' ' x 4;
 128     }
 129     return $count;
 130 }
 131
 132 #
 133 # denied($bool)
 134 # if $bool is false, return true.  This is because SIP statuses
 135 # are inverted:  we report that something has been denied, not that
 136 # it's permitted.  For example, 'renewal priv. denied' of 'Y' means
 137 # that the user's not permitted to renew.  I assume that the ILS has
 138 # real positive tests.
 139 #
 140 sub denied {
 141     my $bool = shift;
 142     return boolspace(!$bool);
 143 }
 144
 145 sub sipbool {
 146     my $bool = shift;
 147     return $bool ? 'Y' : 'N';
 148 }
 149
 150 #
 151 # boolspace: ' ' is false, 'Y' is true. (don't ask)
 152 #
 153 sub boolspace {
 154     my $bool = shift;
 155     return $bool ? 'Y' : ' ';
 156 }
 157
 158
 159 # read_SIP_packet($file)
 160 #
 161 # Read a packet from $file, using the correct record separator
 162 #
 163 sub read_SIP_packet {
 164     my $record;
 165     my $fh = shift or syslog("LOG_ERR", "read_SIP_packet: no filehandle argument!");
 166     my $len1 = 999;
 167
 168     # local $/ = "\r";      # don't need any of these here.  use whatever the prevailing $/ is.
 169     local $/ = "\015";    # proper SPEC: (octal) \015 = (hex) x0D = (dec) 13 = (ascii) carriage return
 170     {    # adapted from http://perldoc.perl.org/5.8.8/functions/readline.html
 171             undef $!;
 172             $record = readline($fh);
 173             if ( defined($record) ) {
 174                 while ( chomp($record) ) { 1; }
 175                 $len1 = length($record);
 176                 syslog( "LOG_DEBUG", "read_SIP_packet, INPUT MSG: '$record'" );
 177                 $record =~ s/^\s*[^A-z0-9]+//s; # Every line must start with a "real" character.  Not whitespace, control chars, etc.
 178                 $record =~ s/[^A-z0-9]+$//s;    # Same for the end.  Note this catches the problem some clients have sending empty fields at the end, like |||
 179                 $record =~ s/\015?\012//g;      # Extra line breaks must die
 180                 $record =~ s/\015?\012//s;      # Extra line breaks must die
 181                 $record =~ s/\015*\012*$//s;    # treat as one line to include the extra linebreaks we are trying to remove!
 182                 while ( chomp($record) ) { 1; }
 183
 184                 $record and last;    # success
 185             }
 186     }
 187     if ($record) {
 188         my $len2 = length($record);
 189         syslog("LOG_INFO", "read_SIP_packet, INPUT MSG: '$record'") if $record;
 190         ($len1 != $len2) and syslog("LOG_DEBUG", "read_SIP_packet, trimmed %s character(s) (after chomps).", $len1-$len2);
 191     } else {
 192         syslog("LOG_WARNING", "read_SIP_packet input %s, end of input.", (defined($record) ? "empty ($record)" : 'undefined'));
 193     }
 194     #
 195     # Cen-Tec self-check terminals transmit '\r\n' line terminators.
 196     # This is actually very hard to deal with in perl in a reasonable
 197     # since every OTHER piece of hardware out there gets the protocol
 198     # right.
 199     #
 200     # The incorrect line terminator presents as a \r at the end of the
 201     # first record, and then a \n at the BEGINNING of the next record.
 202     # So, the simplest thing to do is just throw away a leading newline
 203     # on the input.
 204     #
 205     # This is now handled by the vigorous cleansing above.
 206     # syslog("LOG_INFO", encode_utf8("INPUT MSG: '$record'")) if $record;
 207     syslog("LOG_INFO", "INPUT MSG: '$record'") if $record;
 208     return $record;
 209 }
 210
 211 #
 212 # write_msg($msg, $file)
 213 #
 214 # Send $msg to the SC.  If error detection is active, then
 215 # add the sequence number (if $seqno is non-zero) and checksum
 216 # to the message, and save the whole thing as $last_response
 217 #
 218 # If $file is set, then it's a file handle: write to it, otherwise
 219 # just write to the default destination.
 220 #
 221
 222 sub write_msg {
 223     my ($self, $msg, $file, $terminator, $encoding) = @_;
 224
 225     $terminator ||= q{};
 226     $terminator = ( $terminator eq 'CR' ) ? $CR : $CRLF;
 227
 228     $msg = encode($encoding, $msg) if ( $encoding );
 229
 230     my $cksum;
 231
 232     # $msg = encode_utf8($msg);
 233     if ($error_detection) {
 234         if (defined($self->{seqno})) {
 235             $msg .= 'AY' . $self->{seqno};
 236         }
 237         $msg .= 'AZ';
 238         $cksum = checksum($msg);
 239         $msg .= sprintf('%04.4X', $cksum);
 240     }
 241
 242
 243     if ($file) {
 244         $file->autoflush(1);
 245         print $file $msg, $terminator;
 246     } else {
 247         STDOUT->autoflush(1);
 248         print $msg, $terminator;
 249         syslog("LOG_INFO", "OUTPUT MSG: '$msg'");
 250     }
 251
 252     $last_response = $msg;
 253 }
 254
 255 1;