m4/ax_detect_clang.m4

   1 AC_DEFUN([AX_DETECT_CLANG], [
   2 AC_SUBST(CLANG_CXXFLAGS)
   3 AC_SUBST(CLANG_LDFLAGS)
   4 AC_SUBST(CLANG_RFLAG)
   5 AC_SUBST(CLANG_LIBS)
   6 AC_PROG_GREP
   7 AC_PROG_SED
   8 if test "x$with_clang_prefix" != "x"; then
   9         LLVM_CONFIG="$with_clang_prefix/bin/llvm-config"
  10 fi
  11 AC_PATH_PROG([LLVM_CONFIG], ["llvm-config"])
  12 if test -z "$LLVM_CONFIG" || test ! -x "$LLVM_CONFIG"; then
  13         AC_MSG_ERROR([llvm-config not found])
  14 fi
  15 CLANG_CXXFLAGS=`$LLVM_CONFIG --cxxflags | \
  16         $SED -e 's/-Wcovered-switch-default//;s/-gsplit-dwarf//'`
  17 CLANG_LDFLAGS=`$LLVM_CONFIG --ldflags`
  18 # Construct a -R argument for libtool.
  19 # This is needed in case some of the clang libraries are shared libraries.
  20 CLANG_RFLAG=`echo "$CLANG_LDFLAGS" | $SED -e 's/-L/-R/g'`
  21 targets=`$LLVM_CONFIG --targets-built`
  22 components="$targets asmparser bitreader support mc"
  23 # Link in option and frontendopenmp components when available
  24 # since they may be used by the clang libraries.
  25 for c in option frontendopenmp; do
  26         $LLVM_CONFIG --components | $GREP $c > /dev/null 2> /dev/null
  27         if test $? -eq 0; then
  28                 components="$components $c"
  29         fi
  30 done
  31 CLANG_LIBS=`$LLVM_CONFIG --libs $components`
  32 systemlibs=`$LLVM_CONFIG --system-libs 2> /dev/null | tail -1`
  33 if test $? -eq 0; then
  34         CLANG_LIBS="$CLANG_LIBS $systemlibs"
  35 fi
  36 CLANG_PREFIX=`$LLVM_CONFIG --prefix`
  37 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  38
  39 # If $CLANG_PREFIX/bin/clang cannot find the standard include files,
  40 # then see if setting sysroot to `xcode-select -p`/SDKs/MacOSX.sdk helps.
  41 # This may be required on some versions of OS X since they lack /usr/include.
  42 # If so, set CLANG_SYSROOT accordingly.
  43 SAVE_CC="$CC"
  44 CC="$CLANG_PREFIX/bin/clang"
  45 AC_MSG_CHECKING(
  46         [whether $CLANG_PREFIX/bin/clang can find standard include files])
  47 found_header=no
  48 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[]])],
  49         [found_header=yes])
  50 AC_MSG_RESULT([$found_header])
  51 if test "x$found_header" != "xyes"; then
  52         AC_CHECK_PROG(XCODE_SELECT, xcode-select, xcode-select, [])
  53         if test -z "$XCODE_SELECT"; then
  54                 AC_MSG_ERROR([Cannot find xcode-select])
  55         fi
  56         sysroot=`$XCODE_SELECT -p`/SDKs/MacOSX.sdk
  57         SAVE_CPPFLAGS="$CPPFLAGS"
  58         CPPFLAGS="$CPPFLAGS -isysroot $sysroot"
  59         AC_MSG_CHECKING(
  60                 [whether standard include files can be found with sysroot set])
  61         found_header=no
  62         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[]])],
  63                 [found_header=yes])
  64         AC_MSG_RESULT([$found_header])
  65         CPPFLAGS="$SAVE_CPPFLAGS"
  66         if test "x$found_header" != "xyes"; then
  67                 AC_MSG_ERROR([Cannot find standard include files])
  68         else
  69                 AC_DEFINE_UNQUOTED([CLANG_SYSROOT], ["$sysroot"],
  70                         [Define to sysroot if needed])
  71         fi
  72 fi
  73 CC="$SAVE_CC"
  74
  75 AC_LANG_PUSH(C++)
  76
  77 SAVE_CPPFLAGS="$CPPFLAGS"
  78 CPPFLAGS="$CLANG_CXXFLAGS -I$srcdir $CPPFLAGS"
  79 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  80         [AC_MSG_ERROR([clang header file not found])])
  81 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  82         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  83         [Define to getHostTriple for older versions of clang])])
  84 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  85         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  86         [Define to getInstantiationLineNumber for older versions of clang])])
  87 AC_EGREP_HEADER([getImmediateExpansionRange], [clang/Basic/SourceManager.h],
  88         [],
  89         [AC_DEFINE([getImmediateExpansionRange],
  90         [getImmediateInstantiationRange],
  91         [Define to getImmediateInstantiationRange for older versions of clang])]
  92 )
  93 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h], [],
  94         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  95         [Define to Diagnostic for older versions of clang])])
  96 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  97         [AC_DEFINE([USE_ARRAYREF], [],
  98                 [Define if Driver::BuildCompilation takes ArrayRef])
  99         AC_EGREP_HEADER([ArrayRef.*CommandLineArgs],
 100                 [clang/Frontend/CompilerInvocation.h],
 101                 [AC_DEFINE([CREATE_FROM_ARGS_TAKES_ARRAYREF], [],
 102                         [Define if CompilerInvocation::CreateFromArgs takes
 103                          ArrayRef])
 104                 ])
 105         ])
 106 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
 107         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
 108                 [Define if Driver constructor takes CXXIsProduction argument])])
 109 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
 110         [AC_DEFINE([HAVE_ISPRODUCTION], [],
 111                 [Define if Driver constructor takes IsProduction argument])])
 112 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Driver/Driver.h>]], [[
 113         using namespace clang;
 114         DiagnosticsEngine *Diags;
 115         new driver::Driver("", "", "", *Diags);
 116 ]])], [AC_DEFINE([DRIVER_CTOR_TAKES_DEFAULTIMAGENAME], [],
 117               [Define if Driver constructor takes default image name])])
 118 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
 119         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 120                    [Return type of HandleTopLevelDeclReturn])
 121          AC_DEFINE([HandleTopLevelDeclContinue], [],
 122                    [Return type of HandleTopLevelDeclReturn])],
 123         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 124                    [Return type of HandleTopLevelDeclReturn])
 125          AC_DEFINE([HandleTopLevelDeclContinue], [true],
 126                    [Return type of HandleTopLevelDeclReturn])])
 127 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 128         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 129                    [Define if clang/Basic/DiagnosticOptions.h exists])])
 130 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
 131         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
 132                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
 133         [#include <clang/Basic/LLVM.h>])
 134 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Basic/TargetInfo.h>]], [[
 135         using namespace clang;
 136         std::shared_ptr<TargetOptions> TO;
 137         DiagnosticsEngine *Diags;
 138         TargetInfo::CreateTargetInfo(*Diags, TO);
 139 ]])], [AC_DEFINE([CREATETARGETINFO_TAKES_SHARED_PTR], [],
 140               [Define if TargetInfo::CreateTargetInfo takes shared_ptr])])
 141 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Basic/TargetInfo.h>]], [[
 142         using namespace clang;
 143         TargetOptions *TO;
 144         DiagnosticsEngine *Diags;
 145         TargetInfo::CreateTargetInfo(*Diags, TO);
 146 ]])], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 147               [Define if TargetInfo::CreateTargetInfo takes pointer])])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 149                 [[#include <clang/Frontend/CompilerInstance.h>]], [[
 150         using namespace clang;
 151         DiagnosticConsumer *client;
 152         CompilerInstance *Clang;
 153         Clang->createDiagnostics(client);
 154 ]])], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 155         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 156 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 157                 [[#include <clang/Lex/HeaderSearchOptions.h>]], [[
 158         using namespace clang;
 159         HeaderSearchOptions HSO;
 160         HSO.AddPath("", frontend::Angled, false, false);
 161 ]])], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 162         [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 163 AC_EGREP_HEADER([getNumParams],
 164         [clang/AST/CanonicalType.h],
 165         [AC_DEFINE([getNumArgs], [getNumParams],
 166             [Define to getNumParams for newer versions of clang])
 167          AC_DEFINE([getArgType], [getParamType],
 168             [Define to getParamType for newer versions of clang])])
 169 AC_EGREP_HEADER([getReturnType],
 170         [clang/AST/CanonicalType.h], [],
 171         [AC_DEFINE([getReturnType], [getResultType],
 172             [Define to getResultType for older versions of clang])])
 173 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 174                 [[#include <clang/Frontend/CompilerInstance.h>]], [[
 175         using namespace clang;
 176         CompilerInstance *Clang;
 177         Clang->createPreprocessor(TU_Complete);
 178 ]])], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 179 [Define if CompilerInstance::createPreprocessor takes TranslationUnitKind])])
 180 AC_EGREP_HEADER([setMainFileID], [clang/Basic/SourceManager.h],
 181         [AC_DEFINE([HAVE_SETMAINFILEID], [],
 182         [Define if SourceManager has a setMainFileID method])])
 183 AC_CHECK_HEADER([llvm/ADT/OwningPtr.h],
 184         [AC_DEFINE([HAVE_ADT_OWNINGPTR_H], [],
 185                    [Define if llvm/ADT/OwningPtr.h exists])])
 186 AC_EGREP_HEADER([initializeBuiltins],
 187         [clang/Basic/Builtins.h], [],
 188         [AC_DEFINE([initializeBuiltins], [InitializeBuiltins],
 189                 [Define to InitializeBuiltins for older versions of clang])])
 190 AC_EGREP_HEADER([IK_C], [clang/Frontend/FrontendOptions.h], [],
 191         [AC_CHECK_HEADER([clang/Basic/LangStandard.h],
 192                 [IK_C=Language::C], [IK_C=InputKind::C])
 193          AC_DEFINE_UNQUOTED([IK_C], [$IK_C],
 194          [Define to Language::C or InputKind::C for newer versions of clang])
 195         ])
 196 # llvmorg-15-init-7544-g93471e65df48
 197 AC_EGREP_HEADER([setLangDefaults], [clang/Basic/LangOptions.h],
 198         [SETLANGDEFAULTS=LangOptions],
 199         [SETLANGDEFAULTS=CompilerInvocation])
 200 AC_DEFINE_UNQUOTED([SETLANGDEFAULTS], [$SETLANGDEFAULTS],
 201         [Define to class with setLangDefaults method])
 202 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 203         #include <clang/Basic/TargetOptions.h>
 204         #include <clang/Lex/PreprocessorOptions.h>
 205         #include <clang/Frontend/CompilerInstance.h>
 206
 207         #include "set_lang_defaults_arg4.h"
 208 ]], [[
 209         using namespace clang;
 210         CompilerInstance *Clang;
 211         TargetOptions TO;
 212         llvm::Triple T(TO.Triple);
 213         PreprocessorOptions PO;
 214         SETLANGDEFAULTS::setLangDefaults(Clang->getLangOpts(), IK_C,
 215                         T, setLangDefaultsArg4(PO),
 216                         LangStandard::lang_unspecified);
 217 ]])], [AC_DEFINE([SETLANGDEFAULTS_TAKES_5_ARGUMENTS], [],
 218         [Define if CompilerInvocation::setLangDefaults takes 5 arguments])])
 219 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 220         #include <clang/Frontend/CompilerInstance.h>
 221         #include <clang/Frontend/CompilerInvocation.h>
 222 ]], [[
 223         using namespace clang;
 224         CompilerInvocation *invocation;
 225         CompilerInstance *Clang;
 226         Clang->setInvocation(std::make_shared<CompilerInvocation>(*invocation));
 227 ]])], [AC_DEFINE([SETINVOCATION_TAKES_SHARED_PTR], [],
 228         [Defined if CompilerInstance::setInvocation takes a shared_ptr])])
 229 AC_CHECK_HEADER([llvm/Option/Arg.h],
 230         [AC_DEFINE([HAVE_LLVM_OPTION_ARG_H], [],
 231                    [Define if llvm/Option/Arg.h exists])])
 232 CPPFLAGS="$SAVE_CPPFLAGS"
 233
 234 SAVE_LDFLAGS="$LDFLAGS"
 235 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 236
 237 # Use single libclang-cpp shared library when available.
 238 # Otherwise, use a selection of clang libraries that appears to work.
 239 AC_CHECK_LIB([clang-cpp], [main], [have_lib_clang=yes], [have_lib_clang=no])
 240 if test "$have_lib_clang" = yes; then
 241         CLANG_LIBS="-lclang-cpp $CLANG_LIBS"
 242 else
 243         CLANG_LIBS="-lclangBasic -lclangDriver $CLANG_LIBS"
 244         CLANG_LIBS="-lclangAnalysis -lclangAST -lclangLex $CLANG_LIBS"
 245         LDFLAGS="$CLANG_LDFLAGS $CLANG_LIBS $SAVE_LDFLAGS"
 246         AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 247         CLANG_LIBS="$LIB_CLANG_EDIT $CLANG_LIBS"
 248         CLANG_LIBS="-lclangParse -lclangSema $CLANG_LIBS"
 249         CLANG_LIBS="-lclangFrontend -lclangSerialization $CLANG_LIBS"
 250 fi
 251
 252 LDFLAGS="$SAVE_LDFLAGS"
 253
 254 AC_LANG_POP
 255 ])