m4/ax_cc_maxopt.m4

   1 # ===========================================================================
   2 #          http://www.nongnu.org/autoconf-archive/ax_cc_maxopt.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CC_MAXOPT
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Try to turn on "good" C optimization flags for various compilers and
  12 #   architectures, for some definition of "good". (In our case, good for
  13 #   FFTW and hopefully for other scientific codes. Modify as needed.)
  14 #
  15 #   The user can override the flags by setting the CFLAGS environment
  16 #   variable. The user can also specify --enable-portable-binary in order to
  17 #   disable any optimization flags that might result in a binary that only
  18 #   runs on the host architecture.
  19 #
  20 #   Note also that the flags assume that ANSI C aliasing rules are followed
  21 #   by the code (e.g. for gcc's -fstrict-aliasing), and that floating-point
  22 #   computations can be re-ordered as needed.
  23 #
  24 #   Requires macros: AX_CHECK_COMPILER_FLAGS, AX_COMPILER_VENDOR,
  25 #   AX_GCC_ARCHFLAG, AX_GCC_X86_CPUID.
  26 #
  27 # LICENSE
  28 #
  29 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  30 #   Copyright (c) 2008 Matteo Frigo
  31 #
  32 #   This program is free software: you can redistribute it and/or modify it
  33 #   under the terms of the GNU General Public License as published by the
  34 #   Free Software Foundation, either version 3 of the License, or (at your
  35 #   option) any later version.
  36 #
  37 #   This program is distributed in the hope that it will be useful, but
  38 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  39 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  40 #   Public License for more details.
  41 #
  42 #   You should have received a copy of the GNU General Public License along
  43 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  44 #
  45 #   As a special exception, the respective Autoconf Macro's copyright owner
  46 #   gives unlimited permission to copy, distribute and modify the configure
  47 #   scripts that are the output of Autoconf when processing the Macro. You
  48 #   need not follow the terms of the GNU General Public License when using
  49 #   or distributing such scripts, even though portions of the text of the
  50 #   Macro appear in them. The GNU General Public License (GPL) does govern
  51 #   all other use of the material that constitutes the Autoconf Macro.
  52 #
  53 #   This special exception to the GPL applies to versions of the Autoconf
  54 #   Macro released by the Autoconf Archive. When you make and distribute a
  55 #   modified version of the Autoconf Macro, you may extend this special
  56 #   exception to the GPL to apply to your modified version as well.
  57
  58 AC_DEFUN([AX_CC_MAXOPT],
  59 [
  60 AC_REQUIRE([AC_PROG_CC])
  61 AC_REQUIRE([AX_COMPILER_VENDOR])
  62 AC_REQUIRE([AC_CANONICAL_HOST])
  63
  64 AC_ARG_ENABLE(portable-binary, [AC_HELP_STRING([--enable-portable-binary], [disable compiler optimizations that would produce unportable binaries])],
  65         acx_maxopt_portable=$withval, acx_maxopt_portable=no)
  66
  67 # Try to determine "good" native compiler flags if none specified via CFLAGS
  68 if test "$ac_test_CFLAGS" != "set"; then
  69   CFLAGS=""
  70   case $ax_cv_c_compiler_vendor in
  71     dec) CFLAGS="-newc -w0 -O5 -ansi_alias -ansi_args -fp_reorder -tune host"
  72          if test "x$acx_maxopt_portable" = xno; then
  73            CFLAGS="$CFLAGS -arch host"
  74          fi;;
  75
  76     sun) CFLAGS="-native -fast -xO5 -dalign"
  77          if test "x$acx_maxopt_portable" = xyes; then
  78            CFLAGS="$CFLAGS -xarch=generic"
  79          fi;;
  80
  81     hp)  CFLAGS="+Oall +Optrs_ansi +DSnative"
  82          if test "x$acx_maxopt_portable" = xyes; then
  83            CFLAGS="$CFLAGS +DAportable"
  84          fi;;
  85
  86     ibm) if test "x$acx_maxopt_portable" = xno; then
  87            xlc_opt="-qarch=auto -qtune=auto"
  88          else
  89            xlc_opt="-qtune=auto"
  90          fi
  91          AX_CHECK_COMPILER_FLAGS($xlc_opt,
  92                 CFLAGS="-O3 -qansialias -w $xlc_opt",
  93                [CFLAGS="-O3 -qansialias -w"
  94                 echo "******************************************************"
  95                 echo "*  You seem to have the IBM  C compiler.  It is      *"
  96                 echo "*  recommended for best performance that you use:    *"
  97                 echo "*                                                    *"
  98                 echo "*    CFLAGS=-O3 -qarch=xxx -qtune=xxx -qansialias -w *"
  99                 echo "*                      ^^^        ^^^                *"
 100                 echo "*  where xxx is pwr2, pwr3, 604, or whatever kind of *"
 101                 echo "*  CPU you have.  (Set the CFLAGS environment var.   *"
 102                 echo "*  and re-run configure.)  For more info, man cc.    *"
 103                 echo "******************************************************"])
 104          ;;
 105
 106     intel) CFLAGS="-O3 -ansi_alias"
 107         if test "x$acx_maxopt_portable" = xno; then
 108           icc_archflag=unknown
 109           icc_flags=""
 110           case $host_cpu in
 111             i686*|x86_64*)
 112               # icc accepts gcc assembly syntax, so these should work:
 113               AX_GCC_X86_CPUID(0)
 114               AX_GCC_X86_CPUID(1)
 115               case $ax_cv_gcc_x86_cpuid_0 in # see AX_GCC_ARCHFLAG
 116                 *:756e6547:*:*) # Intel
 117                   case $ax_cv_gcc_x86_cpuid_1 in
 118                     *6a?:*[[234]]:*:*|*6[[789b]]?:*:*:*) icc_flags="-xK";;
 119                     *f3[[347]]:*:*:*|*f4[1347]:*:*:*) icc_flags="-xP -xN -xW -xK";;
 120                     *f??:*:*:*) icc_flags="-xN -xW -xK";;
 121                   esac ;;
 122               esac ;;
 123           esac
 124           if test "x$icc_flags" != x; then
 125             for flag in $icc_flags; do
 126               AX_CHECK_COMPILER_FLAGS($flag, [icc_archflag=$flag; break])
 127             done
 128           fi
 129           AC_MSG_CHECKING([for icc architecture flag])
 130           AC_MSG_RESULT($icc_archflag)
 131           if test "x$icc_archflag" != xunknown; then
 132             CFLAGS="$CFLAGS $icc_archflag"
 133           fi
 134         fi
 135         ;;
 136
 137     gnu)
 138      # default optimization flags for gcc on all systems
 139      CFLAGS="-O3 -fomit-frame-pointer"
 140
 141      # -malign-double for x86 systems
 142      AX_CHECK_COMPILER_FLAGS(-malign-double, CFLAGS="$CFLAGS -malign-double")
 143
 144      #  -fstrict-aliasing for gcc-2.95+
 145      AX_CHECK_COMPILER_FLAGS(-fstrict-aliasing,
 146         CFLAGS="$CFLAGS -fstrict-aliasing")
 147
 148      # note that we enable "unsafe" fp optimization with other compilers, too
 149      AX_CHECK_COMPILER_FLAGS(-ffast-math, CFLAGS="$CFLAGS -ffast-math")
 150
 151      AX_GCC_ARCHFLAG($acx_maxopt_portable)
 152
 153      # drop to -O1 for gcc 4.2
 154      $CC --version |
 155         sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 156         (read major minor
 157             if test $major -eq 4 -a $minor -eq 2; then
 158                                 exit 0
 159             fi
 160             exit 1
 161         ) && CFLAGS="-O1"
 162      ;;
 163   esac
 164
 165   if test -z "$CFLAGS"; then
 166         echo ""
 167         echo "********************************************************"
 168         echo "* WARNING: Don't know the best CFLAGS for this system  *"
 169         echo "* Use ./configure CFLAGS=... to specify your own flags *"
 170         echo "* (otherwise, a default of CFLAGS=-O3 will be used)    *"
 171         echo "********************************************************"
 172         echo ""
 173         CFLAGS="-O3"
 174   fi
 175
 176   AX_CHECK_COMPILER_FLAGS($CFLAGS, [], [
 177         echo ""
 178         echo "********************************************************"
 179         echo "* WARNING: The guessed CFLAGS don't seem to work with  *"
 180         echo "* your compiler.                                       *"
 181         echo "* Use ./configure CFLAGS=... to specify your own flags *"
 182         echo "********************************************************"
 183         echo ""
 184         CFLAGS=""
 185   ])
 186
 187 fi
 188 ])