Tests/QtAutogen/AutogenCoreTest.cmake

   1
   2 # Tell find_package(Qt5) where to find Qt.
   3 if(QT_QMAKE_EXECUTABLE)
   4   get_filename_component(Qt_BIN_DIR "${QT_QMAKE_EXECUTABLE}" PATH)
   5   get_filename_component(Qt_PREFIX_DIR "${Qt_BIN_DIR}" PATH)
   6   list(APPEND CMAKE_PREFIX_PATH ${Qt_PREFIX_DIR})
   7 endif()
   8
   9 if (QT_TEST_VERSION EQUAL 4)
  10
  11   find_package(Qt4 REQUIRED QtCore)
  12   include(UseQt4)
  13
  14   set(QT_QTCORE_TARGET Qt4::QtCore)
  15
  16   # Qt macros
  17   macro(qtx_wrap_cpp)
  18     qt4_wrap_cpp(${ARGN})
  19   endmacro()
  20   macro(qtx_generate_moc)
  21     qt4_generate_moc(${ARGN})
  22   endmacro()
  23
  24 elseif(QT_TEST_VERSION GREATER_EQUAL 5)
  25
  26   find_package(Qt${QT_TEST_VERSION}Core REQUIRED)
  27
  28   set(QT_QTCORE_TARGET Qt${QT_TEST_VERSION}::Core)
  29   set(QT_LIBRARIES Qt${QT_TEST_VERSION}::Core)
  30
  31   # Include directories
  32   include_directories(${Qt${QT_TEST_VERSION}Core_INCLUDE_DIRS})
  33
  34   # Definitions
  35   if(Qt${QT_TEST_VERSION}_POSITION_INDEPENDENT_CODE AND CMAKE_CXX_COMPILE_OPTIONS_PIC)
  36     add_definitions(${CMAKE_CXX_COMPILE_OPTIONS_PIC})
  37   endif()
  38
  39   # Qt macros
  40   macro(qtx_wrap_cpp)
  41     cmake_language(CALL qt${QT_TEST_VERSION}_wrap_cpp ${ARGN})
  42   endmacro()
  43   macro(qtx_generate_moc)
  44     cmake_language(CALL qt${QT_TEST_VERSION}_generate_moc ${ARGN})
  45   endmacro()
  46
  47 else()
  48   message(SEND_ERROR "Invalid Qt version specified: ${QT_TEST_VERSION}")
  49 endif()
  50
  51 # Get Qt compile features
  52 get_property(QT_COMPILE_FEATURES
  53   TARGET ${QT_QTCORE_TARGET}
  54   PROPERTY INTERFACE_COMPILE_FEATURES
  55 )