acqui/pdfformat/layout3pages.pm

   1 #!/usr/bin/perl
   2
   3 #example script to print a basketgroup
   4 #written 07/11/08 by john.soros@biblibre.com and paul.poulain@biblibre.com
   5
   6 # Copyright 2008-2009 BibLibre SARL
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 #you can use any PDF::API2 module, all you need to do is return the stringifyed pdf object from the printpdf sub.
  24 package pdfformat::layout3pages;
  25 use vars qw($VERSION @ISA @EXPORT);
  26 use MIME::Base64;
  27 use List::MoreUtils qw/uniq/;
  28 use strict;
  29 use warnings;
  30 use utf8;
  31
  32 use C4::Branch qw(GetBranchDetail GetBranchName);
  33
  34 use Koha::Number::Price;
  35 use Koha::DateUtils;
  36
  37 BEGIN {
  38          use Exporter   ();
  39          our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  40         # set the version for version checking
  41          $VERSION     = 1.00;
  42         @ISA    = qw(Exporter);
  43         @EXPORT = qw(printpdf);
  44 }
  45
  46
  47 #be careful, all the sizes (height, width, etc...) are in mm, not PostScript points (the default measurment of PDF::API2).
  48 #The constants exported transform that into PostScript points (/mm for milimeter, /in for inch, pt is postscript point, and as so is there only to show what is happening.
  49 use constant mm => 25.4 / 72;
  50 use constant in => 1 / 72;
  51 use constant pt => 1;
  52
  53 use PDF::API2;
  54 #A4 paper specs
  55 my ($height, $width) = (297, 210);
  56 use PDF::Table;
  57
  58 sub printorders {
  59     my ($pdf, $basketgroup, $baskets, $orders) = @_;
  60
  61     my $cur_format = C4::Context->preference("CurrencyFormat");
  62
  63     $pdf->mediabox($height/mm, $width/mm);
  64     my $number = 3;
  65     for my $basket (@$baskets){
  66         my $page = $pdf->page();
  67
  68         # print basket header (box)
  69         my $box = $page->gfx;
  70         $box->rectxy(($width - 10)/mm, ($height - 5)/mm, 10/mm, ($height - 25)/mm);
  71         $box->stroke;
  72 #         $box->restore();
  73
  74         # create a text
  75         my $text = $page->text;
  76         # add basketgroup number
  77         $text->font( $pdf->corefont("Times", -encoding => "utf8"), 6/mm );
  78         $text->translate(20/mm,  ($height-15)/mm);
  79         $text->text("Order no. ".$basketgroup->{'id'}.". Basket no. ".$basket->{basketno}.". ".$basket->{booksellernote});
  80         $text->translate(20/mm,  ($height-20)/mm);
  81         $text->font( $pdf->corefont("Times", -encoding => "utf8"), 4/mm );
  82         $text->text( ( $basket->{billingplace} ? "Billing at " . C4::Branch::GetBranchName( $basket->{billingplace} ) : "" )
  83             . ( $basket->{billingplace} and $basket->{deliveryplace} ? " and " : "" )
  84             . ( $basket->{deliveryplace} ? "delivery at " . C4::Branch::GetBranchName( $basket->{deliveryplace}) : "" )
  85         );
  86
  87         my $pdftable = new PDF::Table();
  88         my $abaskets;
  89         my $arrbasket;
  90         my @keys = ('Document', 'Qty', 'RRP tax exc.', 'RRP tax inc.', 'Discount', 'Discount price', 'GST rate', 'Total tax exc.', 'Total tax inc.');
  91         for my $bkey (@keys) {
  92             push(@$arrbasket, $bkey);
  93         }
  94         push(@$abaskets, $arrbasket);
  95
  96         my $titleinfo;
  97         foreach my $line (@{$orders->{$basket->{basketno}}}) {
  98             $arrbasket = undef;
  99             $titleinfo = "";
 100             if ( C4::Context->preference("marcflavour") eq 'UNIMARC' ) {
 101                 $titleinfo =  $line->{title} . " / " . $line->{author} .
 102                     ( $line->{isbn} ? " ISBN: " . $line->{isbn} : '' ) .
 103                     ( $line->{en} ? " EN: " . $line->{en} : '' ) .
 104                     ( $line->{itemtype} ? ", " . $line->{itemtype} : '' ) .
 105                     ( $line->{edition} ? ", " . $line->{edition} : '' ) .
 106                     ( $line->{publishercode} ? ' published by '. $line->{publishercode} : '') .
 107                     ( $line->{publicationyear} ? ', '. $line->{publicationyear} : '');
 108             }
 109             else { # MARC21, NORMARC
 110                 $titleinfo =  $line->{title} . " " . $line->{author} .
 111                     ( $line->{isbn} ? " ISBN: " . $line->{isbn} : '' ) .
 112                     ( $line->{en} ? " EN: " . $line->{en} : '' ) .
 113                     ( $line->{itemtype} ? " " . $line->{itemtype} : '' ) .
 114                     ( $line->{edition} ? ", " . $line->{edition} : '' ) .
 115                     ( $line->{publishercode} ? ' published by '. $line->{publishercode} : '') .
 116                     ( $line->{copyrightdate} ? ' '. $line->{copyrightdate} : '');
 117             }
 118             push( @$arrbasket,
 119                 $titleinfo. ($line->{order_vendornote} ? "\n----------------\nNote for vendor : " . $line->{order_vendornote} : '' ),
 120                 $line->{quantity},
 121                 Koha::Number::Price->new( $line->{rrpgste} )->format,
 122                 Koha::Number::Price->new( $line->{rrpgsti} )->format,
 123                 Koha::Number::Price->new( $line->{discount} )->format . '%',
 124                 Koha::Number::Price->new( $line->{rrpgste} - $line->{ecostgste})->format,
 125                 Koha::Number::Price->new( $line->{gstrate} * 100 )->format . '%',
 126                 Koha::Number::Price->new( $line->{totalgste} )->format,
 127                 Koha::Number::Price->new( $line->{totalgsti} )->format,
 128             );
 129             push(@$abaskets, $arrbasket);
 130         }
 131
 132         $pdftable->table($pdf, $page, $abaskets,
 133                                         x => 10/mm,
 134                                         w => ($width - 20)/mm,
 135                                         start_y => 270/mm,
 136                                         next_y  => 285/mm,
 137                                         start_h => 250/mm,
 138                                         next_h  => 250/mm,
 139                                         padding => 5,
 140                                         padding_right => 5,
 141                                         background_color_odd  => "lightgray",
 142                                         font       => $pdf->corefont("Times", -encoding => "utf8"),
 143                                         font_size => 3/mm,
 144                                         header_props   =>    {
 145                                             font       => $pdf->corefont("Times", -encoding => "utf8"),
 146                                             font_size  => 9,
 147                                             bg_color   => 'gray',
 148                                             repeat     => 1,
 149                                         },
 150                                         column_props => [
 151                                             {
 152                                                 min_w => 85/mm,       # Minimum column width.
 153                                             },
 154                                             {
 155                                                 justify => 'right', # One of left|right ,
 156                                             },
 157                                             {
 158                                                 justify => 'right', # One of left|right ,
 159                                             },
 160                                             {
 161                                                 justify => 'right', # One of left|right ,
 162                                             },
 163                                             {
 164                                                 justify => 'right', # One of left|right ,
 165                                             },
 166                                             {
 167                                                 justify => 'right', # One of left|right ,
 168                                             },
 169                                             {
 170                                                 justify => 'right', # One of left|right ,
 171                                             },
 172                                             {
 173                                                 justify => 'right', # One of left|right ,
 174                                             },
 175                                             {
 176                                                 justify => 'right', # One of left|right ,
 177                                             },
 178                                         ],
 179              );
 180     }
 181     $pdf->mediabox($width/mm, $height/mm);
 182 }
 183
 184 sub printbaskets {
 185     my ($pdf, $basketgroup, $hbaskets, $bookseller, $GSTrate, $orders) = @_;
 186
 187     # get library name
 188     my $libraryname = C4::Context->preference("LibraryName");
 189
 190     my $cur_format = C4::Context->preference("CurrencyFormat");
 191
 192     $pdf->mediabox($width/mm, $height/mm);
 193     my $page = $pdf->openpage(2);
 194     # create a text
 195     my $text = $page->text;
 196
 197     # add basketgroup number
 198     $text->font( $pdf->corefont("Times", -encoding => "utf8"), 6/mm );
 199     $text->translate(($width-40)/mm,  ($height-53)/mm);
 200     $text->text("".$basketgroup->{'id'});
 201     # print the libraryname in the header
 202     $text->font( $pdf->corefont("Times", -encoding => "utf8"), 6/mm );
 203     $text->translate(30/mm,  ($height-28.5)/mm);
 204     $text->text($libraryname);
 205     my $pdftable = new PDF::Table();
 206     my $abaskets;
 207     my $arrbasket;
 208     # header of the table
 209     my @keys = ('Lot',  'Basket (No.)','Total RRP tax exc.', 'Total RRP tax inc.', 'GST rate', 'GST', 'Total discount', 'Total tax exc.', 'Total tax inc.');
 210     for my $bkey (@keys) {
 211         push(@$arrbasket, $bkey);
 212     }
 213     my ($grandtotalrrpgsti, $grandtotalrrpgste, $grandtotalgsti, $grandtotalgste, $grandtotalgstvalue, $grandtotaldiscount);
 214     # calculate each basket total
 215     push(@$abaskets, $arrbasket);
 216     for my $basket (@$hbaskets) {
 217         my @gst;
 218         $arrbasket = undef;
 219         my ($totalrrpgste, $totalrrpgsti, $totalgste, $totalgsti, $totalgstvalue, $totaldiscount);
 220         my $ords = $orders->{$basket->{basketno}};
 221         my $ordlength = @$ords;
 222         foreach my $ord (@$ords) {
 223             $totalgste += $ord->{totalgste};
 224             $totalgsti += $ord->{totalgsti};
 225             $totalgstvalue += $ord->{gstvalue};
 226             $totaldiscount += ($ord->{rrpgste} - $ord->{ecostgste} ) * $ord->{quantity};
 227             $totalrrpgste += $ord->{rrpgste} * $ord->{quantity};
 228             $totalrrpgsti += $ord->{rrpgsti} * $ord->{quantity};
 229             push @gst, $ord->{gstrate};
 230         }
 231         @gst = uniq map { $_ * 100 } @gst;
 232         $grandtotalrrpgste += $totalrrpgste;
 233         $grandtotalrrpgsti += $totalrrpgsti;
 234         $grandtotalgsti += $totalgsti;
 235         $grandtotalgste += $totalgste;
 236         $grandtotalgstvalue += $totalgstvalue;
 237         $grandtotaldiscount += $totaldiscount;
 238         my @gst_string =
 239           map { Koha::Number::Price->new($_)->format . '%' } @gst;
 240         push(@$arrbasket,
 241             $basket->{contractname},
 242             $basket->{basketname} . ' (No. ' . $basket->{basketno} . ')',
 243             Koha::Number::Price->new( $totalrrpgste )->format,
 244             Koha::Number::Price->new( $totalrrpgsti )->format,
 245             "@gst_string",
 246             Koha::Number::Price->new( $totalgstvalue )->format,
 247             Koha::Number::Price->new( $totaldiscount )->format,
 248             Koha::Number::Price->new( $totalgste )->format,
 249             Koha::Number::Price->new( $totalgsti )->format,
 250         );
 251         push(@$abaskets, $arrbasket);
 252     }
 253     # now, push total
 254     undef $arrbasket;
 255     push @$arrbasket,
 256       '',
 257       'Total',
 258       Koha::Number::Price->new( $grandtotalrrpgste )->format,
 259       Koha::Number::Price->new( $grandtotalrrpgsti )->format,
 260       '',
 261       Koha::Number::Price->new( $grandtotalgstvalue )->format,
 262       Koha::Number::Price->new( $grandtotaldiscount )->format,
 263       Koha::Number::Price->new( $grandtotalgste )->format,
 264       Koha::Number::Price->new( $grandtotalgsti )->format;
 265     push @$abaskets,$arrbasket;
 266     # height is width and width is height in this function, as the pdf is in landscape mode for the Tables.
 267
 268     $pdftable->table($pdf, $page, $abaskets,
 269                                     x => 5/mm,
 270                                     w => ($width - 10)/mm,
 271                                     start_y =>  230/mm,
 272                                     next_y  => 230/mm,
 273                                     start_h => 230/mm,
 274                                     next_h  => 230/mm,
 275                                     font       => $pdf->corefont("Times", -encoding => "utf8"),
 276                                     font_size => 3/mm,
 277                                     padding => 5,
 278                                     padding_right => 10,
 279                                     background_color_odd  => "lightgray",
 280                                     header_props   =>    {
 281                                         bg_color   => 'gray',
 282                                         repeat     => 1,
 283                                     },
 284                                     column_props => [
 285                                         {
 286                                         },
 287                                         {
 288                                         },
 289                                         {
 290                                             justify => 'right',
 291                                         },
 292                                         {
 293                                             justify => 'right',
 294                                         },
 295                                         {
 296                                             justify => 'right',
 297                                         },
 298                                         {
 299                                             justify => 'right',
 300                                         },
 301                                         {
 302                                             justify => 'right',
 303                                         },
 304                                     ],
 305     );
 306     $pdf->mediabox($height/mm, $width/mm);
 307 }
 308
 309 sub printhead {
 310     my ($pdf, $basketgroup, $bookseller) = @_;
 311
 312     # get library name
 313     my $libraryname = C4::Context->preference("LibraryName");
 314     # get branch details
 315     my $billingdetails  = GetBranchDetail( $basketgroup->{billingplace} );
 316     my $deliverydetails = GetBranchDetail( $basketgroup->{deliveryplace} );
 317     my $freedeliveryplace = $basketgroup->{freedeliveryplace};
 318     # get the subject
 319     my $subject;
 320
 321     # open 1st page (with the header)
 322     my $page = $pdf->openpage(1);
 323
 324     # create a text
 325     my $text = $page->text;
 326
 327     # print the libraryname in the header
 328     $text->font( $pdf->corefont("Times", -encoding => "utf8"), 6/mm );
 329     $text->translate(30/mm,  ($height-28.5)/mm);
 330     $text->text($libraryname);
 331
 332     # print order info, on the default PDF
 333     $text->font( $pdf->corefont("Times", -encoding => "utf8"), 8/mm );
 334     $text->translate(100/mm,  ($height-5-48)/mm);
 335     $text->text($basketgroup->{'id'});
 336
 337     # print the date
 338     my $today = output_pref({ dt => dt_from_string, dateonly => 1 });
 339     $text->translate(130/mm,  ($height-5-48)/mm);
 340     $text->text($today);
 341
 342     $text->font( $pdf->corefont("Times", -encoding => "utf8"), 4/mm );
 343
 344     # print billing infos
 345     $text->translate(100/mm,  ($height-86)/mm);
 346     $text->text($libraryname);
 347     $text->translate(100/mm,  ($height-97)/mm);
 348     $text->text($billingdetails->{branchname});
 349     $text->translate(100/mm,  ($height-108.5)/mm);
 350     $text->text($billingdetails->{branchphone});
 351     $text->translate(100/mm,  ($height-115.5)/mm);
 352     $text->text($billingdetails->{branchfax});
 353     $text->translate(100/mm,  ($height-122.5)/mm);
 354     $text->text($billingdetails->{branchaddress1});
 355     $text->translate(100/mm,  ($height-127.5)/mm);
 356     $text->text($billingdetails->{branchaddress2});
 357     $text->translate(100/mm,  ($height-132.5)/mm);
 358     $text->text($billingdetails->{branchaddress3});
 359     $text->translate(100/mm,  ($height-137.5)/mm);
 360     $text->text(join(' ', $billingdetails->{branchzip}, $billingdetails->{branchcity}, $billingdetails->{branchcountry}));
 361     $text->translate(100/mm,  ($height-147.5)/mm);
 362     $text->text($billingdetails->{branchemail});
 363
 364     # print subject
 365     $text->translate(100/mm,  ($height-145.5)/mm);
 366     $text->text($subject);
 367
 368     # print bookseller infos
 369     $text->translate(100/mm,  ($height-180)/mm);
 370     $text->text($bookseller->{name});
 371     $text->translate(100/mm,  ($height-185)/mm);
 372     $text->text($bookseller->{postal});
 373     $text->translate(100/mm,  ($height-190)/mm);
 374     $text->text($bookseller->{address1});
 375     $text->translate(100/mm,  ($height-195)/mm);
 376     $text->text($bookseller->{address2});
 377     $text->translate(100/mm,  ($height-200)/mm);
 378     $text->text($bookseller->{address3});
 379     $text->translate(100/mm, ($height-205)/mm);
 380     $text->text($bookseller->{accountnumber});
 381
 382     # print delivery infos
 383     $text->font( $pdf->corefont("Times-Bold", -encoding => "utf8"), 4/mm );
 384     $text->translate(50/mm,  ($height-237)/mm);
 385     if ($freedeliveryplace) {
 386         my $start = 242;
 387         my @fdp = split('\n', $freedeliveryplace);
 388         foreach (@fdp) {
 389             $text->text($_);
 390             $text->translate( 50 / mm, ( $height - $start ) / mm );
 391             $start += 5;
 392         }
 393     } else {
 394         $text->text($deliverydetails->{branchaddress1});
 395         $text->translate(50/mm,  ($height-242)/mm);
 396         $text->text($deliverydetails->{branchaddress2});
 397         $text->translate(50/mm,  ($height-247)/mm);
 398         $text->text($deliverydetails->{branchaddress3});
 399         $text->translate(50/mm,  ($height-252)/mm);
 400         $text->text(join(' ', $deliverydetails->{branchzip}, $deliverydetails->{branchcity}, $deliverydetails->{branchcountry}));
 401     }
 402     $text->translate(50/mm,  ($height-262)/mm);
 403     $text->text($basketgroup->{deliverycomment});
 404 }
 405
 406 sub printfooters {
 407         my ($pdf) = @_;
 408         for (my $i=1;$i <= $pdf->pages;$i++) {
 409         my $page = $pdf->openpage($i);
 410         my $text = $page->text;
 411         $text->font( $pdf->corefont("Times", -encoding => "utf8"), 3/mm );
 412         $text->translate(10/mm,  10/mm);
 413         $text->text("Page $i / ".$pdf->pages);
 414         }
 415 }
 416
 417 sub printpdf {
 418     my ($basketgroup, $bookseller, $baskets, $orders, $GST) = @_;
 419     # open the default PDF that will be used for base (1st page already filled)
 420     my $pdf_template = C4::Context->config('intrahtdocs') . '/' . C4::Context->preference('template') . '/pdf/layout3pages.pdf';
 421     my $pdf = PDF::API2->open($pdf_template);
 422     $pdf->pageLabel( 0, {
 423         -style => 'roman',
 424     } ); # start with roman numbering
 425     # fill the 1st page (basketgroup information)
 426     printhead($pdf, $basketgroup, $bookseller);
 427     # fill the 2nd page (orders summary)
 428     printbaskets($pdf, $basketgroup, $baskets, $bookseller, $GST, $orders);
 429     # fill other pages (orders)
 430     printorders($pdf, $basketgroup, $baskets, $orders);
 431     # print something on each page (usually the footer, but you could also put a header
 432     printfooters($pdf);
 433     return $pdf->stringify;
 434 }
 435
 436 1;