juk/configure.in.in

   1 #MIN_CONFIG(3)
   2
   3 AM_INIT_AUTOMAKE(juk,1.0)
   4
   5 artsc_config_test_path=$prefix/bin:$exec_prefix/bin:$KDEDIR/bin:$PATH
   6 AC_PATH_PROG(ARTSCCONFIG, artsc-config, no, $artsc_config_test_path)
   7
   8 if test "x$build_arts" = "xyes" && test "x$ARTSCCONFIG" != "xno" ; then
   9         LIB_ARTS="-lartskde"
  10         ARTS_PREFIX=[`$ARTSCCONFIG --arts-prefix`]
  11         ARTS_CFLAGS="-I$ARTS_PREFIX/include/arts"
  12         AC_DEFINE(HAVE_ARTS, 1, [have arts support in juk])
  13 else
  14         build_arts="no"
  15         LIB_ARTS=""
  16         ARTS_CFLAGS=""
  17         AC_DEFINE(HAVE_ARTS, 0, [no arts support in juk])
  18 fi
  19
  20 AC_SUBST(LIB_ARTS)
  21 AC_SUBST(ARTS_CFLAGS)
  22
  23 AC_ARG_WITH(tunepimp,
  24   [AC_HELP_STRING(--with-tunepimp,
  25     [enable support for TunePimp @<:@default=check@:>@])],
  26   [], with_tunepimp=check)
  27
  28 have_tunepimp=no
  29 if test "x$with_tunepimp" != xno; then
  30   KDE_CHECK_HEADER(tunepimp/tp_c.h, have_tunepimp=yes)
  31
  32   if test "x$with_tunepimp" != xcheck && test "x$have_tunepimp" != xyes; then
  33     AC_MSG_ERROR([--with-tunepimp was given, but test for TunePimp failed])
  34   fi
  35 fi
  36
  37 if test "x$have_tunepimp" = xyes; then
  38   AC_DEFINE(HAVE_TUNEPIMP, 1, [have TunePimp])
  39 else
  40   AC_DEFINE(HAVE_TUNEPIMP, 0, [have TunePimp])
  41 fi
  42
  43 AM_CONDITIONAL(link_lib_TP, test "x$have_tunepimp" = xyes)
  44
  45 AC_ARG_WITH(gstreamer,
  46   [AC_HELP_STRING(--with-gstreamer,
  47     [enable support for GStreamer @<:@default=check@:>@])],
  48   [], with_gstreamer=check)
  49
  50 have_gst=no
  51 if test "x$with_gstreamer" != xno; then
  52   # pkg-config seems to have a bug where it masks needed -L entries when it
  53   # shouldn't, so disable that.
  54
  55   PKG_CONFIG_ALLOW_SYSTEM_LIBS=1
  56   export PKG_CONFIG_ALLOW_SYSTEM_LIBS
  57
  58   dnl start with 0.8
  59   GST_MAJORMINOR=0.8
  60   GST_REQ=0.8.0
  61
  62   PKG_CHECK_MODULES(GST, \
  63     gstreamer-$GST_MAJORMINOR >= $GST_REQ \
  64     gstreamer-control-$GST_MAJORMINOR >= $GST_REQ \
  65     gstreamer-libs-$GST_MAJORMINOR >= $GST_REQ,
  66     have_gst=yes, have_gst=no)
  67
  68   if test "x$with_gstreamer" != xcheck && test "x$have_gst" != xyes; then
  69     AC_MSG_ERROR([--with-gstreamer was given, but test for GStreamer failed])
  70   fi
  71 fi
  72
  73 if test "x$have_gst" = "xno"; then
  74         GST_CFLAGS=""
  75         LDADD_GST=""
  76         LDFLAGS_GST=""
  77         AC_DEFINE(HAVE_GSTREAMER, 0, [have GStreamer])
  78 else
  79         LDADD_GST=`$PKG_CONFIG --libs-only-l gstreamer-$GST_MAJORMINOR`
  80         LDFLAGS_GST=`$PKG_CONFIG --libs-only-other gstreamer-$GST_MAJORMINOR`
  81
  82         # Append -L entries, since they are masked by --libs-only-l and
  83         # --libs-only-other
  84         LIBDIRS_GST=`$PKG_CONFIG --libs-only-L gstreamer-$GST_MAJORMINOR`
  85         LDADD_GST="$LDADD_GST $LIBDIRS_GST"
  86
  87         AC_MSG_NOTICE([GStreamer version >= $GST_REQ found.])
  88         AC_DEFINE(HAVE_GSTREAMER, 1, [have GStreamer])
  89 fi
  90
  91 AC_SUBST(GST_CFLAGS)
  92 AC_SUBST(LDADD_GST)
  93 AC_SUBST(LDFLAGS_GST)
  94
  95 # Remove this after we have ported JuK to KDE 4. -- mpyne.
  96 DO_NOT_COMPILE="$DO_NOT_COMPILE juk"
  97
  98 if test "x$have_taglib" != xyes || ( test "x$build_arts" = "xno" && test "x$have_gst" = "xno" && test "x$have_akode" = "xno") ; then
  99         DO_NOT_COMPILE="$DO_NOT_COMPILE juk"
 100 fi