Source/LexerParser/cmExprParser.y

   1 %{
   2 /* Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   3    file Copyright.txt or https://cmake.org/licensing for details.  */
   4 /*
   5
   6 This file must be translated to C and modified to build everywhere.
   7
   8 Run bison like this:
   9
  10   bison --name-prefix=cmExpr_yy --defines=cmExprParserTokens.h -ocmExprParser.cxx cmExprParser.y
  11
  12 */
  13
  14 #include "cmConfigure.h" // IWYU pragma: keep
  15
  16 #include <stdlib.h>
  17 #include <string.h>
  18 #include <stdexcept>
  19
  20 /*-------------------------------------------------------------------------*/
  21 #define YYDEBUG 1
  22 #include "cmExprParserHelper.h" /* Interface to parser object.  */
  23 #include "cmExprLexer.h"  /* Interface to lexer object.  */
  24 #include "cmExprParserTokens.h" /* Need YYSTYPE for YY_DECL.  */
  25
  26 /* Forward declare the lexer entry point.  */
  27 YY_DECL;
  28
  29 /* Helper function to forward error callback from parser.  */
  30 static void cmExpr_yyerror(yyscan_t yyscanner, const char* message);
  31
  32 /* Disable some warnings in the generated code.  */
  33 #ifdef _MSC_VER
  34 # pragma warning (disable: 4102) /* Unused goto label.  */
  35 # pragma warning (disable: 4065) /* Switch statement contains default but no case. */
  36 #endif
  37 #if defined(__GNUC__) && __GNUC__ >= 8
  38 # pragma GCC diagnostic ignored "-Wconversion"
  39 # pragma GCC diagnostic ignored "-Wfree-nonheap-object"
  40 #endif
  41 #if defined(__clang__) && defined(__has_warning)
  42 # if __has_warning("-Wunused-but-set-variable")
  43 #  pragma clang diagnostic ignored "-Wunused-but-set-variable"
  44 # endif
  45 # if __has_warning("-Wused-but-marked-unused")
  46 #  pragma clang diagnostic ignored "-Wused-but-marked-unused"
  47 # endif
  48 #endif
  49
  50 #if defined(__NVCOMPILER)
  51 #  pragma diag_suppress 550 /* variable set but never used */
  52 #endif
  53 %}
  54
  55 /* Generate a reentrant parser object.  */
  56 %define api.pure
  57
  58 /* Configure the parser to use a lexer object.  */
  59 %lex-param   {yyscan_t yyscanner}
  60 %parse-param {yyscan_t yyscanner}
  61
  62 %define parse.error verbose
  63
  64 /*-------------------------------------------------------------------------*/
  65 /* Tokens */
  66 %token exp_PLUS
  67 %token exp_MINUS
  68 %token exp_TIMES
  69 %token exp_DIVIDE
  70 %token exp_MOD
  71 %token exp_SHIFTLEFT
  72 %token exp_SHIFTRIGHT
  73 %token exp_OPENPARENT
  74 %token exp_CLOSEPARENT
  75 %token exp_OR;
  76 %token exp_AND;
  77 %token exp_XOR;
  78 %token exp_NOT;
  79 %token exp_NUMBER;
  80
  81 /*-------------------------------------------------------------------------*/
  82 /* grammar */
  83 %%
  84
  85
  86 start:
  87   exp {
  88     cmExpr_yyget_extra(yyscanner)->SetResult($<Number>1);
  89   }
  90
  91 exp:
  92   bitwiseor {
  93     $<Number>$ = $<Number>1;
  94   }
  95 | exp exp_OR bitwiseor {
  96     $<Number>$ = $<Number>1 | $<Number>3;
  97   }
  98
  99 bitwiseor:
 100   bitwisexor {
 101     $<Number>$ = $<Number>1;
 102   }
 103 | bitwiseor exp_XOR bitwisexor {
 104     $<Number>$ = $<Number>1 ^ $<Number>3;
 105   }
 106
 107 bitwisexor:
 108   bitwiseand {
 109     $<Number>$ = $<Number>1;
 110   }
 111 | bitwisexor exp_AND bitwiseand {
 112     $<Number>$ = $<Number>1 & $<Number>3;
 113   }
 114
 115 bitwiseand:
 116   shift {
 117     $<Number>$ = $<Number>1;
 118   }
 119 | bitwiseand exp_SHIFTLEFT shift {
 120     $<Number>$ = $<Number>1 << $<Number>3;
 121   }
 122 | bitwiseand exp_SHIFTRIGHT shift {
 123     $<Number>$ = $<Number>1 >> $<Number>3;
 124   }
 125
 126 shift:
 127   term {
 128     $<Number>$ = $<Number>1;
 129   }
 130 | shift exp_PLUS term {
 131     $<Number>$ = $<Number>1 + $<Number>3;
 132   }
 133 | shift exp_MINUS term {
 134     $<Number>$ = $<Number>1 - $<Number>3;
 135   }
 136
 137 term:
 138   unary {
 139     $<Number>$ = $<Number>1;
 140   }
 141 | term exp_TIMES unary {
 142     $<Number>$ = $<Number>1 * $<Number>3;
 143   }
 144 | term exp_DIVIDE unary {
 145     if (yyvsp[0].Number == 0) {
 146       throw std::overflow_error("divide by zero");
 147     }
 148     $<Number>$ = $<Number>1 / $<Number>3;
 149   }
 150 | term exp_MOD unary {
 151     $<Number>$ = $<Number>1 % $<Number>3;
 152   }
 153
 154 unary:
 155   factor {
 156     $<Number>$ = $<Number>1;
 157   }
 158 | exp_PLUS unary {
 159     $<Number>$ = + $<Number>2;
 160   }
 161 | exp_MINUS unary {
 162     $<Number>$ = - $<Number>2;
 163   }
 164 | exp_NOT unary {
 165     $<Number>$ = ~ $<Number>2;
 166   }
 167
 168 factor:
 169   exp_NUMBER {
 170     $<Number>$ = $<Number>1;
 171   }
 172 | exp_OPENPARENT exp exp_CLOSEPARENT {
 173     $<Number>$ = $<Number>2;
 174   }
 175 ;
 176
 177 %%
 178 /* End of grammar */
 179
 180 /*--------------------------------------------------------------------------*/
 181 void cmExpr_yyerror(yyscan_t yyscanner, const char* message)
 182 {
 183   cmExpr_yyget_extra(yyscanner)->Error(message);
 184 }