C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79
  80         # Redefine multi_param if cgi version is < 4.08
  81         # Remove the "CGI::param called in list context" warning in this case
  82         if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  83             no warnings 'redefine';
  84             *CGI::multi_param = \&CGI::param;
  85             use warnings 'redefine';
  86             $CGI::LIST_CONTEXT_WARN = 0;
  87         }
  88     }   # else there is no browser to send fatals to!
  89
  90     # Check if there are memcached servers set
  91     $servers = $ENV{'MEMCACHED_SERVERS'};
  92     if ($servers) {
  93         # Load required libraries and create the memcached object
  94         require Cache::Memcached;
  95         $memcached = Cache::Memcached->new({
  96         servers => [ $servers ],
  97         debug   => 0,
  98         compress_threshold => 10_000,
  99         expire_time => 600,
 100         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
 101     });
 102         # Verify memcached available (set a variable and test the output)
 103     $ismemcached = $memcached->set('ismemcached','1');
 104     }
 105
 106 }
 107
 108 use Encode;
 109 use ZOOM;
 110 use XML::Simple;
 111 use Koha::Cache;
 112 use POSIX ();
 113 use DateTime::TimeZone;
 114 use Module::Load::Conditional qw(can_load);
 115 use Carp;
 116
 117 use C4::Boolean;
 118 use C4::Debug;
 119 use Koha;
 120 use Koha::Config::SysPref;
 121 use Koha::Config::SysPrefs;
 122
 123 =head1 NAME
 124
 125 C4::Context - Maintain and manipulate the context of a Koha script
 126
 127 =head1 SYNOPSIS
 128
 129   use C4::Context;
 130
 131   use C4::Context("/path/to/koha-conf.xml");
 132
 133   $config_value = C4::Context->config("config_variable");
 134
 135   $koha_preference = C4::Context->preference("preference");
 136
 137   $db_handle = C4::Context->dbh;
 138
 139   $Zconn = C4::Context->Zconn;
 140
 141 =head1 DESCRIPTION
 142
 143 When a Koha script runs, it makes use of a certain number of things:
 144 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 145 databases, and so forth. These things make up the I<context> in which
 146 the script runs.
 147
 148 This module takes care of setting up the context for a script:
 149 figuring out which configuration file to load, and loading it, opening
 150 a connection to the right database, and so forth.
 151
 152 Most scripts will only use one context. They can simply have
 153
 154   use C4::Context;
 155
 156 at the top.
 157
 158 Other scripts may need to use several contexts. For instance, if a
 159 library has two databases, one for a certain collection, and the other
 160 for everything else, it might be necessary for a script to use two
 161 different contexts to search both databases. Such scripts should use
 162 the C<&set_context> and C<&restore_context> functions, below.
 163
 164 By default, C4::Context reads the configuration from
 165 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 166 environment variable to the pathname of a configuration file to use.
 167
 168 =head1 METHODS
 169
 170 =cut
 171
 172 #'
 173 # In addition to what is said in the POD above, a Context object is a
 174 # reference-to-hash with the following fields:
 175 #
 176 # config
 177 #    A reference-to-hash whose keys and values are the
 178 #    configuration variables and values specified in the config
 179 #    file (/etc/koha/koha-conf.xml).
 180 # dbh
 181 #    A handle to the appropriate database for this context.
 182 # dbh_stack
 183 #    Used by &set_dbh and &restore_dbh to hold other database
 184 #    handles for this context.
 185 # Zconn
 186 #     A connection object for the Zebra server
 187
 188 # Koha's main configuration file koha-conf.xml
 189 # is searched for according to this priority list:
 190 #
 191 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 192 # 2. Path supplied in KOHA_CONF environment variable.
 193 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 194 #    as value has changed from its default of
 195 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 196 #    when Koha is installed in 'standard' or 'single'
 197 #    mode.
 198 # 4. Path supplied in CONFIG_FNAME.
 199 #
 200 # The first entry that refers to a readable file is used.
 201
 202 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 203                 # Default config file, if none is specified
 204
 205 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 206                 # path to config file set by installer
 207                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 208                 # when Koha is installed in 'standard' or 'single'
 209                 # mode.  If Koha was installed in 'dev' mode,
 210                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 211                 # developers should set the KOHA_CONF environment variable
 212
 213 $context = undef;        # Initially, no context is set
 214 @context_stack = ();        # Initially, no saved contexts
 215
 216
 217 =head2 read_config_file
 218
 219 Reads the specified Koha config file.
 220
 221 Returns an object containing the configuration variables. The object's
 222 structure is a bit complex to the uninitiated ... take a look at the
 223 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 224 here are a few examples that may give you what you need:
 225
 226 The simple elements nested within the <config> element:
 227
 228     my $pass = $koha->{'config'}->{'pass'};
 229
 230 The <listen> elements:
 231
 232     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 233
 234 The elements nested within the <server> element:
 235
 236     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 237
 238 Returns undef in case of error.
 239
 240 =cut
 241
 242 sub read_config_file {          # Pass argument naming config file to read
 243     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 244
 245     if ($ismemcached) {
 246       $memcached->set('kohaconf',$koha);
 247     }
 248
 249     return $koha;                       # Return value: ref-to-hash holding the configuration
 250 }
 251
 252 =head2 ismemcached
 253
 254 Returns the value of the $ismemcached variable (0/1)
 255
 256 =cut
 257
 258 sub ismemcached {
 259     return $ismemcached;
 260 }
 261
 262 =head2 memcached
 263
 264 If $ismemcached is true, returns the $memcache variable.
 265 Returns undef otherwise
 266
 267 =cut
 268
 269 sub memcached {
 270     if ($ismemcached) {
 271       return $memcached;
 272     } else {
 273       return;
 274     }
 275 }
 276
 277 =head2 db_scheme2dbi
 278
 279     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 280
 281 This routines translates a database type to part of the name
 282 of the appropriate DBD driver to use when establishing a new
 283 database connection.  It recognizes 'mysql' and 'Pg'; if any
 284 other scheme is supplied it defaults to 'mysql'.
 285
 286 =cut
 287
 288 sub db_scheme2dbi {
 289     my $scheme = shift // '';
 290     return $scheme eq 'Pg' ? $scheme : 'mysql';
 291 }
 292
 293 sub import {
 294     # Create the default context ($C4::Context::Context)
 295     # the first time the module is called
 296     # (a config file can be optionaly passed)
 297
 298     # default context already exists?
 299     return if $context;
 300
 301     # no ? so load it!
 302     my ($pkg,$config_file) = @_ ;
 303     my $new_ctx = __PACKAGE__->new($config_file);
 304     return unless $new_ctx;
 305
 306     # if successfully loaded, use it by default
 307     $new_ctx->set_context;
 308     1;
 309 }
 310
 311 =head2 new
 312
 313   $context = new C4::Context;
 314   $context = new C4::Context("/path/to/koha-conf.xml");
 315
 316 Allocates a new context. Initializes the context from the specified
 317 file, which defaults to either the file given by the C<$KOHA_CONF>
 318 environment variable, or F</etc/koha/koha-conf.xml>.
 319
 320 It saves the koha-conf.xml values in the declared memcached server(s)
 321 if currently available and uses those values until them expire and
 322 re-reads them.
 323
 324 C<&new> does not set this context as the new default context; for
 325 that, use C<&set_context>.
 326
 327 =cut
 328
 329 #'
 330 # Revision History:
 331 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 332 sub new {
 333     my $class = shift;
 334     my $conf_fname = shift;        # Config file to load
 335     my $self = {};
 336
 337     # check that the specified config file exists and is not empty
 338     undef $conf_fname unless
 339         (defined $conf_fname && -s $conf_fname);
 340     # Figure out a good config file to load if none was specified.
 341     if (!defined($conf_fname))
 342     {
 343         # If the $KOHA_CONF environment variable is set, use
 344         # that. Otherwise, use the built-in default.
 345         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 346             $conf_fname = $ENV{"KOHA_CONF"};
 347         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 348             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 349             # regex to anything else -- don't want installer to rewrite it
 350             $conf_fname = $INSTALLED_CONFIG_FNAME;
 351         } elsif (-s CONFIG_FNAME) {
 352             $conf_fname = CONFIG_FNAME;
 353         } else {
 354             warn "unable to locate Koha configuration file koha-conf.xml";
 355             return;
 356         }
 357     }
 358
 359     if ($ismemcached) {
 360         # retrieve from memcached
 361         $self = $memcached->get('kohaconf');
 362         if (not defined $self) {
 363             # not in memcached yet
 364             $self = read_config_file($conf_fname);
 365         }
 366     } else {
 367         # non-memcached env, read from file
 368         $self = read_config_file($conf_fname);
 369     }
 370
 371     $self->{"config_file"} = $conf_fname;
 372     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 373     return if !defined($self->{"config"});
 374
 375     $self->{"Zconn"} = undef;    # Zebra Connections
 376     $self->{"userenv"} = undef;        # User env
 377     $self->{"activeuser"} = undef;        # current active user
 378     $self->{"shelves"} = undef;
 379     $self->{tz} = undef; # local timezone object
 380
 381     bless $self, $class;
 382     $self->{db_driver} = db_scheme2dbi($self->config('db_scheme'));  # cache database driver
 383     return $self;
 384 }
 385
 386 =head2 set_context
 387
 388   $context = new C4::Context;
 389   $context->set_context();
 390 or
 391   set_context C4::Context $context;
 392
 393   ...
 394   restore_context C4::Context;
 395
 396 In some cases, it might be necessary for a script to use multiple
 397 contexts. C<&set_context> saves the current context on a stack, then
 398 sets the context to C<$context>, which will be used in future
 399 operations. To restore the previous context, use C<&restore_context>.
 400
 401 =cut
 402
 403 #'
 404 sub set_context
 405 {
 406     my $self = shift;
 407     my $new_context;    # The context to set
 408
 409     # Figure out whether this is a class or instance method call.
 410     #
 411     # We're going to make the assumption that control got here
 412     # through valid means, i.e., that the caller used an instance
 413     # or class method call, and that control got here through the
 414     # usual inheritance mechanisms. The caller can, of course,
 415     # break this assumption by playing silly buggers, but that's
 416     # harder to do than doing it properly, and harder to check
 417     # for.
 418     if (ref($self) eq "")
 419     {
 420         # Class method. The new context is the next argument.
 421         $new_context = shift;
 422     } else {
 423         # Instance method. The new context is $self.
 424         $new_context = $self;
 425     }
 426
 427     # Save the old context, if any, on the stack
 428     push @context_stack, $context if defined($context);
 429
 430     # Set the new context
 431     $context = $new_context;
 432 }
 433
 434 =head2 restore_context
 435
 436   &restore_context;
 437
 438 Restores the context set by C<&set_context>.
 439
 440 =cut
 441
 442 #'
 443 sub restore_context
 444 {
 445     my $self = shift;
 446
 447     if ($#context_stack < 0)
 448     {
 449         # Stack underflow.
 450         die "Context stack underflow";
 451     }
 452
 453     # Pop the old context and set it.
 454     $context = pop @context_stack;
 455
 456     # FIXME - Should this return something, like maybe the context
 457     # that was current when this was called?
 458 }
 459
 460 =head2 config
 461
 462   $value = C4::Context->config("config_variable");
 463
 464   $value = C4::Context->config_variable;
 465
 466 Returns the value of a variable specified in the configuration file
 467 from which the current context was created.
 468
 469 The second form is more compact, but of course may conflict with
 470 method names. If there is a configuration variable called "new", then
 471 C<C4::Config-E<gt>new> will not return it.
 472
 473 =cut
 474
 475 sub _common_config {
 476         my $var = shift;
 477         my $term = shift;
 478     return if !defined($context->{$term});
 479        # Presumably $self->{$term} might be
 480        # undefined if the config file given to &new
 481        # didn't exist, and the caller didn't bother
 482        # to check the return value.
 483
 484     # Return the value of the requested config variable
 485     return $context->{$term}->{$var};
 486 }
 487
 488 sub config {
 489         return _common_config($_[1],'config');
 490 }
 491 sub zebraconfig {
 492         return _common_config($_[1],'server');
 493 }
 494 sub ModZebrations {
 495         return _common_config($_[1],'serverinfo');
 496 }
 497
 498 =head2 preference
 499
 500   $sys_preference = C4::Context->preference('some_variable');
 501
 502 Looks up the value of the given system preference in the
 503 systempreferences table of the Koha database, and returns it. If the
 504 variable is not set or does not exist, undef is returned.
 505
 506 In case of an error, this may return 0.
 507
 508 Note: It is impossible to tell the difference between system
 509 preferences which do not exist, and those whose values are set to NULL
 510 with this method.
 511
 512 =cut
 513
 514 my $syspref_cache = Koha::Cache->get_instance();
 515 my $use_syspref_cache = 1;
 516 sub preference {
 517     my $self = shift;
 518     my $var  = shift;    # The system preference to return
 519
 520     $var = lc $var;
 521
 522     return $ENV{"OVERRIDE_SYSPREF_$var"}
 523         if defined $ENV{"OVERRIDE_SYSPREF_$var"};
 524
 525     my $cached_var = $use_syspref_cache
 526         ? $syspref_cache->get_from_cache("syspref_$var")
 527         : undef;
 528     return $cached_var if defined $cached_var;
 529
 530     my $syspref;
 531     eval { $syspref = Koha::Config::SysPrefs->find( lc $var ) };
 532     my $value = $syspref ? $syspref->value() : undef;
 533
 534     if ( $use_syspref_cache ) {
 535         $syspref_cache->set_in_cache("syspref_$var", $value);
 536     }
 537     return $value;
 538 }
 539
 540 sub boolean_preference {
 541     my $self = shift;
 542     my $var = shift;        # The system preference to return
 543     my $it = preference($self, $var);
 544     return defined($it)? C4::Boolean::true_p($it): undef;
 545 }
 546
 547 =head2 enable_syspref_cache
 548
 549   C4::Context->enable_syspref_cache();
 550
 551 Enable the in-memory syspref cache used by C4::Context. This is the
 552 default behavior.
 553
 554 =cut
 555
 556 sub enable_syspref_cache {
 557     my ($self) = @_;
 558     $use_syspref_cache = 1;
 559     # We need to clear the cache to have it up-to-date
 560     $self->clear_syspref_cache();
 561 }
 562
 563 =head2 disable_syspref_cache
 564
 565   C4::Context->disable_syspref_cache();
 566
 567 Disable the in-memory syspref cache used by C4::Context. This should be
 568 used with Plack and other persistent environments.
 569
 570 =cut
 571
 572 sub disable_syspref_cache {
 573     my ($self) = @_;
 574     $use_syspref_cache = 0;
 575     $self->clear_syspref_cache();
 576 }
 577
 578 =head2 clear_syspref_cache
 579
 580   C4::Context->clear_syspref_cache();
 581
 582 cleans the internal cache of sysprefs. Please call this method if
 583 you update the systempreferences table. Otherwise, your new changes
 584 will not be seen by this process.
 585
 586 =cut
 587
 588 sub clear_syspref_cache {
 589     return unless $use_syspref_cache;
 590     $syspref_cache->flush_all;
 591 }
 592
 593 =head2 set_preference
 594
 595   C4::Context->set_preference( $variable, $value, [ $explanation, $type, $options ] );
 596
 597 This updates a preference's value both in the systempreferences table and in
 598 the sysprefs cache. If the optional parameters are provided, then the query
 599 becomes a create. It won't update the parameters (except value) for an existing
 600 preference.
 601
 602 =cut
 603
 604 sub set_preference {
 605     my ( $self, $variable, $value, $explanation, $type, $options ) = @_;
 606
 607     $variable = lc $variable;
 608
 609     my $syspref = Koha::Config::SysPrefs->find($variable);
 610     $type =
 611         $type    ? $type
 612       : $syspref ? $syspref->type
 613       :            undef;
 614
 615     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 616
 617     # force explicit protocol on OPACBaseURL
 618     if ( $variable eq 'opacbaseurl' && $value && substr( $value, 0, 4 ) !~ /http/ ) {
 619         $value = 'http://' . $value;
 620     }
 621
 622     if ($syspref) {
 623         $syspref->set(
 624             {   ( defined $value ? ( value       => $value )       : () ),
 625                 ( $explanation   ? ( explanation => $explanation ) : () ),
 626                 ( $type          ? ( type        => $type )        : () ),
 627                 ( $options       ? ( options     => $options )     : () ),
 628             }
 629         )->store;
 630     } else {
 631         $syspref = Koha::Config::SysPref->new(
 632             {   variable    => $variable,
 633                 value       => $value,
 634                 explanation => $explanation || undef,
 635                 type        => $type,
 636                 options     => $options || undef,
 637             }
 638         )->store();
 639     }
 640
 641     if ( $use_syspref_cache ) {
 642         $syspref_cache->set_in_cache( "syspref_$variable", $value );
 643     }
 644
 645     return $syspref;
 646 }
 647
 648 =head2 delete_preference
 649
 650     C4::Context->delete_preference( $variable );
 651
 652 This deletes a system preference from the database. Returns a true value on
 653 success. Failure means there was an issue with the database, not that there
 654 was no syspref of the name.
 655
 656 =cut
 657
 658 sub delete_preference {
 659     my ( $self, $var ) = @_;
 660
 661     if ( Koha::Config::SysPrefs->find( $var )->delete ) {
 662         if ( $use_syspref_cache ) {
 663             $syspref_cache->clear_from_cache("syspref_$var");
 664         }
 665
 666         return 1;
 667     }
 668     return 0;
 669 }
 670
 671 =head2 Zconn
 672
 673   $Zconn = C4::Context->Zconn
 674
 675 Returns a connection to the Zebra database
 676
 677 C<$self>
 678
 679 C<$server> one of the servers defined in the koha-conf.xml file
 680
 681 C<$async> whether this is a asynchronous connection
 682
 683 =cut
 684
 685 sub Zconn {
 686     my ($self, $server, $async ) = @_;
 687     my $cache_key = join ('::', (map { $_ // '' } ($server, $async )));
 688     if ( (!defined($ENV{GATEWAY_INTERFACE})) && defined($context->{"Zconn"}->{$cache_key}) && (0 == $context->{"Zconn"}->{$cache_key}->errcode()) ) {
 689         # if we are running the script from the commandline, lets try to use the caching
 690         return $context->{"Zconn"}->{$cache_key};
 691     }
 692     $context->{"Zconn"}->{$cache_key}->destroy() if defined($context->{"Zconn"}->{$cache_key}); #destroy old connection before making a new one
 693     $context->{"Zconn"}->{$cache_key} = &_new_Zconn( $server, $async );
 694     return $context->{"Zconn"}->{$cache_key};
 695 }
 696
 697 =head2 _new_Zconn
 698
 699 $context->{"Zconn"} = &_new_Zconn($server,$async);
 700
 701 Internal function. Creates a new database connection from the data given in the current context and returns it.
 702
 703 C<$server> one of the servers defined in the koha-conf.xml file
 704
 705 C<$async> whether this is a asynchronous connection
 706
 707 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 708
 709 =cut
 710
 711 sub _new_Zconn {
 712     my ( $server, $async ) = @_;
 713
 714     my $tried=0; # first attempt
 715     my $Zconn; # connection object
 716     my $elementSetName;
 717     my $index_mode;
 718     my $syntax;
 719
 720     $server //= "biblioserver";
 721
 722     if ( $server eq 'biblioserver' ) {
 723         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'dom';
 724     } elsif ( $server eq 'authorityserver' ) {
 725         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 726     }
 727
 728     if ( $index_mode eq 'grs1' ) {
 729         $elementSetName = 'F';
 730         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 731                 ? 'unimarc'
 732                 : 'usmarc';
 733
 734     } else { # $index_mode eq 'dom'
 735         $syntax = 'xml';
 736         $elementSetName = 'marcxml';
 737     }
 738
 739     my $host = $context->{'listen'}->{$server}->{'content'};
 740     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 741     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 742     eval {
 743         # set options
 744         my $o = new ZOOM::Options();
 745         $o->option(user => $user) if $user && $password;
 746         $o->option(password => $password) if $user && $password;
 747         $o->option(async => 1) if $async;
 748         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 749         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 750         $o->option(preferredRecordSyntax => $syntax);
 751         $o->option(elementSetName => $elementSetName) if $elementSetName;
 752         $o->option(databaseName => $context->{"config"}->{$server}||"biblios");
 753
 754         # create a new connection object
 755         $Zconn= create ZOOM::Connection($o);
 756
 757         # forge to server
 758         $Zconn->connect($host, 0);
 759
 760         # check for errors and warn
 761         if ($Zconn->errcode() !=0) {
 762             warn "something wrong with the connection: ". $Zconn->errmsg();
 763         }
 764     };
 765     return $Zconn;
 766 }
 767
 768 # _new_dbh
 769 # Internal helper function (not a method!). This creates a new
 770 # database connection from the data given in the current context, and
 771 # returns it.
 772 sub _new_dbh
 773 {
 774
 775     Koha::Database->schema({ new => 1 })->storage->dbh;
 776 }
 777
 778 =head2 dbh
 779
 780   $dbh = C4::Context->dbh;
 781
 782 Returns a database handle connected to the Koha database for the
 783 current context. If no connection has yet been made, this method
 784 creates one, and connects to the database.
 785
 786 This database handle is cached for future use: if you call
 787 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 788 times. If you need a second database handle, use C<&new_dbh> and
 789 possibly C<&set_dbh>.
 790
 791 =cut
 792
 793 #'
 794 sub dbh
 795 {
 796     my $self = shift;
 797     my $params = shift;
 798     my $sth;
 799
 800     unless ( $params->{new} ) {
 801         return Koha::Database->schema->storage->dbh;
 802     }
 803
 804     return Koha::Database->schema({ new => 1 })->storage->dbh;
 805 }
 806
 807 =head2 new_dbh
 808
 809   $dbh = C4::Context->new_dbh;
 810
 811 Creates a new connection to the Koha database for the current context,
 812 and returns the database handle (a C<DBI::db> object).
 813
 814 The handle is not saved anywhere: this method is strictly a
 815 convenience function; the point is that it knows which database to
 816 connect to so that the caller doesn't have to know.
 817
 818 =cut
 819
 820 #'
 821 sub new_dbh
 822 {
 823     my $self = shift;
 824
 825     return &dbh({ new => 1 });
 826 }
 827
 828 =head2 set_dbh
 829
 830   $my_dbh = C4::Connect->new_dbh;
 831   C4::Connect->set_dbh($my_dbh);
 832   ...
 833   C4::Connect->restore_dbh;
 834
 835 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 836 C<&set_context> and C<&restore_context>.
 837
 838 C<&set_dbh> saves the current database handle on a stack, then sets
 839 the current database handle to C<$my_dbh>.
 840
 841 C<$my_dbh> is assumed to be a good database handle.
 842
 843 =cut
 844
 845 #'
 846 sub set_dbh
 847 {
 848     my $self = shift;
 849     my $new_dbh = shift;
 850
 851     # Save the current database handle on the handle stack.
 852     # We assume that $new_dbh is all good: if the caller wants to
 853     # screw himself by passing an invalid handle, that's fine by
 854     # us.
 855     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 856     $context->{"dbh"} = $new_dbh;
 857 }
 858
 859 =head2 restore_dbh
 860
 861   C4::Context->restore_dbh;
 862
 863 Restores the database handle saved by an earlier call to
 864 C<C4::Context-E<gt>set_dbh>.
 865
 866 =cut
 867
 868 #'
 869 sub restore_dbh
 870 {
 871     my $self = shift;
 872
 873     if ($#{$context->{"dbh_stack"}} < 0)
 874     {
 875         # Stack underflow
 876         die "DBH stack underflow";
 877     }
 878
 879     # Pop the old database handle and set it.
 880     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 881
 882     # FIXME - If it is determined that restore_context should
 883     # return something, then this function should, too.
 884 }
 885
 886 =head2 queryparser
 887
 888   $queryparser = C4::Context->queryparser
 889
 890 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 891
 892 =cut
 893
 894 sub queryparser {
 895     my $self = shift;
 896     unless (defined $context->{"queryparser"}) {
 897         $context->{"queryparser"} = &_new_queryparser();
 898     }
 899
 900     return
 901       defined( $context->{"queryparser"} )
 902       ? $context->{"queryparser"}->new
 903       : undef;
 904 }
 905
 906 =head2 _new_queryparser
 907
 908 Internal helper function to create a new QueryParser object. QueryParser
 909 is loaded dynamically so as to keep the lack of the QueryParser library from
 910 getting in anyone's way.
 911
 912 =cut
 913
 914 sub _new_queryparser {
 915     my $qpmodules = {
 916         'OpenILS::QueryParser'           => undef,
 917         'Koha::QueryParser::Driver::PQF' => undef
 918     };
 919     if ( can_load( 'modules' => $qpmodules ) ) {
 920         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 921         my $config_file = $context->config('queryparser_config');
 922         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 923         if ( $QParser->load_config($config_file) ) {
 924             # Set 'keyword' as the default search class
 925             $QParser->default_search_class('keyword');
 926             # TODO: allow indexes to be configured in the database
 927             return $QParser;
 928         }
 929     }
 930     return;
 931 }
 932
 933 =head2 userenv
 934
 935   C4::Context->userenv;
 936
 937 Retrieves a hash for user environment variables.
 938
 939 This hash shall be cached for future use: if you call
 940 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
 941
 942 =cut
 943
 944 #'
 945 sub userenv {
 946     my $var = $context->{"activeuser"};
 947     if (defined $var and defined $context->{"userenv"}->{$var}) {
 948         return $context->{"userenv"}->{$var};
 949     } else {
 950         return;
 951     }
 952 }
 953
 954 =head2 set_userenv
 955
 956   C4::Context->set_userenv($usernum, $userid, $usercnum,
 957                            $userfirstname, $usersurname,
 958                            $userbranch, $branchname, $userflags,
 959                            $emailaddress, $branchprinter, $persona);
 960
 961 Establish a hash of user environment variables.
 962
 963 set_userenv is called in Auth.pm
 964
 965 =cut
 966
 967 #'
 968 sub set_userenv {
 969     shift @_;
 970     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona, $shibboleth)=
 971     map { Encode::is_utf8( $_ ) ? $_ : Encode::decode('UTF-8', $_) } # CGI::Session doesn't handle utf-8, so we decode it here
 972     @_;
 973     my $var=$context->{"activeuser"} || '';
 974     my $cell = {
 975         "number"     => $usernum,
 976         "id"         => $userid,
 977         "cardnumber" => $usercnum,
 978         "firstname"  => $userfirstname,
 979         "surname"    => $usersurname,
 980         #possibly a law problem
 981         "branch"     => $userbranch,
 982         "branchname" => $branchname,
 983         "flags"      => $userflags,
 984         "emailaddress"     => $emailaddress,
 985         "branchprinter"    => $branchprinter,
 986         "persona"    => $persona,
 987         "shibboleth" => $shibboleth,
 988     };
 989     $context->{userenv}->{$var} = $cell;
 990     return $cell;
 991 }
 992
 993 sub set_shelves_userenv {
 994         my ($type, $shelves) = @_ or return;
 995         my $activeuser = $context->{activeuser} or return;
 996         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
 997         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
 998         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
 999 }
1000
1001 sub get_shelves_userenv {
1002         my $active;
1003         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1004                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1005                 return;
1006         }
1007         my $totshelves = $active->{totshelves} or undef;
1008         my $pubshelves = $active->{pubshelves} or undef;
1009         my $barshelves = $active->{barshelves} or undef;
1010         return ($totshelves, $pubshelves, $barshelves);
1011 }
1012
1013 =head2 _new_userenv
1014
1015   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1016
1017 Builds a hash for user environment variables.
1018
1019 This hash shall be cached for future use: if you call
1020 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1021
1022 _new_userenv is called in Auth.pm
1023
1024 =cut
1025
1026 #'
1027 sub _new_userenv
1028 {
1029     shift;  # Useless except it compensates for bad calling style
1030     my ($sessionID)= @_;
1031      $context->{"activeuser"}=$sessionID;
1032 }
1033
1034 =head2 _unset_userenv
1035
1036   C4::Context->_unset_userenv;
1037
1038 Destroys the hash for activeuser user environment variables.
1039
1040 =cut
1041
1042 #'
1043
1044 sub _unset_userenv
1045 {
1046     my ($sessionID)= @_;
1047     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1048 }
1049
1050
1051 =head2 get_versions
1052
1053   C4::Context->get_versions
1054
1055 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1056
1057 =cut
1058
1059 #'
1060
1061 # A little example sub to show more debugging info for CGI::Carp
1062 sub get_versions {
1063     my %versions;
1064     $versions{kohaVersion}  = Koha::version();
1065     $versions{kohaDbVersion} = C4::Context->preference('version');
1066     $versions{osVersion} = join(" ", POSIX::uname());
1067     $versions{perlVersion} = $];
1068     {
1069         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1070         $versions{mysqlVersion}  = `mysql -V`;
1071         $versions{apacheVersion} = (`apache2ctl -v`)[0];
1072         $versions{apacheVersion} = `httpd -v`             unless  $versions{apacheVersion} ;
1073         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1074         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1075         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1076     }
1077     return %versions;
1078 }
1079
1080
1081 =head2 tz
1082
1083   C4::Context->tz
1084
1085   Returns a DateTime::TimeZone object for the system timezone
1086
1087 =cut
1088
1089 sub tz {
1090     my $self = shift;
1091     if (!defined $context->{tz}) {
1092         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1093     }
1094     return $context->{tz};
1095 }
1096
1097
1098 =head2 IsSuperLibrarian
1099
1100     C4::Context->IsSuperLibrarian();
1101
1102 =cut
1103
1104 sub IsSuperLibrarian {
1105     my $userenv = C4::Context->userenv;
1106
1107     unless ( $userenv and exists $userenv->{flags} ) {
1108         # If we reach this without a user environment,
1109         # assume that we're running from a command-line script,
1110         # and act as a superlibrarian.
1111         carp("C4::Context->userenv not defined!");
1112         return 1;
1113     }
1114
1115     return ($userenv->{flags}//0) % 2;
1116 }
1117
1118 =head2 interface
1119
1120 Sets the current interface for later retrieval in any Perl module
1121
1122     C4::Context->interface('opac');
1123     C4::Context->interface('intranet');
1124     my $interface = C4::Context->interface;
1125
1126 =cut
1127
1128 sub interface {
1129     my ($class, $interface) = @_;
1130
1131     if (defined $interface) {
1132         $interface = lc $interface;
1133         if ($interface eq 'opac' || $interface eq 'intranet' || $interface eq 'sip' || $interface eq 'commandline') {
1134             $context->{interface} = $interface;
1135         } else {
1136             warn "invalid interface : '$interface'";
1137         }
1138     }
1139
1140     return $context->{interface} // 'opac';
1141 }
1142
1143 1;
1144 __END__
1145
1146 =head1 ENVIRONMENT
1147
1148 =head2 C<KOHA_CONF>
1149
1150 Specifies the configuration file to read.
1151
1152 =head1 SEE ALSO
1153
1154 XML::Simple
1155
1156 =head1 AUTHORS
1157
1158 Andrew Arensburger <arensb at ooblick dot com>
1159
1160 Joshua Ferraro <jmf at liblime dot com>
1161