windows/inno/win64.iss

   1 #include "version.iss"
   2
   3 [Setup]
   4 ArchitecturesInstallIn64BitMode=x64
   5 AppName=JACK2
   6 AppPublisher=jackaudio.org
   7 AppPublisherURL=https://github.com/jackaudio/jack2/
   8 AppSupportURL=https://github.com/jackaudio/jack2/issues/
   9 AppUpdatesURL=https://github.com/jackaudio/jack2-releases/releases/
  10 AppVersion={#VERSION}
  11 DefaultDirName={commonpf64}\JACK2
  12 DisableDirPage=yes
  13 OutputBaseFilename=jack2-win64-v{#VERSION}
  14 OutputDir=.
  15 UsePreviousAppDir=no
  16
  17 [Types]
  18 Name: "full"; Description: "Full installation";
  19 Name: "custom"; Description: "Custom installation"; Flags: iscustom;
  20
  21 [Components]
  22 Name: qjackctl; Description: "QJackCtl application (recommended)"; Types: full;
  23 Name: dev; Description: "Developer resources"; Types: full;
  24
  25 [Files]
  26 ; icon
  27 Source: "jack.ico"; DestDir: "{app}";
  28 ; jackd and server libs
  29 Source: "win64\bin\jackd.exe"; DestDir: "{app}";
  30 Source: "win64\lib\libjacknet64.dll"; DestDir: "{app}";
  31 Source: "win64\lib\libjackserver64.dll"; DestDir: "{app}";
  32 ; drivers
  33 Source: "win64\lib\jack\*.dll"; DestDir: "{app}\jack";
  34 ; tools
  35 Source: "win64\bin\jack_*.exe"; DestDir: "{app}\tools";
  36 ; jack client lib (NOTE goes into windir)
  37 Source: "win64\lib\libjack64.dll"; DestDir: "{win}";
  38 ; qjackctl
  39 Source: "win64\bin\qjackctl.exe"; DestDir: "{app}\qjackctl"; Components: qjackctl;
  40 Source: "Qt5*.dll"; DestDir: "{app}\qjackctl"; Components: qjackctl;
  41 Source: "qwindows.dll"; DestDir: "{app}\qjackctl\platforms"; Components: qjackctl;
  42 ; dev
  43 Source: "win64\include\jack\*.h"; DestDir: "{app}\include"; Components: dev;
  44 Source: "win64\lib\*.a"; DestDir: "{app}\lib"; Components: dev;
  45 Source: "win64\lib\jack\*.a"; DestDir: "{app}\lib\jack"; Components: dev;
  46
  47 [Icons]
  48 Name: "{commonprograms}\QJackCtl"; Filename: "{app}\qjackctl\qjackctl.exe"; IconFilename: "{app}\jack.ico"; WorkingDir: "{app}"; Comment: "Graphical Interface for JACK"; Components: qjackctl;
  49
  50 [Registry]
  51 Root: HKLM; Subkey: "Software\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "Location"; ValueData: "{app}\jackd.exe"
  52 Root: HKLM; Subkey: "Software\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "Version"; ValueData: "{#VERSION}"