opac/opac-search.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Garry Collum and the Koha Development team
   4 # Copyright 2010 BibLibre
   5 # Copyright 2011 KohaAloha, NZ
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 # Script to perform searching
  23 # Mostly copied from search.pl, see POD there
  24 use Modern::Perl;
  25
  26 ## STEP 1. Load things that are used in both search page and
  27 # results page and decide which template to load, operations
  28 # to perform, etc.
  29 ## load Koha modules
  30 use C4::Context;
  31 use List::MoreUtils q/any/;
  32
  33 use Data::Dumper; # TODO remove
  34
  35 use Koha::SearchEngine::Search;
  36 use Koha::SearchEngine::QueryBuilder;
  37
  38 my $searchengine = C4::Context->preference("SearchEngine");
  39 my ($builder, $searcher);
  40 #$searchengine = 'Zebra'; # XXX
  41 $builder  = Koha::SearchEngine::QueryBuilder->new({index => 'biblios'});
  42 $searcher = Koha::SearchEngine::Search->new({index => 'biblios'});
  43
  44 use C4::Output;
  45 use C4::Auth qw(:DEFAULT get_session);
  46 use C4::Languages qw(getLanguages);
  47 use C4::Search;
  48 use C4::Search::History;
  49 use C4::Biblio; # Unused here?
  50 use C4::Koha;
  51 use C4::Tags qw(get_tags);
  52 use C4::SocialData;
  53 use C4::External::OverDrive;
  54
  55 use Koha::ItemTypes;
  56 use Koha::Ratings;
  57 use Koha::Virtualshelves;
  58 use Koha::Library::Groups;
  59
  60 use POSIX qw(ceil floor strftime);
  61 use URI::Escape;
  62 use JSON qw/decode_json encode_json/;
  63 use Business::ISBN;
  64
  65 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
  66 # create a new CGI object
  67 # FIXME: no_undef_params needs to be tested
  68 use CGI qw('-no_undef_params' -utf8);
  69 my $cgi = new CGI;
  70
  71 my $branch_group_limit = $cgi->param("branch_group_limit");
  72 if ( $branch_group_limit ) {
  73     if ( $branch_group_limit =~ /^multibranchlimit-/ ) {
  74         # For search groups we are going to convert this branch_group_limit CGI
  75         # parameter into a multibranchlimit CGI parameter for the purposes of
  76         # actually performing the query
  77         $cgi->param(
  78             -name => 'multibranchlimit',
  79             -values => substr($branch_group_limit, 17)
  80         );
  81     } else {
  82         $cgi->append(
  83             -name => 'limit',
  84             -values => [ $branch_group_limit ]
  85         );
  86     }
  87 }
  88
  89 BEGIN {
  90     if (C4::Context->preference('BakerTaylorEnabled')) {
  91         require C4::External::BakerTaylor;
  92         import C4::External::BakerTaylor qw(&image_url &link_url);
  93     }
  94 }
  95
  96 my ($template,$borrowernumber,$cookie);
  97 # decide which template to use
  98 my $template_name;
  99 my $template_type = 'basic';
 100 my @params = $cgi->multi_param("limit");
 101 my @searchCategories = $cgi->multi_param('searchcat');
 102
 103 my $format = $cgi->param("format") || '';
 104 my $build_grouped_results = C4::Context->preference('OPACGroupResults');
 105 if ($format =~ /(rss|atom|opensearchdescription)/) {
 106     $template_name = 'opac-opensearch.tt';
 107 }
 108 elsif (@params && $build_grouped_results) {
 109     $template_name = 'opac-results-grouped.tt';
 110 }
 111 elsif ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 112     $template_name = 'opac-results.tt';
 113 }
 114 else {
 115     $template_name = 'opac-advsearch.tt';
 116     $template_type = 'advsearch';
 117 }
 118 # load the template
 119 ($template, $borrowernumber, $cookie) = get_template_and_user({
 120     template_name => $template_name,
 121     query => $cgi,
 122     type => "opac",
 123     authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
 124     }
 125 );
 126
 127 my $lang = C4::Languages::getlanguage($cgi);
 128
 129 if ($template_name eq 'opac-results.tt') {
 130    $template->param('COinSinOPACResults' => C4::Context->preference('COinSinOPACResults'));
 131 }
 132
 133 # get biblionumbers stored in the cart
 134 my @cart_list;
 135
 136 if($cgi->cookie("bib_list")){
 137     my $cart_list = $cgi->cookie("bib_list");
 138     @cart_list = split(/\//, $cart_list);
 139 }
 140
 141 if ($format eq 'rss2' or $format eq 'opensearchdescription' or $format eq 'atom') {
 142     $template->param($format => 1);
 143     $template->param(timestamp => strftime("%Y-%m-%dT%H:%M:%S-00:00", gmtime)) if ($format eq 'atom');
 144     # FIXME - the timestamp is a hack - the biblio update timestamp should be used for each
 145     # entry, but not sure if that's worth an extra database query for each bib
 146 }
 147 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 148     $template->param('UNIMARC' => 1);
 149 }
 150 elsif (C4::Context->preference("marcflavour") eq "MARC21" ) {
 151     $template->param('usmarc' => 1);
 152 }
 153
 154 $template->param( 'OPACNoResultsFound' => C4::Context->preference('OPACNoResultsFound') );
 155
 156 $template->param(
 157     OpacStarRatings => C4::Context->preference("OpacStarRatings") );
 158
 159 if (C4::Context->preference('BakerTaylorEnabled')) {
 160     $template->param(
 161         BakerTaylorEnabled  => 1,
 162         BakerTaylorImageURL => &image_url(),
 163         BakerTaylorLinkURL  => &link_url(),
 164         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 165     );
 166 }
 167
 168 if (C4::Context->preference('TagsEnabled')) {
 169     $template->param(TagsEnabled => 1);
 170     foreach (qw(TagsShowOnList TagsInputOnList)) {
 171         C4::Context->preference($_) and $template->param($_ => 1);
 172     }
 173 }
 174
 175 ## URI Re-Writing
 176 # Deprecated, but preserved because it's interesting :-)
 177 # The same thing can be accomplished with mod_rewrite in
 178 # a more elegant way
 179 #
 180 #my $rewrite_flag;
 181 #my $uri = $cgi->url(-base => 1);
 182 #my $relative_url = $cgi->url(-relative=>1);
 183 #$uri.="/".$relative_url."?";
 184 #warn "URI:$uri";
 185 #my @cgi_params_list = $cgi->param();
 186 #my $url_params = $cgi->Vars;
 187 #
 188 #for my $each_param_set (@cgi_params_list) {
 189 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 190 #}
 191 #warn "New URI:$uri";
 192 # Only re-write a URI if there are params or if it already hasn't been re-written
 193 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 194 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 195 #                            -cookie => $cookie);
 196 #    exit;
 197 #}
 198
 199 # load the branches
 200
 201 if ($cgi->param("returntosearch")) {
 202     $template->param('ReturnToSearch' => 1);
 203 }
 204 if ($cgi->cookie("search_path_code")) {
 205     my $pathcode = $cgi->cookie("search_path_code");
 206     if ($pathcode eq '"ads"') {
 207         $template->param('ReturnPath' => '/cgi-bin/koha/opac-search.pl?returntosearch=1');
 208     }
 209     elsif ($pathcode eq '"exs"') {
 210          $template->param('ReturnPath' => '/cgi-bin/koha/opac-search.pl?expanded_options=1&returntosearch=1');
 211     }
 212     else {
 213         warn "ReturnPath switch error";
 214     }
 215 }
 216
 217 my @search_groups = Koha::Library::Groups->get_search_groups();
 218 $template->param( search_groups => \@search_groups );
 219
 220 # load the language limits (for search)
 221 my $languages_limit_loop = getLanguages($lang, 1);
 222 $template->param(search_languages_loop => $languages_limit_loop,);
 223
 224 # load the Type stuff
 225 my $itemtypes = GetItemTypesCategorized;
 226 # add translated_description to itemtypes
 227 foreach my $itemtype ( keys %{$itemtypes} ) {
 228     # Itemtypes search categories don't have (yet) translated descriptions, they are auth values (and could still have no descriptions too BZ 18400)
 229     my $translated_description = Koha::ItemTypes->find( $itemtype )->translated_description;
 230     $itemtypes->{$itemtype}->{translated_description} = $translated_description || $itemtypes->{$itemtype}->{description} || q{};
 231 }
 232
 233 # the index parameter is different for item-level itemtypes
 234 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 235 my @advancedsearchesloop;
 236 my $cnt;
 237 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 238 my @advanced_search_types = split(/\|/, $advanced_search_types);
 239
 240 my $hidingrules = {};
 241 my $yaml = C4::Context->preference('OpacHiddenItems');
 242 if ( $yaml =~ /\S/ ) {
 243     $yaml = "$yaml\n\n"; # YAML expects trailing newline. Surplus does not hurt.
 244     eval {
 245         $hidingrules = YAML::Load($yaml);
 246     };
 247     if ($@) {
 248         warn "Unable to parse OpacHiddenItems syspref : $@";
 249     }
 250 }
 251
 252 my @sorted_itemtypes = sort { $itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes;
 253 foreach my $advanced_srch_type (@advanced_search_types) {
 254     $advanced_srch_type =~ s/^\s*//;
 255     $advanced_srch_type =~ s/\s*$//;
 256    if ($advanced_srch_type eq 'itemtypes') {
 257    # itemtype is a special case, since it's not defined in authorized values
 258         my @itypesloop;
 259         foreach my $thisitemtype ( @sorted_itemtypes ) {
 260             next if $hidingrules->{itype} && any { $_ eq $thisitemtype } @{$hidingrules->{itype}};
 261             next if $hidingrules->{itemtype} && any { $_ eq $thisitemtype } @{$hidingrules->{itemtype}};
 262             my %row =(  number=>$cnt++,
 263                 ccl => "$itype_or_itemtype,phr",
 264                 code => $thisitemtype,
 265                 description => $itemtypes->{$thisitemtype}->{translated_description},
 266                 imageurl=> getitemtypeimagelocation( 'opac', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 267                 cat => $itemtypes->{$thisitemtype}->{'iscat'},
 268                 hideinopac => $itemtypes->{$thisitemtype}->{'hideinopac'},
 269                 searchcategory => $itemtypes->{$thisitemtype}->{'searchcategory'},
 270             );
 271             if ( !$itemtypes->{$thisitemtype}->{'hideinopac'} ) {
 272                 push @itypesloop, \%row;
 273             }
 274         }
 275         my %search_code = (  advanced_search_type => $advanced_srch_type,
 276                              code_loop => \@itypesloop );
 277         push @advancedsearchesloop, \%search_code;
 278     } else {
 279     # covers all the other cases: non-itemtype authorized values
 280        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type, 'opac');
 281         my @authvalueloop;
 282         for my $thisitemtype (@$advsearchtypes) {
 283             my $hiding_key = lc $thisitemtype->{category};
 284             $hiding_key = "location" if $hiding_key eq 'loc';
 285             next if $hidingrules->{$hiding_key} && any { $_ eq $thisitemtype->{authorised_value} } @{$hidingrules->{$hiding_key}};
 286                 my %row =(
 287                                 number=>$cnt++,
 288                                 ccl => $advanced_srch_type,
 289                 code => $thisitemtype->{authorised_value},
 290                 description => $thisitemtype->{'lib_opac'} || $thisitemtype->{'lib'},
 291                 searchcategory => $itemtypes->{$thisitemtype}->{'searchcategory'},
 292                 imageurl => getitemtypeimagelocation( 'opac', $thisitemtype->{'imageurl'} ),
 293                 );
 294                 push @authvalueloop, \%row;
 295         }
 296         my %search_code = (  advanced_search_type => $advanced_srch_type,
 297                              code_loop => \@authvalueloop );
 298         push @advancedsearchesloop, \%search_code;
 299     }
 300 }
 301 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 302
 303 # The following should only be loaded if we're bringing up the advanced search template
 304 if ( $template_type && $template_type eq 'advsearch' ) {
 305     # load the servers (used for searching -- to do federated searching, etc.)
 306     my $primary_servers_loop;# = displayPrimaryServers();
 307     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 308
 309     my $secondary_servers_loop;
 310     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 311
 312     # set the default sorting
 313     if (   C4::Context->preference('OPACdefaultSortField')
 314         && C4::Context->preference('OPACdefaultSortOrder') ) {
 315         my $default_sort_by =
 316             C4::Context->preference('OPACdefaultSortField') . '_'
 317           . C4::Context->preference('OPACdefaultSortOrder');
 318         $template->param( sort_by => $default_sort_by );
 319     }
 320
 321     # determine what to display next to the search boxes (ie, boolean option
 322     # shouldn't appear on the first one, scan indexes should, adding a new
 323     # box should only appear on the last, etc.
 324     my @search_boxes_array;
 325     my $search_boxes_count = 3; # begin whith 3 boxes
 326     $template->param( search_boxes_count => $search_boxes_count );
 327
 328     if ($cgi->cookie("num_paragraph")){
 329         $search_boxes_count = $cgi->cookie("num_paragraph");
 330     }
 331
 332     for (my $i=1;$i<=$search_boxes_count;$i++) {
 333         # if it's the first one, don't display boolean option, but show scan indexes
 334         if ($i==1) {
 335             push @search_boxes_array,
 336                 {
 337                 scan_index => 1,
 338                 };
 339
 340         }
 341         # if it's the last one, show the 'add field' box
 342         elsif ($i==$search_boxes_count) {
 343             push @search_boxes_array,
 344                 {
 345                 boolean => 1,
 346                 add_field => 1,
 347                 };
 348         }
 349         else {
 350             push @search_boxes_array,
 351                 {
 352                 boolean => 1,
 353                 };
 354         }
 355
 356     }
 357
 358     my @advsearch_limits = split /,/, C4::Context->preference('OpacAdvSearchOptions');
 359     my @advsearch_more_limits = split /,/,
 360       C4::Context->preference('OpacAdvSearchMoreOptions');
 361     $template->param(
 362         uc( C4::Context->preference("marcflavour") ) => 1,    # we already did this for UNIMARC
 363         advsearch         => 1,
 364         search_boxes_loop => \@search_boxes_array,
 365         OpacAdvSearchOptions     => \@advsearch_limits,
 366         OpacAdvSearchMoreOptions => \@advsearch_more_limits,
 367     );
 368
 369     # use the global setting by default
 370     if ( C4::Context->preference("expandedSearchOption") == 1 ) {
 371         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 372     }
 373     # but let the user override it
 374     if (defined $cgi->param('expanded_options')) {
 375         if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 376             $template->param( expanded_options => scalar $cgi->param('expanded_options'));
 377         }
 378     }
 379
 380     if (C4::Context->preference('OPACNumbersPreferPhrase')) {
 381         $template->param('numbersphr' => 1);
 382     }
 383
 384     output_html_with_http_headers $cgi, $cookie, $template->output;
 385     exit;
 386 }
 387
 388 ### OK, if we're this far, we're performing an actual search
 389
 390 # Fetch the paramater list as a hash in scalar context:
 391 #  * returns paramater list as tied hash ref
 392 #  * we can edit the values by changing the key
 393 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 394 my $params = $cgi->Vars;
 395 my $tag;
 396 if ( $params->{tag} ) {
 397     $tag = $params->{tag};
 398     $template->param( tag => $tag );
 399 }
 400
 401 # String with params with the search criteria for the paging in opac-detail
 402 # param value is URI encoded and params separator is HTML encode (&amp;)
 403 my $pasarParams = '';
 404 my $j = 0;
 405 for (keys %$params) {
 406     my @pasarParam = $cgi->multi_param($_);
 407     for my $paramValue(@pasarParam) {
 408         $pasarParams .= '&amp;' if ($j > 0);
 409         $pasarParams .= $_ . '=' . uri_escape_utf8($paramValue);
 410         $j++;
 411     }
 412 }
 413
 414 # Params that can have more than one value
 415 # sort by is used to sort the query
 416 # in theory can have more than one but generally there's just one
 417 my @sort_by;
 418 my $default_sort_by;
 419 if (   C4::Context->preference('OPACdefaultSortField')
 420     && C4::Context->preference('OPACdefaultSortOrder') ) {
 421     $default_sort_by =
 422         C4::Context->preference('OPACdefaultSortField') . '_'
 423       . C4::Context->preference('OPACdefaultSortOrder');
 424 }
 425
 426 my @allowed_sortby = qw /acqdate_asc acqdate_dsc author_az author_za call_number_asc call_number_dsc popularity_asc popularity_dsc pubdate_asc pubdate_dsc relevance title_az title_za/;
 427 @sort_by = $cgi->multi_param('sort_by');
 428 $sort_by[0] = $default_sort_by if !$sort_by[0] && defined($default_sort_by);
 429 foreach my $sort (@sort_by) {
 430     if ( grep { /^$sort$/ } @allowed_sortby ) {
 431         $template->param($sort => 1);
 432     }
 433 }
 434 $template->param('sort_by' => $sort_by[0]);
 435
 436 # Use the servers defined, or just search our local catalog(default)
 437 my @servers = $cgi->multi_param('server');
 438 unless (@servers) {
 439     #FIXME: this should be handled using Context.pm
 440     @servers = ("biblioserver");
 441     # @servers = C4::Context->config("biblioserver");
 442 }
 443
 444 # operators include boolean and proximity operators and are used
 445 # to evaluate multiple operands
 446 my @operators = $cgi->multi_param('op');
 447 @operators = map { uri_unescape($_) } @operators;
 448
 449 # indexes are query qualifiers, like 'title', 'author', etc. They
 450 # can be single or multiple parameters separated by comma: kw,right-Truncation
 451 my @indexes = $cgi->multi_param('idx');
 452 @indexes = map { uri_unescape($_) } @indexes;
 453
 454 # if a simple index (only one)  display the index used in the top search box
 455 if ($indexes[0] && !$indexes[1]) {
 456     $template->param("ms_".$indexes[0] => 1);
 457 }
 458 # an operand can be a single term, a phrase, or a complete ccl query
 459 my @operands = $cgi->multi_param('q');
 460 @operands = map { uri_unescape($_) } @operands;
 461
 462 $template->{VARS}->{querystring} = join(' ', @operands);
 463
 464 # if a simple search, display the value in the search box
 465 if ($operands[0] && !$operands[1]) {
 466     my $ms_query = $operands[0];
 467     $ms_query =~ s/ #\S+//;
 468     $template->param(ms_value => $ms_query);
 469 }
 470
 471 # limits are use to limit to results to a pre-defined category such as branch or language
 472 my @limits = $cgi->multi_param('limit');
 473 @limits = map { uri_unescape($_) } @limits;
 474 my @nolimits = $cgi->multi_param('nolimit');
 475 @nolimits = map { uri_unescape($_) } @nolimits;
 476 my %is_nolimit = map { $_ => 1 } @nolimits;
 477 @limits = grep { not $is_nolimit{$_} } @limits;
 478
 479 if (@searchCategories > 0) {
 480     my @tabcat;
 481     foreach my $typecategory (@searchCategories) {
 482         my @itemtypes = Koha::ItemTypes->search({ searchcategory => $typecategory });
 483         push @tabcat, $_->itemtype for @itemtypes;
 484     }
 485
 486     foreach my $itemtypeInCategory (@tabcat) {
 487         push (@limits, "mc-$itype_or_itemtype,phr:".$itemtypeInCategory);
 488     }
 489 }
 490
 491 @limits = map { uri_unescape($_) } @limits;
 492
 493 if($params->{'multibranchlimit'}) {
 494     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 495     my @libraries = $search_group->all_libraries;
 496     my $multibranch = '('.join( " or ", map { 'branch: ' . $_->id } @libraries ) .')';
 497     push @limits, $multibranch if ($multibranch ne  '()');
 498 }
 499
 500 my $available;
 501 foreach my $limit(@limits) {
 502     if ($limit =~/available/) {
 503         $available = 1;
 504     }
 505 }
 506 $template->param(available => $available);
 507
 508 # append year limits if they exist
 509 if ($params->{'limit-yr'}) {
 510     if ($params->{'limit-yr'} =~ /\d{4}/) {
 511         push @limits, "yr,st-numeric=$params->{'limit-yr'}";
 512     }
 513     else {
 514         #FIXME: Should return a error to the user, incorect date format specified
 515     }
 516 }
 517
 518 # Params that can only have one value
 519 my $scan = $params->{'scan'};
 520 my $count = C4::Context->preference('OPACnumSearchResults') || 20;
 521 my $countRSS         = C4::Context->preference('numSearchRSSResults') || 50;
 522 my $results_per_page = $params->{'count'} || $count;
 523 my $offset = $params->{'offset'} || 0;
 524 $offset = 0 if $offset < 0;
 525 my $page = $cgi->param('page') || 1;
 526 $offset = ($page-1)*$results_per_page if $page>1;
 527 my $hits;
 528 my $expanded_facet = $params->{'expand'};
 529
 530 # Define some global variables
 531 my ($error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 532
 533 my @results;
 534
 535 my $suppress = 0;
 536 if (C4::Context->preference('OpacSuppression')) {
 537     # OPAC suppression by IP address
 538     if (C4::Context->preference('OpacSuppressionByIPRange')) {
 539         my $IPAddress = $ENV{'REMOTE_ADDR'};
 540         my $IPRange = C4::Context->preference('OpacSuppressionByIPRange');
 541         $suppress = ($IPAddress !~ /^$IPRange/);
 542     }
 543     else {
 544         $suppress = 1;
 545     }
 546 }
 547
 548 ## I. BUILD THE QUERY
 549 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type)
 550   = $builder->build_query_compat(
 551     \@operators,
 552     \@operands,
 553     \@indexes,
 554     \@limits,
 555     \@sort_by,
 556     0,
 557     $lang,
 558     { expanded_facet => $expanded_facet, suppress => $suppress }
 559     );
 560
 561 sub _input_cgi_parse {
 562     my @elements;
 563     my $query_cgi = shift or return @elements;
 564     for my $this_cgi ( split('&',$query_cgi) ) {
 565         next unless $this_cgi;
 566         $this_cgi =~ /(.*?)=(.*)/;
 567         push @elements, { input_name => $1, input_value => Encode::decode_utf8( uri_unescape($2) ) };
 568     }
 569     return @elements;
 570 }
 571
 572 ## parse the query_cgi string and put it into a form suitable for <input>s
 573 my @query_inputs = _input_cgi_parse($query_cgi);
 574 $template->param ( QUERY_INPUTS => \@query_inputs );
 575
 576 ## parse the limit_cgi string and put it into a form suitable for <input>s
 577 my @limit_inputs = $limit_cgi ? _input_cgi_parse($limit_cgi) : ();
 578
 579 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 580 $template->param ( OPACResultsSidebar => C4::Context->preference('OPACResultsSidebar'));
 581
 582 ## II. DO THE SEARCH AND GET THE RESULTS
 583 my $total = 0; # the total results for the whole set
 584 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 585 my @results_array;
 586 my $results_hashref;
 587 my @coins;
 588
 589 if ($tag) {
 590     $query_cgi = "tag=" .$tag . "&" . $query_cgi;
 591     my $taglist = get_tags({term=>$tag, approved=>1});
 592     $results_hashref->{biblioserver}->{hits} = scalar (@$taglist);
 593     my @marclist = map { C4::Biblio::GetXmlBiblio( $_->{biblionumber} ) } @$taglist;
 594     $DEBUG and printf STDERR "taglist (%s biblionumber)\nmarclist (%s records)\n", scalar(@$taglist), scalar(@marclist);
 595     $results_hashref->{biblioserver}->{RECORDS} = \@marclist;
 596     # FIXME: tag search and standard search should work together, not exclusively
 597     # FIXME: No facets for tags search.
 598 } elsif ($build_grouped_results) {
 599     eval {
 600         ($error, $results_hashref, $facets) = C4::Search::pazGetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,undef,$query_type,$scan);
 601     };
 602 } else {
 603     $pasarParams .= '&amp;query=' . uri_escape_utf8($query);
 604     $pasarParams .= '&amp;count=' . uri_escape_utf8($results_per_page);
 605     $pasarParams .= '&amp;simple_query=' . uri_escape_utf8($simple_query);
 606     $pasarParams .= '&amp;query_type=' . uri_escape_utf8($query_type) if ($query_type);
 607     my $itemtypes_nocategory = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 608     eval {
 609         ($error, $results_hashref, $facets) = $searcher->search_compat($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,undef,$itemtypes_nocategory,$query_type,$scan,1);
 610 };
 611 }
 612
 613 # use Data::Dumper; print STDERR "-" x 25, "\n", Dumper($results_hashref);
 614 if (not $tag and ( $@ || $error)) {
 615     $template->param(query_error => $error.$@);
 616     output_html_with_http_headers $cgi, $cookie, $template->output;
 617     exit;
 618 }
 619
 620 # At this point, each server has given us a result set
 621 # now we build that set for template display
 622 my @sup_results_array;
 623 for (my $i=0;$i<@servers;$i++) {
 624     my $server = $servers[$i];
 625     if ($server && $server =~/biblioserver/) { # this is the local bibliographic server
 626         $hits = $results_hashref->{$server}->{"hits"};
 627         my $page = $cgi->param('page') || 0;
 628         my @newresults;
 629         if ($build_grouped_results) {
 630             foreach my $group (@{ $results_hashref->{$server}->{"GROUPS"} }) {
 631                 # because pazGetRecords handles retieving only the records
 632                 # we want as specified by $offset and $results_per_page,
 633                 # we need to set the offset parameter of searchResults to 0
 634                 my @group_results = searchResults( 'opac', $query_desc, $group->{'group_count'},$results_per_page, 0, $scan,
 635                                                    $group->{"RECORDS"});
 636                 push @newresults, { group_label => $group->{'group_label'}, GROUP_RESULTS => \@group_results };
 637             }
 638         } else {
 639             @newresults = searchResults('opac', $query_desc, $hits, $results_per_page, $offset, $scan,
 640                                         $results_hashref->{$server}->{"RECORDS"});
 641         }
 642         $hits = 0 unless @newresults;
 643
 644         foreach my $res (@newresults) {
 645
 646             # must define a value for size if not present in DB
 647             # in order to avoid problems generated by the default size value in TT
 648             if ( not exists $res->{'size'} ) { $res->{'size'} = "" }
 649             # while we're checking each line, see if item is in the cart
 650             if ( grep {$_ eq $res->{'biblionumber'}} @cart_list) {
 651                 $res->{'incart'} = 1;
 652             }
 653
 654             if (C4::Context->preference('COinSinOPACResults')) {
 655                 my $record = GetMarcBiblio({ biblionumber => $res->{'biblionumber'} });
 656                 $res->{coins} = GetCOinSBiblio($record);
 657             }
 658             if ( C4::Context->preference( "Babeltheque" ) and $res->{normalized_isbn} ) {
 659                 if( my $isbn = Business::ISBN->new( $res->{normalized_isbn} ) ) {
 660                     $isbn = $isbn->as_isbn13->as_string;
 661                     $isbn =~ s/-//g;
 662                     my $social_datas = C4::SocialData::get_data( $isbn );
 663                     if ( $social_datas ) {
 664                         for my $key ( keys %$social_datas ) {
 665                             $res->{$key} = $$social_datas{$key};
 666                             if ( $key eq 'score_avg' ){
 667                                 $res->{score_int} = sprintf("%.0f", $$social_datas{score_avg} );
 668                             }
 669                         }
 670                     }
 671                 }
 672             }
 673
 674             if (C4::Context->preference('TagsEnabled') and
 675                 C4::Context->preference('TagsShowOnList')) {
 676                 if ( my $bibnum = $res->{biblionumber} ) {
 677                     $res->{itemsissued} = CountItemsIssued( $bibnum );
 678                     $res->{'TagLoop'} = get_tags({
 679                         biblionumber => $bibnum,
 680                         approved => 1,
 681                         sort => '-weight',
 682                         limit => C4::Context->preference('TagsShowOnList')
 683                     });
 684                 }
 685             }
 686
 687             $res->{shelves} = Koha::Virtualshelves->get_shelves_containing_record(
 688                 {
 689                     biblionumber   => $res->{biblionumber},
 690                     borrowernumber => $borrowernumber
 691                 }
 692             );
 693
 694             if ( C4::Context->preference('OpacStarRatings') eq 'all' ) {
 695                 my $ratings = Koha::Ratings->search({ biblionumber => $res->{biblionumber} });
 696                 $res->{ratings} = $ratings;
 697                 $res->{my_rating} = $borrowernumber ? $ratings->search({ borrowernumber => $borrowernumber })->next : undef;
 698             }
 699         }
 700
 701         if ($results_hashref->{$server}->{"hits"}){
 702             $total = $total + $hits;
 703         }
 704
 705         # Opac search history
 706         if (C4::Context->preference('EnableOpacSearchHistory')) {
 707             unless ( $offset ) {
 708                 my $path_info = $cgi->url(-path_info=>1);
 709                 my $query_cgi_history = $cgi->url(-query=>1);
 710                 $query_cgi_history =~ s/^$path_info\?//;
 711                 $query_cgi_history =~ s/;/&/g;
 712                 my $query_desc_history = join ", ", grep { defined $_ } $query_desc, $limit_desc;
 713
 714                 unless ( $borrowernumber ) {
 715                     my $new_searches = C4::Search::History::add_to_session({
 716                             cgi => $cgi,
 717                             query_desc => $query_desc_history,
 718                             query_cgi => $query_cgi_history,
 719                             total => $total,
 720                             type => "biblio",
 721                     });
 722                 } else {
 723                     # To the session (the user is logged in)
 724                     C4::Search::History::add({
 725                         userid => $borrowernumber,
 726                         sessionid => $cgi->cookie("CGISESSID"),
 727                         query_desc => $query_desc_history,
 728                         query_cgi => $query_cgi_history,
 729                         total => $total,
 730                         type => "biblio",
 731                     });
 732                 }
 733             }
 734             $template->param( EnableOpacSearchHistory => 1 );
 735         }
 736
 737         ## If there's just one result, redirect to the detail page
 738         if ($total == 1 && $format ne 'rss2'
 739         && $format ne 'opensearchdescription' && $format ne 'atom') {
 740             my $biblionumber=$newresults[0]->{biblionumber};
 741             if (C4::Context->preference('BiblioDefaultView') eq 'isbd') {
 742                 print $cgi->redirect("/cgi-bin/koha/opac-ISBDdetail.pl?biblionumber=$biblionumber");
 743             } elsif  (C4::Context->preference('BiblioDefaultView') eq 'marc') {
 744                 print $cgi->redirect("/cgi-bin/koha/opac-MARCdetail.pl?biblionumber=$biblionumber");
 745             } else {
 746                 print $cgi->redirect("/cgi-bin/koha/opac-detail.pl?biblionumber=$biblionumber");
 747             }
 748             exit;
 749         }
 750         if ($hits) {
 751             if ( !$build_grouped_results ) {
 752                 # We build the encrypted list of first OPACnumSearchResults biblios to pass with the search criteria for paging on opac-detail
 753                 $pasarParams .= '&amp;listBiblios=';
 754                 my $j = 0;
 755                 foreach (@newresults) {
 756                     my $bibnum = ($_->{biblionumber})?$_->{biblionumber}:0;
 757                     $pasarParams .= uri_escape_utf8($bibnum) . ',';
 758                     $j++;
 759                     last if ($j == $results_per_page);
 760                 }
 761                 chop $pasarParams if ($pasarParams =~ /,$/);
 762                 $pasarParams .= '&amp;total=' . uri_escape_utf8( int($total) ) if ($pasarParams !~ /total=(?:[0-9]+)?/);
 763                 if ($pasarParams) {
 764                     my $session = get_session($cgi->cookie("CGISESSID"));
 765                     $session->param('busc' => $pasarParams);
 766                 }
 767                 #
 768             }
 769             $template->param(total => $hits);
 770             my $limit_cgi_not_availablity = $limit_cgi;
 771             $limit_cgi_not_availablity =~ s/&limit=available//g if defined $limit_cgi_not_availablity;
 772             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 773             $template->param(limit_cgi => $limit_cgi);
 774             $template->param(countrss  => $countRSS );
 775             $template->param(query_cgi => $query_cgi);
 776             $template->param(query_desc => $query_desc);
 777             $template->param(limit_desc => $limit_desc);
 778             $template->param(offset     => $offset);
 779             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 780             if ($query_desc || $limit_desc) {
 781                 $template->param(searchdesc => 1);
 782             }
 783             $template->param(results_per_page =>  $results_per_page);
 784             my $hide = C4::Context->preference('OpacHiddenItems');
 785             $hide = ($hide =~ m/\S/) if $hide; # Just in case it has some spaces/new lines
 786             my $branch = '';
 787             if (C4::Context->userenv){
 788                 $branch = C4::Context->userenv->{branch};
 789             }
 790             if ( C4::Context->preference('HighlightOwnItemsOnOPAC') ) {
 791                 if (
 792                     ( ( C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'PatronBranch' ) && $branch )
 793                     ||
 794                     C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'OpacURLBranch'
 795                 ) {
 796                     my $branchcode;
 797                     if ( C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'PatronBranch' ) {
 798                         $branchcode = $branch;
 799                     }
 800                     elsif (  C4::Context->preference('HighlightOwnItemsOnOPACWhich') eq 'OpacURLBranch' ) {
 801                         $branchcode = $ENV{'BRANCHCODE'};
 802                     }
 803
 804                     foreach my $res ( @newresults ) {
 805                         my @new_loop;
 806                         my @top_loop;
 807                         my @old_loop = @{$res->{'available_items_loop'}};
 808                         foreach my $item ( @old_loop ) {
 809                             if ( $item->{'branchcode'} eq $branchcode ) {
 810                                 $item->{'this_branch'} = 1;
 811                                 push( @top_loop, $item );
 812                             } else {
 813                                 push( @new_loop, $item );
 814                             }
 815                         }
 816                         my @complete_loop = ( @top_loop, @new_loop );
 817                         $res->{'available_items_loop'} = \@complete_loop;
 818                     }
 819                 }
 820             }
 821
 822             $template->param(
 823                 SEARCH_RESULTS => \@newresults,
 824                 OPACItemsResultsDisplay => (C4::Context->preference("OPACItemsResultsDisplay")),
 825                 suppress_result_number => $hide,
 826                             );
 827             if (C4::Context->preference("OPACLocalCoverImages")){
 828                 $template->param(OPACLocalCoverImages => 1);
 829                 $template->param(OPACLocalCoverImagesPriority => C4::Context->preference("OPACLocalCoverImagesPriority"));
 830             }
 831             ## Build the page numbers on the bottom of the page
 832             my @page_numbers;
 833             # total number of pages there will be
 834             my $pages = ceil($hits / $results_per_page);
 835             my $last_page_offset = ( $pages - 1 ) * $results_per_page;
 836             # default page number
 837             my $current_page_number = 1;
 838             if ($offset) {
 839                 $current_page_number = ( $offset / $results_per_page + 1 );
 840             }
 841             my $previous_page_offset;
 842             if ( $offset >= $results_per_page ) {
 843                 $previous_page_offset = $offset - $results_per_page;
 844             }
 845             my $next_page_offset = $offset + $results_per_page;
 846             # If we're within the first 10 pages, keep it simple
 847             #warn "current page:".$current_page_number;
 848             if ($current_page_number < 10) {
 849                 # just show the first 10 pages
 850                 # Loop through the pages
 851                 my $pages_to_show = 10;
 852                 $pages_to_show = $pages if $pages<10;
 853                 for ($i=1; $i<=$pages_to_show;$i++) {
 854                     # the offset for this page
 855                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 856                     # the page number for this page
 857                     my $this_page_number = $i;
 858                     # put it in the array
 859                     push @page_numbers,
 860                       { offset    => $this_offset,
 861                         pg        => $this_page_number,
 862                         highlight => $this_page_number == $current_page_number,
 863                         sort_by   => join ' ', @sort_by
 864                       };
 865
 866                 }
 867
 868             }
 869             # now, show twenty pages, with the current one smack in the middle
 870             else {
 871                 for ($i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 872                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 873                     my $this_page_number = $i-9;
 874                     if ( $this_page_number <= $pages ) {
 875                         push @page_numbers,
 876                           { offset    => $this_offset,
 877                             pg        => $this_page_number,
 878                             highlight => $this_page_number == $current_page_number,
 879                             sort_by => join ' ', @sort_by
 880                           };
 881                     }
 882                 }
 883
 884             }
 885             $template->param(   PAGE_NUMBERS => \@page_numbers,
 886                                 last_page_offset => $last_page_offset,
 887                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 888             $template->param(next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 889         }
 890         # no hits
 891         else {
 892             my $nohits = C4::Context->preference('OPACNoResultsFound');
 893             if ($nohits and $nohits=~/{QUERY_KW}/){
 894                 # extracting keywords in case of relaunching search
 895                 (my $query_kw=$query_desc)=~s/ and|or / /g;
 896                 my @query_kw=($query_kw=~ /([-\w]+\b)(?:[^,:]|$)/g);
 897                 $query_kw=join('+',@query_kw);
 898                 $nohits=~s/{QUERY_KW}/$query_kw/g;
 899                 $template->param('OPACNoResultsFound' =>$nohits);
 900             }
 901             $template->param(
 902                 searchdesc => 1,
 903                 query_desc => $query_desc,
 904                 limit_desc => $limit_desc,
 905                 query_cgi  => $query_cgi,
 906                 limit_cgi  => $limit_cgi
 907             );
 908         }
 909     } # end of the if local
 910     # asynchronously search the authority server
 911     elsif ($server && $server =~/authorityserver/) { # this is the local authority server
 912         my @inner_sup_results_array;
 913         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 914             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 915             my $title_field = $marc_record_object->field(100);
 916             push @inner_sup_results_array, {
 917                 'title' => $title_field->subfield('a'),
 918                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 919             };
 920         }
 921         my $servername = $server;
 922         push @sup_results_array, {  servername => $servername,
 923                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 924     }
 925     # FIXME: can add support for other targets as needed here
 926     $template->param(           outer_sup_results_loop => \@sup_results_array);
 927 } #/end of the for loop
 928 #$template->param(FEDERATED_RESULTS => \@results_array);
 929
 930 for my $facet ( @$facets ) {
 931     for my $entry ( @{ $facet->{facets} } ) {
 932         my $index = $entry->{type_link_value};
 933         my $value = $entry->{facet_link_value};
 934         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 935     }
 936 }
 937
 938
 939 $template->param(
 940             #classlist => $classlist,
 941             total => $total,
 942             opacfacets => 1,
 943             facets_loop => $facets,
 944             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 945             scan => $scan,
 946             search_error => $error,
 947 );
 948
 949 if ($query_desc || $limit_desc) {
 950     $template->param(searchdesc => 1);
 951 }
 952
 953 # VI. BUILD THE TEMPLATE
 954 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 955     {
 956         borrowernumber => $borrowernumber,
 957         add_allowed    => 1,
 958         category       => 1,
 959     }
 960 );
 961 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 962     {
 963         borrowernumber => $borrowernumber,
 964         add_allowed    => 1,
 965         category       => 2,
 966     }
 967 );
 968
 969 $template->param(
 970     add_to_some_private_shelves => $some_private_shelves,
 971     add_to_some_public_shelves  => $some_public_shelves,
 972 );
 973
 974 my $content_type = ($format eq 'rss' or $format eq 'atom') ? $format : 'html';
 975
 976 # If GoogleIndicTransliteration system preference is On Set parameter to load Google's javascript in OPAC search screens
 977 if (C4::Context->preference('GoogleIndicTransliteration')) {
 978         $template->param('GoogleIndicTransliteration' => 1);
 979 }
 980
 981 $template->{VARS}->{DidYouMean} =
 982   ( defined C4::Context->preference('OPACdidyoumean')
 983       && C4::Context->preference('OPACdidyoumean') =~ m/enable/ );
 984 $template->{VARS}->{IDreamBooksReviews} = C4::Context->preference('IDreamBooksReviews');
 985 $template->{VARS}->{IDreamBooksReadometer} = C4::Context->preference('IDreamBooksReadometer');
 986 $template->{VARS}->{IDreamBooksResults} = C4::Context->preference('IDreamBooksResults');
 987
 988 if ($offset == 0 && IsOverDriveEnabled()) {
 989     $template->param(OverDriveEnabled => 1);
 990     $template->param(OverDriveLibraryID => C4::Context->preference('OverDriveLibraryID'));
 991 }
 992
 993     $template->param( borrowernumber    => $borrowernumber);
 994 output_with_http_headers $cgi, $cookie, $template->output, $content_type;