members/statistics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2012 BibLibre
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 =head1 members/statistics.pl
  20
  21   Generate statistic issues for a member
  22
  23 =cut
  24
  25 use Modern::Perl;
  26
  27 use CGI qw ( -utf8 );
  28 use C4::Auth;
  29 use C4::Branch;
  30 use C4::Context;
  31 use C4::Members;
  32 use C4::Members::Statistics;
  33 use C4::Members::Attributes qw(GetBorrowerAttributes);
  34 use C4::Output;
  35
  36 my $input = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name   => "members/statistics.tt",
  40         query           => $input,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { borrowers => 1 },
  44         debug           => 1,
  45     }
  46 );
  47
  48 my $borrowernumber = $input->param('borrowernumber');
  49
  50 # Set informations for the patron
  51 my $borrower = GetMemberDetails( $borrowernumber, 0 );
  52 if ( not defined $borrower ) {
  53     $template->param (unknowuser => 1);
  54     output_html_with_http_headers $input, $cookie, $template->output;
  55     exit;
  56 }
  57
  58 foreach my $key ( keys %$borrower ) {
  59     $template->param( $key => $borrower->{$key} );
  60 }
  61 $template->param(
  62     categoryname    => $borrower->{'description'},
  63     branchname      => GetBranchName($borrower->{'branchcode'}),
  64 );
  65 # Construct column names
  66 my $fields = C4::Members::Statistics::get_fields();
  67 our @statistic_column_names = split '\|', $fields;
  68 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
  69 our @column_names = ( @statistic_column_names, @value_column_names );
  70
  71 # Get statistics
  72 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
  73 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
  74 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
  75 my $r = merge (
  76     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
  77 );
  78
  79 add_actual_state( $r );
  80 my ( $total, $datas ) = build_array( $r );
  81
  82 # Gettings sums
  83 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
  84 my $count_total_issues = $total->{count_total_issues_today} || 0;
  85 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
  86 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
  87
  88 if (C4::Context->preference('ExtendedPatronAttributes')) {
  89     my $attributes = GetBorrowerAttributes($borrowernumber);
  90     $template->param(
  91         ExtendedPatronAttributes => 1,
  92         extendedattributes => $attributes
  93     );
  94 }
  95
  96 my ($picture, $dberror) = GetPatronImage($borrower->{'borrowernumber'});
  97 $template->param( picture => 1 ) if $picture;
  98
  99 $template->param(%$borrower);
 100
 101 $template->param(
 102     statisticsview     => 1,
 103     datas              => $datas,
 104     column_names       => \@statistic_column_names,
 105     count_total_issues => $count_total_issues,
 106     count_total_issues_returned => $count_total_issues_returned,
 107     count_total_precedent_state => $count_total_precedent_state,
 108     count_total_actual_state => $count_total_actual_state,
 109     RoutingSerials => C4::Context->preference('RoutingSerials'),
 110 );
 111
 112 output_html_with_http_headers $input, $cookie, $template->output;
 113
 114
 115 =head1 FUNCTIONS
 116
 117 =head2 add_actual_state
 118
 119   Add a 'count_actual_state' key in all hashes
 120   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
 121
 122 =cut
 123
 124 sub add_actual_state {
 125     my ( $array ) = @_;
 126     for my $hash ( @$array ) {
 127         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
 128     }
 129 }
 130
 131 =head2 build_array
 132
 133   Build a new array containing values of hashes.
 134   It used by template whitch display silly values.
 135   ex:
 136     $array = [
 137       {
 138         'count_total_issues_returned_today' => 1,
 139         'ccode' => 'ccode',
 140         'count_actual_state' => 1,
 141         'count_precedent_state' => 1,
 142         'homebranch' => 'homebranch',
 143         'count_total_issues_today' => 1,
 144         'itype' => 'itype'
 145       }
 146     ];
 147   and returns:
 148     [
 149       [
 150         'homebranch',
 151         'itype',
 152         'ccode',
 153         1,
 154         1,
 155         1,
 156         1
 157       ]
 158     ];
 159
 160 =cut
 161
 162 sub build_array {
 163     my ( $array ) = @_;
 164     my ( @r, $total );
 165     for my $hash ( @$array) {
 166         my @line;
 167         for my $cn ( ( @column_names, 'count_actual_state') ) {
 168             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
 169                 $hash->{$cn} //= 0;
 170                 if ( exists $total->{$cn} ) {
 171                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
 172                 } else {
 173                     $total->{$cn} = $hash->{$cn};
 174                 }
 175             }
 176             push @line, $hash->{$cn};
 177         }
 178         push @r, \@line;
 179     }
 180     return ( $total, \@r );
 181 }
 182
 183 =head2 merge
 184
 185   Merge hashes with the same statistic column names into one
 186   param: array, a arrayref of arrayrefs
 187   ex:
 188   @array = (
 189      {
 190        'ccode' => 'ccode',
 191        'count_precedent_state' => '1',
 192        'homebranch' => 'homebranch',
 193        'itype' => 'itype'
 194      },
 195      {
 196        'count_total_issues_returned_today' => '1',
 197        'ccode' => 'ccode',
 198        'homebranch' => 'homebranch',
 199        'itype' => 'itype'
 200      }
 201    );
 202    and returns:
 203    [
 204      {
 205        'count_total_issues_returned_today' => '1',
 206        'ccode' => 'ccode',
 207        'count_precedent_state' => '1',
 208        'homebranch' => 'homebranch',
 209        'itype' => 'itype'
 210      }
 211    ];
 212
 213 =cut
 214
 215 sub merge {
 216     my @array = @_;
 217     my @r;
 218     for my $h ( @array ) {
 219         my $exists = 0;
 220         for my $ch ( @r ) {
 221             $exists = 1;
 222             for my $cn ( @statistic_column_names ) {
 223                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
 224                     $exists = 0;
 225                     last;
 226                 }
 227             }
 228             if ($exists){
 229                 for my $cn ( @value_column_names ) {
 230                     next if not exists $h->{$cn};
 231                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
 232                 }
 233                 last;
 234             }
 235         }
 236
 237         if ( not $exists ) {push @r, $h;}
 238     }
 239     return \@r;
 240 }