opac/opac-account.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Katipo Communications 2002
   4 # Copyright Biblibre 2007,2010
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use Modern::Perl;
  23 use CGI qw ( -utf8 );
  24 use C4::Members;
  25 use C4::Auth;
  26 use C4::Output;
  27 use Koha::Account::Lines;
  28 use Koha::Patrons;
  29 use Koha::Plugins;
  30
  31 my $query = new CGI;
  32 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  33     {
  34         template_name   => "opac-account.tt",
  35         query           => $query,
  36         type            => "opac",
  37         debug           => 1,
  38     }
  39 );
  40
  41 my $patron = Koha::Patrons->find( $borrowernumber );
  42 my $account = $patron->account;
  43 my $accountlines = $account->lines->search({ amountoutstanding => { '>=' => 0 }});
  44 my $total_outstanding = $accountlines->total_outstanding;
  45 my $outstanding_credits = $account->outstanding_credits;
  46
  47 if ( C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
  48     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor')
  49   )
  50 {
  51     my @relatives;
  52
  53     # Filter out guarantees that don't want guarantor to see checkouts
  54     foreach my $gr ( $patron->guarantee_relationships() ) {
  55         my $g = $gr->guarantee;
  56         if ( $g->privacy_guarantor_fines ) {
  57
  58             my $relatives_accountlines = Koha::Account::Lines->search(
  59                 { borrowernumber => $g->borrowernumber },
  60                 { order_by       => { -desc => 'accountlines_id' } }
  61             );
  62             push(
  63                 @relatives,
  64                 {
  65                     patron       => $g,
  66                     accountlines => $relatives_accountlines,
  67                 }
  68             );
  69         }
  70     }
  71     $template->param( relatives => \@relatives );
  72 }
  73
  74
  75 $template->param(
  76     ACCOUNT_LINES       => $accountlines,
  77     total               => $total_outstanding,
  78     outstanding_credits => $outstanding_credits,
  79     accountview         => 1,
  80     message             => scalar $query->param('message') || q{},
  81     message_value       => scalar $query->param('message_value') || q{},
  82     payment             => scalar $query->param('payment') || q{},
  83     payment_error       => scalar $query->param('payment-error') || q{},
  84 );
  85
  86 if ( C4::Context->config("enable_plugins") ) {
  87     my @plugins = Koha::Plugins->new()->GetPlugins({
  88         method => 'opac_online_payment',
  89     });
  90     # Only pass in plugins where opac online payment is enabled
  91     @plugins = grep { $_->opac_online_payment } @plugins;
  92     $template->param( plugins => \@plugins );
  93 }
  94
  95 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };