C4/Templates.pm

   1 package C4::Templates;
   2
   3 use strict;
   4 use warnings;
   5 use Carp;
   6 use CGI qw ( -utf8 );
   7 use List::MoreUtils qw/ any uniq /;
   8
   9 # Copyright 2009 Chris Cormack and The Koha Dev Team
  10 #
  11 # This file is part of Koha.
  12 #
  13 # Koha is free software; you can redistribute it and/or modify it
  14 # under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 3 of the License, or
  16 # (at your option) any later version.
  17 #
  18 # Koha is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  21 # GNU General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  25
  26 =head1 NAME
  27
  28 C4::Templates - Object for manipulating templates for use with Koha
  29
  30 =cut
  31
  32 use base qw(Class::Accessor);
  33 use Template;
  34 use Template::Constants qw( :debug );
  35 use C4::Languages qw(getTranslatedLanguages get_bidi regex_lang_subtags language_get_description accept_language );
  36
  37 use C4::Context;
  38
  39 use Koha::Cache::Memory::Lite;
  40 use Koha::Exceptions;
  41
  42 __PACKAGE__->mk_accessors(qw( theme activethemes preferredtheme lang filename htdocs interface vars));
  43
  44
  45
  46 sub new {
  47     my $class     = shift;
  48     my $interface = shift;
  49     my $filename  = shift;
  50     my $tmplbase  = shift;
  51     my $query     = @_? shift: undef;
  52     my $htdocs;
  53     if ( $interface ne "intranet" ) {
  54         $htdocs = C4::Context->config('opachtdocs');
  55     }
  56     else {
  57         $htdocs = C4::Context->config('intrahtdocs');
  58     }
  59     my ($theme, $lang, $activethemes)= themelanguage( $htdocs, $tmplbase, $interface, $query);
  60     my @includes;
  61     foreach (@$activethemes) {
  62         push @includes, "$htdocs/$_/$lang/includes";
  63         push @includes, "$htdocs/$_/en/includes" unless $lang eq 'en';
  64     }
  65     # Do not use template cache if script is called from commandline
  66     my $use_template_cache = C4::Context->config('template_cache_dir') && defined $ENV{GATEWAY_INTERFACE};
  67     my $template = Template->new(
  68         {   EVAL_PERL    => 1,
  69             ABSOLUTE     => 1,
  70             PLUGIN_BASE => 'Koha::Template::Plugin',
  71             COMPILE_EXT => $use_template_cache ? '.ttc' : '',
  72             COMPILE_DIR => $use_template_cache ? C4::Context->config('template_cache_dir') : '',
  73             INCLUDE_PATH => \@includes,
  74             FILTERS => {},
  75             ENCODING => 'UTF-8',
  76         }
  77     ) or die Template->error();
  78     my $self = {
  79         TEMPLATE => $template,
  80         VARS     => {},
  81     };
  82     bless $self, $class;
  83     $self->theme($theme);
  84     $self->lang($lang);
  85     $self->activethemes($activethemes);
  86     $self->preferredtheme($activethemes->[0]);
  87     $self->filename($filename);
  88     $self->htdocs($htdocs);
  89     $self->interface($interface);
  90     $self->{VARS}->{"test"} = "value";
  91     return $self;
  92
  93 }
  94
  95 sub output {
  96     my $self = shift;
  97     my $vars = shift;
  98
  99 #    my $file = $self->htdocs . '/' . $self->theme .'/'.$self->lang.'/'.$self->filename;
 100     my $template = $self->{TEMPLATE};
 101     if ( $self->interface eq 'intranet' ) {
 102         $vars->{themelang} = '/intranet-tmpl';
 103     }
 104     else {
 105         $vars->{themelang} = '/opac-tmpl';
 106     }
 107     $vars->{lang} = $self->lang;
 108     $vars->{themelang} .= '/' . $self->preferredtheme . '/' . $self->lang;
 109     $vars->{interface} =
 110       ( $self->{interface} ne 'intranet' ? '/opac-tmpl' : '/intranet-tmpl' );
 111     $vars->{theme} = $self->theme;
 112     $vars->{OpacAdditionalStylesheet} =
 113         C4::Context->preference('OpacAdditionalStylesheet');
 114     $vars->{opaclayoutstylesheet} =
 115         C4::Context->preference('opaclayoutstylesheet');
 116
 117     # add variables set via param to $vars for processing
 118     $vars = { %$vars, %{ $self->{VARS} } };
 119
 120     my $data;
 121     binmode( STDOUT, ":utf8" );
 122     $template->process( $self->filename, $vars, \$data )
 123       || die "Template process failed: ", $template->error();
 124     return $data;
 125 }
 126
 127 # wrapper method to allow easier transition from HTML template pro to Template Toolkit
 128 sub param {
 129     my $self = shift;
 130     while (@_) {
 131         my $key = shift;
 132         my $val = shift;
 133         if    ( ref($val) eq 'ARRAY' && !scalar @$val ) { $val = undef; }
 134         elsif ( ref($val) eq 'HASH'  && !scalar %$val ) { $val = undef; }
 135         if ( $key ) {
 136             $self->{VARS}->{$key} = $val;
 137         } else {
 138             warn "Problem = a value of $val has been passed to param without key";
 139         }
 140     }
 141 }
 142
 143
 144 =head1 NAME
 145
 146 C4::Templates - Functions for managing templates
 147
 148 =head1 FUNCTIONS
 149
 150 =cut
 151
 152 # FIXME: this is a quick fix to stop rc1 installing broken
 153 # Still trying to figure out the correct fix.
 154 my $path = C4::Context->config('intrahtdocs') . "/prog/en/includes/";
 155
 156 #---------------------------------------------------------------------------------------------------------
 157 # FIXME - POD
 158
 159 sub _get_template_file {
 160     my ($tmplbase, $interface, $query) = @_;
 161
 162     my $is_intranet = $interface eq 'intranet';
 163     my $htdocs = C4::Context->config($is_intranet ? 'intrahtdocs' : 'opachtdocs');
 164     my ($theme, $lang, $availablethemes) = themelanguage($htdocs, $tmplbase, $interface, $query);
 165     $lang //= 'en';
 166     $theme //= '';
 167     $tmplbase = "$htdocs/$theme/$lang/modules/$tmplbase" if $tmplbase !~ /^\//;
 168         # do not prefix an absolute path
 169
 170     return ( $htdocs, $theme, $lang, $tmplbase );
 171 }
 172
 173 =head2 badtemplatecheck
 174
 175     badtemplatecheck( $template_path );
 176
 177     The sub will throw an exception if the template path is not allowed.
 178
 179     Note: At this moment the sub is actually a helper routine for
 180     sub gettemplate.
 181
 182 =cut
 183
 184 sub badtemplatecheck {
 185     my ( $template ) = @_;
 186     if( !$template || $template !~ m/^[a-zA-Z0-9_\-\/]+\.(tt|pref)$/ ) {
 187         # This also includes two dots
 188         Koha::Exceptions::NoPermission->throw( 'bad template path' );
 189     } else {
 190         # Check allowed dirs
 191         my $dirs = C4::Context->config("pluginsdir");
 192         $dirs = [ $dirs ] if !ref($dirs);
 193         unshift @$dirs, C4::Context->config('opachtdocs'), C4::Context->config('intrahtdocs');
 194         my $found = 0;
 195         foreach my $dir ( @$dirs ) {
 196             $dir .= '/' if $dir !~ m/\/$/;
 197             $found++ if $template =~ m/^$dir/;
 198             last if $found;
 199         }
 200         Koha::Exceptions::NoPermission->throw( 'bad template path' ) if !$found;
 201     }
 202 }
 203
 204 sub gettemplate {
 205     my ( $tmplbase, $interface, $query ) = @_;
 206     ($query) or warn "no query in gettemplate";
 207     my ($htdocs, $theme, $lang, $filename)
 208        =  _get_template_file($tmplbase, $interface, $query);
 209     badtemplatecheck( $filename ); # single trip for bad templates
 210     my $template = C4::Templates->new($interface, $filename, $tmplbase, $query);
 211
 212 # NOTE: Commenting these out rather than deleting them so that those who need
 213 # to know how we previously shimmed these directories will be able to understand.
 214 #    my $is_intranet = $interface eq 'intranet';
 215 #    my $themelang =
 216 #        ($is_intranet ? '/intranet-tmpl' : '/opac-tmpl') .
 217 #        "/$theme/$lang";
 218 #    $template->param(
 219 #        themelang => $themelang,
 220 #        interface => $is_intranet ? '/intranet-tmpl' : '/opac-tmpl',
 221 #        theme     => $theme,
 222 #        lang      => $lang
 223 #    );
 224
 225     # Bidirectionality, must be sent even if is the only language
 226     my $current_lang = regex_lang_subtags($lang);
 227     my $bidi;
 228     $bidi = get_bidi($current_lang->{script}) if $current_lang->{script};
 229     $template->param(
 230             bidi                 => $bidi,
 231     );
 232     # Languages
 233     my $languages_loop = getTranslatedLanguages($interface,$theme,$lang);
 234     my $num_languages_enabled = 0;
 235     foreach my $lang (@$languages_loop) {
 236         foreach my $sublang (@{ $lang->{'sublanguages_loop'} }) {
 237             $num_languages_enabled++ if $sublang->{enabled};
 238          }
 239     }
 240     my $one_language_enabled = ($num_languages_enabled <= 1) ? 1 : 0; # deal with zero enabled langs as well
 241     $template->param(
 242             languages_loop       => $languages_loop,
 243             one_language_enabled => $one_language_enabled,
 244     ) unless $one_language_enabled;
 245     $template->param(
 246         KOHA_VERSION => C4::Context->preference('Version')
 247     );
 248
 249     return $template;
 250 }
 251
 252
 253 =head2 themelanguage
 254
 255     my ($theme,$lang,\@themes) = themelanguage($htdocs,$tmpl,$interface,query);
 256
 257 This function returns the theme and language to be used for rendering the UI.
 258 It also returns the list of themes that should be applied as a fallback. This is
 259 used for the theme overlay feature (i.e. if a file doesn't exist on the requested
 260 theme, fallback to the configured fallback).
 261
 262 Important: this function is used on the webinstaller too, so always consider
 263 the use case where the DB is not populated already when rewriting/fixing.
 264
 265 =cut
 266
 267 sub themelanguage {
 268     my ($htdocs, $tmpl, $interface, $query) = @_;
 269     ($query) or warn "no query in themelanguage";
 270
 271     # Select a language based on cookie, syspref available languages & browser
 272     my $lang = C4::Languages::getlanguage($query);
 273
 274     # Get theme
 275     my @themes;
 276     my $theme_syspref    = ($interface eq 'intranet') ? 'template' : 'opacthemes';
 277     my $fallback_syspref = ($interface eq 'intranet') ? 'template' : 'OPACFallback';
 278     # Yeah, hardcoded, last resort if the DB is not populated
 279     my $hardcoded_theme = ($interface eq 'intranet') ? 'prog' : 'bootstrap';
 280
 281     # Configured theme is the first one
 282     push @themes, C4::Context->preference( $theme_syspref )
 283         if C4::Context->preference( $theme_syspref );
 284     # Configured fallback next
 285     push @themes, C4::Context->preference( $fallback_syspref )
 286         if C4::Context->preference( $fallback_syspref );
 287     # The hardcoded fallback theme is the last one
 288     push @themes, $hardcoded_theme;
 289
 290     # Try to find first theme for the selected theme/lang, then for fallback/lang
 291     my $where = $tmpl =~ /xsl$/ ? 'xslt' : 'modules';
 292     for my $theme (@themes) {
 293         if ( -e "$htdocs/$theme/$lang/$where/$tmpl" ) {
 294             return ( $theme, $lang, [ uniq(@themes) ] );
 295         }
 296     }
 297     # Otherwise return theme/'en', last resort fallback/'en'
 298     for my $theme (@themes) {
 299         if ( -e "$htdocs/$theme/en/$where/$tmpl" ) {
 300             return ( $theme, 'en', [ uniq(@themes) ] );
 301         }
 302     }
 303     # tmpl is a full path, so this is a template for a plugin
 304     if ( $tmpl =~ /^\// && -e $tmpl ) {
 305         return ( $themes[0], $lang, [ uniq(@themes) ] );
 306     }
 307 }
 308
 309
 310 sub setlanguagecookie {
 311     my ( $query, $language, $uri ) = @_;
 312
 313     my $cookie = getlanguagecookie( $query, $language );
 314
 315     # We do not want to set getlanguage in cache, some additional checks are
 316     # done in C4::Languages::getlanguage
 317     Koha::Cache::Memory::Lite->get_instance()->clear_from_cache( 'getlanguage' );
 318
 319     print $query->redirect(
 320         -uri    => $uri,
 321         -cookie => $cookie
 322     );
 323 }
 324
 325 =head2 getlanguagecookie
 326
 327     my $cookie = getlanguagecookie($query,$language);
 328
 329 Returns a cookie object containing the calculated language to be used.
 330
 331 =cut
 332
 333 sub getlanguagecookie {
 334     my ( $query, $language ) = @_;
 335     my $cookie = $query->cookie(
 336         -name    => 'KohaOpacLanguage',
 337         -value   => $language,
 338         -HttpOnly => 1,
 339         -expires => '+3y'
 340     );
 341
 342     return $cookie;
 343 }
 344
 345 =head2 GetColumnDefs
 346
 347     my $columns = GetColumnDefs( $cgi )
 348
 349 It is passed a CGI object and returns a hash of hashes containing
 350 the column names and descriptions for each table defined in the
 351 columns.def file corresponding to the CGI object.
 352
 353 =cut
 354
 355 sub GetColumnDefs {
 356
 357     my $query = shift;
 358
 359     my $columns = {};
 360
 361     my $htdocs = C4::Context->config('intrahtdocs');
 362     my $columns_file = 'columns.def';
 363
 364     # Get theme and language to build the path to columns.def
 365     my ($theme, $lang, $availablethemes) =
 366         themelanguage($htdocs, 'about.tt', 'intranet', $query);
 367     # Build columns.def path
 368     my $path = "$htdocs/$theme/$lang/$columns_file";
 369     my $fh;
 370     if ( ! open ( $fh, q{<:encoding(utf-8)}, $path ) )  {
 371         carp "Error opening $path. Check your templates.";
 372         return;
 373     }
 374     # Loop through the columns.def file
 375     while ( my $input = <$fh> ){
 376         chomp $input;
 377         if ( $input =~ m|<field name="(.*)">(.*)</field>| ) {
 378             my ( $table, $column ) =  split( '\.', $1);
 379             my $description        = $2;
 380             # Initialize the table array if needed.
 381             @{$columns->{ $table }} = () if ! defined $columns->{ $table };
 382             # Push field and description
 383             push @{$columns->{ $table }},
 384                 { field => $column, description => $description };
 385         }
 386     }
 387     close $fh;
 388
 389     return $columns;
 390 }
 391
 392 1;