configure.ac

   1 AC_INIT([isl], [0.18], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=18:0:3
   8
   9 if test "x$prefix" != "xNONE"; then
  10         prefix_wd=`cd $prefix && pwd`
  11         srcdir_wd=`cd $srcdir && pwd`
  12         wd=`pwd`
  13         if test "x$prefix_wd" = "x$srcdir_wd"; then
  14                 AC_MSG_ERROR(Installation in source directory not supported)
  15         fi
  16         if test "x$prefix_wd" = "x$wd"; then
  17                 AC_MSG_ERROR(Installation in build directory not supported)
  18         fi
  19 fi
  20
  21 AC_PROG_CC
  22 AC_PROG_CXX
  23
  24 AX_CC_MAXOPT
  25 AX_GCC_WARN_UNUSED_RESULT
  26 AX_C___ATTRIBUTE__
  27
  28 AC_PROG_LIBTOOL
  29
  30 AC_CHECK_PROG(PERL, perl, perl, [])
  31 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  32 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  33
  34 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  35
  36 AX_CREATE_STDINT_H(include/isl/stdint.h)
  37
  38 AC_ARG_WITH([int],
  39             [AS_HELP_STRING([--with-int=gmp|imath|imath-32],
  40                             [Which package to use to represent
  41                                 multi-precision integers [default=gmp]])],
  42             [], [with_int=gmp])
  43 case "$with_int" in
  44 gmp|imath|imath-32)
  45         ;;
  46 *)
  47         AC_MSG_ERROR(
  48             [bad value ${withval} for --with-int (use gmp, imath or imath-32)])
  49 esac
  50
  51 AC_SUBST(MP_CPPFLAGS)
  52 AC_SUBST(MP_LDFLAGS)
  53 AC_SUBST(MP_LIBS)
  54 case "$with_int" in
  55 gmp)
  56         AX_DETECT_GMP
  57         ;;
  58 imath|imath-32)
  59         AX_DETECT_IMATH
  60         ;;
  61 esac
  62 if test "x$with_int" = "ximath-32" -a "x$GCC" = "xyes"; then
  63         MP_CPPFLAGS="-std=gnu99 $MP_CPPFLAGS"
  64 fi
  65
  66 AM_CONDITIONAL(IMATH_FOR_MP, test x$with_int = ximath -o x$with_int = ximath-32)
  67 AM_CONDITIONAL(GMP_FOR_MP, test x$with_int = xgmp)
  68
  69 AM_CONDITIONAL(SMALL_INT_OPT, test "x$with_int" == "ximath-32")
  70 AS_IF([test "x$with_int" == "ximath-32"], [
  71         AC_DEFINE([USE_SMALL_INT_OPT], [], [Use small integer optimization])
  72 ])
  73
  74 AC_CHECK_DECLS(ffs,[],[],[#include <strings.h>])
  75 AC_CHECK_DECLS(__builtin_ffs,[],[],[])
  76 AC_CHECK_DECLS([_BitScanForward],[],[],[#include <intrin.h>])
  77 if test "x$ac_cv_have_decl_ffs" = xno -a \
  78                 "x$ac_cv_have_decl___builtin_ffs" = xno -a \
  79                 "x$ac_cv_have_decl__BitScanForward" = xno; then
  80         AC_MSG_ERROR([No ffs implementation found])
  81 fi
  82 AC_CHECK_DECLS([strcasecmp,strncasecmp],[],[],[#include <strings.h>])
  83 AC_CHECK_DECLS([_stricmp,_strnicmp],[],[],[#include <string.h>])
  84 if test "x$ac_cv_have_decl_strcasecmp" = xno -a \
  85                 "x$ac_cv_have_decl__stricmp" = xno; then
  86         AC_MSG_ERROR([No strcasecmp implementation found])
  87 fi
  88 if test "x$ac_cv_have_decl_strncasecmp" = xno -a \
  89                 "x$ac_cv_have_decl__strnicmp" = xno; then
  90         AC_MSG_ERROR([No strncasecmp implementation found])
  91 fi
  92 AC_CHECK_DECLS([snprintf,_snprintf],[],[],[#include <stdio.h>])
  93 if test "x$ac_cv_have_decl_snprintf" = xno -a \
  94                 "x$ac_cv_have_decl__snprintf" = xno; then
  95         AC_MSG_ERROR([No snprintf implementation found])
  96 fi
  97
  98 AX_SUBMODULE(clang,system|no,no)
  99 case "$with_clang" in
 100 system)
 101         AX_DETECT_CLANG
 102         ;;
 103 esac
 104 AM_CONDITIONAL(HAVE_CLANG, test $with_clang = system)
 105
 106 AX_SET_WARNING_FLAGS
 107
 108 AC_SUBST(WARNING_FLAGS)
 109
 110 PACKAGE_CFLAGS="$MP_CPPFLAGS"
 111 PACKAGE_LDFLAGS="$MP_LDFLAGS"
 112 PACKAGE_LIBS="-lisl $MP_LIBS"
 113 AX_CREATE_PKGCONFIG_INFO
 114
 115 AX_DETECT_GIT_HEAD
 116
 117 AH_BOTTOM([#include <isl_config_post.h>])
 118 AC_CONFIG_HEADERS(isl_config.h)
 119 AC_CONFIG_FILES(isl_srcdir.c)
 120 AC_CONFIG_FILES(Makefile)
 121 AC_CONFIG_FILES(doc/Makefile)
 122 if test $with_clang = system; then
 123         AC_CONFIG_FILES(interface/Makefile)
 124 fi
 125 AC_CONFIG_FILES([bound_test.sh], [chmod +x bound_test.sh])
 126 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 127 AC_CONFIG_FILES([pip_test.sh], [chmod +x pip_test.sh])
 128 AC_CONFIG_COMMANDS_POST([
 129         dnl pass on arguments to subdir configures, but don't
 130         dnl add them to config.status
 131         ac_configure_args="$ac_configure_args $isl_configure_args"
 132 ])
 133 AC_OUTPUT