C4/SIP/ILS.pm

   1 #
   2 # ILS.pm: Koha ILS interface module
   3 #
   4
   5 package C4::SIP::ILS;
   6
   7 use warnings;
   8 use strict;
   9 use Sys::Syslog qw(syslog);
  10 use Data::Dumper;
  11
  12 use C4::SIP::ILS::Item;
  13 use C4::SIP::ILS::Patron;
  14 use C4::SIP::ILS::Transaction;
  15 use C4::SIP::ILS::Transaction::Checkout;
  16 use C4::SIP::ILS::Transaction::Checkin;
  17 use C4::SIP::ILS::Transaction::FeePayment;
  18 use C4::SIP::ILS::Transaction::Hold;
  19 use C4::SIP::ILS::Transaction::Renew;
  20 use C4::SIP::ILS::Transaction::RenewAll;
  21
  22 my $debug = 0;
  23
  24 my %supports = (
  25     'magnetic media'        => 1,
  26     'security inhibit'      => 0,
  27     'offline operation'     => 0,
  28     "patron status request" => 1,
  29     "checkout"              => 1,
  30     "checkin"               => 1,
  31     "block patron"          => 1,
  32     "acs status"            => 1,
  33     "login"                 => 1,
  34     "patron information"    => 1,
  35     "end patron session"    => 1,
  36     "fee paid"              => 1,
  37     "item information"      => 1,
  38     "item status update"    => 0,
  39     "patron enable"         => 1,
  40     "hold"                  => 1,
  41     "renew"                 => 1,
  42     "renew all"             => 1,
  43 );
  44
  45 sub new {
  46     my ($class, $institution) = @_;
  47     my $type = ref($class) || $class;
  48     my $self = {};
  49         $debug and warn "new ILS: INSTITUTION: " . Dumper($institution);
  50     syslog("LOG_DEBUG", "new ILS '%s'", $institution->{id});
  51     $self->{institution} = $institution;
  52     return bless $self, $type;
  53 }
  54
  55 sub find_patron {
  56     my $self = shift;
  57         $debug and warn "ILS: finding patron";
  58     return C4::SIP::ILS::Patron->new(@_);
  59 }
  60
  61 sub find_item {
  62     my $self = shift;
  63         $debug and warn "ILS: finding item";
  64     return C4::SIP::ILS::Item->new(@_);
  65 }
  66
  67 sub institution {
  68     my $self = shift;
  69     return $self->{institution}->{id};  # consider making this return the whole institution
  70 }
  71
  72 sub institution_id {
  73     my $self = shift;
  74     return $self->{institution}->{id};
  75 }
  76
  77 sub supports {
  78     my ($self, $op) = @_;
  79     return (exists($supports{$op}) && $supports{$op});
  80 }
  81
  82 sub check_inst_id {
  83     my ($self, $id, $whence) = @_;
  84     if ($id ne $self->{institution}->{id}) {
  85         syslog("LOG_WARNING", "%s: received institution '%s', expected '%s'", $whence, $id, $self->{institution}->{id});
  86         # Just an FYI check, we don't expect the user to change location from that in SIPconfig.xml
  87     }
  88 }
  89
  90 sub to_bool {
  91     my $bool = shift;
  92     # If it's defined, and matches a true sort of string, or is
  93     # a non-zero number, then it's true.
  94     defined($bool) or return;                   # false
  95     ($bool =~ /true|y|yes/i) and return 1;      # true
  96     return ($bool =~ /^\d+$/ and $bool != 0);   # true for non-zero numbers, false otherwise
  97 }
  98
  99 sub checkout_ok {
 100     my $self = shift;
 101     return (exists($self->{institution}->{policy}->{checkout})
 102             && to_bool($self->{institution}->{policy}->{checkout}));
 103 }
 104 sub checkin_ok {
 105     my $self = shift;
 106     return (exists($self->{institution}->{policy}->{checkin})
 107             && to_bool($self->{institution}->{policy}->{checkin}));
 108 }
 109 sub status_update_ok {
 110     my $self = shift;
 111     return (exists($self->{institution}->{policy}->{status_update})
 112             && to_bool($self->{institution}->{policy}->{status_update}));
 113 }
 114 sub offline_ok {
 115     my $self = shift;
 116     return (exists($self->{institution}->{policy}->{offline})
 117             && to_bool($self->{institution}->{policy}->{offline}));
 118 }
 119
 120 #
 121 # Checkout(patron_id, item_id, sc_renew):
 122 #    patron_id & item_id are the identifiers send by the terminal
 123 #    sc_renew is the renewal policy configured on the terminal
 124 # returns a status opject that can be queried for the various bits
 125 # of information that the protocol (SIP or NCIP) needs to generate
 126 # the response.
 127 #
 128 sub checkout {
 129     my ( $self, $patron_id, $item_id, $sc_renew, $fee_ack ) = @_;
 130     my ( $patron, $item, $circ );
 131
 132     $circ = C4::SIP::ILS::Transaction::Checkout->new();
 133
 134     # BEGIN TRANSACTION
 135     $circ->patron( $patron = C4::SIP::ILS::Patron->new($patron_id) );
 136     $circ->item( $item     = C4::SIP::ILS::Item->new($item_id) );
 137     if ($fee_ack) {
 138         $circ->fee_ack($fee_ack);
 139     }
 140
 141     if ( !$patron ) {
 142         $circ->screen_msg("Invalid Patron");
 143     }
 144     elsif ( !$patron->charge_ok ) {
 145         $circ->screen_msg("Patron Blocked");
 146     }
 147     elsif ( !$item ) {
 148         $circ->screen_msg("Invalid Item");
 149     }
 150     elsif ( $item->{patron}
 151         && !_ci_cardnumber_cmp( $item->{patron}, $patron_id ) )
 152     {
 153         $circ->screen_msg("Item checked out to another patron");
 154     }
 155     else {
 156         $circ->do_checkout();
 157         if ( $circ->ok ) {
 158             $debug and warn "circ is ok";
 159
 160             # If the item is already associated with this patron, then
 161             # we're renewing it.
 162             $circ->renew_ok( $item->{patron}
 163                   && _ci_cardnumber_cmp( $item->{patron}, $patron_id ) );
 164
 165             $item->{patron}   = $patron_id;
 166             $item->{due_date} = $circ->{due};
 167             push( @{ $patron->{items} }, $item_id );
 168             $circ->desensitize( !$item->magnetic_media );
 169
 170             syslog(
 171                 "LOG_DEBUG", "ILS::Checkout: patron %s has checked out %s",
 172                 $patron_id, join( ', ', @{ $patron->{items} } )
 173             );
 174         }
 175         else {
 176             syslog( "LOG_ERR", "ILS::Checkout Issue failed" );
 177         }
 178     }
 179
 180     # END TRANSACTION
 181
 182     return $circ;
 183 }
 184
 185 sub _ci_cardnumber_cmp {
 186     my ( $s1, $s2) = @_;
 187     # As the database is case insensitive we need to normalize two strings
 188     # before comparing them
 189     return ( uc($s1) eq uc($s2) );
 190 }
 191
 192 # wrapper which allows above to be called for testing
 193
 194 sub test_cardnumber_compare {
 195     my ($self, $str1, $str2) = @_;
 196     return _ci_cardnumber_cmp($str1, $str2);
 197 }
 198
 199 sub checkin {
 200     my ( $self, $item_id, $trans_date, $return_date, $current_loc, $item_props, $cancel, $checked_in_ok ) = @_;
 201     my ( $patron, $item, $circ );
 202
 203     $circ = C4::SIP::ILS::Transaction::Checkin->new();
 204
 205     # BEGIN TRANSACTION
 206     $circ->item( $item = C4::SIP::ILS::Item->new($item_id) );
 207
 208     if ($item) {
 209         $circ->do_checkin( $current_loc, $return_date );
 210     }
 211     else {
 212         $circ->alert(1);
 213         $circ->alert_type(99);
 214         $circ->screen_msg('Invalid Item');
 215     }
 216
 217     # It's ok to check it in if it exists, and if it was checked out
 218     # or it was not checked out but the checked_in_ok flag was set
 219     $circ->ok( ( $checked_in_ok && $item ) || ( $item && $item->{patron} ) );
 220     syslog("LOG_DEBUG", "C4::SIP::ILS::checkin - using checked_in_ok") if $checked_in_ok;
 221
 222     if ( !defined( $item->{patron} ) ) {
 223         $circ->screen_msg("Item not checked out") unless $checked_in_ok;
 224         syslog("LOG_DEBUG", "C4::SIP::ILS::checkin - item not checked out");
 225     }
 226     else {
 227         if ( $circ->ok ) {
 228             $circ->patron( $patron = C4::SIP::ILS::Patron->new( $item->{patron} ) );
 229             delete $item->{patron};
 230             delete $item->{due_date};
 231             $patron->{items} = [ grep { $_ ne $item_id } @{ $patron->{items} } ];
 232         }
 233     }
 234
 235     # END TRANSACTION
 236
 237     return $circ;
 238 }
 239
 240 # If the ILS caches patron information, this lets it free
 241 # it up
 242 sub end_patron_session {
 243     my ($self, $patron_id) = @_;
 244
 245     # success?, screen_msg, print_line
 246     return (1, 'Thank you !', '');
 247 }
 248
 249 sub pay_fee {
 250     my ($self, $patron_id, $patron_pwd, $fee_amt, $fee_type,
 251         $pay_type, $fee_id, $trans_id, $currency) = @_;
 252     my $trans;
 253
 254     $trans = C4::SIP::ILS::Transaction::FeePayment->new();
 255
 256
 257     $trans->transaction_id($trans_id);
 258     my $patron;
 259     $trans->patron($patron = C4::SIP::ILS::Patron->new($patron_id));
 260     if (!$patron) {
 261         $trans->screen_msg('Invalid patron barcode.');
 262         return $trans;
 263     }
 264     $trans->pay($patron->{borrowernumber},$fee_amt, $pay_type);
 265     $trans->ok(1);
 266
 267     return $trans;
 268 }
 269
 270 sub add_hold {
 271     my ($self, $patron_id, $patron_pwd, $item_id, $title_id,
 272         $expiry_date, $pickup_location, $hold_type, $fee_ack) = @_;
 273     my ($patron, $item);
 274
 275         my $trans = C4::SIP::ILS::Transaction::Hold->new();
 276
 277     $patron = C4::SIP::ILS::Patron->new( $patron_id);
 278     if (!$patron
 279         || (defined($patron_pwd) && !$patron->check_password($patron_pwd))) {
 280                 $trans->screen_msg("Invalid Patron.");
 281                 return $trans;
 282     }
 283
 284         unless ($item = C4::SIP::ILS::Item->new($item_id || $title_id)) {
 285                 $trans->screen_msg("No such item.");
 286                 return $trans;
 287         }
 288
 289     if ( $patron->holds_blocked_by_excessive_fees() ) {
 290         $trans->screen_msg("Excessive fees blocking placement of hold.");
 291     }
 292
 293    if ($item->fee and $fee_ack ne 'Y') {
 294                 $trans->screen_msg = "Fee required to place hold.";
 295                 return $trans;
 296     }
 297
 298     my $hold = {
 299         item_id         => $item->id,
 300         patron_id       => $patron->id,
 301         expiration_date => $expiry_date,
 302         pickup_location => $pickup_location,
 303         hold_type       => $hold_type,
 304     };
 305
 306     $trans->ok(1);
 307     $trans->patron($patron);
 308     $trans->item($item);
 309     $trans->pickup_location($pickup_location);
 310         $trans->do_hold;
 311
 312     push(@{$item->hold_queue},     $hold);
 313     push(@{$patron->{hold_items}}, $hold);
 314
 315     return $trans;
 316 }
 317
 318 sub cancel_hold {
 319     my ($self, $patron_id, $patron_pwd, $item_id, $title_id) = @_;
 320     my ($patron, $item, $hold);
 321
 322         my $trans = C4::SIP::ILS::Transaction::Hold->new();
 323
 324     $patron = C4::SIP::ILS::Patron->new( $patron_id );
 325     if (!$patron) {
 326                 $trans->screen_msg("Invalid patron barcode.");
 327                 return $trans;
 328     } elsif (defined($patron_pwd) && !$patron->check_password($patron_pwd)) {
 329                 $trans->screen_msg('Invalid patron password.');
 330                 return $trans;
 331     }
 332
 333     unless ($item = C4::SIP::ILS::Item->new($item_id || $title_id)) {
 334                 $trans->screen_msg("No such item.");
 335                 return $trans;
 336     }
 337
 338     $trans->patron($patron);
 339     $trans->item($item);
 340         $trans->drop_hold;
 341         unless ($trans->ok) {
 342                 $trans->screen_msg("Error with transaction drop_hold: " . $trans->screen_msg);
 343                 return $trans;
 344         }
 345     # Remove the hold from the patron's record first
 346     $trans->ok($patron->drop_hold($item_id));   # different than the transaction drop!
 347
 348     unless ($trans->ok) {
 349                 # We didn't find it on the patron record
 350                 $trans->screen_msg("No such hold on patron record.");
 351                 return $trans;
 352     }
 353
 354     # Now, remove it from the item record.  If it was on the patron
 355     # record but not on the item record, we'll treat that as success.
 356     foreach my $i (0 .. scalar @{$item->hold_queue}) {
 357                 $hold = $item->hold_queue->[$i];
 358                 if ($item->barcode_is_borrowernumber($patron->id, $hold->{borrowernumber})) {
 359                     # found it: delete it.
 360                     splice @{$item->hold_queue}, $i, 1;
 361                     last;               # ?? should we keep going, in case there are multiples
 362                 }
 363     }
 364
 365     $trans->screen_msg("Hold Cancelled.");
 366
 367     return $trans;
 368 }
 369
 370
 371 # The patron and item id's can't be altered, but the
 372 # date, location, and type can.
 373 sub alter_hold {
 374     my ($self, $patron_id, $patron_pwd, $item_id, $title_id,
 375         $expiry_date, $pickup_location, $hold_type, $fee_ack) = @_;
 376     my ($patron, $item);
 377     my $hold;
 378     my $trans;
 379
 380     $trans = C4::SIP::ILS::Transaction::Hold->new();
 381
 382     # BEGIN TRANSACTION
 383     $patron = C4::SIP::ILS::Patron->new( $patron_id );
 384     unless ($patron) {
 385                 $trans->screen_msg("Invalid patron barcode: '$patron_id'.");
 386                 return $trans;
 387     }
 388
 389     foreach my $i (0 .. scalar @{$patron->{hold_items}}) {
 390                 $hold = $patron->{hold_items}[$i];
 391
 392         if ($hold->{item_id} eq $item_id) {
 393             # Found it.  So fix it.
 394             $hold->{expiration_date} = $expiry_date     if $expiry_date;
 395             $hold->{pickup_location} = $pickup_location if $pickup_location;
 396             $hold->{hold_type}       = $hold_type       if $hold_type;
 397                 $trans->change_hold();
 398             # $trans->ok(1);
 399             $trans->screen_msg("Hold updated.");
 400             $trans->patron($patron);
 401             $trans->item(C4::SIP::ILS::Item->new( $hold->{item_id}));
 402             last;
 403         }
 404     }
 405
 406     # The same hold structure is linked into both the patron's
 407     # list of hold items and into the queue of outstanding holds
 408     # for the item, so we don't need to search the hold queue for
 409     # the item, since it's already been updated by the patron code.
 410
 411     if (!$trans->ok) {
 412                 $trans->screen_msg("No such outstanding hold.");
 413     }
 414
 415     return $trans;
 416 }
 417
 418 sub renew {
 419     my ($self, $patron_id, $patron_pwd, $item_id, $title_id,
 420         $no_block, $nb_due_date, $third_party,
 421         $item_props, $fee_ack) = @_;
 422     my ($patron, $item);
 423     my $trans;
 424
 425     $trans = C4::SIP::ILS::Transaction::Renew->new();
 426     $trans->patron($patron = C4::SIP::ILS::Patron->new( $patron_id ));
 427
 428     if (!$patron) {
 429                 $trans->screen_msg("Invalid patron barcode.");
 430                 return $trans;
 431     } elsif (!$patron->renew_ok) {
 432                 $trans->screen_msg("Renewals not allowed.");
 433                 return $trans;
 434     }
 435
 436         # Previously: renewing a title, rather than an item (sort of)
 437         # This is gross, but in a real ILS it would be better
 438
 439     # if (defined($title_id)) {
 440         #       foreach my $i (@{$patron->{items}}) {
 441         #               $item = new ILS::Item $i;
 442         #               last if ($title_id eq $item->title_id);
 443         #               $item = undef;
 444         #       }
 445     # } else {
 446                 my $j = 0;
 447                 my $count = scalar @{$patron->{items}};
 448                 foreach my $i (@{$patron->{items}}) {
 449             unless (defined $i->{barcode}) {    # FIXME: using data instead of objects may violate the abstraction layer
 450                 syslog("LOG_ERR", "No barcode for item %s of %s: $item_id", $j+1, $count);
 451                 next;
 452             }
 453             syslog("LOG_DEBUG", "checking item %s of %s: $item_id vs. %s", ++$j, $count, $i->{barcode});
 454             if ($i->{barcode} eq $item_id) {
 455                                 # We have it checked out
 456                                 $item = C4::SIP::ILS::Item->new( $item_id );
 457                                 last;
 458                         }
 459                 }
 460     # }
 461
 462     $trans->item($item);
 463
 464     if (!defined($item)) {
 465                 $trans->screen_msg("Item not checked out to " . $patron->name);     # not checked out to $patron_id
 466         $trans->ok(0);
 467     } else {
 468         $trans->do_renew();
 469         if ($trans->renewal_ok()) {
 470             $item->{due_date} = $trans->{due};
 471             $trans->desensitize(0);
 472         }
 473     }
 474
 475     return $trans;
 476 }
 477
 478 sub renew_all {
 479     my ($self, $patron_id, $patron_pwd, $fee_ack) = @_;
 480     my ($patron, $item_id);
 481     my $trans;
 482
 483     $trans = C4::SIP::ILS::Transaction::RenewAll->new();
 484
 485     $trans->patron($patron = C4::SIP::ILS::Patron->new( $patron_id ));
 486     if (defined $patron) {
 487         syslog("LOG_DEBUG", "ILS::renew_all: patron '%s': renew_ok: %s", $patron->name, $patron->renew_ok);
 488     } else {
 489         syslog("LOG_DEBUG", "ILS::renew_all: Invalid patron id: '%s'", $patron_id);
 490     }
 491
 492     if (!defined($patron)) {
 493                 $trans->screen_msg("Invalid patron barcode.");
 494                 return $trans;
 495     } elsif (!$patron->renew_ok) {
 496                 $trans->screen_msg("Renewals not allowed.");
 497                 return $trans;
 498     } elsif (defined($patron_pwd) && !$patron->check_password($patron_pwd)) {
 499                 $trans->screen_msg("Invalid patron password.");
 500                 return $trans;
 501     }
 502
 503         $trans->do_renew_all;
 504     $trans->ok(1);
 505     return $trans;
 506 }
 507
 508 1;
 509 __END__
 510