opac/opac-downloadcart.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw(encode);
  25
  26 use C4::Auth;
  27 use C4::Biblio;
  28 use C4::Items;
  29 use C4::Output;
  30 use C4::Record;
  31 use C4::Ris;
  32 use C4::Csv;
  33 use utf8;
  34 my $query = new CGI;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  37     {
  38         template_name   => "opac-downloadcart.tt",
  39         query           => $query,
  40         type            => "opac",
  41         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  42     }
  43 );
  44
  45 my $bib_list = $query->param('bib_list');
  46 my $format  = $query->param('format');
  47 my $dbh     = C4::Context->dbh;
  48
  49 if ($bib_list && $format) {
  50
  51     my @bibs = split( /\//, $bib_list );
  52
  53     my $marcflavour = C4::Context->preference('marcflavour');
  54     my $output;
  55     my $extension;
  56     my $type;
  57
  58     # CSV
  59     if ($format =~ /^\d+$/) {
  60
  61         $output = marc2csv(\@bibs, $format);
  62
  63         # Other formats
  64     } else {
  65         foreach my $biblio (@bibs) {
  66
  67             my $record = GetMarcBiblio($biblio, 1);
  68             next unless $record;
  69
  70             if ($format eq 'iso2709') {
  71                 $output .= $record->as_usmarc();
  72             }
  73             elsif ($format eq 'ris') {
  74                 $output .= marc2ris($record);
  75             }
  76             elsif ($format eq 'bibtex') {
  77                 $output .= marc2bibtex($record, $biblio);
  78             }
  79             elsif ( $format eq 'isbd' ) {
  80                 $output   .= GetISBDView($biblio, "opac");
  81                 $extension = "txt";
  82                 $type      = "text/plain";
  83             }
  84         }
  85     }
  86
  87     # If it was a CSV export we change the format after the export so the file extension is fine
  88     $format = "csv" if ($format =~ m/^\d+$/);
  89
  90     print $query->header(
  91                                -type => ($type) ? $type : 'application/octet-stream',
  92         -'Content-Transfer-Encoding' => 'binary',
  93                          -attachment => ($extension) ? "cart.$format.$extension" : "cart.$format"
  94     );
  95     print $output;
  96
  97 } else {
  98     $template->param(csv_profiles => GetCsvProfilesLoop('marc'));
  99     $template->param(bib_list => $bib_list);
 100     output_html_with_http_headers $query, $cookie, $template->output;
 101 }