initjimsh.tcl

   1 # This pseudo-package is loaded from jimsh to add additional
   2 # paths to $auto_path and to source ~/.jimrc
   3
   4 proc _jimsh_init {} {
   5         rename _jimsh_init {}
   6         global jim::exe jim::argv0 tcl_interactive auto_path tcl_platform
   7
   8         # Stash the result of [info nameofexecutable] now, before a possible [cd]
   9         if {[exists jim::argv0]} {
  10                 if {[string match "*/*" $jim::argv0]} {
  11                         set jim::exe [file join [pwd] $jim::argv0]
  12                 } else {
  13                         foreach path [split [env PATH ""] $tcl_platform(pathSeparator)] {
  14                                 set exec [file join [pwd] [string map {\\ /} $path] $jim::argv0]
  15                                 if {[file executable $exec]} {
  16                                         set jim::exe $exec
  17                                         break
  18                                 }
  19                         }
  20                 }
  21         }
  22
  23         # Add to the standard auto_path
  24         lappend p {*}[split [env JIMLIB {}] $tcl_platform(pathSeparator)]
  25         if {[exists jim::exe]} {
  26                 lappend p [file dirname $jim::exe]
  27         }
  28         lappend p {*}$auto_path
  29         set auto_path $p
  30
  31         if {$tcl_interactive && [env HOME {}] ne ""} {
  32                 foreach src {.jimrc jimrc.tcl} {
  33                         if {[file exists [env HOME]/$src]} {
  34                                 uplevel #0 source [env HOME]/$src
  35                                 break
  36                         }
  37                 }
  38         }
  39         return ""
  40 }
  41
  42 if {$tcl_platform(platform) eq "windows"} {
  43         set jim::argv0 [string map {\\ /} $jim::argv0]
  44 }
  45
  46 # Simple interactive command line completion callback
  47 # Explicitly knows about some commands that support "-commands"
  48 proc tcl::autocomplete {prefix} {
  49         if {[string match "* " $prefix]} {
  50                 set cmd [string range $prefix 0 end-1]
  51                 if {$cmd in {info tcl::prefix socket namespace array clock file package string dict signal history} || [info channel $cmd] ne ""} {
  52                         # Add any results from -commands
  53                         return [lmap p [$cmd -commands] {
  54                                 function "$cmd $p"
  55                         }]
  56                 }
  57         }
  58         # Find matching files.
  59         if {[string match "source *" $prefix]} {
  60                 set path [string range $prefix 7 end]
  61                 return [lmap p [glob -nocomplain "${path}*"] {
  62                         function "source $p"
  63                 }]
  64         }
  65         # Find matching commands, omitting results containing spaces
  66         return [lmap p [lsort [info commands $prefix*]] {
  67                 if {[string match "* *" $p]} {
  68                         continue
  69                 }
  70                 function $p
  71         }]
  72 }
  73
  74 _jimsh_init