Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use C4::Context;
  24
  25 use base 'Exporter';
  26 use version; our $VERSION = qv('1.0.0');
  27
  28 our @EXPORT = (
  29     qw( dt_from_string output_pref format_sqldatetime )
  30 );
  31
  32 =head1 DateUtils
  33
  34 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  35
  36 =head1 DESCRIPTION
  37
  38 Koha has historically only used dates not datetimes and been content to
  39 handle these as strings. It also has confused formatting with actual dates
  40 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  41
  42 =cut
  43
  44 =head2 dt_ftom_string
  45
  46 $dt = dt_from_string($date_string, [$format, $timezone ]);
  47
  48 Passed a date string returns a DateTime object format and timezone default
  49 to the system preferences. If the date string is empty DateTime->now is returned
  50
  51 =cut
  52
  53 sub dt_from_string {
  54     my ( $date_string, $date_format, $tz ) = @_;
  55
  56     return if $date_string and $date_string =~ m|^0000-0|;
  57
  58     $tz = C4::Context->tz unless $tz;;
  59
  60     return DateTime->now( time_zone => $tz ) unless $date_string;
  61
  62     $date_format = C4::Context->preference('dateformat') unless $date_format;
  63
  64     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  65         return $date_string;
  66     }
  67
  68     my $regex;
  69
  70     # The fallback format is sql/iso
  71     my $fallback_re = qr|
  72         (?<year>\d{4})
  73         -
  74         (?<month>\d{2})
  75         -
  76         (?<day>\d{2})
  77     |xms;
  78
  79     if ( $date_format eq 'metric' ) {
  80         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  81         $regex = qr|
  82             (?<day>\d{2})
  83             /
  84             (?<month>\d{2})
  85             /
  86             (?<year>\d{4})
  87         |xms;
  88     }
  89     elsif ( $date_format eq 'us' ) {
  90         # us format is "mm/dd/yyyy[ hh:mm:ss]"
  91         $regex = qr|
  92             (?<month>\d{2})
  93             /
  94             (?<day>\d{2})
  95             /
  96             (?<year>\d{4})
  97         |xms;
  98     }
  99     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 100         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 101         $regex = $fallback_re;
 102     }
 103     else {
 104         die "Invalid dateformat parameter ($date_format)";
 105     }
 106
 107     # Add the faculative time part [hh:mm[:ss]]
 108     my $time_re .= qr|
 109             (
 110                 \s*
 111                 (?<hour>\d{2})
 112                 :
 113                 (?<minute>\d{2})
 114                 (
 115                     :
 116                     (?<second>\d{2})
 117                 )?
 118             )?
 119     |xms;
 120     $regex .= $time_re;
 121     $fallback_re .= $time_re;
 122
 123     my %dt_params;
 124     if ( $date_string =~ $regex ) {
 125         %dt_params = (
 126             year   => $+{year},
 127             month  => $+{month},
 128             day    => $+{day},
 129             hour   => $+{hour},
 130             minute => $+{minute},
 131             second => $+{second},
 132         );
 133     } elsif ( $date_string =~ $fallback_re ) {
 134         %dt_params = (
 135             year   => $+{year},
 136             month  => $+{month},
 137             day    => $+{day},
 138             hour   => $+{hour},
 139             minute => $+{minute},
 140             second => $+{second},
 141         );
 142     }
 143     else {
 144         die "The given date ($date_string) does not match the date format ($date_format)";
 145     }
 146
 147     # system allows the 0th of the month
 148     $dt_params{day} = '01' if $dt_params{day} eq '00';
 149
 150     # Set default hh:mm:ss to 00:00:00
 151     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 152     $dt_params{minute} = 00 unless defined $dt_params{minute};
 153     $dt_params{second} = 00 unless defined $dt_params{second};
 154
 155     my $dt = eval {
 156         DateTime->new(
 157             %dt_params,
 158             # No TZ for dates 'infinite' => see bug 13242
 159             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 160         );
 161     };
 162     if ($@) {
 163         $tz = DateTime::TimeZone->new( name => 'floating' );
 164         $dt = DateTime->new(
 165             %dt_params,
 166             # No TZ for dates 'infinite' => see bug 13242
 167             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 168         );
 169     }
 170     return $dt;
 171 }
 172
 173 =head2 output_pref
 174
 175 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 176 $date_string = output_pref( $dt );
 177
 178 Returns a string containing the time & date formatted as per the C4::Context setting,
 179 or C<undef> if C<undef> was provided.
 180
 181 This routine can either be passed a DateTime object or or a hashref.  If it is
 182 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 183 an optional 'dateformat' to override the dateformat system preference, an
 184 optional 'timeformat' to override the TimeFormat system preference value,
 185 and an optional 'dateonly' to specify that only the formatted date string
 186 should be returned without the time.
 187
 188 =cut
 189
 190 sub output_pref {
 191     my $params = shift;
 192     my ( $dt, $force_pref, $force_time, $dateonly, $as_due_date );
 193     if ( ref $params eq 'HASH' ) {
 194         $dt         = $params->{dt};
 195         $force_pref = $params->{dateformat};         # if testing we want to override Context
 196         $force_time = $params->{timeformat};
 197         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 198         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 199     } else {
 200         $dt = $params;
 201     }
 202
 203     return unless defined $dt;
 204
 205     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 206     if ( $dt->ymd !~ /^9999/ ) {
 207         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 208         $dt->set_time_zone( $tz );
 209     }
 210
 211     my $pref =
 212       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 213
 214     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 215     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 216     my $date;
 217     if ( $pref =~ m/^iso/ ) {
 218         $date = $dateonly
 219           ? $dt->strftime("%Y-%m-%d")
 220           : $dt->strftime("%Y-%m-%d $time");
 221     }
 222     elsif ( $pref =~ m/^metric/ ) {
 223         $date = $dateonly
 224           ? $dt->strftime("%d/%m/%Y")
 225           : $dt->strftime("%d/%m/%Y $time");
 226     }
 227     elsif ( $pref =~ m/^us/ ) {
 228         $date = $dateonly
 229           ? $dt->strftime("%m/%d/%Y")
 230           : $dt->strftime("%m/%d/%Y $time");
 231     }
 232     else {
 233         $date = $dateonly
 234           ? $dt->strftime("%Y-%m-%d")
 235           : $dt->strftime("%Y-%m-%d $time");
 236     }
 237
 238     if ( $as_due_date ) {
 239         $time_format eq '12hr'
 240             ? $date =~ s| 11:59 PM$||
 241             : $date =~ s| 23:59$||;
 242     }
 243
 244     return $date;
 245 }
 246
 247 =head2 format_sqldatetime
 248
 249 $string = format_sqldatetime( $string_as_returned_from_db );
 250
 251 a convenience routine for calling dt_from_string and formatting the result
 252 with output_pref as it is a frequent activity in scripts
 253
 254 =cut
 255
 256 sub format_sqldatetime {
 257     my $str        = shift;
 258     my $force_pref = shift;    # if testing we want to override Context
 259     my $force_time = shift;
 260     my $dateonly   = shift;
 261
 262     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 263         my $dt = dt_from_string( $str, 'sql' );
 264         return q{} unless $dt;
 265         $dt->truncate( to => 'minute' );
 266         return output_pref({
 267             dt => $dt,
 268             dateformat => $force_pref,
 269             timeformat => $force_time,
 270             dateonly => $dateonly
 271         });
 272     }
 273     return q{};
 274 }
 275
 276 1;