circ/ysearch.pl

   1 #!/usr/bin/perl
   2
   3 # This software is placed under the gnu General Public License, v2 (http://www.gnu.org/licenses/gpl.html)
   4
   5 # Copyright 2007 Tamil s.a.r.l.
   6 # Parts copyright 2010-2012 Athens County Public Libraries
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 ysearch.pl
  24
  25 =cut
  26
  27 use Modern::Perl;
  28 use CGI qw ( -utf8 );
  29 use C4::Context;
  30 use C4::Auth qw/check_cookie_auth/;
  31 use Koha::Borrowers;
  32
  33 use JSON qw( to_json );
  34
  35 my $input = new CGI;
  36 my $query = $input->param('term');
  37
  38 binmode STDOUT, ":encoding(UTF-8)";
  39 print $input->header( -type => 'text/plain', -charset => 'UTF-8' );
  40
  41 my ( $auth_status, $sessionID ) = check_cookie_auth( $input->cookie('CGISESSID'), { circulate => '*' } );
  42 if ( $auth_status ne "ok" ) {
  43     exit 0;
  44 }
  45
  46 my $limit_on_branch;
  47 if (   C4::Context->preference("IndependentBranches")
  48     && C4::Context->userenv
  49     && !C4::Context->IsSuperLibrarian()
  50     && C4::Context->userenv->{'branch'} ) {
  51     $limit_on_branch = 1;
  52 }
  53
  54 my @parts = split( / /, $query );
  55 my @params;
  56 foreach my $p (@parts) {
  57     push(
  58         @params,
  59         -or => [
  60             surname    => { -like => "%$p%" },
  61             firstname  => { -like => "%$p%" },
  62             cardnumber => { -like => "$p%" },
  63         ]
  64     );
  65 }
  66
  67 push( @params, { branchcode => C4::Context->userenv->{branch} } ) if $limit_on_branch;
  68
  69 my $borrowers_rs = Koha::Borrowers->search(
  70     { -and => \@params },
  71     {
  72         # Get the first 10 results
  73         page     => 1,
  74         rows     => 10,
  75         order_by => [ 'surname', 'firstname' ],
  76     },
  77 );
  78
  79 my @borrowers;
  80 while ( my $b = $borrowers_rs->next ) {
  81     push @borrowers,
  82       { borrowernumber => $b->borrowernumber,
  83         surname        => $b->surname    // '',
  84         firstname      => $b->firstname  // '',
  85         cardnumber     => $b->cardnumber // '',
  86         address        => $b->address    // '',
  87         city           => $b->city       // '',
  88         zipcode        => $b->zipcode    // '',
  89         country        => $b->country    // '',
  90       };
  91 }
  92
  93 print to_json( \@borrowers );