cataloguing/addbiblio.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright 2000-2002 Katipo Communications
   5 # Copyright 2004-2010 BibLibre
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use strict;
  23 #use warnings; FIXME - Bug 2505
  24 use CGI;
  25 use C4::Output;
  26 use C4::Auth;
  27 use C4::Biblio;
  28 use C4::Search;
  29 use C4::AuthoritiesMarc;
  30 use C4::Context;
  31 use MARC::Record;
  32 use C4::Log;
  33 use C4::Koha;    # XXX subfield_is_koha_internal_p
  34 use C4::Branch;    # XXX subfield_is_koha_internal_p
  35 use C4::ClassSource;
  36 use C4::ImportBatch;
  37 use C4::Charset;
  38
  39 use Date::Calc qw(Today);
  40 use MARC::File::USMARC;
  41 use MARC::File::XML;
  42 use URI::Escape;
  43
  44 if ( C4::Context->preference('marcflavour') eq 'UNIMARC' ) {
  45     MARC::File::XML->default_record_format('UNIMARC');
  46 }
  47
  48 our($tagslib,$authorised_values_sth,$is_a_modif,$usedTagsLib,$mandatory_z3950);
  49
  50 =head1 FUNCTIONS
  51
  52 =head2 MARCfindbreeding
  53
  54     $record = MARCfindbreeding($breedingid);
  55
  56 Look up the import record repository for the record with
  57 record with id $breedingid.  If found, returns the decoded
  58 MARC::Record; otherwise, -1 is returned (FIXME).
  59 Returns as second parameter the character encoding.
  60
  61 =cut
  62
  63 sub MARCfindbreeding {
  64     my ( $id ) = @_;
  65     my ($marc, $encoding) = GetImportRecordMarc($id);
  66     # remove the - in isbn, koha store isbn without any -
  67     if ($marc) {
  68         my $record = MARC::Record->new_from_usmarc($marc);
  69         my ($isbnfield,$isbnsubfield) = GetMarcFromKohaField('biblioitems.isbn','');
  70         if ( $record->field($isbnfield) ) {
  71             foreach my $field ( $record->field($isbnfield) ) {
  72                 foreach my $subfield ( $field->subfield($isbnsubfield) ) {
  73                     my $newisbn = $field->subfield($isbnsubfield);
  74                     $newisbn =~ s/-//g;
  75                     $field->update( $isbnsubfield => $newisbn );
  76                 }
  77             }
  78         }
  79         # fix the unimarc 100 coded field (with unicode information)
  80         if (C4::Context->preference('marcflavour') eq 'UNIMARC' && $record->subfield(100,'a')) {
  81             my $f100a=$record->subfield(100,'a');
  82             my $f100 = $record->field(100);
  83             my $f100temp = $f100->as_string;
  84             $record->delete_field($f100);
  85             if ( length($f100temp) > 28 ) {
  86                 substr( $f100temp, 26, 2, "50" );
  87                 $f100->update( 'a' => $f100temp );
  88                 my $f100 = MARC::Field->new( '100', '', '', 'a' => $f100temp );
  89                 $record->insert_fields_ordered($f100);
  90             }
  91         }
  92
  93         if ( !defined(ref($record)) ) {
  94             return -1;
  95         }
  96         else {
  97             # normalize author : UNIMARC specific...
  98             if (    C4::Context->preference("z3950NormalizeAuthor")
  99                 and C4::Context->preference("z3950AuthorAuthFields")
 100                 and C4::Context->preference("marcflavour") eq 'UNIMARC' )
 101             {
 102                 my ( $tag, $subfield ) = GetMarcFromKohaField("biblio.author", '');
 103
 104  #                 my $summary = C4::Context->preference("z3950authortemplate");
 105                 my $auth_fields =
 106                   C4::Context->preference("z3950AuthorAuthFields");
 107                 my @auth_fields = split /,/, $auth_fields;
 108                 my $field;
 109
 110                 if ( $record->field($tag) ) {
 111                     foreach my $tmpfield ( $record->field($tag)->subfields ) {
 112
 113        #                        foreach my $subfieldcode ($tmpfield->subfields){
 114                         my $subfieldcode  = shift @$tmpfield;
 115                         my $subfieldvalue = shift @$tmpfield;
 116                         if ($field) {
 117                             $field->add_subfields(
 118                                 "$subfieldcode" => $subfieldvalue )
 119                               if ( $subfieldcode ne $subfield );
 120                         }
 121                         else {
 122                             $field =
 123                               MARC::Field->new( $tag, "", "",
 124                                 $subfieldcode => $subfieldvalue )
 125                               if ( $subfieldcode ne $subfield );
 126                         }
 127                     }
 128                 }
 129                 $record->delete_field( $record->field($tag) );
 130                 foreach my $fieldtag (@auth_fields) {
 131                     next unless ( $record->field($fieldtag) );
 132                     my $lastname  = $record->field($fieldtag)->subfield('a');
 133                     my $firstname = $record->field($fieldtag)->subfield('b');
 134                     my $title     = $record->field($fieldtag)->subfield('c');
 135                     my $number    = $record->field($fieldtag)->subfield('d');
 136                     if ($title) {
 137
 138 #                         $field->add_subfields("$subfield"=>"[ ".ucfirst($title).ucfirst($firstname)." ".$number." ]");
 139                         $field->add_subfields(
 140                                 "$subfield" => ucfirst($title) . " "
 141                               . ucfirst($firstname) . " "
 142                               . $number );
 143                     }
 144                     else {
 145
 146 #                       $field->add_subfields("$subfield"=>"[ ".ucfirst($firstname).", ".ucfirst($lastname)." ]");
 147                         $field->add_subfields(
 148                             "$subfield" => ucfirst($firstname) . ", "
 149                               . ucfirst($lastname) );
 150                     }
 151                 }
 152                 $record->insert_fields_ordered($field);
 153             }
 154             return $record, $encoding;
 155         }
 156     }
 157     return -1;
 158 }
 159
 160 =head2 build_authorized_values_list
 161
 162 =cut
 163
 164 sub build_authorized_values_list {
 165     my ( $tag, $subfield, $value, $dbh, $authorised_values_sth,$index_tag,$index_subfield ) = @_;
 166
 167     my @authorised_values;
 168     my %authorised_lib;
 169
 170     # builds list, depending on authorised value...
 171
 172     #---- branch
 173     if ( $tagslib->{$tag}->{$subfield}->{'authorised_value'} eq "branches" ) {
 174         #Use GetBranches($onlymine)
 175         my $onlymine =
 176              C4::Context->preference('IndependentBranches')
 177           && C4::Context->userenv
 178           && !C4::Context->IsSuperLibrarian()
 179           && C4::Context->userenv->{branch};
 180         my $branches = GetBranches($onlymine);
 181         my @branchloop;
 182         foreach my $thisbranch ( sort keys %$branches ) {
 183             push @authorised_values, $thisbranch;
 184             $authorised_lib{$thisbranch} = $branches->{$thisbranch}->{'branchname'};
 185         }
 186
 187         #----- itemtypes
 188     }
 189     elsif ( $tagslib->{$tag}->{$subfield}->{authorised_value} eq "itemtypes" ) {
 190         my $sth =
 191           $dbh->prepare(
 192             "select itemtype,description from itemtypes order by description");
 193         $sth->execute;
 194         push @authorised_values, ""
 195           unless ( $tagslib->{$tag}->{$subfield}->{mandatory}
 196             && ( $value || $tagslib->{$tag}->{$subfield}->{defaultvalue} ) );
 197
 198         my $itemtype;
 199
 200         while ( my ( $itemtype, $description ) = $sth->fetchrow_array ) {
 201             push @authorised_values, $itemtype;
 202             $authorised_lib{$itemtype} = $description;
 203         }
 204         $value = $itemtype unless ($value);
 205
 206           #---- class_sources
 207     }
 208     elsif ( $tagslib->{$tag}->{$subfield}->{authorised_value} eq "cn_source" ) {
 209         push @authorised_values, ""
 210           unless ( $tagslib->{$tag}->{$subfield}->{mandatory} );
 211
 212         my $class_sources = GetClassSources();
 213
 214         my $default_source = C4::Context->preference("DefaultClassificationSource");
 215
 216         foreach my $class_source (sort keys %$class_sources) {
 217             next unless $class_sources->{$class_source}->{'used'} or
 218                         ($value and $class_source eq $value) or
 219                         ($class_source eq $default_source);
 220             push @authorised_values, $class_source;
 221             $authorised_lib{$class_source} = $class_sources->{$class_source}->{'description'};
 222         }
 223         $value = $default_source unless $value;
 224     }
 225     else {
 226         my $branch_limit = C4::Context->userenv ? C4::Context->userenv->{"branch"} : "";
 227         $authorised_values_sth->execute(
 228             $tagslib->{$tag}->{$subfield}->{authorised_value},
 229             $branch_limit ? $branch_limit : (),
 230         );
 231
 232         push @authorised_values, ""
 233           unless ( $tagslib->{$tag}->{$subfield}->{mandatory}
 234             && ( $value || $tagslib->{$tag}->{$subfield}->{defaultvalue} ) );
 235
 236         while ( my ( $value, $lib ) = $authorised_values_sth->fetchrow_array ) {
 237             push @authorised_values, $value;
 238             $authorised_lib{$value} = $lib;
 239         }
 240     }
 241     $authorised_values_sth->finish;
 242     return {
 243         type     => 'select',
 244         id       => "tag_".$tag."_subfield_".$subfield."_".$index_tag."_".$index_subfield,
 245         name     => "tag_".$tag."_subfield_".$subfield."_".$index_tag."_".$index_subfield,
 246         default  => $value,
 247         values   => \@authorised_values,
 248         labels   => \%authorised_lib,
 249     };
 250
 251 }
 252
 253 =head2 CreateKey
 254
 255     Create a random value to set it into the input name
 256
 257 =cut
 258
 259 sub CreateKey {
 260     return int(rand(1000000));
 261 }
 262
 263 =head2 GetMandatoryFieldZ3950
 264
 265     This function return an hashref which containts all mandatory field
 266     to search with z3950 server.
 267
 268 =cut
 269
 270 sub GetMandatoryFieldZ3950 {
 271     my $frameworkcode = shift;
 272     my @isbn   = GetMarcFromKohaField('biblioitems.isbn',$frameworkcode);
 273     my @title  = GetMarcFromKohaField('biblio.title',$frameworkcode);
 274     my @author = GetMarcFromKohaField('biblio.author',$frameworkcode);
 275     my @issn   = GetMarcFromKohaField('biblioitems.issn',$frameworkcode);
 276     my @lccn   = GetMarcFromKohaField('biblioitems.lccn',$frameworkcode);
 277
 278     return {
 279         $isbn[0].$isbn[1]     => 'isbn',
 280         $title[0].$title[1]   => 'title',
 281         $author[0].$author[1] => 'author',
 282         $issn[0].$issn[1]     => 'issn',
 283         $lccn[0].$lccn[1]     => 'lccn',
 284     };
 285 }
 286
 287 =head2 create_input
 288
 289  builds the <input ...> entry for a subfield.
 290
 291 =cut
 292
 293 sub create_input {
 294     my ( $tag, $subfield, $value, $index_tag, $tabloop, $rec, $authorised_values_sth,$cgi ) = @_;
 295
 296     my $index_subfield = CreateKey(); # create a specifique key for each subfield
 297
 298     $value =~ s/"/&quot;/g;
 299
 300     # if there is no value provided but a default value in parameters, get it
 301     if ( $value eq '' ) {
 302         $value = $tagslib->{$tag}->{$subfield}->{defaultvalue};
 303
 304         # get today date & replace YYYY, MM, DD if provided in the default value
 305         my ( $year, $month, $day ) = Today();
 306         $month = sprintf( "%02d", $month );
 307         $day   = sprintf( "%02d", $day );
 308         $value =~ s/YYYY/$year/g;
 309         $value =~ s/MM/$month/g;
 310         $value =~ s/DD/$day/g;
 311         my $username=(C4::Context->userenv?C4::Context->userenv->{'surname'}:"superlibrarian");
 312         $value=~s/user/$username/g;
 313
 314     }
 315     my $dbh = C4::Context->dbh;
 316
 317     # map '@' as "subfield" label for fixed fields
 318     # to something that's allowed in a div id.
 319     my $id_subfield = $subfield;
 320     $id_subfield = "00" if $id_subfield eq "@";
 321
 322     my %subfield_data = (
 323         tag        => $tag,
 324         subfield   => $id_subfield,
 325         marc_lib   => substr( $tagslib->{$tag}->{$subfield}->{lib}, 0, 22 ),
 326         marc_lib_plain => $tagslib->{$tag}->{$subfield}->{lib},
 327         tag_mandatory  => $tagslib->{$tag}->{mandatory},
 328         mandatory      => $tagslib->{$tag}->{$subfield}->{mandatory},
 329         repeatable     => $tagslib->{$tag}->{$subfield}->{repeatable},
 330         kohafield      => $tagslib->{$tag}->{$subfield}->{kohafield},
 331         index          => $index_tag,
 332         id             => "tag_".$tag."_subfield_".$id_subfield."_".$index_tag."_".$index_subfield,
 333         value          => $value,
 334         maxlength      => $tagslib->{$tag}->{$subfield}->{maxlength},
 335         random         => CreateKey(),
 336     );
 337
 338     if(exists $mandatory_z3950->{$tag.$subfield}){
 339         $subfield_data{z3950_mandatory} = $mandatory_z3950->{$tag.$subfield};
 340     }
 341     # Subfield is hidden depending of hidden and mandatory flag, and is always
 342     # shown if it contains anything or if its field is mandatory.
 343     my $tdef = $tagslib->{$tag};
 344     $subfield_data{visibility} = "display:none;"
 345         if $tdef->{$subfield}->{hidden} % 2 == 1 &&
 346            $value eq '' &&
 347            !$tdef->{$subfield}->{mandatory} &&
 348            !$tdef->{mandatory};
 349     # expand all subfields of 773 if there is a host item provided in the input
 350     $subfield_data{visibility} ="" if ($tag eq 773 and $cgi->param('hostitemnumber'));
 351
 352
 353     # it's an authorised field
 354     if ( $tagslib->{$tag}->{$subfield}->{authorised_value} ) {
 355         $subfield_data{marc_value} =
 356           build_authorized_values_list( $tag, $subfield, $value, $dbh,
 357             $authorised_values_sth,$index_tag,$index_subfield );
 358
 359     # it's a subfield $9 linking to an authority record - see bug 2206
 360     }
 361     elsif ($subfield eq "9" and
 362            exists($tagslib->{$tag}->{'a'}->{authtypecode}) and
 363            defined($tagslib->{$tag}->{'a'}->{authtypecode}) and
 364            $tagslib->{$tag}->{'a'}->{authtypecode} ne '') {
 365
 366         $subfield_data{marc_value} = {
 367             type      => 'text',
 368             id        => $subfield_data{id},
 369             name      => $subfield_data{id},
 370             value     => $value,
 371             size      => 5,
 372             maxlength => $subfield_data{maxlength},
 373             readonly  => 1,
 374         };
 375
 376     # it's a thesaurus / authority field
 377     }
 378     elsif ( $tagslib->{$tag}->{$subfield}->{authtypecode} ) {
 379         # when authorities auto-creation is allowed, do not set readonly
 380         my $is_readonly = !C4::Context->preference("BiblioAddsAuthorities");
 381
 382         $subfield_data{marc_value} = {
 383             type      => 'text',
 384             id        => $subfield_data{id},
 385             name      => $subfield_data{id},
 386             value     => $value,
 387             size      => 67,
 388             maxlength => $subfield_data{maxlength},
 389             readonly  => ($is_readonly) ? 1 : 0,
 390             authtype  => $tagslib->{$tag}->{$subfield}->{authtypecode},
 391         };
 392
 393     # it's a plugin field
 394     }
 395     elsif ( $tagslib->{$tag}->{$subfield}->{'value_builder'} ) {
 396
 397         # opening plugin. Just check whether we are on a developer computer on a production one
 398         # (the cgidir differs)
 399         my $cgidir = C4::Context->intranetdir . "/cgi-bin/cataloguing/value_builder";
 400         unless ( opendir( DIR, "$cgidir" ) ) {
 401             $cgidir = C4::Context->intranetdir . "/cataloguing/value_builder";
 402             closedir( DIR );
 403         }
 404         my $plugin = $cgidir . "/" . $tagslib->{$tag}->{$subfield}->{'value_builder'};
 405         if (do $plugin) {
 406             my $extended_param = plugin_parameters( $dbh, $rec, $tagslib, $subfield_data{id}, $tabloop );
 407             my ( $function_name, $javascript ) = plugin_javascript( $dbh, $rec, $tagslib, $subfield_data{id}, $tabloop );
 408
 409             $subfield_data{marc_value} = {
 410                 type           => 'text_complex',
 411                 id             => $subfield_data{id},
 412                 name           => $subfield_data{id},
 413                 value          => $value,
 414                 size           => 67,
 415                 maxlength      => $subfield_data{maxlength},
 416                 function_name  => $function_name,
 417                 index_tag      => $index_tag,
 418                 javascript     => $javascript,
 419             };
 420
 421         } else {
 422             warn "Plugin Failed: $plugin";
 423             # supply default input form
 424             $subfield_data{marc_value} = {
 425                 type      => 'text',
 426                 id        => $subfield_data{id},
 427                 name      => $subfield_data{id},
 428                 value     => $value,
 429                 size      => 67,
 430                 maxlength => $subfield_data{maxlength},
 431                 readonly  => 0,
 432             };
 433
 434         }
 435         # it's an hidden field
 436     }
 437     elsif ( $tag eq '' ) {
 438         $subfield_data{marc_value} = {
 439             type      => 'hidden',
 440             id        => $subfield_data{id},
 441             name      => $subfield_data{id},
 442             value     => $value,
 443             size      => 67,
 444             maxlength => $subfield_data{maxlength},
 445         };
 446
 447     }
 448     else {
 449         # it's a standard field
 450         if (
 451             length($value) > 100
 452             or
 453             ( C4::Context->preference("marcflavour") eq "UNIMARC" && $tag >= 300
 454                 and $tag < 400 && $subfield eq 'a' )
 455             or (    $tag >= 500
 456                 and $tag < 600
 457                 && C4::Context->preference("marcflavour") eq "MARC21" )
 458           )
 459         {
 460             $subfield_data{marc_value} = {
 461                 type      => 'textarea',
 462                 id        => $subfield_data{id},
 463                 name      => $subfield_data{id},
 464                 value     => $value,
 465             };
 466
 467         }
 468         else {
 469             $subfield_data{marc_value} = {
 470                 type      => 'text',
 471                 id        => $subfield_data{id},
 472                 name      => $subfield_data{id},
 473                 value     => $value,
 474                 size      => 67,
 475                 maxlength => $subfield_data{maxlength},
 476                 readonly  => 0,
 477             };
 478
 479         }
 480     }
 481     $subfield_data{'index_subfield'} = $index_subfield;
 482     return \%subfield_data;
 483 }
 484
 485
 486 =head2 format_indicator
 487
 488 Translate indicator value for output form - specifically, map
 489 indicator = ' ' to ''.  This is for the convenience of a cataloger
 490 using a mouse to select an indicator input.
 491
 492 =cut
 493
 494 sub format_indicator {
 495     my $ind_value = shift;
 496     return '' if not defined $ind_value;
 497     return '' if $ind_value eq ' ';
 498     return $ind_value;
 499 }
 500
 501 sub build_tabs {
 502     my ( $template, $record, $dbh, $encoding,$input ) = @_;
 503
 504     # fill arrays
 505     my @loop_data = ();
 506     my $tag;
 507
 508     my $branch_limit = C4::Context->userenv ? C4::Context->userenv->{"branch"} : "";
 509     my $query = "SELECT authorised_value, lib
 510                 FROM authorised_values";
 511     $query .= qq{ LEFT JOIN authorised_values_branches ON ( id = av_id )} if $branch_limit;
 512     $query .= " WHERE category = ?";
 513     $query .= " AND ( branchcode = ? OR branchcode IS NULL )" if $branch_limit;
 514     $query .= " GROUP BY lib ORDER BY lib, lib_opac";
 515     my $authorised_values_sth = $dbh->prepare( $query );
 516
 517     # in this array, we will push all the 10 tabs
 518     # to avoid having 10 tabs in the template : they will all be in the same BIG_LOOP
 519     my @BIG_LOOP;
 520     my %seen;
 521     my @tab_data; # all tags to display
 522
 523     foreach my $used ( @$usedTagsLib ){
 524         push @tab_data,$used->{tagfield} if not $seen{$used->{tagfield}};
 525         $seen{$used->{tagfield}}++;
 526     }
 527
 528     my $max_num_tab=-1;
 529     foreach(@$usedTagsLib){
 530         if($_->{tab} > -1 && $_->{tab} >= $max_num_tab && $_->{tagfield} != '995'){ # FIXME : MARC21 ?
 531             $max_num_tab = $_->{tab};
 532         }
 533     }
 534     if($max_num_tab >= 9){
 535         $max_num_tab = 9;
 536     }
 537     # loop through each tab 0 through 9
 538     for ( my $tabloop = 0 ; $tabloop <= $max_num_tab ; $tabloop++ ) {
 539         my @loop_data = (); #innerloop in the template.
 540         my $i = 0;
 541         foreach my $tag (@tab_data) {
 542             $i++;
 543             next if ! $tag;
 544             my ($indicator1, $indicator2);
 545             my $index_tag = CreateKey;
 546
 547             # if MARC::Record is not empty =>use it as master loop, then add missing subfields that should be in the tab.
 548             # if MARC::Record is empty => use tab as master loop.
 549             if ( $record ne -1 && ( $record->field($tag) || $tag eq '000' ) ) {
 550                 my @fields;
 551                 if ( $tag ne '000' ) {
 552                     @fields = $record->field($tag);
 553                 }
 554                 else {
 555                    push @fields, $record->leader(); # if tag == 000
 556                 }
 557                 # loop through each field
 558                 foreach my $field (@fields) {
 559
 560                     my @subfields_data;
 561                     if ( $tag < 10 ) {
 562                         my ( $value, $subfield );
 563                         if ( $tag ne '000' ) {
 564                             $value    = $field->data();
 565                             $subfield = "@";
 566                         }
 567                         else {
 568                             $value    = $field;
 569                             $subfield = '@';
 570                         }
 571                         next if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 572                         next
 573                           if ( $tagslib->{$tag}->{$subfield}->{kohafield} eq
 574                             'biblio.biblionumber' );
 575                         push(
 576                             @subfields_data,
 577                             &create_input(
 578                                 $tag, $subfield, $value, $index_tag, $tabloop, $record,
 579                                 $authorised_values_sth,$input
 580                             )
 581                         );
 582                     }
 583                     else {
 584                         my @subfields = $field->subfields();
 585                         foreach my $subfieldcount ( 0 .. $#subfields ) {
 586                             my $subfield = $subfields[$subfieldcount][0];
 587                             my $value    = $subfields[$subfieldcount][1];
 588                             next if ( length $subfield != 1 );
 589                             next if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 590                             push(
 591                                 @subfields_data,
 592                                 &create_input(
 593                                     $tag, $subfield, $value, $index_tag, $tabloop,
 594                                     $record, $authorised_values_sth,$input
 595                                 )
 596                             );
 597                         }
 598                     }
 599
 600                     # now, loop again to add parameter subfield that are not in the MARC::Record
 601                     foreach my $subfield ( sort( keys %{ $tagslib->{$tag} } ) )
 602                     {
 603                         next if ( length $subfield != 1 );
 604                         next if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 605                         next if ( $tag < 10 );
 606                         next
 607                           if ( ( $tagslib->{$tag}->{$subfield}->{hidden} <= -4 )
 608                             or ( $tagslib->{$tag}->{$subfield}->{hidden} >= 5 ) )
 609                             and not ( $subfield eq "9" and
 610                                       exists($tagslib->{$tag}->{'a'}->{authtypecode}) and
 611                                       defined($tagslib->{$tag}->{'a'}->{authtypecode}) and
 612                                       $tagslib->{$tag}->{'a'}->{authtypecode} ne ""
 613                                     )
 614                           ;    #check for visibility flag
 615                                # if subfield is $9 in a field whose $a is authority-controlled,
 616                                # always include in the form regardless of the hidden setting - bug 2206
 617                         next if ( defined( $field->subfield($subfield) ) );
 618                         push(
 619                             @subfields_data,
 620                             &create_input(
 621                                 $tag, $subfield, '', $index_tag, $tabloop, $record,
 622                                 $authorised_values_sth,$input
 623                             )
 624                         );
 625                     }
 626                     if ( $#subfields_data >= 0 ) {
 627                         # build the tag entry.
 628                         # note that the random() field is mandatory. Otherwise, on repeated fields, you'll
 629                         # have twice the same "name" value, and cgi->param() will return only one, making
 630                         # all subfields to be merged in a single field.
 631                         my %tag_data = (
 632                             tag           => $tag,
 633                             index         => $index_tag,
 634                             tag_lib       => $tagslib->{$tag}->{lib},
 635                             repeatable       => $tagslib->{$tag}->{repeatable},
 636                             mandatory       => $tagslib->{$tag}->{mandatory},
 637                             subfield_loop => \@subfields_data,
 638                             fixedfield    => $tag < 10?1:0,
 639                             random        => CreateKey,
 640                         );
 641                         if ($tag >= 10){ # no indicator for 00x tags
 642                            $tag_data{indicator1} = format_indicator($field->indicator(1)),
 643                            $tag_data{indicator2} = format_indicator($field->indicator(2)),
 644                         }
 645                         push( @loop_data, \%tag_data );
 646                     }
 647                  } # foreach $field end
 648
 649             # if breeding is empty
 650             }
 651             else {
 652                 my @subfields_data;
 653                 foreach my $subfield ( sort( keys %{ $tagslib->{$tag} } ) ) {
 654                     next if ( length $subfield != 1 );
 655                     next
 656                       if ( ( $tagslib->{$tag}->{$subfield}->{hidden} <= -4 )
 657                         or ( $tagslib->{$tag}->{$subfield}->{hidden} >= 5 ) )
 658                       and not ( $subfield eq "9" and
 659                                 exists($tagslib->{$tag}->{'a'}->{authtypecode}) and
 660                                 defined($tagslib->{$tag}->{'a'}->{authtypecode}) and
 661                                 $tagslib->{$tag}->{'a'}->{authtypecode} ne ""
 662                               )
 663                       ;    #check for visibility flag
 664                            # if subfield is $9 in a field whose $a is authority-controlled,
 665                            # always include in the form regardless of the hidden setting - bug 2206
 666                     next
 667                       if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 668                         push(
 669                         @subfields_data,
 670                         &create_input(
 671                             $tag, $subfield, '', $index_tag, $tabloop, $record,
 672                             $authorised_values_sth,$input
 673                         )
 674                     );
 675                 }
 676                 if ( $#subfields_data >= 0 ) {
 677                     my %tag_data = (
 678                         tag              => $tag,
 679                         index            => $index_tag,
 680                         tag_lib          => $tagslib->{$tag}->{lib},
 681                         repeatable       => $tagslib->{$tag}->{repeatable},
 682                         mandatory       => $tagslib->{$tag}->{mandatory},
 683                         indicator1       => $indicator1,
 684                         indicator2       => $indicator2,
 685                         subfield_loop    => \@subfields_data,
 686                         tagfirstsubfield => $subfields_data[0],
 687                         fixedfield       => $tag < 10?1:0,
 688                     );
 689
 690                     push @loop_data, \%tag_data ;
 691                 }
 692             }
 693         }
 694         if ( $#loop_data >= 0 ) {
 695             push @BIG_LOOP, {
 696                 number    => $tabloop,
 697                 innerloop => \@loop_data,
 698             };
 699         }
 700     }
 701     $authorised_values_sth->finish;
 702     $template->param( BIG_LOOP => \@BIG_LOOP );
 703 }
 704
 705 # ========================
 706 #          MAIN
 707 #=========================
 708 my $input = new CGI;
 709 my $error = $input->param('error');
 710 my $biblionumber  = $input->param('biblionumber'); # if biblionumber exists, it's a modif, not a new biblio.
 711 my $parentbiblio  = $input->param('parentbiblionumber');
 712 my $breedingid    = $input->param('breedingid');
 713 my $z3950         = $input->param('z3950');
 714 my $op            = $input->param('op');
 715 my $mode          = $input->param('mode');
 716 my $frameworkcode = $input->param('frameworkcode');
 717 my $redirect      = $input->param('redirect');
 718 my $searchid      = $input->param('searchid');
 719 my $dbh           = C4::Context->dbh;
 720 my $hostbiblionumber = $input->param('hostbiblionumber');
 721 my $hostitemnumber = $input->param('hostitemnumber');
 722 # fast cataloguing datas in transit
 723 my $fa_circborrowernumber = $input->param('circborrowernumber');
 724 my $fa_barcode            = $input->param('barcode');
 725 my $fa_branch             = $input->param('branch');
 726 my $fa_stickyduedate      = $input->param('stickyduedate');
 727 my $fa_duedatespec        = $input->param('duedatespec');
 728
 729 my $userflags = 'edit_catalogue';
 730
 731 my $changed_framework = $input->param('changed_framework');
 732 $frameworkcode = &GetFrameworkCode($biblionumber)
 733   if ( $biblionumber and not($frameworkcode) and $op ne 'addbiblio' );
 734
 735 if ($frameworkcode eq 'FA'){
 736     $userflags = 'fast_cataloging';
 737 }
 738
 739 $frameworkcode = '' if ( $frameworkcode eq 'Default' );
 740 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 741     {
 742         template_name   => "cataloguing/addbiblio.tt",
 743         query           => $input,
 744         type            => "intranet",
 745         authnotrequired => 0,
 746         flagsrequired   => { editcatalogue => $userflags },
 747     }
 748 );
 749
 750 if ($frameworkcode eq 'FA'){
 751     # We need to grab and set some variables in the template for use on the additems screen
 752     $template->param(
 753         'circborrowernumber' => $fa_circborrowernumber,
 754         'barcode'            => $fa_barcode,
 755         'branch'             => $fa_branch,
 756         'stickyduedate'      => $fa_stickyduedate,
 757         'duedatespec'        => $fa_duedatespec,
 758     );
 759 }
 760
 761 # Getting the list of all frameworks
 762 # get framework list
 763 my $frameworks = getframeworks;
 764 my @frameworkcodeloop;
 765 foreach my $thisframeworkcode ( keys %$frameworks ) {
 766         my %row = (
 767                 value         => $thisframeworkcode,
 768                 frameworktext => $frameworks->{$thisframeworkcode}->{'frameworktext'},
 769         );
 770         if ($frameworkcode eq $thisframeworkcode){
 771                 $row{'selected'} = 1;
 772                 }
 773         push @frameworkcodeloop, \%row;
 774 }
 775 $template->param( frameworkcodeloop => \@frameworkcodeloop,
 776         breedingid => $breedingid );
 777
 778 # ++ Global
 779 $tagslib         = &GetMarcStructure( 1, $frameworkcode );
 780 $usedTagsLib     = &GetUsedMarcStructure( $frameworkcode );
 781 $mandatory_z3950 = GetMandatoryFieldZ3950($frameworkcode);
 782 # -- Global
 783
 784 my $record   = -1;
 785 my $encoding = "";
 786 my (
 787         $biblionumbertagfield,
 788         $biblionumbertagsubfield,
 789         $biblioitemnumtagfield,
 790         $biblioitemnumtagsubfield,
 791         $bibitem,
 792         $biblioitemnumber
 793 );
 794
 795 if (($biblionumber) && !($breedingid)){
 796         $record = GetMarcBiblio($biblionumber);
 797 }
 798 if ($breedingid) {
 799     ( $record, $encoding ) = MARCfindbreeding( $breedingid ) ;
 800 }
 801
 802 #populate hostfield if hostbiblionumber is available
 803 if ($hostbiblionumber) {
 804     my $marcflavour = C4::Context->preference("marcflavour");
 805     $record = MARC::Record->new();
 806     $record->leader('');
 807     my $field =
 808       PrepHostMarcField( $hostbiblionumber, $hostitemnumber, $marcflavour );
 809     $record->append_fields($field);
 810 }
 811
 812 # This is  a child record
 813 if ($parentbiblio) {
 814     my $marcflavour = C4::Context->preference('marcflavour');
 815     $record = MARC::Record->new();
 816     SetMarcUnicodeFlag($record, $marcflavour);
 817     my $hostfield = prepare_host_field($parentbiblio,$marcflavour);
 818     if ($hostfield) {
 819         $record->append_fields($hostfield);
 820     }
 821 }
 822
 823 $is_a_modif = 0;
 824
 825 if ($biblionumber) {
 826     $is_a_modif = 1;
 827     my $title = C4::Context->preference('marcflavour') eq "UNIMARC" ? $record->subfield('200', 'a') : $record->title;
 828     $template->param( title => $title );
 829
 830     # if it's a modif, retrieve bibli and biblioitem numbers for the future modification of old-DB.
 831     ( $biblionumbertagfield, $biblionumbertagsubfield ) =
 832         &GetMarcFromKohaField( "biblio.biblionumber", $frameworkcode );
 833     ( $biblioitemnumtagfield, $biblioitemnumtagsubfield ) =
 834         &GetMarcFromKohaField( "biblioitems.biblioitemnumber", $frameworkcode );
 835
 836     # search biblioitems value
 837     my $sth =  $dbh->prepare("select biblioitemnumber from biblioitems where biblionumber=?");
 838     $sth->execute($biblionumber);
 839     ($biblioitemnumber) = $sth->fetchrow;
 840 }
 841
 842 #-------------------------------------------------------------------------------------
 843 if ( $op eq "addbiblio" ) {
 844 #-------------------------------------------------------------------------------------
 845     $template->param(
 846         biblionumberdata => $biblionumber,
 847     );
 848     # getting html input
 849     my @params = $input->param();
 850     $record = TransformHtmlToMarc( $input );
 851     # check for a duplicate
 852     my ( $duplicatebiblionumber, $duplicatetitle );
 853     if ( !$is_a_modif ) {
 854         ( $duplicatebiblionumber, $duplicatetitle ) = FindDuplicate($record);
 855     }
 856     my $confirm_not_duplicate = $input->param('confirm_not_duplicate');
 857     # it is not a duplicate (determined either by Koha itself or by user checking it's not a duplicate)
 858     if ( !$duplicatebiblionumber or $confirm_not_duplicate ) {
 859         my $oldbibnum;
 860         my $oldbibitemnum;
 861         if (C4::Context->preference("BiblioAddsAuthorities")){
 862             BiblioAutoLink( $record, $frameworkcode );
 863         }
 864         if ( $is_a_modif ) {
 865             ModBiblioframework( $biblionumber, $frameworkcode );
 866             ModBiblio( $record, $biblionumber, $frameworkcode );
 867         }
 868         else {
 869             ( $biblionumber, $oldbibitemnum ) = AddBiblio( $record, $frameworkcode );
 870         }
 871         if ($redirect eq "items" || ($mode ne "popup" && !$is_a_modif && $redirect ne "view" && $redirect ne "just_save")){
 872             if ($frameworkcode eq 'FA'){
 873                 print $input->redirect(
 874             '/cgi-bin/koha/cataloguing/additem.pl?'
 875             .'biblionumber='.$biblionumber
 876             .'&frameworkcode='.$frameworkcode
 877             .'&circborrowernumber='.$fa_circborrowernumber
 878             .'&branch='.$fa_branch
 879             .'&barcode='.uri_escape($fa_barcode)
 880             .'&stickyduedate='.$fa_stickyduedate
 881             .'&duedatespec='.$fa_duedatespec
 882                 );
 883                 exit;
 884             }
 885             else {
 886                 print $input->redirect(
 887                 "/cgi-bin/koha/cataloguing/additem.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid"
 888                 );
 889                 exit;
 890             }
 891         }
 892     elsif(($is_a_modif || $redirect eq "view") && $redirect ne "just_save"){
 893             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 894             my $views = { C4::Search::enabled_staff_search_views };
 895             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 896                 print $input->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 897             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 898                 print $input->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid");
 899             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 900                 print $input->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 901             } else {
 902                 print $input->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&searchid=$searchid");
 903             }
 904             exit;
 905
 906     }
 907     elsif ($redirect eq "just_save"){
 908         my $tab = $input->param('current_tab');
 909         print $input->redirect("/cgi-bin/koha/cataloguing/addbiblio.pl?biblionumber=$biblionumber&framework=$frameworkcode&tab=$tab&searchid=$searchid");
 910     }
 911     else {
 912           $template->param(
 913             biblionumber => $biblionumber,
 914             done         =>1,
 915             popup        =>1
 916           );
 917           if ( $record ne '-1' ) {
 918               my $title = C4::Context->preference('marcflavour') eq "UNIMARC" ? $record->subfield('200', 'a') : $record->title;
 919               $template->param( title => $title );
 920           }
 921           $template->param(
 922             popup => $mode,
 923             itemtype => $frameworkcode,
 924           );
 925           output_html_with_http_headers $input, $cookie, $template->output;
 926           exit;
 927         }
 928     } else {
 929     # it may be a duplicate, warn the user and do nothing
 930         build_tabs ($template, $record, $dbh,$encoding,$input);
 931         $template->param(
 932             biblionumber             => $biblionumber,
 933             biblioitemnumber         => $biblioitemnumber,
 934             duplicatebiblionumber    => $duplicatebiblionumber,
 935             duplicatebibid           => $duplicatebiblionumber,
 936             duplicatetitle           => $duplicatetitle,
 937         );
 938     }
 939 }
 940 elsif ( $op eq "delete" ) {
 941
 942     my $error = &DelBiblio($biblionumber);
 943     if ($error) {
 944         warn "ERROR when DELETING BIBLIO $biblionumber : $error";
 945         print "Content-Type: text/html\n\n<html><body><h1>ERROR when DELETING BIBLIO $biblionumber : $error</h1></body></html>";
 946         exit;
 947     }
 948
 949     print $input->redirect('/cgi-bin/koha/catalogue/search.pl');
 950     exit;
 951
 952 } else {
 953    #----------------------------------------------------------------------------
 954    # If we're in a duplication case, we have to set to "" the biblionumber
 955    # as we'll save the biblio as a new one.
 956     $template->param(
 957         biblionumberdata => $biblionumber,
 958         op               => $op,
 959     );
 960     if ( $op eq "duplicate" ) {
 961         $biblionumber = "";
 962     }
 963
 964     if($changed_framework eq "changed"){
 965         $record = TransformHtmlToMarc( $input );
 966     }
 967     elsif( $record ne -1 ) {
 968 #FIXME: it's kind of silly to go from MARC::Record to MARC::File::XML and then back again just to fix the encoding
 969         eval {
 970             my $uxml = $record->as_xml;
 971             MARC::Record::default_record_format("UNIMARC")
 972             if ( C4::Context->preference("marcflavour") eq "UNIMARC" );
 973             my $urecord = MARC::Record::new_from_xml( $uxml, 'UTF-8' );
 974             $record = $urecord;
 975         };
 976     }
 977     build_tabs( $template, $record, $dbh, $encoding,$input );
 978     $template->param(
 979         biblionumber             => $biblionumber,
 980         biblionumbertagfield        => $biblionumbertagfield,
 981         biblionumbertagsubfield     => $biblionumbertagsubfield,
 982         biblioitemnumtagfield    => $biblioitemnumtagfield,
 983         biblioitemnumtagsubfield => $biblioitemnumtagsubfield,
 984         biblioitemnumber         => $biblioitemnumber,
 985         hostbiblionumber        => $hostbiblionumber,
 986         hostitemnumber          => $hostitemnumber
 987     );
 988 }
 989
 990 if ( $record ne '-1' ) {
 991     my $title = C4::Context->preference('marcflavour') eq "UNIMARC" ? $record->subfield('200', 'a') : $record->title;
 992     $template->param( title => $title );
 993 }
 994 $template->param(
 995     popup => $mode,
 996     frameworkcode => $frameworkcode,
 997     itemtype => $frameworkcode,
 998     borrowernumber => $loggedinuser,
 999     tab => $input->param('tab')
1000 );
1001 $template->{'VARS'}->{'searchid'} = $searchid;
1002
1003 output_html_with_http_headers $input, $cookie, $template->output;