Source/LexerParser/cmCTestResourceGroupsLexer.in.l

   1 %{
   2 /* Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   3    file Copyright.txt or https://cmake.org/licensing for details.  */
   4 /*
   5
   6 This file must be translated to C++ and modified to build everywhere.
   7
   8 Run flex >= 2.6 like this:
   9
  10   flex --nounistd -DFLEXINT_H --noline --header-file=cmCTestResourceGroupsLexer.h -ocmCTestResourceGroupsLexer.cxx cmCTestResourceGroupsLexer.in.l
  11
  12 Modify cmCTestResourceGroupsLexer.cxx:
  13   - remove trailing whitespace:              sed -i 's/\s*$//' cmCTestResourceGroupsLexer.h cmCTestResourceGroupsLexer.cxx
  14   - remove blank lines at end of file:       sed -i '${/^$/d;}' cmCTestResourceGroupsLexer.h cmCTestResourceGroupsLexer.cxx
  15   - #include "cmStandardLexer.h" at the top: sed -i '1i#include "cmStandardLexer.h"' cmCTestResourceGroupsLexer.cxx
  16
  17 */
  18
  19 /* IWYU pragma: no_forward_declare yyguts_t */
  20
  21 #ifndef __clang_analyzer__ /* Suppress clang-analyzer warnings */
  22
  23 #include "cmCTestResourceGroupsLexerHelper.h"
  24
  25 #include <string>
  26
  27 #include <cstddef>
  28
  29 #ifndef _WIN32
  30 #  include <termios.h>
  31 #endif
  32
  33 /*--------------------------------------------------------------------------*/
  34 %}
  35
  36 %option prefix="cmCTestResourceGroups_yy"
  37
  38 %option reentrant
  39 %option noyywrap
  40 %option nodefault
  41 %pointer
  42
  43 %s RESOURCE_GROUPS_START
  44 %s RESOURCE_GROUPS_END
  45 %s RESOURCE_START
  46 %s RESOURCE_COUNT
  47 %s RESOURCE_END
  48
  49 NUMBER [0-9]+
  50 IDENTIFIER [a-z_][a-z0-9_]*
  51
  52 %%
  53
  54 <INITIAL,RESOURCE_GROUPS_START,RESOURCE_START>{IDENTIFIER}: {
  55   BEGIN(RESOURCE_COUNT);
  56   yyextra->SetResourceType(std::string(yytext, yyleng - 1));
  57 }
  58
  59 <INITIAL,RESOURCE_GROUPS_START>{NUMBER} {
  60   BEGIN(RESOURCE_GROUPS_END);
  61   std::size_t len = yyleng;
  62   yyextra->SetProcessCount(std::stoll(yytext, &len, 10));
  63 }
  64
  65 <RESOURCE_COUNT>{NUMBER} {
  66   BEGIN(RESOURCE_END);
  67   std::size_t len = yyleng;
  68   yyextra->SetNeededSlots(std::stoll(yytext, &len, 10));
  69   yyextra->WriteRequirement();
  70 }
  71
  72 <RESOURCE_GROUPS_END,RESOURCE_END>,+ {
  73   BEGIN(RESOURCE_START);
  74 }
  75
  76 <INITIAL,RESOURCE_GROUPS_START,RESOURCE_START>;+ {
  77   BEGIN(RESOURCE_GROUPS_START);
  78 }
  79
  80 <RESOURCE_GROUPS_END,RESOURCE_END>;+ {
  81   BEGIN(RESOURCE_GROUPS_START);
  82   yyextra->WriteProcess();
  83 }
  84
  85 <RESOURCE_START,RESOURCE_GROUPS_END,RESOURCE_END><<EOF>> {
  86   yyextra->WriteProcess();
  87   return 0;
  88 }
  89
  90 <INITIAL,RESOURCE_GROUPS_START><<EOF>> {
  91   return 0;
  92 }
  93
  94 <<EOF>> {
  95   return 1;
  96 }
  97
  98 .|\n {
  99   return 1;
 100 }
 101
 102 %%
 103
 104 /*--------------------------------------------------------------------------*/
 105
 106 #endif /* __clang_analyzer__ */