windows/inno/win64.iss

   1 #include "version.iss"
   2
   3 [Setup]
   4 ArchitecturesInstallIn64BitMode=x64
   5 AppName=JACK2
   6 AppPublisher=jackaudio.org
   7 AppPublisherURL=https://github.com/jackaudio/jack2/
   8 AppSupportURL=https://github.com/jackaudio/jack2/issues/
   9 AppUpdatesURL=https://github.com/jackaudio/jack2-releases/releases/
  10 AppVersion={#VERSION}
  11 DefaultDirName={commonpf64}\JACK2
  12 DisableDirPage=yes
  13 DisableWelcomePage=no
  14 LicenseFile=..\..\COPYING
  15 OutputBaseFilename=jack2-win64-{#VERSION}
  16 OutputDir=.
  17 UsePreviousAppDir=no
  18
  19 [Types]
  20 Name: "full"; Description: "Full installation (without JACK-Router)";
  21 Name: "router"; Description: "Full installation (with JACK-Router)";
  22 Name: "custom"; Description: "Custom installation"; Flags: iscustom;
  23
  24 [Components]
  25 Name: jackserver; Description: "JACK Server and tools"; Types: full router custom; Flags: fixed;
  26 Name: qjackctl; Description: "QjackCtl application (recommended)"; Types: full router;
  27 Name: router; Description: "JACK-Router ASIO Driver"; Types: router;
  28 Name: dev; Description: "Developer resources"; Types: full router;
  29
  30 [Files]
  31 ; icon
  32 Source: "jack.ico"; DestDir: "{app}"; Components: jackserver; Flags: ignoreversion;
  33 ; jackd and server libs
  34 Source: "win64\bin\jackd.exe"; DestDir: "{app}"; Components: jackserver; Flags: ignoreversion;
  35 Source: "win64\lib\libjacknet64.dll"; DestDir: "{app}"; Components: jackserver; Flags: ignoreversion;
  36 Source: "win64\lib\libjackserver64.dll"; DestDir: "{app}"; Components: jackserver; Flags: ignoreversion;
  37 ; drivers
  38 Source: "win64\lib\jack\*.dll"; DestDir: "{app}\jack"; Components: jackserver; Flags: ignoreversion;
  39 ; tools
  40 Source: "win64\bin\jack_*.exe"; DestDir: "{app}\tools"; Components: jackserver; Flags: ignoreversion;
  41 ; jack client lib (NOTE goes into windir)
  42 Source: "win64\lib\libjack64.dll"; DestDir: "{win}"; Components: jackserver; Flags: ignoreversion;
  43 Source: "win64\lib32\libjack.dll"; DestDir: "{win}"; Components: jackserver; Flags: ignoreversion;
  44 ; qjackctl
  45 Source: "win64\bin\qjackctl.exe"; DestDir: "{app}\qjackctl"; Components: qjackctl; Flags: ignoreversion;
  46 Source: "Qt5*.dll"; DestDir: "{app}\qjackctl"; Components: qjackctl; Flags: ignoreversion;
  47 Source: "qwindows.dll"; DestDir: "{app}\qjackctl\platforms"; Components: qjackctl; Flags: ignoreversion;
  48 Source: "qwindowsvistastyle.dll"; DestDir: "{app}\qjackctl\styles"; Components: qjackctl; Flags: ignoreversion;
  49 ; dev
  50 Source: "win64\include\jack\*.h"; DestDir: "{app}\include\jack"; Components: dev; Flags: ignoreversion;
  51 Source: "win64\lib\*.a"; DestDir: "{app}\lib"; Components: dev; Flags: ignoreversion;
  52 Source: "win64\lib\*.def"; DestDir: "{app}\lib"; Components: dev; Flags: ignoreversion;
  53 Source: "win64\lib\*.lib"; DestDir: "{app}\lib"; Components: dev; Flags: ignoreversion;
  54 Source: "win64\lib32\*.a"; DestDir: "{app}\lib32"; Components: dev; Flags: ignoreversion;
  55 Source: "win64\lib32\*.def"; DestDir: "{app}\lib32"; Components: dev; Flags: ignoreversion;
  56 Source: "win64\lib32\*.lib"; DestDir: "{app}\lib32"; Components: dev; Flags: ignoreversion;
  57 Source: "win64\lib\jack\*.a"; DestDir: "{app}\lib\jack"; Components: dev; Flags: ignoreversion;
  58 ; router
  59 Source: "win64\jack-router\README.txt"; DestDir: "{app}\jack-router"; Components: router; Flags: ignoreversion;
  60 Source: "win64\jack-router\win32\JackRouter.dll"; DestDir: "{app}\jack-router\win32"; Components: router; Flags: ignoreversion regserver 32bit;
  61 Source: "win64\jack-router\win32\JackRouter.ini"; DestDir: "{app}\jack-router\win32"; Components: router; Flags: ignoreversion;
  62 Source: "win64\jack-router\win64\JackRouter.dll"; DestDir: "{app}\jack-router\win64"; Components: router; Flags: ignoreversion regserver 64bit;
  63 Source: "win64\jack-router\win64\JackRouter.ini"; DestDir: "{app}\jack-router\win64"; Components: router; Flags: ignoreversion;
  64
  65 [Icons]
  66 Name: "{commonprograms}\QjackCtl"; Filename: "{app}\qjackctl\qjackctl.exe"; IconFilename: "{app}\jack.ico"; WorkingDir: "{app}"; Comment: "Graphical Interface for JACK"; Components: qjackctl;
  67
  68 [Registry]
  69 Root: HKLM; Subkey: "Software\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "ServerExecutable"; ValueData: "{app}\jackd.exe"
  70 Root: HKLM; Subkey: "Software\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "InstallPath"; ValueData: "{app}"
  71 Root: HKLM; Subkey: "Software\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "Version"; ValueData: "{#VERSION}"
  72 ; 32bit compat keys
  73 Root: HKLM; Subkey: "Software\WOW6432Node\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "ServerExecutable"; ValueData: "{app}\jackd.exe"
  74 Root: HKLM; Subkey: "Software\WOW6432Node\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "InstallPath"; ValueData: "{app}"
  75 Root: HKLM; Subkey: "Software\WOW6432Node\JACK"; Flags: deletevalue uninsdeletekeyifempty uninsdeletevalue; ValueType: string; ValueName: "Version"; ValueData: "{#VERSION}"