autosetup/cc-lib.tcl

   1 # Copyright (c) 2011 WorkWare Systems http://www.workware.net.au/
   2 # All rights reserved
   3
   4 # @synopsis:
   5 #
   6 # Provides a library of common tests on top of the 'cc' module.
   7
   8 use cc
   9
  10 module-options {}
  11
  12 # @cc-check-lfs
  13 #
  14 # The equivalent of the AC_SYS_LARGEFILE macro
  15 #
  16 # defines 'HAVE_LFS' if LFS is available,
  17 # and defines '_FILE_OFFSET_BITS=64' if necessary
  18 #
  19 # Returns 1 if 'LFS' is available or 0 otherwise
  20 #
  21 proc cc-check-lfs {} {
  22         cc-check-includes sys/types.h
  23         msg-checking "Checking if -D_FILE_OFFSET_BITS=64 is needed..."
  24         set lfs 1
  25         if {[msg-quiet cc-with {-includes sys/types.h} {cc-check-sizeof off_t}] == 8} {
  26                 msg-result no
  27         } elseif {[msg-quiet cc-with {-includes sys/types.h -cflags -D_FILE_OFFSET_BITS=64} {cc-check-sizeof off_t}] == 8} {
  28                 define _FILE_OFFSET_BITS 64
  29                 msg-result yes
  30         } else {
  31                 set lfs 0
  32                 msg-result none
  33         }
  34         define-feature lfs $lfs
  35         return $lfs
  36 }
  37
  38 # @cc-check-endian
  39 #
  40 # The equivalent of the AC_C_BIGENDIAN macro
  41 #
  42 # defines 'HAVE_BIG_ENDIAN' if endian is known to be big,
  43 # or 'HAVE_LITTLE_ENDIAN' if endian is known to be little.
  44 #
  45 # Returns 1 if determined, or 0 if not.
  46 #
  47 proc cc-check-endian {} {
  48         cc-check-includes sys/types.h sys/param.h
  49         set rc 0
  50         msg-checking "Checking endian..."
  51         cc-with {-includes {sys/types.h sys/param.h}} {
  52                 if {[cctest -code {
  53                         #if !defined(BIG_ENDIAN) || !defined(BYTE_ORDER)
  54                                 #error unknown
  55                         #elif BYTE_ORDER != BIG_ENDIAN
  56                                 #error little
  57                         #endif
  58                 }]} {
  59                         define-feature big-endian
  60                         msg-result "big"
  61                         set rc 1
  62                 } elseif {[cctest -code {
  63                         #if !defined(LITTLE_ENDIAN) || !defined(BYTE_ORDER)
  64                                 #error unknown
  65                         #elif BYTE_ORDER != LITTLE_ENDIAN
  66                                 #error big
  67                         #endif
  68                 }]} {
  69                         define-feature little-endian
  70                         msg-result "little"
  71                         set rc 1
  72                 } else {
  73                         msg-result "unknown"
  74                 }
  75         }
  76         return $rc
  77 }
  78
  79 # @cc-check-flags flag ?...?
  80 #
  81 # Checks whether the given C/C++ compiler flags can be used. Defines feature
  82 # names prefixed with 'HAVE_CFLAG' and 'HAVE_CXXFLAG' respectively, and
  83 # appends working flags to '-cflags' and 'CFLAGS' or 'CXXFLAGS'.
  84 proc cc-check-flags {args} {
  85     set result 1
  86     array set opts [cc-get-settings]
  87     switch -exact -- $opts(-lang) {
  88         c++ {
  89             set lang C++
  90             set prefix CXXFLAG
  91         }
  92         c {
  93             set lang C
  94             set prefix CFLAG
  95         }
  96         default {
  97             autosetup-error "cc-check-flags failed with unknown language: $opts(-lang)"
  98         }
  99     }
 100     foreach flag $args {
 101         msg-checking "Checking whether the $lang compiler accepts $flag..."
 102         if {[cctest -cflags $flag]} {
 103             msg-result yes
 104             define-feature $prefix$flag
 105             cc-with [list -cflags [list $flag]]
 106             define-append ${prefix}S $flag
 107         } else {
 108             msg-result no
 109             set result 0
 110         }
 111     }
 112     return $result
 113 }
 114
 115 # @cc-check-standards ver ?...?
 116 #
 117 # Checks whether the C/C++ compiler accepts one of the specified '-std=$ver'
 118 # options, and appends the first working one to '-cflags' and 'CFLAGS' or
 119 # 'CXXFLAGS'.
 120 proc cc-check-standards {args} {
 121     array set opts [cc-get-settings]
 122     foreach std $args {
 123         if {[cc-check-flags -std=$std]} {
 124             return $std
 125         }
 126     }
 127     return ""
 128 }
 129
 130 # Checks whether $keyword is usable as alignof
 131 proc cctest_alignof {keyword} {
 132     msg-checking "Checking for $keyword..."
 133     if {[cctest -code [subst -nobackslashes {
 134         printf("minimum alignment is %d == %d\n", ${keyword}(char), ${keyword}('x'));
 135     }]]} then {
 136         msg-result ok
 137         define-feature $keyword
 138     } else {
 139         msg-result "not found"
 140     }
 141 }
 142
 143 # @cc-check-c11
 144 #
 145 # Checks for several C11/C++11 extensions and their alternatives. Currently
 146 # checks for '_Static_assert', '_Alignof', '__alignof__', '__alignof'.
 147 proc cc-check-c11 {} {
 148     msg-checking "Checking for _Static_assert..."
 149     if {[cctest -code {
 150         _Static_assert(1, "static assertions are available");
 151     }]} then {
 152         msg-result ok
 153         define-feature _Static_assert
 154     } else {
 155         msg-result "not found"
 156     }
 157
 158     cctest_alignof _Alignof
 159     cctest_alignof __alignof__
 160     cctest_alignof __alignof
 161 }
 162
 163 # @cc-check-alloca
 164 #
 165 # The equivalent of the AC_FUNC_ALLOCA macro
 166 #
 167 # Checks for the existence of alloca
 168 # defines HAVE_ALLOCA and returns 1 if it exists
 169 proc cc-check-alloca {} {
 170     cc-check-some-feature alloca {
 171         cctest -includes alloca.h -code { alloca (2 * sizeof (int)); }
 172     }
 173 }
 174
 175 # @cc-signal-return-type
 176 #
 177 # The equivalent of the AC_TYPE_SIGNAL macro
 178 #
 179 # defines RETSIGTYPE to int or void
 180 proc cc-signal-return-type {} {
 181     msg-checking "Checking return type of signal handlers..."
 182     cc-with {-includes {sys/types.h signal.h}} {
 183         if {[cctest -code {return *(signal (0, 0)) (0) == 1;}]} {
 184                 set type int
 185         } else {
 186                 set type void
 187         }
 188         define RETSIGTYPE $type
 189         msg-result $type
 190     }
 191 }