opac/opac-sendbasket.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Doxulting 2004
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw(encode);
  24 use Carp;
  25 use Mail::Sendmail;
  26 use MIME::QuotedPrint;
  27 use MIME::Base64;
  28
  29 use C4::Biblio;
  30 use C4::Items;
  31 use C4::Auth;
  32 use C4::Output;
  33 use C4::Members;
  34 use C4::Templates ();
  35 use Koha::Email;
  36 use Koha::Patrons;
  37 use Koha::Token;
  38
  39 my $query = new CGI;
  40
  41 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  42     {
  43         template_name   => "opac-sendbasketform.tt",
  44         query           => $query,
  45         type            => "opac",
  46         authnotrequired => 0,
  47     }
  48 );
  49
  50 my $bib_list     = $query->param('bib_list') || '';
  51 my $email_add    = $query->param('email_add');
  52
  53 my $dbh          = C4::Context->dbh;
  54
  55 if ( $email_add ) {
  56     die "Wrong CSRF token" unless Koha::Token->new->check_csrf({
  57         session_id => scalar $query->cookie('CGISESSID'),
  58         token  => scalar $query->param('csrf_token'),
  59     });
  60     my $email = Koha::Email->new();
  61     my $patron = Koha::Patrons->find( $borrowernumber );
  62     my $user_email = GetFirstValidEmailAddress($borrowernumber)
  63     || C4::Context->preference('KohaAdminEmailAddress');
  64
  65     my $email_replyto = $patron->firstname . " " . $patron->surname . " <$user_email>";
  66     my $comment    = $query->param('comment');
  67
  68    # if you want to use the KohaAdmin address as from, that is the default no need to set it
  69     my %mail = $email->create_message_headers({
  70         to => $email_add,
  71         replyto => $email_replyto,
  72     });
  73     $mail{'X-Abuse-Report'} = C4::Context->preference('KohaAdminEmailAddress');
  74
  75     # Since we are already logged in, no need to check credentials again
  76     # when loading a second template.
  77     my $template2 = C4::Templates::gettemplate(
  78         'opac-sendbasket.tt', 'opac', $query,
  79     );
  80
  81     my @bibs = split( /\//, $bib_list );
  82     my @results;
  83     my $iso2709;
  84     my $marcflavour = C4::Context->preference('marcflavour');
  85     foreach my $biblionumber (@bibs) {
  86         $template2->param( biblionumber => $biblionumber );
  87
  88         my $dat              = GetBiblioData($biblionumber);
  89         next unless $dat;
  90         my $record           = GetMarcBiblio($biblionumber, 1);
  91         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  92         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  93
  94         my @items = GetItemsInfo( $biblionumber );
  95
  96         my $hasauthors = 0;
  97         if($dat->{'author'} || @$marcauthorsarray) {
  98           $hasauthors = 1;
  99         }
 100
 101
 102         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
 103         $dat->{MARCAUTHORS}    = $marcauthorsarray;
 104         $dat->{HASAUTHORS}     = $hasauthors;
 105         $dat->{'biblionumber'} = $biblionumber;
 106         $dat->{ITEM_RESULTS}   = \@items;
 107
 108         $iso2709 .= $record->as_usmarc();
 109
 110         push( @results, $dat );
 111     }
 112
 113     my $resultsarray = \@results;
 114
 115     $template2->param(
 116         BIBLIO_RESULTS => $resultsarray,
 117         comment        => $comment,
 118         firstname      => $patron->firstname,
 119         surname        => $patron->surname,
 120     );
 121
 122     # Getting template result
 123     my $template_res = $template2->output();
 124     my $body;
 125
 126     # Analysing information and getting mail properties
 127
 128     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 129         $mail{subject} = $1;
 130         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 131         $mail{subject} = Encode::encode("UTF-8", $mail{subject});
 132     }
 133     else { $mail{'subject'} = "no subject"; }
 134
 135     my $email_header = "";
 136     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 137         $email_header = $1;
 138         $email_header =~ s|\n?(.*)\n?|$1|;
 139         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 140     }
 141
 142     my $email_file = "basket.txt";
 143     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 144         $email_file = $1;
 145         $email_file =~ s|\n?(.*)\n?|$1|;
 146     }
 147
 148     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 149         $body = $1;
 150         $body =~ s|\n?(.*)\n?|$1|;
 151         $body = encode_qp(Encode::encode("UTF-8", $body));
 152     }
 153
 154     $mail{body} = $body;
 155
 156     my $boundary = "====" . time() . "====";
 157
 158     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 159     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 160     $boundary = '--' . $boundary;
 161     $mail{body} = <<END_OF_BODY;
 162 $boundary
 163 MIME-Version: 1.0
 164 Content-Type: text/plain; charset="UTF-8"
 165 Content-Transfer-Encoding: quoted-printable
 166
 167 $email_header
 168 $body
 169 $boundary
 170 Content-Type: application/octet-stream; name="basket.iso2709"
 171 Content-Transfer-Encoding: base64
 172 Content-Disposition: attachment; filename="basket.iso2709"
 173
 174 $isofile
 175 $boundary--
 176 END_OF_BODY
 177
 178     # Sending mail (if not empty basket)
 179     if ( defined($iso2709) && sendmail %mail ) {
 180     # do something if it works....
 181         $template->param( SENT      => "1" );
 182     }
 183     else {
 184         # do something if it doesnt work....
 185     carp "Error sending mail: empty basket" if !defined($iso2709);
 186         carp "Error sending mail: $Mail::Sendmail::error" if $Mail::Sendmail::error;
 187         $template->param( error => 1 );
 188     }
 189     $template->param( email_add => $email_add );
 190     output_html_with_http_headers $query, $cookie, $template->output;
 191 }
 192 else {
 193     $template->param(
 194         bib_list       => $bib_list,
 195         url            => "/cgi-bin/koha/opac-sendbasket.pl",
 196         suggestion     => C4::Context->preference("suggestion"),
 197         virtualshelves => C4::Context->preference("virtualshelves"),
 198         csrf_token => Koha::Token->new->generate_csrf(
 199             { session_id => scalar $query->cookie('CGISESSID'), } ),
 200     );
 201     output_html_with_http_headers $query, $cookie, $template->output;
 202 }