configure.ac

   1 AC_INIT([isl], [0.20], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=20:0:1
   8
   9 if test "x$prefix" != "xNONE"; then
  10         prefix_wd=`cd $prefix && pwd`
  11         srcdir_wd=`cd $srcdir && pwd`
  12         wd=`pwd`
  13         if test "x$prefix_wd" = "x$srcdir_wd"; then
  14                 AC_MSG_ERROR(Installation in source directory not supported)
  15         fi
  16         if test "x$prefix_wd" = "x$wd"; then
  17                 AC_MSG_ERROR(Installation in build directory not supported)
  18         fi
  19 fi
  20
  21 AC_PROG_CC
  22 AC_PROG_CXX
  23
  24 AX_CC_MAXOPT
  25 AX_GCC_WARN_UNUSED_RESULT
  26 AX_C___ATTRIBUTE__
  27
  28 # CXX11FLAGS contains the flags (if any) added by AX_CXX_COMPILE_STDCXX_11
  29 # Original state of CXX and CXXCPP is preserved because CXX11FLAGS
  30 # is only needed for compiling interface/isl_test_cpp
  31 AC_SUBST(CXX11FLAGS)
  32 ac_save_CXX="$CXX"
  33 ac_save_CXXCPP="$CXXCPP"
  34 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
  35 CXX11FLAGS=${CXX#$ac_save_CXX}
  36 CXX="$ac_save_CXX"
  37 CXXCPP="$ac_save_CXXCPP"
  38
  39 AC_PROG_GREP
  40 AC_PROG_LIBTOOL
  41 AC_PROG_SED
  42 AM_PATH_PYTHON([2.5], [], [:])
  43 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  44
  45 AC_CHECK_PROG(PERL, perl, perl, [])
  46 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  47 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  48
  49 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  50
  51 AX_CREATE_STDINT_H(include/isl/stdint.h)
  52
  53 AC_ARG_WITH([int],
  54             [AS_HELP_STRING([--with-int=gmp|imath|imath-32],
  55                             [Which package to use to represent
  56                                 multi-precision integers [default=gmp]])],
  57             [], [with_int=gmp])
  58 case "$with_int" in
  59 gmp|imath|imath-32)
  60         ;;
  61 *)
  62         AC_MSG_ERROR(
  63             [bad value ${withval} for --with-int (use gmp, imath or imath-32)])
  64 esac
  65
  66 AC_SUBST(MP_CPPFLAGS)
  67 AC_SUBST(MP_CFLAGS)
  68 AC_SUBST(MP_LDFLAGS)
  69 AC_SUBST(MP_LIBS)
  70 case "$with_int" in
  71 gmp)
  72         AX_DETECT_GMP
  73         ;;
  74 imath|imath-32)
  75         AX_DETECT_IMATH
  76         ;;
  77 esac
  78 if test "x$with_int" = "ximath-32" -a "x$GCC" = "xyes"; then
  79         MP_CFLAGS="-std=gnu99 $MP_CFLAGS"
  80 fi
  81
  82 AM_CONDITIONAL(IMATH_FOR_MP, test x$with_int = ximath -o x$with_int = ximath-32)
  83 AM_CONDITIONAL(GMP_FOR_MP, test x$with_int = xgmp)
  84
  85 AM_CONDITIONAL(HAVE_CXX11, test "x$HAVE_CXX11" = "x1")
  86 AM_CONDITIONAL(SMALL_INT_OPT, test "x$with_int" == "ximath-32")
  87 AS_IF([test "x$with_int" == "ximath-32"], [
  88         AC_DEFINE([USE_SMALL_INT_OPT], [], [Use small integer optimization])
  89 ])
  90
  91 AC_CHECK_DECLS(ffs,[],[],[#include <strings.h>])
  92 AC_CHECK_DECLS(__builtin_ffs,[],[],[])
  93 AC_CHECK_DECLS([_BitScanForward],[],[],[#include <intrin.h>])
  94 if test "x$ac_cv_have_decl_ffs" = xno -a \
  95                 "x$ac_cv_have_decl___builtin_ffs" = xno -a \
  96                 "x$ac_cv_have_decl__BitScanForward" = xno; then
  97         AC_MSG_ERROR([No ffs implementation found])
  98 fi
  99 AC_CHECK_DECLS([strcasecmp,strncasecmp],[],[],[#include <strings.h>])
 100 AC_CHECK_DECLS([_stricmp,_strnicmp],[],[],[#include <string.h>])
 101 if test "x$ac_cv_have_decl_strcasecmp" = xno -a \
 102                 "x$ac_cv_have_decl__stricmp" = xno; then
 103         AC_MSG_ERROR([No strcasecmp implementation found])
 104 fi
 105 if test "x$ac_cv_have_decl_strncasecmp" = xno -a \
 106                 "x$ac_cv_have_decl__strnicmp" = xno; then
 107         AC_MSG_ERROR([No strncasecmp implementation found])
 108 fi
 109 AC_CHECK_DECLS([snprintf,_snprintf],[],[],[#include <stdio.h>])
 110 if test "x$ac_cv_have_decl_snprintf" = xno -a \
 111                 "x$ac_cv_have_decl__snprintf" = xno; then
 112         AC_MSG_ERROR([No snprintf implementation found])
 113 fi
 114
 115 AX_SUBMODULE(clang,system|no,no)
 116 case "$with_clang" in
 117 system)
 118         AX_DETECT_CLANG
 119         ;;
 120 esac
 121 AM_CONDITIONAL(HAVE_CLANG, test $with_clang = system)
 122 AM_CONDITIONAL(HAVE_CPP_ISL_H,
 123     [test $with_clang = system -o -f $srcdir/include/isl/cpp.h])
 124
 125 AX_SET_WARNING_FLAGS
 126
 127 AC_SUBST(WARNING_FLAGS)
 128
 129 PACKAGE_CFLAGS="$MP_CPPFLAGS"
 130 PACKAGE_LDFLAGS="$MP_LDFLAGS"
 131 PACKAGE_LIBS="-lisl $MP_LIBS"
 132 AX_CREATE_PKGCONFIG_INFO
 133
 134 AX_DETECT_GIT_HEAD
 135
 136 AH_BOTTOM([#include <isl_config_post.h>])
 137 AC_CONFIG_HEADERS(isl_config.h)
 138 AC_CONFIG_FILES(isl_srcdir.c)
 139 AC_CONFIG_FILES(Makefile)
 140 AC_CONFIG_FILES(doc/Makefile)
 141 if test $with_clang = system; then
 142         AC_CONFIG_FILES(interface/Makefile)
 143 fi
 144 AC_CONFIG_FILES([bound_test.sh], [chmod +x bound_test.sh])
 145 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 146 AC_CONFIG_FILES([pip_test.sh], [chmod +x pip_test.sh])
 147 AC_CONFIG_FILES([flow_test.sh], [chmod +x flow_test.sh])
 148 AC_CONFIG_FILES([schedule_test.sh], [chmod +x schedule_test.sh])
 149 AC_CONFIG_COMMANDS_POST([
 150         dnl pass on arguments to subdir configures, but don't
 151         dnl add them to config.status
 152         ac_configure_args="$ac_configure_args $isl_configure_args"
 153 ])
 154 AC_OUTPUT