Tests/QtAutogen/AutogenOriginDependsOn/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.16)
   2 project(AutogenOriginDependsOn)
   3 include("../AutogenCoreTest.cmake")
   4
   5 include_directories(${CMAKE_CURRENT_BINARY_DIR})
   6 set(CSD ${CMAKE_CURRENT_SOURCE_DIR})
   7 set(CBD ${CMAKE_CURRENT_BINARY_DIR})
   8
   9 # -- Test dependency on header generated by a custom command
  10 #
  11 # The ORIGIN_autogen target must depend on the same *GENERATED* source files as
  12 # the ORIGIN target. This is a requirement to ensure that all files for the
  13 # ORIGIN target are generated before the ORIGIN_autogen target is built.
  14 #
  15 # This tests the dependency of the mocDepGenFile_autogen target of
  16 # mocDepGenFile to the source file GenFile.hpp, which is *GENERATED*
  17 # by a custom command.
  18 # If mocDepGenFile_autogen gets built *before* or in *parallel* to the
  19 # custom command, the build will fail. That's because GenFile.hpp,
  20 # which is required by mocDepGenFile_autogen, is only valid after the
  21 # custom command has been completed.
  22 #
  23 # The sleep seconds artificially increase the build time of the custom command
  24 # to simulate a slow file generation process that takes longer to run than
  25 # the build of the mocDepGenFile_autogen target.
  26 add_custom_command(
  27   OUTPUT ${CBD}/GenFile.hpp
  28   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/object_invalid.hpp.in ${CBD}/GenFile.hpp
  29   COMMAND ${CMAKE_COMMAND} -E sleep 3
  30   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/object_valid.hpp.in ${CBD}/GenFile.hpp)
  31
  32 add_executable(mocDepGenFile testGenFile.cpp ${CBD}/GenFile.hpp)
  33 target_link_libraries(mocDepGenFile ${QT_QTCORE_TARGET})
  34 set_target_properties(mocDepGenFile PROPERTIES AUTOMOC TRUE)
  35
  36
  37 # -- Test dependency on header generating custom target
  38 #
  39 # The ORIGIN_autogen target must depend on the same user defined targets
  40 # as the ORIGIN target. This is a requirement to ensure that all files for the
  41 # ORIGIN target are generated before the ORIGIN_autogen target is built.
  42 #
  43 # This tests the dependency of the mocDepTarget_autogen target of
  44 # mocDepTarget to the utility target mocDepTargetUtil.
  45 # If mocDepTarget_autogen gets built *before* or in *parallel* to
  46 # mocDepTargetUtil, the build will fail. That's
  47 # because GenTarget.hpp, which is required by mocDepTarget_autogen,
  48 # is only valid after the mocDepTargetUtil build has been completed.
  49 #
  50 # The sleep seconds artificially increase the build time of mocDepTargetUtil
  51 # to simulate a slow utility target build that takes longer to run than
  52 # the build of the mocDepTarget_autogen target.
  53 add_custom_target(mocDepTargetUtil
  54   BYPRODUCTS ${CBD}/GenTarget.hpp
  55   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/object_invalid.hpp.in ${CBD}/GenTarget.hpp
  56   COMMAND ${CMAKE_COMMAND} -E sleep 3
  57   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/object_valid.hpp.in ${CBD}/GenTarget.hpp)
  58
  59 add_executable(mocDepTarget testGenTarget.cpp)
  60 target_link_libraries(mocDepTarget ${QT_QTCORE_TARGET})
  61 set_target_properties(mocDepTarget PROPERTIES AUTOMOC TRUE)
  62 add_dependencies(mocDepTarget mocDepTargetUtil)
  63
  64
  65 # -- Test 3: Depend on generated linked library
  66 # The ORIGIN_autogen target must depend on the same linked libraries
  67 # as the ORIGIN target. This is a requirement to ensure that all files for the
  68 # ORIGIN target are generated before the ORIGIN_autogen target is built.
  69 #
  70 # This tests the dependency of the mocDepGenLib_autogen target of mocDepGenLib
  71 # to the user generated library SimpleLib, which mocDepGenLib links to.
  72 # If mocDepGenLib_autogen gets built *before* or in *parallel* to SimpleLib,
  73 # the build will fail. That's because simpleLib.hpp, which is required by
  74 # mocDepGenLib_autogen, is only valid after the SimpleLib build has been
  75 # completed.
  76 #
  77 # The sleep seconds artificially increase the build time of SimpleLib
  78 # to simulate a slow utility library build that takes longer to run than
  79 # the build of the mocDepGenLib_autogen target.
  80 add_custom_command(
  81   OUTPUT ${CBD}/simpleLib.hpp ${CBD}/simpleLib.cpp
  82   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/object_invalid.hpp.in ${CBD}/simpleLib.hpp
  83   COMMAND ${CMAKE_COMMAND} -E sleep 3
  84   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/simpleLib.hpp.in ${CBD}/simpleLib.hpp
  85   COMMAND ${CMAKE_COMMAND} -E copy ${CSD}/simpleLib.cpp.in ${CBD}/simpleLib.cpp)
  86 add_library(SimpleLib STATIC ${CBD}/simpleLib.hpp ${CBD}/simpleLib.cpp)
  87 target_link_libraries(SimpleLib ${QT_QTCORE_TARGET})
  88
  89 add_executable(mocDepGenLib testGenLib.cpp)
  90 target_link_libraries(mocDepGenLib SimpleLib ${QT_QTCORE_TARGET})
  91 set_target_properties(mocDepGenLib PROPERTIES AUTOMOC TRUE)