jack_mixer/meson.build

   1 # https://mesonbuild.com/Python-module.html
   2
   3 c_args = []
   4
   5 if get_option('jack-midi').enabled()
   6     c_args += ['-DHAVE_JACK_MIDI']
   7 endif
   8
   9 if get_option('verbose')
  10     c_args += ['-DLOG_LEVEL=0']
  11 else
  12     c_args += ['-DLOG_LEVEL=2']
  13 endif
  14
  15
  16 # Build and install the extension module
  17 module = python.extension_module(
  18     '_jack_mixer',
  19     [jack_mixer_cython, jack_mixer_sources],
  20     dependencies: [
  21         python.dependency(),
  22         glib_dep,
  23         jack_dep,
  24         math_dep,
  25     ],
  26     include_directories: jack_mixer_inc,
  27     c_args: c_args,
  28     install: true,
  29     subdir: 'jack_mixer',
  30 )
  31
  32 version_py = configure_file(
  33     input: 'version.py.in',
  34     output: 'version.py',
  35     configuration: {
  36         'VERSION': meson.project_version()
  37     }
  38 )
  39
  40
  41 # Pure Python sources
  42 python_sources = files([
  43     'abspeak.py',
  44     'app.py',
  45     'channel.py',
  46     'gui.py',
  47     '__main__.py',
  48     'meter.py',
  49     'nsmclient.py',
  50     'preferences.py',
  51     'scale.py',
  52     'serialization.py',
  53     'serialization_xml.py',
  54     'slider.py',
  55     'styling.py',
  56 ])
  57
  58
  59 # Install pure Python modules
  60 python.install_sources(
  61     python_sources,
  62     version_py,
  63     pure: true,
  64     subdir: 'jack_mixer',
  65 )
  66
  67
  68 # Install application starter script
  69 if not get_option('wheel')
  70     install_data(
  71         '__main__.py',
  72         rename: 'jack_mixer',
  73         install_dir: bindir,
  74         install_mode: 'rwxr-xr-x'
  75     )
  76 endif