catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = new CGI;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     $template->param(
 198         holdfor => $cgi->cookie("holdfor"),
 199         holdfor_surname => $holdfor_patron->surname,
 200         holdfor_firstname => $holdfor_patron->firstname,
 201         holdfor_cardnumber => $holdfor_patron->cardnumber,
 202     );
 203 }
 204
 205 if($cgi->cookie("holdforclub")){
 206     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 207     $template->param(
 208         holdforclub => $cgi->cookie("holdforclub"),
 209         holdforclub_name => $holdfor_club->name,
 210     );
 211 }
 212
 213 if($cgi->cookie("searchToOrder")){
 214     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 215     $template->param(
 216         searchtoorder_basketno => $basketno,
 217         searchtoorder_vendorid => $vendorid
 218     );
 219 }
 220
 221 # get biblionumbers stored in the cart
 222 my @cart_list;
 223
 224 if($cgi->cookie("intranet_bib_list")){
 225     my $cart_list = $cgi->cookie("intranet_bib_list");
 226     @cart_list = split(/\//, $cart_list);
 227 }
 228
 229 my @search_groups =
 230   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 231 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 232
 233 $template->param(
 234     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 235     search_groups    => \@search_groups,
 236 );
 237
 238 # load the Type stuff
 239 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 240 my $advancedsearchesloop = prepare_adv_search_types($types);
 241 $template->param(advancedsearchesloop => $advancedsearchesloop);
 242
 243 $template->param( searchid => scalar $cgi->param('searchid'), );
 244
 245 # The following should only be loaded if we're bringing up the advanced search template
 246 if ( $template_type eq 'advsearch' ) {
 247
 248     # load the servers (used for searching -- to do federated searching, etc.)
 249     my $primary_servers_loop;# = displayPrimaryServers();
 250     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 251
 252     my $secondary_servers_loop;
 253     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 254
 255     # set the default sorting
 256     if (   C4::Context->preference('defaultSortField')
 257         && C4::Context->preference('defaultSortOrder') ) {
 258         my $default_sort_by =
 259             C4::Context->preference('defaultSortField') . '_'
 260           . C4::Context->preference('defaultSortOrder');
 261         $template->param( sort_by => $default_sort_by  );
 262     }
 263
 264     # determine what to display next to the search boxes (ie, boolean option
 265     # shouldn't appear on the first one, scan indexes should, adding a new
 266     # box should only appear on the last, etc.
 267     my @search_boxes_array;
 268     my $search_boxes_count = 3; # begin with 3 boxes
 269     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 270     for (my $i=1;$i<=$search_boxes_count;$i++) {
 271         # if it's the first one, don't display boolean option, but show scan indexes
 272         if ($i==1) {
 273             push @search_boxes_array, {scan_index => 1};
 274         }
 275         # if it's the last one, show the 'add field' box
 276         elsif ($i==$search_boxes_count) {
 277             push @search_boxes_array,
 278                 {
 279                 boolean => 1,
 280                 add_field => 1,
 281                 };
 282         }
 283         else {
 284             push @search_boxes_array,
 285                 {
 286                 boolean => 1,
 287                 };
 288         }
 289
 290     }
 291     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 292                       search_boxes_loop => \@search_boxes_array);
 293
 294     # load the language limits (for search)
 295     my $languages_limit_loop = getLanguages($lang, 1);
 296     $template->param(search_languages_loop => $languages_limit_loop,);
 297
 298     # Expanded search options in advanced search:
 299     # use the global setting by default, but let the user override it
 300     {
 301         my $expanded = $cgi->param('expanded_options');
 302         $expanded = C4::Context->preference("expandedSearchOption") || 0
 303             if !defined($expanded) || $expanded !~ /^0|1$/;
 304         $template->param( expanded_options => $expanded );
 305     }
 306
 307     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 308
 309     output_html_with_http_headers $cgi, $cookie, $template->output;
 310     exit;
 311 }
 312
 313 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 314
 315 # Fetch the paramater list as a hash in scalar context:
 316 #  * returns paramater list as tied hash ref
 317 #  * we can edit the values by changing the key
 318 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 319 my $params = $cgi->Vars;
 320 # Params that can have more than one value
 321 # sort by is used to sort the query
 322 # in theory can have more than one but generally there's just one
 323 my @sort_by;
 324 my $default_sort_by;
 325 if (   C4::Context->preference('defaultSortField')
 326     && C4::Context->preference('defaultSortOrder') ) {
 327     $default_sort_by =
 328         C4::Context->preference('defaultSortField') . '_'
 329       . C4::Context->preference('defaultSortOrder');
 330 }
 331
 332 @sort_by = $cgi->multi_param('sort_by');
 333 $sort_by[0] = $default_sort_by unless $sort_by[0];
 334 foreach my $sort (@sort_by) {
 335     $template->param($sort => 1) if $sort;
 336 }
 337 $template->param('sort_by' => $sort_by[0]);
 338
 339 # Use the servers defined, or just search our local catalog(default)
 340 my @servers = $cgi->multi_param('server');
 341 unless (@servers) {
 342     #FIXME: this should be handled using Context.pm
 343     @servers = ("biblioserver");
 344     # @servers = C4::Context->config("biblioserver");
 345 }
 346 # operators include boolean and proximity operators and are used
 347 # to evaluate multiple operands
 348 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 349
 350 # indexes are query qualifiers, like 'title', 'author', etc. They
 351 # can be single or multiple parameters separated by comma: kw,right-Truncation
 352 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 353
 354 # if a simple index (only one)  display the index used in the top search box
 355 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 356     my $idx = "ms_".$indexes[0];
 357     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 358     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 359     $template->param($idx => 1);
 360 }
 361
 362 # an operand can be a single term, a phrase, or a complete ccl query
 363 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 364
 365 # if a simple search, display the value in the search box
 366 if ($operands[0] && !$operands[1]) {
 367     my $ms_query = $operands[0];
 368     $ms_query =~ s/ #\S+//;
 369     $template->param(ms_value => $ms_query);
 370 }
 371
 372 # limits are use to limit to results to a pre-defined category such as branch or language
 373 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 374 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 375 my %is_nolimit = map { $_ => 1 } @nolimits;
 376 @limits = grep { not $is_nolimit{$_} } @limits;
 377
 378 if($params->{'multibranchlimit'}) {
 379     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 380     my @libraries = $search_group->all_libraries;
 381     my $multibranch = '('.join( " OR ", map { '(homebranch: ' . $_->branchcode .')' } @libraries ) .')';
 382     push @limits, $multibranch if ($multibranch ne  '()');
 383 }
 384
 385 my $available;
 386 foreach my $limit(@limits) {
 387     if ($limit =~/available/) {
 388         $available = 1;
 389     }
 390 }
 391 $template->param(available => $available);
 392
 393 # append year limits if they exist
 394 my $limit_yr;
 395 my $limit_yr_value;
 396 if ($params->{'limit-yr'}) {
 397     if ($params->{'limit-yr'} =~ /\d{4}/) {
 398         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 399         $limit_yr_value = $params->{'limit-yr'};
 400     }
 401     push @limits,$limit_yr;
 402     #FIXME: Should return a error to the user, incorect date format specified
 403 }
 404
 405 # convert indexes and operands to corresponding parameter names for the z3950 search
 406 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 407 my $z3950par;
 408 my $indexes2z3950 = {
 409     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 410     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 411     ti=>'title', 'ti,phr'=>'title', se=>'title'
 412 };
 413 for (my $ii = 0; $ii < @operands; ++$ii)
 414 {
 415     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 416     if (defined $name && defined $operands[$ii])
 417     {
 418         $z3950par ||= {};
 419         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 420     }
 421 }
 422
 423
 424 # Params that can only have one value
 425 my $scan = $params->{'scan'};
 426 my $count = C4::Context->preference('numSearchResults') || 20;
 427 my $results_per_page = $params->{'count'} || $count;
 428 my $offset = $params->{'offset'} || 0;
 429 my $whole_record = $params->{'whole_record'} || 0;
 430 $offset = 0 if $offset < 0;
 431 my $page = $cgi->param('page') || 1;
 432 #my $offset = ($page-1)*$results_per_page;
 433
 434 # Define some global variables
 435 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 436
 437 my $builder = Koha::SearchEngine::QueryBuilder->new(
 438     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 439 my $searcher = Koha::SearchEngine::Search->new(
 440     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 441
 442 ## I. BUILD THE QUERY
 443 (
 444     $error,             $query, $simple_query, $query_cgi,
 445     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 446     $query_type
 447   )
 448   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 449     \@sort_by, $scan, $lang, { weighted_fields => !$cgi->param('advsearch'), whole_record => $whole_record });
 450
 451 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 452
 453 ## parse the query_cgi string and put it into a form suitable for <input>s
 454 my @query_inputs;
 455 my $scan_index_to_use;
 456 my $scan_search_term_to_use;
 457
 458 if ($query_cgi) {
 459     for my $this_cgi ( split('&', $query_cgi) ) {
 460         next unless $this_cgi;
 461         $this_cgi =~ m/(.*?)=(.*)/;
 462         my $input_name = $1;
 463         my $input_value = $2;
 464         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 465         if ($input_name eq 'idx') {
 466             # The form contains multiple fields, so take the first value as the scan index
 467             $scan_index_to_use = $input_value unless $scan_index_to_use;
 468         }
 469         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 470             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 471         }
 472     }
 473 }
 474
 475 $template->param ( QUERY_INPUTS => \@query_inputs,
 476                    scan_index_to_use => $scan_index_to_use,
 477                    scan_search_term_to_use => $scan_search_term_to_use );
 478
 479 ## parse the limit_cgi string and put it into a form suitable for <input>s
 480 my @limit_inputs;
 481 if ($limit_cgi) {
 482     for my $this_cgi ( split('&', $limit_cgi) ) {
 483         next unless $this_cgi;
 484         # handle special case limit-yr
 485         if ($this_cgi =~ /yr,st-numeric/) {
 486             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 487             next;
 488         }
 489         $this_cgi =~ m/(.*=)(.*)/;
 490         my $input_name = $1;
 491         my $input_value = $2;
 492         $input_name =~ s/=$//;
 493         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 494     }
 495 }
 496 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 497
 498 ## II. DO THE SEARCH AND GET THE RESULTS
 499 my $total = 0; # the total results for the whole set
 500 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 501 my $results_hashref;
 502
 503 eval {
 504     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 505     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 506         $query,            $simple_query, \@sort_by,       \@servers,
 507         $results_per_page, $offset,       undef,           $itemtypes,
 508         $query_type,       $scan
 509     );
 510 };
 511
 512 if ($@ || $error) {
 513     $template->param(query_error => $error.$@);
 514     output_html_with_http_headers $cgi, $cookie, $template->output;
 515     exit;
 516 }
 517
 518 # At this point, each server has given us a result set
 519 # now we build that set for template display
 520 my @sup_results_array;
 521 for (my $i=0;$i<@servers;$i++) {
 522     my $server = $servers[$i];
 523     if ($server =~/biblioserver/) { # this is the local bibliographic server
 524         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 525         my $page = $cgi->param('page') || 0;
 526         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 527                                        $results_hashref->{$server}->{"RECORDS"});
 528         $total = $total + $hits;
 529
 530         # Search history
 531         if (C4::Context->preference('EnableSearchHistory')) {
 532             unless ( $offset ) {
 533                 my $path_info = $cgi->url(-path_info=>1);
 534                 my $query_cgi_history = $cgi->url(-query=>1);
 535                 $query_cgi_history =~ s/^$path_info\?//;
 536                 $query_cgi_history =~ s/;/&/g;
 537                 my $query_desc_history = $query_desc;
 538                 $query_desc_history .= ", $limit_desc"
 539                     if $limit_desc;
 540
 541                 C4::Search::History::add({
 542                     userid => $borrowernumber,
 543                     sessionid => $cgi->cookie("CGISESSID"),
 544                     query_desc => $query_desc_history,
 545                     query_cgi => $query_cgi_history,
 546                     total => $total,
 547                     type => "biblio",
 548                 });
 549             }
 550             $template->param( EnableSearchHistory => 1 );
 551         }
 552
 553         ## If there's just one result, redirect to the detail page unless doing an index scan
 554         if ($total == 1 && !$scan) {
 555             my $biblionumber = $newresults[0]->{biblionumber};
 556             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 557             my $views = { C4::Search::enabled_staff_search_views };
 558             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 559                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 560             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 561                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 562             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 563                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 564             } else {
 565                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 566             }
 567             exit;
 568         }
 569
 570         # set up parameters if user wishes to re-run the search
 571         # as a Z39.50 search
 572         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 573
 574         if ($hits) {
 575             $template->param(total => $hits);
 576             if ($limit_cgi) {
 577                 my $limit_cgi_not_availablity = $limit_cgi;
 578                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 579                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 580             }
 581             $template->param(limit_cgi => $limit_cgi);
 582             $template->param(query_cgi => $query_cgi);
 583             $template->param(query_desc => $query_desc);
 584             $template->param(limit_desc => $limit_desc);
 585             $template->param(offset     => $offset);
 586             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 587             if ($query_desc || $limit_desc) {
 588                 $template->param(searchdesc => 1);
 589             }
 590             $template->param(results_per_page =>  $results_per_page);
 591             # must define a value for size if not present in DB
 592             # in order to avoid problems generated by the default size value in TT
 593             foreach my $line (@newresults) {
 594                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 595                 # while we're checking each line, see if item is in the cart
 596                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 597                     $line->{'incart'} = 1;
 598                 }
 599             }
 600             $template->param(SEARCH_RESULTS => \@newresults);
 601             ## FIXME: add a global function for this, it's better than the current global one
 602             ## Build the page numbers on the bottom of the page
 603             my @page_numbers;
 604             my $max_result_window = $searcher->max_result_window;
 605             my $hits_to_paginate = ($max_result_window && $max_result_window < $hits) ? $max_result_window : $hits;
 606             $template->param( hits_to_paginate => $hits_to_paginate );
 607             # total number of pages there will be
 608             my $pages = ceil($hits_to_paginate / $results_per_page);
 609             my $last_page_offset = ( $pages -1 ) * $results_per_page;
 610             # default page number
 611             my $current_page_number = 1;
 612             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 613             my $previous_page_offset;
 614             if ( $offset >= $results_per_page ) {
 615                 $previous_page_offset = $offset - $results_per_page;
 616             }
 617             my $next_page_offset = $offset + $results_per_page;
 618             # If we're within the first 10 pages, keep it simple
 619             #warn "current page:".$current_page_number;
 620             if ($current_page_number < 10) {
 621                 # just show the first 10 pages
 622                 # Loop through the pages
 623                 my $pages_to_show = 10;
 624                 $pages_to_show = $pages if $pages<10;
 625                 for (my $i=1; $i<=$pages_to_show;$i++) {
 626                     # the offset for this page
 627                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 628                     # the page number for this page
 629                     my $this_page_number = $i;
 630                     # put it in the array
 631                     push @page_numbers,
 632                       { offset    => $this_offset,
 633                         pg        => $this_page_number,
 634                         # it should only be highlighted if it's the current page
 635                         highlight => $this_page_number == $current_page_number,
 636                         sort_by   => join ' ', @sort_by
 637                       };
 638
 639                 }
 640
 641             }
 642
 643             # now, show twenty pages, with the current one smack in the middle
 644             else {
 645                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 646                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 647                     my $this_page_number = $i-9;
 648                     if ( $this_page_number <= $pages ) {
 649                         push @page_numbers,
 650                           { offset    => $this_offset,
 651                             pg        => $this_page_number,
 652                             highlight => $this_page_number == $current_page_number,
 653                             sort_by   => join ' ', @sort_by
 654                           };
 655                     }
 656                 }
 657             }
 658             # FIXME: no previous_page_offset when pages < 2
 659             $template->param(   PAGE_NUMBERS => \@page_numbers,
 660                                 last_page_offset => $last_page_offset,
 661                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 662             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 663         }
 664
 665
 666         # no hits
 667         else {
 668             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 669         }
 670
 671     } # end of the if local
 672
 673     # asynchronously search the authority server
 674     elsif ($server =~/authorityserver/) { # this is the local authority server
 675         my @inner_sup_results_array;
 676         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 677             my $marc_record_object = C4::Search::new_record_from_zebra(
 678                 'authorityserver',
 679                 $sup_record
 680             );
 681             # warn "Authority Found: ".$marc_record_object->as_formatted();
 682             push @inner_sup_results_array, {
 683                 'title' => $marc_record_object->field(100)->subfield('a'),
 684                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 685             };
 686         }
 687         push @sup_results_array, {  servername => $server,
 688                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 689     }
 690     # FIXME: can add support for other targets as needed here
 691     $template->param(           outer_sup_results_loop => \@sup_results_array);
 692 } #/end of the for loop
 693 #$template->param(FEDERATED_RESULTS => \@results_array);
 694
 695 my $gotonumber = $cgi->param('gotoNumber');
 696 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 697     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 698 }
 699 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 700 my $gotopage = $cgi->param('gotoPage');
 701 $template->{'VARS'}->{'gotoPage'} = $gotopage
 702   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 703
 704 for my $facet ( @$facets ) {
 705     for my $entry ( @{ $facet->{facets} } ) {
 706         my $index = $entry->{type_link_value};
 707         my $value = $entry->{facet_link_value};
 708         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 709     }
 710 }
 711
 712 $template->param(
 713             #classlist => $classlist,
 714             total => $total,
 715             opacfacets => 1,
 716             facets_loop => $facets,
 717             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 718             scan => $scan,
 719             search_error => $error,
 720 );
 721
 722 if ($query_desc || $limit_desc) {
 723     $template->param(searchdesc => 1);
 724 }
 725
 726 # VI. BUILD THE TEMPLATE
 727
 728 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 729     {
 730         borrowernumber => $borrowernumber,
 731         add_allowed    => 1,
 732         category       => 1,
 733     }
 734 );
 735 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 736     {
 737         borrowernumber => $borrowernumber,
 738         add_allowed    => 1,
 739         category       => 2,
 740     }
 741 );
 742
 743
 744 $template->param(
 745     add_to_some_private_shelves => $some_private_shelves,
 746     add_to_some_public_shelves  => $some_public_shelves,
 747 );
 748
 749 output_html_with_http_headers $cgi, $cookie, $template->output;
 750
 751
 752 =head2 prepare_adv_search_types
 753
 754     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 755     my @advanced_search_types = prepare_adv_search_types($type);
 756
 757 Different types can be searched for in the advanced search. This takes the
 758 system preference that defines these types and parses it into an arrayref for
 759 the template.
 760
 761 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 762 It also accounts for the "item-level_itypes" system preference.
 763
 764 =cut
 765
 766 sub prepare_adv_search_types {
 767     my ($types) = @_;
 768
 769     my @advanced_search_types = split( /\|/, $types );
 770
 771     # the index parameter is different for item-level itemtypes
 772     my $itype_or_itemtype =
 773       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 774     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 775
 776     my ( $cnt, @result );
 777     foreach my $advanced_srch_type (@advanced_search_types) {
 778         $advanced_srch_type =~ s/^\s*//;
 779         $advanced_srch_type =~ s/\s*$//;
 780         if ( $advanced_srch_type eq 'itemtypes' ) {
 781
 782        # itemtype is a special case, since it's not defined in authorized values
 783             my @itypesloop;
 784             foreach my $thisitemtype (
 785                 sort {
 786                     $itemtypes->{$a}->{'translated_description'}
 787                       cmp $itemtypes->{$b}->{'translated_description'}
 788                 } keys %$itemtypes
 789               )
 790             {
 791                 my %row = (
 792                     number      => $cnt++,
 793                     ccl         => "$itype_or_itemtype,phr",
 794                     code        => $thisitemtype,
 795                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 796                     imageurl    => getitemtypeimagelocation(
 797                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 798                     ),
 799                 );
 800                 push @itypesloop, \%row;
 801             }
 802             my %search_code = (
 803                 advanced_search_type => $advanced_srch_type,
 804                 code_loop            => \@itypesloop
 805             );
 806             push @result, \%search_code;
 807         }
 808         else {
 809             # covers all the other cases: non-itemtype authorized values
 810             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 811             my @authvalueloop;
 812             for my $thisitemtype (@$advsearchtypes) {
 813                 my %row = (
 814                     number      => $cnt++,
 815                     ccl         => $advanced_srch_type,
 816                     code        => $thisitemtype->{authorised_value},
 817                     description => $thisitemtype->{'lib'},
 818                     imageurl    => getitemtypeimagelocation(
 819                         'intranet', $thisitemtype->{'imageurl'}
 820                     ),
 821                 );
 822                 push @authvalueloop, \%row;
 823             }
 824             my %search_code = (
 825                 advanced_search_type => $advanced_srch_type,
 826                 code_loop            => \@authvalueloop
 827             );
 828             push @result, \%search_code;
 829         }
 830     }
 831     return \@result;
 832 }