knotes/src/CMakeLists.txt

   1 add_definitions(-DTRANSLATION_DOMAIN=\"knotes\")
   2
   3 configure_file(config-knotes.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-knotes.h )
   4
   5 add_subdirectory(icons)
   6
   7 if (BUILD_TESTING)
   8     add_subdirectory(print/autotests)
   9 endif()
  10
  11 add_subdirectory(kontactplugin)
  12 add_subdirectory(kconf_update)
  13
  14 ########### next target ###############
  15
  16 set(libknotesprivate_config_lib_SRCS
  17     configdialog/knotesimpleconfigdialog.cpp
  18     configdialog/knoteconfigdialog.cpp
  19     configdialog/knotedisplayconfigwidget.cpp
  20     configdialog/knoteeditorconfigwidget.cpp
  21     configdialog/knotecollectionconfigwidget.cpp
  22     )
  23
  24 set(libknotesprivate_print_lib_SRCS
  25     print/knoteprintselectthemedialog.cpp
  26     print/knoteprintselectthemecombobox.cpp
  27     print/knoteprinter.cpp
  28     print/knoteprintobject.cpp
  29     print/knotegrantleeprint.cpp
  30     )
  31
  32 set(libknotesprivate_lib_SRCS
  33     ${libknotesprivate_config_lib_SRCS}
  34     ${libknotesprivate_print_lib_SRCS}
  35     knoteedit.cpp
  36     knotes_debug.cpp
  37     notes/knotedisplaysettings.cpp
  38     utils/knoteutils.cpp
  39     notes/knoteinterface.cpp
  40     notes/knotesmigrateapplication.cpp
  41     finddialog/knotefinddialog.cpp
  42     )
  43
  44 configure_file(settings/knotesglobalconfig.kcfg.cmake ${CMAKE_CURRENT_BINARY_DIR}/knotesglobalconfig.kcfg )
  45
  46 set( libknotesprivate_kcfg_lib_SRCS settings/knotesglobalconfig.kcfgc )
  47
  48 kconfig_add_kcfg_files(libknotesprivate_kcfg_lib_SRCS ${libknotesprivate_kcfg_lib_SRCS})
  49 ecm_qt_declare_logging_category(libknotesprivate_lib_SRCS HEADER knotes_debug.h IDENTIFIER KNOTES_LOG CATEGORY_NAME log_knotes)
  50
  51 add_library(knotesprivate ${libknotesprivate_lib_SRCS} ${libknotesprivate_kcfg_lib_SRCS} )
  52 generate_export_header(knotesprivate BASE_NAME knotes)
  53
  54 target_link_libraries(knotesprivate
  55     PUBLIC
  56     KF5::IconThemes
  57     PRIVATE
  58     KF5::PimCommon
  59     KF5::KCMUtils Grantlee5::Templates KF5::NewStuff KF5::WindowSystem Qt5::PrintSupport KF5::TextWidgets KF5::I18n notesharedprivate KF5::AkonadiSearchPIM KF5::AkonadiNotes KF5::PimTextEdit
  60     )
  61
  62 set_target_properties(knotesprivate
  63     PROPERTIES VERSION ${KDEPIM_LIB_VERSION} SOVERSION ${KDEPIM_LIB_SOVERSION}
  64     )
  65
  66 install(TARGETS knotesprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
  67
  68
  69 set(knotes_SRCS knotes_debug.cpp
  70     apps/main.cpp
  71     apps/application.cpp
  72     apps/knotesapp.cpp
  73     apps/knotesakonaditray.cpp
  74     dialog/knoteskeydialog.cpp
  75     dialog/knotedeleteselectednotesdialog.cpp
  76     notes/knotebutton.cpp
  77     print/knoteprintselectednotesdialog.cpp
  78     notes/knote.cpp
  79     dialog/knoteselectednotesdialog.cpp
  80     )
  81
  82
  83 qt5_add_dbus_adaptor(knotes_SRCS  apps/org.kde.KNotes.xml apps/knotesapp.h KNotesApp )
  84
  85 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/icons/*-apps-knotes.png")
  86 ecm_add_app_icon(knotes_SRCS ICONS ${ICONS_SRCS})
  87
  88 add_executable(knotes ${knotes_SRCS})
  89
  90 target_link_libraries(knotes
  91     knotesprivate
  92     KF5::KCMUtils
  93     KF5::PimCommon
  94     KF5::DNSSD
  95     KF5::KontactInterface
  96     notesharedprivate
  97     KF5::AkonadiCore
  98     KF5::Mime
  99     KF5::GlobalAccel
 100     KF5::KDELibs4Support
 101     KF5::AkonadiSearchDebug
 102     KF5::AkonadiNotes
 103     KF5::Crash
 104     )
 105 if (Qt5X11Extras_FOUND)
 106     target_link_libraries(knotes Qt5::X11Extras ${X11_LIBRARIES})
 107 endif()
 108 install(TARGETS knotes  ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
 109
 110
 111 ########### next target ###############
 112 set(kcm_knotes_PART_SRCS configdialog/knoteconfigdialog.cpp configdialog/knotedisplayconfigwidget.cpp configdialog/knoteeditorconfigwidget.cpp configdialog/knotecollectionconfigwidget.cpp knotes_debug.cpp)
 113
 114 add_library(kcm_knote MODULE ${kcm_knotes_PART_SRCS} )
 115
 116 target_link_libraries(kcm_knote knotesprivate KF5::AkonadiCore  KF5::KCMUtils KF5::NewStuff KF5::WindowSystem notesharedprivate KF5::AkonadiNotes KF5::PimCommon KF5::I18n)
 117
 118 install(TARGETS kcm_knote DESTINATION ${KDE_INSTALL_PLUGINDIR})
 119
 120
 121 install(FILES
 122     data/knote_config_action.desktop
 123     data/knote_config_display.desktop
 124     data/knote_config_editor.desktop
 125     data/knote_config_network.desktop
 126     data/knote_config_print.desktop
 127     data/knote_config_collection.desktop
 128     data/knote_config_misc.desktop
 129     DESTINATION ${KDE_INSTALL_KSERVICES5DIR})
 130
 131 ########### install files ###############
 132
 133 install( PROGRAMS data/org.kde.knotes.desktop  DESTINATION ${KDE_INSTALL_APPDIR})
 134 install( FILES data/org.kde.knotes.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
 135 install( FILES ${CMAKE_CURRENT_BINARY_DIR}/knotesglobalconfig.kcfg  DESTINATION ${KDE_INSTALL_KCFGDIR})
 136 install( FILES data/knotesappui.rc data/knotesui.rc  DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/knotes)
 137 install( FILES apps/org.kde.KNotes.xml DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR})
 138 install( FILES data/knotes_printing_theme.knsrc DESTINATION ${KDE_INSTALL_CONFDIR} )
 139
 140 install(DIRECTORY print/themes/ DESTINATION ${KDE_INSTALL_DATADIR}/knotes/print/themes )