CMakeLists.txt

   1 project(kdepim)
   2
   3 # where to look first for cmake modules. This line must be the first one or cmake will use the system's FindFoo.cmake
   4 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules")
   5
   6 ############### Build Options ###############
   7
   8 option(KDEPIM_BUILD_EXAMPLES "Build the kdepim example applications." FALSE)
   9 option(KDEPIM_BUILD_MOBILE "Build the mobile applications. Note that you have to enable KDEPIM_MOBILE_UI if you want to run these applications on a mobile device." TRUE)
  10 option(KDEPIM_ENTERPRISE_BUILD "Enable features specific to the enterprise branch, which are normally disabled. Also, it disables many components not needed for Kontact such as the Kolab client." FALSE)
  11 option(KDEPIM_MOBILE_UI "Build UI for mobile devices instead of for desktops" FALSE)
  12 option(KDEPIM_ONLY_KLEO "Only build Kleopatra. This option will build only libkleo and kleopatra" FALSE)
  13 option(KDEPIM_BUILD_STATIC "Build KDEPIM static." FALSE)
  14 option(KDEPIM_BUILD_DESKTOP "Build Desktop Applications. Can be deactivated for mobile" TRUE)
  15 option(KDEPIM_NO_NEPOMUK "Build the mail libraries and applications without nepomuk dependency" FALSE)
  16 option(KDEPIM_NO_WEBKIT "Do not use WebKit in the kdepim applications" FALSE)
  17
  18 if(KDEPIM_BUILD_STATIC)
  19   set(LIBRARY_TYPE STATIC)
  20 else()
  21   set(LIBRARY_TYPE SHARED)
  22 endif()
  23
  24 add_definitions( -DDISABLE_NEPOMUK_LEGACY )
  25 add_definitions(-DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
  26
  27 if(KDEPIM_NO_NEPOMUK)
  28   add_definitions(-DKDEPIM_NO_NEPOMUK)
  29 endif()
  30
  31 if(KDEPIM_NO_WEBKIT)
  32   add_definitions(-DKDEPIM_NO_WEBKIT)
  33 endif()
  34
  35 # cmake would not find kde for xcompile if that is not set
  36 if(WINCE)
  37     set(KDE4_DATA_DIR "${CMAKE_PREFIX_PATH}/share/apps")
  38     set(LIBRARY_TYPE STATIC)
  39     add_definitions(-DKDELIBS_STATIC_LIBS)
  40     add_definitions(-DKDEPIM_STATIC_LIBS)
  41 endif()
  42
  43 if(KDEPIM_ENTERPRISE_BUILD)
  44   message(STATUS "Enterprise build is enabled.")
  45 endif()
  46
  47 # if KDEPIM_ONLY_KLEO is defined, KDEPIM_BUILD_MOBILE and KDEPIM_MOBILE_UI are disabled.
  48 if(KDEPIM_ONLY_KLEO)
  49  set(KDEPIM_BUILD_MOBILE FALSE)
  50  set(KDEPIM_MOBILE_UI FALSE)
  51  set(KDEPIM_DEFINITIONS "-DHAVE_CONFIG_H=1")
  52  message(STATUS "Only libkleo and Kleopatra will be built.")
  53 endif()
  54
  55 if(KDEPIM_MOBILE_UI)
  56     # Build the mobile applications
  57     set(KDEPIM_BUILD_MOBILE TRUE)
  58 endif()
  59
  60 # config-enterprise.h is needed for both ENTERPRISE_BUILD and BUILD_EVERYTHING
  61 configure_file(config-enterprise.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-enterprise.h )
  62
  63 ############### generate kdepim-version.h ###############
  64 # Support for the GIT revision number in kdepim-version.h
  65 if(EXISTS "${kdepim_SOURCE_DIR}/.git")
  66   find_program(GIT_EXECUTABLE NAMES git)
  67   if(GIT_EXECUTABLE)
  68     message(STATUS "Found git: ${GIT_EXECUTABLE}")
  69     execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  70                     WORKING_DIRECTORY ${kdepim_SOURCE_DIR}
  71                     OUTPUT_VARIABLE kdepim_git_revision)
  72     string(REGEX REPLACE "\n" "" kdepim_git_revision "${kdepim_git_revision}")
  73     set(kdepim_git_revision "git-${kdepim_git_revision}")
  74
  75     execute_process(COMMAND ${GIT_EXECUTABLE} log -1 --oneline --format=%ci
  76                     WORKING_DIRECTORY ${kdepim_SOURCE_DIR}
  77                     OUTPUT_VARIABLE kdepim_git_last_change)
  78     string(REGEX REPLACE " [-0-9:+ ]*\n" "" kdepim_git_last_change "${kdepim_git_last_change}")
  79   endif()
  80 endif()
  81
  82 # KDEPIM_VERSION
  83 # Version scheme: "x.y.z build".
  84 #
  85 # x is the version number.
  86 # y is the major release number.
  87 # z is the minor release number.
  88 #
  89 # "x.y.z" follow the kdelibs version kdepim is released with.
  90 #
  91 # If "z" is 0, it the version is "x.y"
  92 #
  93 # KDEPIM_DEV_VERSION
  94 # is empty for final versions. For development versions "build" is
  95 # something like "pre", "alpha1", "alpha2", "beta1", "beta2", "rc1", "rc2".
  96 #
  97 # Examples in chronological order:
  98 #
  99 #    3.0
 100 #    3.0.1
 101 #    3.1 alpha1
 102 #    3.1 beta1
 103 #    3.1 beta2
 104 #    3.1 rc1
 105 #    3.1
 106 #    3.1.1
 107 #    3.2 pre
 108 #    3.2 alpha1
 109
 110 # Do NOT add quote
 111 set(KDEPIM_DEV_VERSION pre)
 112
 113 # add an extra space
 114 if(DEFINED KDEPIM_DEV_VERSION)
 115   set(KDEPIM_DEV_VERSION " ${KDEPIM_DEV_VERSION}")
 116 endif()
 117
 118 set(KDEPIM_VERSION "4.9${KDEPIM_DEV_VERSION}")
 119
 120 configure_file(kdepim-version.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/kdepim-version.h @ONLY)
 121
 122 ############### search packages used by KDE ###############
 123
 124 # It is needed otherwise it finds the kde4-config of the target platform
 125 if(WINCE)
 126   find_program(KDE4_KDECONFIG_EXECUTABLE NAMES kde4-config PATHS ${HOST_BINDIR} NO_DEFAULT_PATH)
 127 endif()
 128
 129 find_package(KDE4 4.7.0 REQUIRED)
 130 include(KDE4Defaults)
 131 include(MacroLibrary)
 132 include(CheckIncludeFiles)
 133 include(MacroBoolTo01)
 134 find_package(KdepimLibs 4.8.43 REQUIRED)
 135
 136 ############### Load the CTest options ###############
 137
 138 # CMake is irritating and doesn't allow setting the tests timeout globally.
 139 # Let's work around this. The global timeout is now 2 minutes.
 140 set(_DartConfigFile "${CMAKE_BINARY_DIR}/DartConfiguration.tcl")
 141 if(EXISTS ${_DartConfigFile})
 142   set(DartTestingTimeout "120")
 143   file(READ ${_DartConfigFile} _DartConfigFile_content)
 144   string(REGEX REPLACE "TimeOut: 1500" "TimeOut: ${DartTestingTimeout}" _DartConfigFile_content ${_DartConfigFile_content})
 145   file(WRITE ${_DartConfigFile} ${_DartConfigFile_content})
 146 endif()
 147
 148 # CTestCustom.cmake has to be in the CTEST_BINARY_DIR.
 149 # in the KDE build system, this is the same as CMAKE_BINARY_DIR.
 150 configure_file(${CMAKE_SOURCE_DIR}/CTestCustom.cmake ${CMAKE_BINARY_DIR}/CTestCustom.cmake)
 151
 152 ############### search Boost ###############
 153
 154 find_package(Boost 1.34.0)
 155 macro_log_feature(Boost_FOUND "Boost" "Boost C++ Libraries" "http://www.boost.org" TRUE "1.34.0" "Required by several critical KDEPIM apps.")
 156
 157 # Kleopatra needs to know if the topological.hpp header exists (part of Boost_graph).
 158 find_path(Boost_TOPOLOGICAL_SORT_DIR NAMES boost/graph/topological_sort.hpp PATHS ${Boost_INCLUDE_DIRS})
 159 macro_log_feature(Boost_TOPOLOGICAL_SORT_DIR "The Boost Topological_sort header" "topological_sort.hpp (part of Boost_graph)" "http://www.boost.org/" FALSE "" "Necessary to build kleopatra")
 160
 161 ############### Windows specific ###############
 162
 163 if(WIN32)
 164   # detect oxygen icon dir at configure time based on KDEDIRS - there may be different package installation locations
 165   execute_process(COMMAND "${KDE4_KDECONFIG_EXECUTABLE}" --path icon OUTPUT_VARIABLE _dir ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
 166   file(TO_CMAKE_PATH "${_dir}" __dir)
 167   find_path(KDE4_ICON_DIR oxygen PATHS
 168     ${__dir}
 169   )
 170   message(STATUS "using oxygen application icons from ${KDE4_ICON_DIR}")
 171 else()
 172     set (KDE4_ICON_DIR  ${CMAKE_INSTALL_PREFIX}/share/icons)
 173 endif()
 174
 175 ############### ONLY_KLEO ###############
 176
 177 # The KDEPIM_ONLY_KLEO option is true
 178 if(KDEPIM_ONLY_KLEO)
 179   find_package(QGpgme)
 180   macro_log_feature(QGPGME_FOUND "QGpgME" "The QGpgME library" "http://www.kde.org" TRUE "" "QGpgME is required to build Kleopatra.")
 181
 182   add_definitions(${QT_DEFINITIONS} ${KDE4_DEFINITIONS} ${KDEPIM_DEFINITIONS} -DQT3_SUPPORT_WARNINGS)
 183   include_directories (${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} ${KDE4_INCLUDES} ${KDEPIMLIBS_INCLUDE_DIRS} ${QT_QTDBUS_INCLUDE_DIR})
 184   include(kleopatra/ConfigureChecks.cmake)
 185
 186   add_subdirectory(libkleo)
 187   if(Boost_TOPOLOGICAL_SORT_DIR)
 188     add_subdirectory(kleopatra)
 189   endif()
 190 else()
 191
 192 # Otherwise...
 193 ############### Find the stuff we need ###############
 194   set(AKONADI_MIN_VERSION 1.4.91)
 195   find_package(Akonadi QUIET NO_MODULE ${AKONADI_MIN_VERSION})
 196   macro_log_feature(Akonadi_FOUND "Akonadi" "Akonadi server libraries" "http://pim.kde.org/akonadi" TRUE "${AKONADI_MIN_VERSION}" "Akonadi is required to build KDEPIM")
 197
 198   find_package(ZLIB)
 199   macro_log_feature(ZLIB_FOUND "ZLib" "The Zlib compression library" "http://www.zlib.net" TRUE "" "")
 200
 201   find_package(Strigi)
 202   macro_log_feature(STRIGI_FOUND "Strigi" "Index metadata of files" "http://strigi.sourceforge.net" TRUE "" "")
 203
 204   find_package(QGpgme)
 205   macro_log_feature(QGPGME_FOUND "QGpgME" "The QGpgME library" "http://www.kde.org" FALSE "" "QGpgME is required to build KMail, KOrganizer and Kleopatra")
 206
 207   set(SDO_MIN_VERSION 0.9)
 208   set(SOPRANO_MIN_VERSION 2.3.70)
 209
 210   find_package(SharedDesktopOntologies ${SDO_MIN_VERSION})
 211   macro_log_feature(SHAREDDESKTOPONTOLOGIES_FOUND "Shared desktop ontologies" "Desktop ontologies" "http://oscaf.sourceforge.net" TRUE "${SDO_MIN_VERSION}" "Ontologies necessary for the Nepomuk semantic desktop.")
 212
 213   find_package(Soprano)
 214   macro_log_feature(Soprano_FOUND "Soprano" "Semantic Desktop Storing" "http://soprano.sourceforge.net" TRUE "${SOPRANO_MIN_VERSION}" "Soprano is needed for Nepomuk")
 215   include(SopranoAddOntology)
 216
 217   find_package(Grantlee QUIET NO_MODULE)
 218   macro_log_feature(Grantlee_FOUND "Grantlee" "The Grantlee Template System" "http://www.grantlee.org" FALSE "" "Templating and theming for KJots and KaddressBook." )
 219
 220   if(NOT KDEPIM_NO_NEPOMUK)
 221     find_package(Nepomuk)
 222     macro_log_feature(Nepomuk_FOUND "Nepomuk" "The Nepomuk libraries" "http://www.kde.org" TRUE "" "Nepomuk extends the search and tagging functionalities in KMail and Akonadi")
 223   endif()
 224
 225   find_package(LibXslt)
 226   macro_log_feature(XSLTPROC_EXECUTABLE "xsltproc" "The command line XSLT processor from libxslt" "http://xmlsoft.org/XSLT/" TRUE "" "Required to generate the D-Bus interfaces.")
 227
 228 ############### Desktop vs. Mobile options ##############
 229
 230   if(KDEPIM_MOBILE_UI)
 231     macro_log_feature(QT_QTDECLARATIVE_FOUND "QtDeclarative" "Qt Declarative (QML) module" "http://qt.nokia.com" TRUE "4.7" "Required for building mobile UI")
 232     add_definitions( -DKDEPIM_MOBILE_UI )
 233   else()
 234     macro_log_feature(QT_QTDECLARATIVE_FOUND "QtDeclarative" "Qt Declarative (QML) module" "http://qt.nokia.com" FALSE "4.7" "Required for building the mobile applications")
 235     if(NOT QT_QTDECLARATIVE_FOUND)
 236       message(STATUS "The Qt Declarative (QML) module was not found. The mobile applications will not be built.")
 237       set(KDEPIM_BUILD_MOBILE FALSE)
 238     endif()
 239   endif()
 240
 241 ############### Needed commands before building anything ###############
 242
 243   add_definitions (${QT_DEFINITIONS} ${KDE4_DEFINITIONS} ${KDEPIM_DEFINITIONS} ${AKONADI_DEFINITIONS})
 244
 245   include_directories (${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} ${KDEPIMLIBS_INCLUDE_DIRS} ${KDE4_INCLUDES} ${QT_QTDBUS_INCLUDE_DIR} ${Boost_INCLUDE_DIR})
 246
 247   if(NOT KDEPIMLIBS_KRESOURCES_LIBRARY)
 248     add_definitions( -DKDEPIM_NO_KRESOURCES )
 249   endif()
 250
 251 ############### Macros ###############
 252
 253   # generates a D-Bus interface description from a KConfigXT file
 254   macro(kcfg_generate_dbus_interface _kcfg _name)
 255     add_custom_command(
 256       OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_name}.xml
 257       COMMAND ${XSLTPROC_EXECUTABLE} --stringparam interfaceName ${_name}
 258       ${KDEPIMLIBS_DATA_DIR}/akonadi-kde/kcfg2dbus.xsl
 259       ${_kcfg}
 260       > ${CMAKE_CURRENT_BINARY_DIR}/${_name}.xml
 261       DEPENDS ${KDEPIMLIBS_DATA_DIR}/akonadi-kde/kcfg2dbus.xsl
 262       ${_kcfg}
 263       )
 264   endmacro(kcfg_generate_dbus_interface)
 265
 266 ############### Code used in several places ###############
 267 # TODO Remove from the top CMakeLists.
 268
 269 # used in knotes, kontact/plugins/knotes, wizard
 270   set(libknotesresources_SRCS
 271     ${CMAKE_SOURCE_DIR}/knotes/resourcemanager.cpp
 272     ${CMAKE_SOURCE_DIR}/knotes/resourcenotes.cpp
 273     ${CMAKE_SOURCE_DIR}/knotes/resourcelocal.cpp
 274     ${CMAKE_SOURCE_DIR}/knotes/resourcelocalconfig.cpp
 275   )
 276
 277 # used in knotes, kontact/plugins/knotes
 278   set(libknoteseditor_SRCS
 279     ${CMAKE_SOURCE_DIR}/knotes/knoteedit.cpp
 280   )
 281
 282 ############### Now, we add the PIM components ###############
 283
 284   include (kleopatra/ConfigureChecks.cmake)
 285
 286   # These targets will always be built before anything else.
 287
 288   add_subdirectory(ontologies) # must be the first one.
 289   add_subdirectory(akonadi_next)
 290   add_subdirectory(libkdepim)
 291   add_subdirectory(calendarsupport)
 292   add_subdirectory(calendarviews)
 293   add_subdirectory(incidenceeditor-ng)
 294   add_subdirectory(libkdepimdbusinterfaces)
 295   add_subdirectory(libkleo)
 296   add_subdirectory(libkpgp)
 297   add_subdirectory(libksieve)
 298   add_subdirectory(kdgantt2)
 299   add_subdirectory(icons)
 300   add_subdirectory(messagecore)
 301   if(NOT WINCE)
 302     add_subdirectory(messagelist)
 303   else()
 304     # We need to compile runtime in kdepim because of the static
 305     # linking of korgac and the applications need to link against
 306     # plugins like the serializer plugins. If the korgac would
 307     # move to runtime this can be avoided
 308     add_subdirectory(runtime)
 309   endif()
 310   add_subdirectory(templateparser)
 311
 312   if(QGPGME_FOUND)
 313     if(Boost_TOPOLOGICAL_SORT_DIR)
 314       macro_optional_add_subdirectory(kleopatra)
 315     endif()
 316   endif()
 317
 318   # The following components depend on QGpgME.
 319   set(MESSAGEVIEWER_SUPPORTED TRUE)
 320   add_subdirectory(messageviewer)
 321   macro_optional_add_subdirectory(messagecomposer)
 322   add_subdirectory(mailcommon) # TODO: does this make sense?!?
 323   add_subdirectory(mailfilteragent)
 324   macro_optional_add_subdirectory(kmail)
 325
 326   if(KDEPIM_BUILD_MOBILE)
 327     add_subdirectory(mobile)
 328   endif()
 329
 330   if(KDEPIM_BUILD_EXAMPLES)
 331     add_subdirectory(examples)
 332   endif()
 333
 334   # If kmail is compiled, KMAIL_SUPPORTED is true (used in several places)
 335   if(BUILD_kmail)
 336     set(KMAIL_SUPPORTED TRUE)
 337     add_definitions(-DKMAIL_SUPPORTED)
 338   endif()
 339
 340   macro_optional_add_subdirectory(korganizer)
 341   if(KDEPIM_BUILD_DESKTOP)
 342     macro_optional_add_subdirectory(akregator)
 343     macro_optional_add_subdirectory(archivemailagent)
 344     macro_optional_add_subdirectory(importwizard)
 345     macro_optional_add_subdirectory(kaddressbook)
 346     macro_optional_add_subdirectory(kmailcvt)
 347     macro_optional_add_subdirectory(knotes)
 348     macro_optional_add_subdirectory(ksendemail)
 349     macro_optional_add_subdirectory(ktnef)
 350     macro_optional_add_subdirectory(mailimporter)
 351     macro_optional_add_subdirectory(backupmail)
 352
 353     if(KDEPIMLIBS_KCAL_LIBRARY)
 354       macro_optional_add_subdirectory(blogilo)
 355     endif()
 356
 357     if(Grantlee_FOUND)
 358       macro_optional_add_subdirectory(kjots)
 359     endif()
 360
 361     if(KDEPIMLIBS_KRESOURCES_LIBRARY)
 362       macro_optional_add_subdirectory(kalarm)
 363
 364       if(QT_QT3SUPPORT_FOUND)
 365         macro_optional_add_subdirectory(knode)
 366       endif()
 367
 368       if(Q_WS_X11)
 369         macro_optional_add_subdirectory(ktimetracker)
 370       endif()
 371
 372     endif()
 373     macro_optional_add_subdirectory(kontact) # must be the last one.
 374   endif()
 375
 376   macro_optional_add_subdirectory(akonadiconsole)
 377   macro_optional_add_subdirectory(console)
 378   macro_optional_add_subdirectory(strigi-analyzer)
 379
 380   # These targets depend on optional applications
 381   if(KDEPIMLIBS_KRESOURCES_LIBRARY)
 382     add_subdirectory(kresources) # Must be after KAddressbook
 383   endif()
 384
 385   add_subdirectory(plugins) # Must be after KMail
 386
 387 endif()
 388
 389 # doc must be a subdir of kdepim or packagers will kill us
 390 macro_optional_add_subdirectory(doc)
 391
 392
 393 # We really want to encourage users to enable/install QGpgME from kdepimlibs
 394 if(NOT QGPGME_FOUND)
 395   # Users must be aware that QGpgMe is really needed
 396   message(STATUS "*** WARNING: QGpgME is not installed on your system ***")
 397   message(STATUS "*** It is required if you want to use KMail, KOrganizer or Kleopatra ***")
 398   message(STATUS "*** You are really encouraged to install it ***")
 399 endif()
 400
 401 # All done, let's display what we found...
 402 macro_display_feature_log()