m4/ax_detect_clang.m4

   1 AC_DEFUN([AX_DETECT_CLANG], [
   2 AC_SUBST(CLANG_CXXFLAGS)
   3 AC_SUBST(CLANG_LDFLAGS)
   4 AC_SUBST(CLANG_RFLAG)
   5 AC_SUBST(CLANG_LIBS)
   6 AC_PROG_GREP
   7 AC_PROG_SED
   8 if test "x$with_clang_prefix" != "x"; then
   9         LLVM_CONFIG="$with_clang_prefix/bin/llvm-config"
  10 fi
  11 AC_PATH_PROG([LLVM_CONFIG], ["llvm-config"])
  12 if test -z "$LLVM_CONFIG" || test ! -x "$LLVM_CONFIG"; then
  13         AC_MSG_ERROR([llvm-config not found])
  14 fi
  15 CLANG_CXXFLAGS=`$LLVM_CONFIG --cxxflags | \
  16         $SED -e 's/-Wcovered-switch-default//;s/-gsplit-dwarf//'`
  17 CLANG_LDFLAGS=`$LLVM_CONFIG --ldflags`
  18 # Construct a -R argument for libtool.
  19 # This is needed in case some of the clang libraries are shared libraries.
  20 CLANG_RFLAG=`echo "$CLANG_LDFLAGS" | $SED -e 's/-L/-R/g'`
  21 targets=`$LLVM_CONFIG --targets-built`
  22 components="$targets asmparser bitreader support mc"
  23 # Link in option and frontendopenmp components when available
  24 # since they may be used by the clang libraries.
  25 for c in option frontendopenmp; do
  26         $LLVM_CONFIG --components | $GREP $c > /dev/null 2> /dev/null
  27         if test $? -eq 0; then
  28                 components="$components $c"
  29         fi
  30 done
  31 CLANG_LIBS=`$LLVM_CONFIG --libs $components`
  32 systemlibs=`$LLVM_CONFIG --system-libs 2> /dev/null | tail -1`
  33 if test $? -eq 0; then
  34         CLANG_LIBS="$CLANG_LIBS $systemlibs"
  35 fi
  36 CLANG_PREFIX=`$LLVM_CONFIG --prefix`
  37 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  38
  39 # If $CLANG_PREFIX/bin/clang cannot find the standard include files,
  40 # then see if setting sysroot to `xcode-select -p`/SDKs/MacOSX.sdk helps.
  41 # This may be required on some versions of OS X since they lack /usr/include.
  42 # If so, set CLANG_SYSROOT accordingly.
  43 SAVE_CC="$CC"
  44 CC="$CLANG_PREFIX/bin/clang"
  45 AC_MSG_CHECKING(
  46         [whether $CLANG_PREFIX/bin/clang can find standard include files])
  47 found_header=no
  48 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[]])],
  49         [found_header=yes])
  50 AC_MSG_RESULT([$found_header])
  51 if test "x$found_header" != "xyes"; then
  52         AC_CHECK_PROG(XCODE_SELECT, xcode-select, xcode-select, [])
  53         if test -z "$XCODE_SELECT"; then
  54                 AC_MSG_ERROR([Cannot find xcode-select])
  55         fi
  56         sysroot=`$XCODE_SELECT -p`/SDKs/MacOSX.sdk
  57         SAVE_CPPFLAGS="$CPPFLAGS"
  58         CPPFLAGS="$CPPFLAGS -isysroot $sysroot"
  59         AC_MSG_CHECKING(
  60                 [whether standard include files can be found with sysroot set])
  61         found_header=no
  62         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[]])],
  63                 [found_header=yes])
  64         AC_MSG_RESULT([$found_header])
  65         CPPFLAGS="$SAVE_CPPFLAGS"
  66         if test "x$found_header" != "xyes"; then
  67                 AC_MSG_ERROR([Cannot find standard include files])
  68         else
  69                 AC_DEFINE_UNQUOTED([CLANG_SYSROOT], ["$sysroot"],
  70                         [Define to sysroot if needed])
  71         fi
  72 fi
  73 CC="$SAVE_CC"
  74
  75 AC_LANG_PUSH(C++)
  76
  77 SAVE_CPPFLAGS="$CPPFLAGS"
  78 CPPFLAGS="$CLANG_CXXFLAGS -I$srcdir $CPPFLAGS"
  79 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  80         [AC_MSG_ERROR([clang header file not found])])
  81 AC_CHECK_HEADER([llvm/TargetParser/Host.h],
  82         [AC_DEFINE([HAVE_TARGETPARSER_HOST_H], [],
  83                    [Define if llvm/TargetParser/Host.h exists])],
  84         [AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  85                 [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  86                 [Define to getHostTriple for older versions of clang])])
  87         ])
  88 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  89         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  90         [Define to getInstantiationLineNumber for older versions of clang])])
  91 AC_EGREP_HEADER([getImmediateExpansionRange], [clang/Basic/SourceManager.h],
  92         [],
  93         [AC_DEFINE([getImmediateExpansionRange],
  94         [getImmediateInstantiationRange],
  95         [Define to getImmediateInstantiationRange for older versions of clang])]
  96 )
  97 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h], [],
  98         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  99         [Define to Diagnostic for older versions of clang])])
 100 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
 101         [AC_DEFINE([USE_ARRAYREF], [],
 102                 [Define if Driver::BuildCompilation takes ArrayRef])
 103         AC_EGREP_HEADER([ArrayRef.*CommandLineArgs],
 104                 [clang/Frontend/CompilerInvocation.h],
 105                 [AC_DEFINE([CREATE_FROM_ARGS_TAKES_ARRAYREF], [],
 106                         [Define if CompilerInvocation::CreateFromArgs takes
 107                          ArrayRef])
 108                 ])
 109         ])
 110 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
 111         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
 112                 [Define if Driver constructor takes CXXIsProduction argument])])
 113 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
 114         [AC_DEFINE([HAVE_ISPRODUCTION], [],
 115                 [Define if Driver constructor takes IsProduction argument])])
 116 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Driver/Driver.h>]], [[
 117         using namespace clang;
 118         DiagnosticsEngine *Diags;
 119         new driver::Driver("", "", "", *Diags);
 120 ]])], [AC_DEFINE([DRIVER_CTOR_TAKES_DEFAULTIMAGENAME], [],
 121               [Define if Driver constructor takes default image name])])
 122 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
 123         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 124                    [Return type of HandleTopLevelDeclReturn])
 125          AC_DEFINE([HandleTopLevelDeclContinue], [],
 126                    [Return type of HandleTopLevelDeclReturn])],
 127         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 128                    [Return type of HandleTopLevelDeclReturn])
 129          AC_DEFINE([HandleTopLevelDeclContinue], [true],
 130                    [Return type of HandleTopLevelDeclReturn])])
 131 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 132         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 133                    [Define if clang/Basic/DiagnosticOptions.h exists])])
 134 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
 135         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
 136                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
 137         [#include <clang/Basic/LLVM.h>])
 138 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Basic/TargetInfo.h>]], [[
 139         using namespace clang;
 140         std::shared_ptr<TargetOptions> TO;
 141         DiagnosticsEngine *Diags;
 142         TargetInfo::CreateTargetInfo(*Diags, TO);
 143 ]])], [AC_DEFINE([CREATETARGETINFO_TAKES_SHARED_PTR], [],
 144               [Define if TargetInfo::CreateTargetInfo takes shared_ptr])])
 145 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Basic/TargetInfo.h>]], [[
 146         using namespace clang;
 147         TargetOptions *TO;
 148         DiagnosticsEngine *Diags;
 149         TargetInfo::CreateTargetInfo(*Diags, TO);
 150 ]])], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 151               [Define if TargetInfo::CreateTargetInfo takes pointer])])
 152 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 153                 [[#include <clang/Frontend/CompilerInstance.h>]], [[
 154         using namespace clang;
 155         DiagnosticConsumer *client;
 156         CompilerInstance *Clang;
 157         Clang->createDiagnostics(client);
 158 ]])], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 159         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 160 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 161                 [[#include <clang/Lex/HeaderSearchOptions.h>]], [[
 162         using namespace clang;
 163         HeaderSearchOptions HSO;
 164         HSO.AddPath("", frontend::Angled, false, false);
 165 ]])], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 166         [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 167 AC_EGREP_HEADER([getNumParams],
 168         [clang/AST/CanonicalType.h],
 169         [AC_DEFINE([getNumArgs], [getNumParams],
 170             [Define to getNumParams for newer versions of clang])
 171          AC_DEFINE([getArgType], [getParamType],
 172             [Define to getParamType for newer versions of clang])])
 173 AC_EGREP_HEADER([getReturnType],
 174         [clang/AST/CanonicalType.h], [],
 175         [AC_DEFINE([getReturnType], [getResultType],
 176             [Define to getResultType for older versions of clang])])
 177 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 178                 [[#include <clang/Frontend/CompilerInstance.h>]], [[
 179         using namespace clang;
 180         CompilerInstance *Clang;
 181         Clang->createPreprocessor(TU_Complete);
 182 ]])], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 183 [Define if CompilerInstance::createPreprocessor takes TranslationUnitKind])])
 184 AC_EGREP_HEADER([setMainFileID], [clang/Basic/SourceManager.h],
 185         [AC_DEFINE([HAVE_SETMAINFILEID], [],
 186         [Define if SourceManager has a setMainFileID method])])
 187 AC_CHECK_HEADER([llvm/ADT/OwningPtr.h],
 188         [AC_DEFINE([HAVE_ADT_OWNINGPTR_H], [],
 189                    [Define if llvm/ADT/OwningPtr.h exists])])
 190 AC_EGREP_HEADER([initializeBuiltins],
 191         [clang/Basic/Builtins.h], [],
 192         [AC_DEFINE([initializeBuiltins], [InitializeBuiltins],
 193                 [Define to InitializeBuiltins for older versions of clang])])
 194 AC_EGREP_HEADER([IK_C], [clang/Frontend/FrontendOptions.h], [],
 195         [AC_CHECK_HEADER([clang/Basic/LangStandard.h],
 196                 [IK_C=Language::C], [IK_C=InputKind::C])
 197          AC_DEFINE_UNQUOTED([IK_C], [$IK_C],
 198          [Define to Language::C or InputKind::C for newer versions of clang])
 199         ])
 200 # llvmorg-15-init-7544-g93471e65df48
 201 AC_EGREP_HEADER([setLangDefaults], [clang/Basic/LangOptions.h],
 202         [SETLANGDEFAULTS=LangOptions],
 203         [SETLANGDEFAULTS=CompilerInvocation])
 204 AC_DEFINE_UNQUOTED([SETLANGDEFAULTS], [$SETLANGDEFAULTS],
 205         [Define to class with setLangDefaults method])
 206 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 207         #include <clang/Basic/TargetOptions.h>
 208         #include <clang/Lex/PreprocessorOptions.h>
 209         #include <clang/Frontend/CompilerInstance.h>
 210
 211         #include "set_lang_defaults_arg4.h"
 212 ]], [[
 213         using namespace clang;
 214         CompilerInstance *Clang;
 215         TargetOptions TO;
 216         llvm::Triple T(TO.Triple);
 217         PreprocessorOptions PO;
 218         SETLANGDEFAULTS::setLangDefaults(Clang->getLangOpts(), IK_C,
 219                         T, setLangDefaultsArg4(PO),
 220                         LangStandard::lang_unspecified);
 221 ]])], [AC_DEFINE([SETLANGDEFAULTS_TAKES_5_ARGUMENTS], [],
 222         [Define if CompilerInvocation::setLangDefaults takes 5 arguments])])
 223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 224         #include <clang/Frontend/CompilerInstance.h>
 225         #include <clang/Frontend/CompilerInvocation.h>
 226 ]], [[
 227         using namespace clang;
 228         CompilerInvocation *invocation;
 229         CompilerInstance *Clang;
 230         Clang->setInvocation(std::make_shared<CompilerInvocation>(*invocation));
 231 ]])], [AC_DEFINE([SETINVOCATION_TAKES_SHARED_PTR], [],
 232         [Defined if CompilerInstance::setInvocation takes a shared_ptr])])
 233 AC_CHECK_HEADER([llvm/Option/Arg.h],
 234         [AC_DEFINE([HAVE_LLVM_OPTION_ARG_H], [],
 235                    [Define if llvm/Option/Arg.h exists])])
 236 CPPFLAGS="$SAVE_CPPFLAGS"
 237
 238 SAVE_LDFLAGS="$LDFLAGS"
 239 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 240
 241 # Use single libclang-cpp shared library when available.
 242 # Otherwise, use a selection of clang libraries that appears to work.
 243 AC_CHECK_LIB([clang-cpp], [main], [have_lib_clang=yes], [have_lib_clang=no])
 244 if test "$have_lib_clang" = yes; then
 245         CLANG_LIBS="-lclang-cpp $CLANG_LIBS"
 246 else
 247         CLANG_LIBS="-lclangBasic -lclangDriver $CLANG_LIBS"
 248         CLANG_LIBS="-lclangAnalysis -lclangAST -lclangLex $CLANG_LIBS"
 249         LDFLAGS="$CLANG_LDFLAGS $CLANG_LIBS $SAVE_LDFLAGS"
 250         AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 251         CLANG_LIBS="$LIB_CLANG_EDIT $CLANG_LIBS"
 252         CLANG_LIBS="-lclangParse -lclangSema $CLANG_LIBS"
 253         CLANG_LIBS="-lclangFrontend -lclangSerialization $CLANG_LIBS"
 254 fi
 255
 256 LDFLAGS="$SAVE_LDFLAGS"
 257
 258 AC_LANG_POP
 259 ])