Bug 17618: perl-modules Debian package name change
[koha.git] / C4 / Auth_with_ldap.pm
blob91d3f633d7675a3929abfb5e6e31e5224b478e36
1 package C4::Auth_with_ldap;
3 # Copyright 2000-2002 Katipo Communications
5 # This file is part of Koha.
7 # Koha is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
12 # Koha is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 # GNU General Public License for more details.
17 # You should have received a copy of the GNU General Public License
18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
20 use strict;
21 #use warnings; FIXME - Bug 2505
22 use Carp;
24 use C4::Debug;
25 use C4::Context;
26 use C4::Members qw(AddMember);
27 use C4::Members::Attributes;
28 use C4::Members::AttributeTypes;
29 use C4::Members::Messaging;
30 use C4::Auth qw(checkpw_internal);
31 use Koha::Patrons;
32 use Koha::AuthUtils qw(hash_password);
33 use List::MoreUtils qw( any );
34 use Net::LDAP;
35 use Net::LDAP::Filter;
37 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
39 BEGIN {
40 require Exporter;
41 @ISA = qw(Exporter);
42 @EXPORT = qw( checkpw_ldap );
45 # Redefine checkpw_ldap:
46 # connect to LDAP (named or anonymous)
47 # ~ retrieves $userid from KOHA_CONF mapping
48 # ~ then compares $password with userPassword
49 # ~ then gets the LDAP entry
50 # ~ and calls the memberadd if necessary
52 sub ldapserver_error {
53 return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
56 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
57 my $context = C4::Context->new() or die 'C4::Context->new failed';
58 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
59 my $prefhost = $ldap->{hostname} or die ldapserver_error('hostname');
60 my $base = $ldap->{base} or die ldapserver_error('base');
61 $ldapname = $ldap->{user} ;
62 $ldappassword = $ldap->{pass} ;
63 $ldap->{anonymous_bind} = 1 unless $ldapname && $ldappassword;
64 our %mapping = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
65 my @mapkeys = keys %mapping;
66 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys ( total ): ", join ' ', @mapkeys, "\n";
67 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
68 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
70 my %categorycode_conversions;
71 my $default_categorycode;
72 if(defined $ldap->{categorycode_mapping}) {
73 $default_categorycode = $ldap->{categorycode_mapping}->{default};
74 foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
75 $categorycode_conversions{$cat->{value}} = $cat->{content};
79 my %config = (
80 anonymous => ($ldapname and $ldappassword) ? 0 : 1,
81 replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1, # add from LDAP to Koha database for new user
82 update => defined($ldap->{update} ) ? $ldap->{update} : 1, # update from LDAP to Koha database for existing user
85 sub description {
86 my $result = shift or return;
87 return "LDAP error #" . $result->code
88 . ": " . $result->error_name . "\n"
89 . "# " . $result->error_text . "\n";
92 sub search_method {
93 my $db = shift or return;
94 my $userid = shift or return;
95 my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
96 my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
97 my $search = $db->search(
98 base => $base,
99 filter => $filter,
100 # attrs => ['*'],
102 die "LDAP search failed to return object : " . $search->error if $search->code;
104 my $count = $search->count;
105 if ($search->code > 0) {
106 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
107 return 0;
109 if ($count == 0) {
110 warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
111 return 0;
113 return $search;
116 sub checkpw_ldap {
117 my ($dbh, $userid, $password) = @_;
118 my @hosts = split(',', $prefhost);
119 my $db = Net::LDAP->new(\@hosts);
120 unless ( $db ) {
121 warn "LDAP connexion failed";
122 return 0;
125 #$debug and $db->debug(5);
126 my $userldapentry;
128 # first, LDAP authentication
129 if ( $ldap->{auth_by_bind} ) {
130 my $principal_name;
131 if ( $ldap->{anonymous_bind} ) {
133 # Perform an anonymous bind
134 my $res = $db->bind;
135 if ( $res->code ) {
136 warn "Anonymous LDAP bind failed: " . description($res);
137 return 0;
140 # Perform a LDAP search for the given username
141 my $search = search_method( $db, $userid )
142 or return 0; # warnings are in the sub
143 $userldapentry = $search->shift_entry;
144 $principal_name = $userldapentry->dn;
146 else {
147 $principal_name = $ldap->{principal_name};
148 if ( $principal_name and $principal_name =~ /\%/ ) {
149 $principal_name = sprintf( $principal_name, $userid );
151 else {
152 $principal_name = $userid;
156 # Perform a LDAP bind for the given username using the matched DN
157 my $res = $db->bind( $principal_name, password => $password );
158 if ( $res->code ) {
159 if ( $ldap->{anonymous_bind} ) {
160 # With anonymous_bind approach we can be sure we have found the correct user
161 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
162 # or password changed). We should not fall back to local accounts in this case.
163 warn "LDAP bind failed as kohauser $userid: " . description($res);
164 return -1;
165 } else {
166 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
167 # at all, and thus we should fall back to local logins to restore previous behaviour
168 # see bug 12831
169 warn "LDAP bind failed as kohauser $userid: " . description($res);
170 return 0;
173 if ( !defined($userldapentry)
174 && ( $config{update} or $config{replicate} ) )
176 my $search = search_method( $db, $userid ) or return 0;
177 $userldapentry = $search->shift_entry;
179 } else {
180 my $res = ($ldap->{anonymous_bind}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
181 if ($res->code) { # connection refused
182 warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
183 return 0;
185 my $search = search_method($db, $userid) or return 0; # warnings are in the sub
186 # Handle multiple branches. Same login exists several times in different branches.
187 my $bind_ok = 0;
188 while (my $entry = $search->shift_entry) {
189 my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
190 unless ($user_ldap_bind_ret->code) {
191 $userldapentry = $entry;
192 $bind_ok = 1;
193 last;
197 unless ($bind_ok) {
198 warn "LDAP Auth rejected : invalid password for user '$userid'.";
199 return -1;
205 # To get here, LDAP has accepted our user's login attempt.
206 # But we still have work to do. See perldoc below for detailed breakdown.
208 my (%borrower);
209 my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
211 if (( $borrowernumber and $config{update} ) or
212 (!$borrowernumber and $config{replicate}) ) {
213 %borrower = ldap_entry_2_hash($userldapentry,$userid);
214 $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
217 if ($borrowernumber) {
218 if ($config{update}) { # A1, B1
219 my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
220 ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
221 } else { # C1, D1
222 # maybe update just the password?
223 return(1, $cardnumber, $local_userid);
225 } elsif ($config{replicate}) { # A2, C2
226 $borrowernumber = C4::Members::AddMember(%borrower) or die "AddMember failed";
227 C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
228 } else {
229 return 0; # B2, D2
231 if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
232 foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
233 my $code = $attribute_type->{code};
234 unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
235 next;
237 if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
238 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, attribute => $borrower{$code}});
239 } else {
240 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
244 return(1, $cardnumber, $userid);
247 # Pass LDAP entry object and local cardnumber (userid).
248 # Returns borrower hash.
249 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
250 # Ensure that mandatory fields are correctly filled!
252 sub ldap_entry_2_hash {
253 my $userldapentry = shift;
254 my %borrower = ( cardnumber => shift );
255 my %memberhash;
256 $userldapentry->exists('uid'); # This is bad, but required! By side-effect, this initializes the attrs hash.
257 if ($debug) {
258 foreach (keys %$userldapentry) {
259 print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
262 my $x = $userldapentry->{attrs} or return;
263 foreach (keys %$x) {
264 $memberhash{$_} = join ' ', @{$x->{$_}};
265 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
267 $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
268 "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
269 foreach my $key (keys %mapping) {
270 my $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
271 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
272 unless (defined $data) {
273 $data = $mapping{$key}->{content} || ''; # default or failsafe ''
275 $borrower{$key} = ($data ne '') ? $data : ' ' ;
277 $borrower{initials} = $memberhash{initials} ||
278 ( substr($borrower{'firstname'},0,1)
279 . substr($borrower{ 'surname' },0,1)
280 . " ");
282 # categorycode conversions
283 if(defined $categorycode_conversions{$borrower{categorycode}}) {
284 $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
286 elsif($default_categorycode) {
287 $borrower{categorycode} = $default_categorycode;
290 # check if categorycode exists, if not, fallback to default from koha-conf.xml
291 my $dbh = C4::Context->dbh;
292 my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
293 $sth->execute( uc($borrower{'categorycode'}) );
294 unless ( my $row = $sth->fetchrow_hashref ) {
295 my $default = $mapping{'categorycode'}->{content};
296 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
297 $borrower{'categorycode'} = $default
300 return %borrower;
303 sub exists_local {
304 my $arg = shift;
305 my $dbh = C4::Context->dbh;
306 my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
308 my $sth = $dbh->prepare("$select WHERE userid=?"); # was cardnumber=?
309 $sth->execute($arg);
310 $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
311 ($sth->rows == 1) and return $sth->fetchrow;
313 $sth = $dbh->prepare("$select WHERE cardnumber=?");
314 $sth->execute($arg);
315 $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
316 ($sth->rows == 1) and return $sth->fetchrow;
317 return 0;
320 # This function performs a password update, given the userid, borrowerid,
321 # and digested password. It will verify that things are correct and return the
322 # borrowers cardnumber. The idea is that it is used to keep the local
323 # passwords in sync with the LDAP passwords.
325 # $cardnum = _do_changepassword($userid, $borrowerid, $digest)
327 # Note: if the LDAP config has the update_password tag set to a false value,
328 # then this will not update the password, it will simply return the cardnumber.
329 sub _do_changepassword {
330 my ($userid, $borrowerid, $password) = @_;
332 if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
334 # We don't store the password in the database
335 my $sth = C4::Context->dbh->prepare(
336 'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
337 $sth->execute($borrowerid);
338 die "Unable to access borrowernumber "
339 . "with userid=$userid, "
340 . "borrowernumber=$borrowerid"
341 if !$sth->rows;
342 my ($cardnum) = $sth->fetchrow;
343 $sth = C4::Context->dbh->prepare(
344 'UPDATE borrowers SET password = null WHERE borrowernumber=?');
345 $sth->execute($borrowerid);
346 return $cardnum;
348 my $digest = hash_password($password);
350 $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
351 Koha::Patrons->find($borrowerid)->update_password( $userid, $digest );
353 my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
354 return $cardnum if $ok;
356 warn "Password mismatch after update to borrowernumber=$borrowerid";
357 return;
360 sub update_local {
361 my $userid = shift or croak "No userid";
362 my $password = shift or croak "No password";
363 my $borrowerid = shift or croak "No borrowerid";
364 my $borrower = shift or croak "No borrower record";
366 my @keys = keys %$borrower;
367 my $dbh = C4::Context->dbh;
368 my $query = "UPDATE borrowers\nSET " .
369 join(',', map {"$_=?"} @keys) .
370 "\nWHERE borrowernumber=? ";
371 my $sth = $dbh->prepare($query);
372 if ($debug) {
373 print STDERR $query, "\n",
374 join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
375 print STDERR "\nuserid = $userid\n";
377 $sth->execute(
378 ((map {$borrower->{$_}} @keys), $borrowerid)
381 # MODIFY PASSWORD/LOGIN if password was mapped
382 _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
386 __END__
388 =head1 NAME
390 C4::Auth - Authenticates Koha users
392 =head1 SYNOPSIS
394 use C4::Auth_with_ldap;
396 =head1 LDAP Configuration
398 This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
399 working LDAP servers.
400 To use it :
401 * Modify ldapserver element in KOHA_CONF
402 * Establish field mapping in <mapping> element.
404 For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
405 the username would match the "uid" field, and the password should match the "userpassword" field.
407 Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
408 What are the required fields? Well, in mysql you can check the database table "borrowers" like this:
410 mysql> show COLUMNS from borrowers;
411 +---------------------+--------------+------+-----+---------+----------------+
412 | Field | Type | Null | Key | Default | Extra |
413 +---------------------+--------------+------+-----+---------+----------------+
414 | borrowernumber | int(11) | NO | PRI | NULL | auto_increment |
415 | cardnumber | varchar(16) | YES | UNI | NULL | |
416 | surname | mediumtext | NO | | NULL | |
417 | firstname | text | YES | | NULL | |
418 | title | mediumtext | YES | | NULL | |
419 | othernames | mediumtext | YES | | NULL | |
420 | initials | text | YES | | NULL | |
421 | streetnumber | varchar(10) | YES | | NULL | |
422 | streettype | varchar(50) | YES | | NULL | |
423 | address | mediumtext | NO | | NULL | |
424 | address2 | text | YES | | NULL | |
425 | city | mediumtext | NO | | NULL | |
426 | state | mediumtext | YES | | NULL | |
427 | zipcode | varchar(25) | YES | | NULL | |
428 | country | text | YES | | NULL | |
429 | email | mediumtext | YES | | NULL | |
430 | phone | text | YES | | NULL | |
431 | mobile | varchar(50) | YES | | NULL | |
432 | fax | mediumtext | YES | | NULL | |
433 | emailpro | text | YES | | NULL | |
434 | phonepro | text | YES | | NULL | |
435 | B_streetnumber | varchar(10) | YES | | NULL | |
436 | B_streettype | varchar(50) | YES | | NULL | |
437 | B_address | varchar(100) | YES | | NULL | |
438 | B_address2 | text | YES | | NULL | |
439 | B_city | mediumtext | YES | | NULL | |
440 | B_state | mediumtext | YES | | NULL | |
441 | B_zipcode | varchar(25) | YES | | NULL | |
442 | B_country | text | YES | | NULL | |
443 | B_email | text | YES | | NULL | |
444 | B_phone | mediumtext | YES | | NULL | |
445 | dateofbirth | date | YES | | NULL | |
446 | branchcode | varchar(10) | NO | MUL | | |
447 | categorycode | varchar(10) | NO | MUL | | |
448 | dateenrolled | date | YES | | NULL | |
449 | dateexpiry | date | YES | | NULL | |
450 | gonenoaddress | tinyint(1) | YES | | NULL | |
451 | lost | tinyint(1) | YES | | NULL | |
452 | debarred | date | YES | | NULL | |
453 | debarredcomment | varchar(255) | YES | | NULL | |
454 | contactname | mediumtext | YES | | NULL | |
455 | contactfirstname | text | YES | | NULL | |
456 | contacttitle | text | YES | | NULL | |
457 | guarantorid | int(11) | YES | MUL | NULL | |
458 | borrowernotes | mediumtext | YES | | NULL | |
459 | relationship | varchar(100) | YES | | NULL | |
460 | ethnicity | varchar(50) | YES | | NULL | |
461 | ethnotes | varchar(255) | YES | | NULL | |
462 | sex | varchar(1) | YES | | NULL | |
463 | password | varchar(30) | YES | | NULL | |
464 | flags | int(11) | YES | | NULL | |
465 | userid | varchar(30) | YES | MUL | NULL | |
466 | opacnote | mediumtext | YES | | NULL | |
467 | contactnote | varchar(255) | YES | | NULL | |
468 | sort1 | varchar(80) | YES | | NULL | |
469 | sort2 | varchar(80) | YES | | NULL | |
470 | altcontactfirstname | varchar(255) | YES | | NULL | |
471 | altcontactsurname | varchar(255) | YES | | NULL | |
472 | altcontactaddress1 | varchar(255) | YES | | NULL | |
473 | altcontactaddress2 | varchar(255) | YES | | NULL | |
474 | altcontactaddress3 | varchar(255) | YES | | NULL | |
475 | altcontactstate | mediumtext | YES | | NULL | |
476 | altcontactzipcode | varchar(50) | YES | | NULL | |
477 | altcontactcountry | text | YES | | NULL | |
478 | altcontactphone | varchar(50) | YES | | NULL | |
479 | smsalertnumber | varchar(50) | YES | | NULL | |
480 | privacy | int(11) | NO | | 1 | |
481 +---------------------+--------------+------+-----+---------+----------------+
482 66 rows in set (0.00 sec)
483 Where Null="NO", the field is required.
485 =head1 KOHA_CONF and field mapping
487 Example XML stanza for LDAP configuration in KOHA_CONF.
489 <config>
491 <useldapserver>1</useldapserver>
492 <!-- LDAP SERVER (optional) -->
493 <ldapserver id="ldapserver">
494 <hostname>localhost</hostname>
495 <base>dc=metavore,dc=com</base>
496 <user>cn=Manager,dc=metavore,dc=com</user> <!-- DN, if not anonymous -->
497 <pass>metavore</pass> <!-- password, if not anonymous -->
498 <replicate>1</replicate> <!-- add new users from LDAP to Koha database -->
499 <update>1</update> <!-- update existing users in Koha database -->
500 <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
501 password comparison, e.g., to use Active Directory -->
502 <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
503 an anonymous bind, even when auth_by_bind is on -->
504 <principal_name>%s@my_domain.com</principal_name>
505 <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
506 Not used with anonymous_bind. -->
507 <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
508 synced to the local database -->
509 <mapping> <!-- match koha SQL field names to your LDAP record field names -->
510 <firstname is="givenname" ></firstname>
511 <surname is="sn" ></surname>
512 <address is="postaladdress" ></address>
513 <city is="l" >Athens, OH</city>
514 <zipcode is="postalcode" ></zipcode>
515 <branchcode is="branch" >MAIN</branchcode>
516 <userid is="uid" ></userid>
517 <password is="userpassword" ></password>
518 <email is="mail" ></email>
519 <categorycode is="employeetype" >PT</categorycode>
520 <phone is="telephonenumber"></phone>
521 </mapping>
522 </ldapserver>
523 </config>
525 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
526 is the column in mysql, with the "is" characteristic set to the LDAP attribute name. Optionally, any content
527 between the element tags is taken as the default value. In this example, the default categorycode is "PT" (for
528 patron).
530 =head1 CONFIGURATION
532 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
533 your configuration and the presence of a matching Koha user in your local DB:
535 LOCAL_USER
536 OPTION UPDATE REPLICATE EXISTS? RESULT
537 A1 1 1 1 OK : We're updating them anyway.
538 A2 1 1 0 OK : We're adding them anyway.
539 B1 1 0 1 OK : We update them.
540 B2 1 0 0 FAIL: We cannot add new user.
541 C1 0 1 1 OK : We do nothing. (maybe should update password?)
542 C2 0 1 0 OK : We add the new user.
543 D1 0 0 1 OK : We do nothing. (maybe should update password?)
544 D2 0 0 0 FAIL: We cannot add new user.
546 Note: failure here just means that Koha will fallback to checking the local DB. That is, a given user could login with
547 their LDAP password OR their local one. If this is a problem, then you should enable update and supply a mapping for
548 password. Then the local value will be updated at successful LDAP login and the passwords will be synced.
550 If you choose NOT to update local users, the borrowers table will not be affected at all.
551 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
552 the local table never contained the LDAP values.
554 =head2 auth_by_bind
556 Binds as the user instead of retrieving their record. Recommended if update disabled.
558 =head2 principal_name
560 Provides an optional sprintf-style format for manipulating the userid before the bind.
561 Even though the userPrincipalName is one intended target, any uniquely identifying
562 attribute that the server allows to be used for binding could be used.
564 Currently, principal_name only operates when auth_by_bind is enabled.
566 =head2 update_password
568 If this tag is left out or set to a true value, then the user's LDAP password
569 will be stored (hashed) in the local Koha database. If you don't want this
570 to happen, then set the value of this to '0'. Note that if passwords are not
571 stored locally, and the connection to the LDAP system fails, then the users
572 will not be able to log in at all.
574 =head2 Active Directory
576 The auth_by_bind and principal_name settings are recommended for Active Directory.
578 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
579 we would typically under openldap. Instead of:
581 distinguishedName: CN=barnes.7,DC=my_company,DC=com
583 We might get:
585 distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
587 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
588 in Koha userids. But the userPrincipalName should be consistent, something like:
590 userPrincipalName: barnes.7@my_company.com
592 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
593 canonical email address for that user, or what it would be if email were enabled for them. If Koha userid values
594 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
595 like this:
596 <principal_name>%s@core.my_company.com</principal_name>
598 The user of the previous example, barnes.7, would then attempt to bind as:
599 barnes.7@core.my_company.com
601 =head1 SEE ALSO
603 CGI(3)
605 Net::LDAP()
607 XML::Simple()
609 Digest::MD5(3)
611 sprintf()
613 =cut
615 # For reference, here's an important difference in the data structure we rely on.
616 # ========================================
617 # Using attrs instead of {asn}->attributes
618 # ========================================
620 # LDAP key: ->{ cn} = ARRAY w/ 3 members.
621 # LDAP key: ->{ cn}->{ sss} = sss
622 # LDAP key: ->{ cn}->{ Steve Smith} = Steve Smith
623 # LDAP key: ->{ cn}->{Steve S. Smith} = Steve S. Smith
625 # LDAP key: ->{ givenname} = ARRAY w/ 1 members.
626 # LDAP key: ->{ givenname}->{Steve} = Steve