kdbg/testprogs/xsldoc.xsl

   1 <?xml version="1.0" ?>
   2 <!--
   3      File : xsldoc.xsl
   4      Author: Keith Isdale <k_isdale@tpg.com.au>
   5      Description: Stylesheet to process xsldoc.xml and generate help text
   6      Copyright Reserved Under GPL
   7 -->
   8 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9                 version="1.0">
  10   <xsl:output method="text"/>
  11   <xsl:strip-space elements="text"/>
  12   <xsl:variable name="overview_node" select="/xsldoc/overview"/>
  13   <xsl:variable name="command_nodes" select="/xsldoc/cmd"/>
  14   <xsl:variable name="doc_version" select="'0.5'"/>
  15   <xsl:param name="xsldbg_version" select="'0.5.9'"/>
  16   <!-- We want help to point to a invalid command if stylesheet
  17        user has not provided a value for 'help' param-->
  18   <xsl:param name="help" select="'_#_'"/>
  19
  20
  21   <xsl:template match="/">
  22     <xsl:variable name="help_cmd" select="$command_nodes[@name=$help]"/>
  23          xsldbg version <xsl:value-of select="$xsldbg_version"/>
  24          ====================
  25
  26     <xsl:choose>
  27     <xsl:when test="count($help_cmd) > 0" >
  28       <xsl:apply-templates select="$help_cmd" />
  29       </xsl:when>
  30       <xsl:otherwise>
  31         <xsl:if test="$help !='_#_'">
  32           <xsl:text>Help about </xsl:text>
  33           <xsl:value-of select="$help"/>
  34           <xsl:text> was not found.
  35         </xsl:text>
  36       </xsl:if>
  37       <xsl:apply-templates select="$overview_node"/>
  38     </xsl:otherwise>
  39   </xsl:choose>
  40 <xsl:text>
  41 </xsl:text>
  42   Help document version <xsl:value-of select="$doc_version"/><xsl:text>
  43 </xsl:text>
  44   </xsl:template>
  45
  46   <xsl:template match="header">
  47 <xsl:value-of select="."/>
  48 <xsl:text>
  49     </xsl:text>
  50 <xsl:value-of
  51   select="substring('____________________________________________________________',
  52   1, string-length())" />
  53 <xsl:text>
  54 </xsl:text>
  55   </xsl:template>
  56
  57
  58   <xsl:template match="text()">
  59     <xsl:value-of select="normalize-space()"/>
  60   </xsl:template>
  61
  62   <xsl:template match="para">
  63     <xsl:text>
  64 </xsl:text>
  65     <xsl:apply-templates/>
  66   </xsl:template>
  67
  68   <xsl:template match="list | usage">
  69     <xsl:text>
  70 </xsl:text>
  71     <xsl:for-each select="li">
  72       <xsl:text>     </xsl:text><xsl:apply-templates />
  73       <xsl:text>
  74 </xsl:text>
  75     </xsl:for-each>
  76   </xsl:template>
  77
  78   <xsl:template match="comment">
  79     <xsl:text>   </xsl:text><xsl:value-of select="."/>
  80   </xsl:template>
  81
  82   <xsl:template name="cmd-summary" match="cmd-summary">
  83     <xsl:text >                   Command summary
  84 </xsl:text>
  85     <xsl:apply-templates select="cmd"/>
  86   </xsl:template>
  87
  88   <xsl:template match="cmd">
  89 Command : <xsl:value-of select="@title"/><xsl:text >
  90 </xsl:text>Summary : <xsl:value-of select="summary"/><xsl:text>
  91 </xsl:text>
  92     <xsl:if test="body">
  93         <xsl:apply-templates select="body"/><xsl:text >
  94 </xsl:text>
  95     </xsl:if>
  96     <xsl:text>Usage:
  97 </xsl:text>
  98     <xsl:apply-templates select="usage"/>
  99   </xsl:template>
 100
 101
 102 </xsl:stylesheet>
 103
 104
 105 <!-- initialization code for xemacs -->
 106 <!--
 107 Local Variables:
 108 mode: xsl
 109 sgml-minimize-attributes:nil
 110 sgml-general-insert-case:lower
 111 sgml-indent-step:2
 112 sgml-indent-data:nil
 113 End:
 114 -->