Modules/BasicConfigVersion-SameMajorVersion.cmake.in

   1 # This is a basic version file for the Config-mode of find_package().
   2 # It is used by write_basic_package_version_file() as input file for configure_file()
   3 # to create a version-file which can be installed along a config.cmake file.
   4 #
   5 # The created file sets PACKAGE_VERSION_EXACT if the current version string and
   6 # the requested version string are exactly the same and it sets
   7 # PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
   8 # but only if the requested major version is the same as the current one.
   9 # The variable CVF_VERSION must be set before calling configure_file().
  10
  11
  12 set(PACKAGE_VERSION "@CVF_VERSION@")
  13
  14 if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
  15   set(PACKAGE_VERSION_COMPATIBLE FALSE)
  16 else()
  17
  18   if("@CVF_VERSION@" MATCHES "^([0-9]+)\\.")
  19     set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
  20     if(NOT CVF_VERSION_MAJOR VERSION_EQUAL 0)
  21       string(REGEX REPLACE "^0+" "" CVF_VERSION_MAJOR "${CVF_VERSION_MAJOR}")
  22     endif()
  23   else()
  24     set(CVF_VERSION_MAJOR "@CVF_VERSION@")
  25   endif()
  26
  27   if(PACKAGE_FIND_VERSION_RANGE)
  28     # both endpoints of the range must have the expected major version
  29     math (EXPR CVF_VERSION_MAJOR_NEXT "${CVF_VERSION_MAJOR} + 1")
  30     if (NOT PACKAGE_FIND_VERSION_MIN_MAJOR STREQUAL CVF_VERSION_MAJOR
  31         OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND NOT PACKAGE_FIND_VERSION_MAX_MAJOR STREQUAL CVF_VERSION_MAJOR)
  32           OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND NOT PACKAGE_FIND_VERSION_MAX VERSION_LESS_EQUAL CVF_VERSION_MAJOR_NEXT)))
  33       set(PACKAGE_VERSION_COMPATIBLE FALSE)
  34     elseif(PACKAGE_FIND_VERSION_MIN_MAJOR STREQUAL CVF_VERSION_MAJOR
  35         AND ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS_EQUAL PACKAGE_FIND_VERSION_MAX)
  36         OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MAX)))
  37       set(PACKAGE_VERSION_COMPATIBLE TRUE)
  38     else()
  39       set(PACKAGE_VERSION_COMPATIBLE FALSE)
  40     endif()
  41   else()
  42     if(PACKAGE_FIND_VERSION_MAJOR STREQUAL CVF_VERSION_MAJOR)
  43       set(PACKAGE_VERSION_COMPATIBLE TRUE)
  44     else()
  45       set(PACKAGE_VERSION_COMPATIBLE FALSE)
  46     endif()
  47
  48     if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
  49       set(PACKAGE_VERSION_EXACT TRUE)
  50     endif()
  51   endif()
  52 endif()
  53
  54 @CVF_ARCH_INDEPENDENT_CHECK@