CompileFlags.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #-----------------------------------------------------------------------------
   5 # set some special flags for different compilers
   6 #
   7 if(WIN32 AND CMAKE_C_COMPILER_ID STREQUAL "Intel")
   8   set(_INTEL_WINDOWS 1)
   9 endif()
  10
  11 if(WIN32 AND CMAKE_C_COMPILER_ID MATCHES "^(Clang|IntelLLVM)$"
  12    AND "x${CMAKE_CXX_SIMULATE_ID}" STREQUAL "xMSVC")
  13   set(_CLANG_MSVC_WINDOWS 1)
  14 endif()
  15
  16 # Disable deprecation warnings for standard C functions.
  17 # really only needed for newer versions of VS, but should
  18 # not hurt other versions, and this will work into the
  19 # future
  20 if(MSVC OR _INTEL_WINDOWS OR _CLANG_MSVC_WINDOWS)
  21   add_compile_definitions(_CRT_SECURE_NO_DEPRECATE _CRT_NONSTDC_NO_DEPRECATE)
  22 else()
  23 endif()
  24
  25 # MSVC 14.28 enables C5105, but the Windows SDK 10.0.18362.0 triggers it.
  26 if(CMAKE_C_COMPILER_ID STREQUAL "MSVC" AND NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 19.28)
  27   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -wd5105")
  28   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -wd5105")
  29 endif()
  30
  31 # Use a stack size large enough for CMake_DEFAULT_RECURSION_LIMIT.
  32 if(MSVC)
  33   string(APPEND CMAKE_EXE_LINKER_FLAGS " ${CMAKE_CXX_LINKER_WRAPPER_FLAG}-stack:10000000")
  34 elseif(MINGW OR MSYS OR CYGWIN)
  35   string(APPEND CMAKE_EXE_LINKER_FLAGS " -Wl,--stack,10000000")
  36 elseif(_CLANG_MSVC_WINDOWS AND "x${CMAKE_CXX_COMPILER_FRONTEND_VARIANT}" STREQUAL "xGNU")
  37   string(APPEND CMAKE_EXE_LINKER_FLAGS " -Xlinker -stack:20000000")
  38 endif()
  39
  40 # Silence "Additional optimization may be attained by recompiling and
  41 # specifying MAXMEM option" warning on XLC (AIX)
  42 if(CMAKE_CXX_COMPILER_ID MATCHES "^(XL|XLClang)$")
  43   string(APPEND CMAKE_CXX_FLAGS " -qmaxmem=-1")
  44 endif()
  45
  46 # Silence duplicate symbol warnings on AIX
  47 if(CMAKE_SYSTEM_NAME MATCHES "AIX")
  48   if(NOT CMAKE_COMPILER_IS_GNUCXX)
  49     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -bhalt:5 ")
  50   endif()
  51 endif()
  52
  53 if(CMAKE_SYSTEM MATCHES "OSF1-V")
  54   if(NOT CMAKE_COMPILER_IS_GNUCXX)
  55     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -timplicit_local -no_implicit_include ")
  56   endif()
  57 endif()
  58
  59 # Workaround for short jump tables on PA-RISC
  60 if(CMAKE_SYSTEM_PROCESSOR MATCHES "^parisc")
  61   if(CMAKE_COMPILER_IS_GNUCC)
  62     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mlong-calls")
  63   endif()
  64   if(CMAKE_COMPILER_IS_GNUCXX)
  65     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mlong-calls")
  66   endif()
  67 endif()
  68
  69 # Use 64-bit off_t on 32-bit Linux
  70 if (CMAKE_SYSTEM_NAME STREQUAL "Linux" AND CMAKE_SIZEOF_VOID_P EQUAL 4)
  71   # ensure 64bit offsets are used for filesystem accesses for 32bit compilation
  72   add_compile_definitions(_FILE_OFFSET_BITS=64)
  73 endif()
  74
  75 # Workaround for TOC Overflow on ppc64
  76 set(bigTocFlag "")
  77 if(CMAKE_SYSTEM_NAME STREQUAL "AIX" AND
  78    CMAKE_SYSTEM_PROCESSOR MATCHES "powerpc")
  79   set(bigTocFlag "-Wl,-bbigtoc")
  80 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux" AND
  81    CMAKE_SYSTEM_PROCESSOR MATCHES "ppc64")
  82   set(bigTocFlag "-Wl,--no-multi-toc")
  83 endif()
  84 if(bigTocFlag)
  85   include(CheckCXXLinkerFlag)
  86   check_cxx_linker_flag(${bigTocFlag} BIG_TOC_FLAG_SUPPORTED)
  87   if(BIG_TOC_FLAG_SUPPORTED)
  88     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${bigTocFlag}")
  89   endif()
  90 endif()
  91
  92 if (CMAKE_CXX_COMPILER_ID STREQUAL SunPro AND
  93     NOT DEFINED CMAKE_CXX${CMAKE_CXX_STANDARD}_STANDARD_COMPILE_OPTION)
  94   if (NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.13)
  95     if (NOT CMAKE_CXX_STANDARD OR CMAKE_CXX_STANDARD EQUAL 98)
  96       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++03")
  97     endif()
  98   else()
  99     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -library=stlport4")
 100   endif()
 101 endif()
 102
 103 foreach(lang IN ITEMS C CXX)
 104   # Suppress warnings from PGI compiler.
 105   if (CMAKE_${lang}_COMPILER_ID STREQUAL "PGI")
 106     set(CMAKE_${lang}_FLAGS "${CMAKE_${lang}_FLAGS} -w")
 107   endif()
 108 endforeach()
 109
 110 # use the ansi CXX compile flag for building cmake
 111 if (CMAKE_ANSI_CXXFLAGS)
 112   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_ANSI_CXXFLAGS}")
 113 endif ()
 114
 115 if (CMAKE_ANSI_CFLAGS)
 116   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${CMAKE_ANSI_CFLAGS}")
 117 endif ()
 118
 119 # Allow per-translation-unit parallel builds when using MSVC
 120 if(CMAKE_GENERATOR MATCHES "Visual Studio" AND
 121    (CMAKE_C_COMPILER_ID MATCHES "MSVC|Intel" OR
 122    CMAKE_CXX_COMPILER_ID MATCHES "MSVC|Intel"))
 123
 124   set(CMake_MSVC_PARALLEL ON CACHE STRING "\
 125 Enables /MP flag for parallel builds using MSVC. Specify an \
 126 integer value to control the number of threads used (Only \
 127 works on some older versions of Visual Studio). Setting to \
 128 ON lets the toolchain decide how many threads to use. Set to \
 129 OFF to disable /MP completely." )
 130
 131   if(CMake_MSVC_PARALLEL)
 132     if(CMake_MSVC_PARALLEL GREATER 0)
 133       string(APPEND CMAKE_C_FLAGS " /MP${CMake_MSVC_PARALLEL}")
 134       string(APPEND CMAKE_CXX_FLAGS " /MP${CMake_MSVC_PARALLEL}")
 135     else()
 136       string(APPEND CMAKE_C_FLAGS " /MP")
 137       string(APPEND CMAKE_CXX_FLAGS " /MP")
 138     endif()
 139   endif()
 140 endif()
 141
 142 # Get rid of excess -Wunused-but-set-variable on release builds with LCC >= 1.26
 143 foreach(l IN ITEMS C CXX)
 144   if(CMAKE_${l}_COMPILER_ID STREQUAL "LCC" AND NOT CMAKE_${l}_COMPILER_VERSION VERSION_LESS 1.26)
 145     foreach(c IN ITEMS MINSIZEREL RELEASE RELWITHDEBINFO)
 146       string(APPEND "CMAKE_${l}_FLAGS_${c}" " -Wno-unused-but-set-variable")
 147     endforeach()
 148   endif()
 149 endforeach()