kscreensaver/configure.in.in

   1
   2 AC_MSG_CHECKING(for Qt with OpenGL support)
   3 AC_CACHE_VAL(ac_cv_kde_qt_has_opengl,
   4 [
   5   AC_LANG_SAVE
   6   AC_LANG_CPLUSPLUS
   7
   8   save_CXXFLAGS="$CXXFLAGS"
   9   save_LIBS="$LIBS"
  10   save_LDFLAGS="$LDFLAGS"
  11
  12   CXXFLAGS="$CXXFLAGS -I$qt_incdir $all_includes"
  13   LDFLAGS="$LDFLAGS -L$qt_libdir $all_libraries $USER_LDFLAGS $KDE_MT_LDFLAGS"
  14   LIBS="$LIBS $LIB_QTOPENGL $KDE_MT_LIBS"
  15
  16   AC_TRY_LINK([
  17   #include <qgl.h>
  18   ],
  19   [
  20    (void)new QGLWidget((QWidget*)0);
  21   ],
  22   ac_cv_kde_qt_has_opengl=yes,
  23   ac_cv_kde_qt_has_opengl=no)
  24
  25   CXXFLAGS="$save_CXXFLAGS"
  26   LIBS="$save_LIBS"
  27   LDFLAGS="$save_LDFLAGS"
  28   AC_LANG_RESTORE
  29 ])
  30 AC_MSG_RESULT($ac_cv_kde_qt_has_opengl)
  31
  32 AC_HAVE_GL( have_gl=yes, have_gl=no )
  33
  34 AM_CONDITIONAL(COMPILE_GL_XSAVERS, test x$have_gl = xyes)
  35 AM_CONDITIONAL(COMPILE_GL_KSAVERS, test x$have_gl = xyes && test x$ac_cv_kde_qt_has_opengl = xyes)
  36 AM_CONDITIONAL(COMPILE_X11_KSAVERS, test "x$ac_x_includes" != x && test "x$ac_x_libraries" != x)
  37 AM_CONDITIONAL(COMPILE_ARTS_KSAVERS, test x$build_arts = xyes)
  38 AM_CONDITIONAL(COMPILE_ARTS_GL_KSAVERS, test x$have_gl = xyes && test x$ac_cv_kde_qt_has_opengl = xyes && test x$build_arts = xyes)
  39
  40 AC_ARG_WITH(libart,
  41   [AS_HELP_STRING(--with-libart,
  42     [enable support for libart @<:@default=check@:>@])],
  43   [], with_libart=check)
  44
  45 LIBART=
  46 if test "x$with_libart" != xno; then
  47   KDE_FIND_PATH(libart2-config, LIBART_CONFIG, [${prefix}/bin ${exec_prefix}/bin /usr/local/bin /opt/local/bin], [
  48     AC_MSG_WARN([Could not find libart anywhere, check http://www.levien.com/libart/])
  49   ])
  50
  51   if test -n "$LIBART_CONFIG"; then
  52     vers=`$LIBART_CONFIG --version 2>/dev/null | awk 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
  53     if test -n "$vers" && test "$vers" -ge 2003008; then
  54       LIBART_LIBS="`$LIBART_CONFIG --libs`"
  55       LIBART_RPATH=
  56       for args in $LIBART_LIBS; do
  57           case $args in
  58             -L*)
  59                LIBART_RPATH="$LIBART_RPATH $args"
  60                ;;
  61           esac
  62       done
  63       LIBART_RPATH=`echo $LIBART_RPATH | sed -e "s/-L/-R/g"`
  64       LIBART_CFLAGS="`$LIBART_CONFIG --cflags`"
  65       LIBART=yes
  66
  67       AC_DEFINE_UNQUOTED(HAVE_LIBART, 1, [Defines if your system has the libart library])
  68     else
  69       AC_MSG_WARN([You need at least libart 2.3.8])
  70     fi
  71   fi
  72
  73   if test "x$with_libart" != xcheck && test -z "$LIBART"; then
  74       AC_MSG_FAILURE([--with-libart was given, but test for libart failed])
  75   fi
  76 fi
  77
  78 AC_SUBST(LIBART_LIBS)
  79 AC_SUBST(LIBART_CFLAGS)
  80 AC_SUBST(LIBART_RPATH)
  81 AM_CONDITIONAL(COMPILE_LIBART_KSAVERS, test -n "$LIBART")
  82
  83
  84 AC_CHECK_FUNCS(gettimeofday)
  85
  86 AC_HAVE_DPMS()