m4/ax_prog_cc_for_build.m4

   1 # ===========================================================================
   2 #   https://www.gnu.org/software/autoconf-archive/ax_prog_cc_for_build.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PROG_CC_FOR_BUILD
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro searches for a C compiler that generates native executables,
  12 #   that is a C compiler that surely is not a cross-compiler. This can be
  13 #   useful if you have to generate source code at compile-time like for
  14 #   example GCC does.
  15 #
  16 #   The macro sets the CC_FOR_BUILD and CPP_FOR_BUILD macros to anything
  17 #   needed to compile or link (CC_FOR_BUILD) and preprocess (CPP_FOR_BUILD).
  18 #   The value of these variables can be overridden by the user by specifying
  19 #   a compiler with an environment variable (like you do for standard CC).
  20 #
  21 #   It also sets BUILD_EXEEXT and BUILD_OBJEXT to the executable and object
  22 #   file extensions for the build platform, and GCC_FOR_BUILD to `yes' if
  23 #   the compiler we found is GCC. All these variables but GCC_FOR_BUILD are
  24 #   substituted in the Makefile.
  25 #
  26 # LICENSE
  27 #
  28 #   Copyright (c) 2008 Paolo Bonzini <bonzini@gnu.org>
  29 #
  30 #   Copying and distribution of this file, with or without modification, are
  31 #   permitted in any medium without royalty provided the copyright notice
  32 #   and this notice are preserved. This file is offered as-is, without any
  33 #   warranty.
  34
  35 #serial 18
  36
  37 AU_ALIAS([AC_PROG_CC_FOR_BUILD], [AX_PROG_CC_FOR_BUILD])
  38 AC_DEFUN([AX_PROG_CC_FOR_BUILD], [dnl
  39 AC_REQUIRE([AC_PROG_CC])dnl
  40 AC_REQUIRE([AC_PROG_CPP])dnl
  41 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
  42
  43 dnl Use the standard macros, but make them use other variable names
  44 dnl
  45 pushdef([ac_cv_prog_CPP], ac_cv_build_prog_CPP)dnl
  46 pushdef([ac_cv_prog_cc_c89], ac_cv_build_prog_cc_c89)dnl
  47 pushdef([ac_cv_prog_gcc], ac_cv_build_prog_gcc)dnl
  48 pushdef([ac_cv_prog_cc_works], ac_cv_build_prog_cc_works)dnl
  49 pushdef([ac_cv_prog_cc_cross], ac_cv_build_prog_cc_cross)dnl
  50 pushdef([ac_cv_prog_cc_g], ac_cv_build_prog_cc_g)dnl
  51 pushdef([ac_cv_c_compiler_gnu], ac_cv_build_c_compiler_gnu)dnl
  52 pushdef([ac_cv_exeext], ac_cv_build_exeext)dnl
  53 pushdef([ac_cv_objext], ac_cv_build_objext)dnl
  54 pushdef([ac_exeext], ac_build_exeext)dnl
  55 pushdef([ac_objext], ac_build_objext)dnl
  56 pushdef([CC], CC_FOR_BUILD)dnl
  57 pushdef([CCDEPMODE], CCDEPMODE_FOR_BUILD)dnl
  58 pushdef([CPP], CPP_FOR_BUILD)dnl
  59 pushdef([GCC], GCC_FOR_BUILD)dnl
  60 pushdef([CFLAGS], CFLAGS_FOR_BUILD)dnl
  61 pushdef([CPPFLAGS], CPPFLAGS_FOR_BUILD)dnl
  62 pushdef([EXEEXT], BUILD_EXEEXT)dnl
  63 pushdef([LDFLAGS], LDFLAGS_FOR_BUILD)dnl
  64 pushdef([OBJEXT], BUILD_OBJEXT)dnl
  65 pushdef([host], build)dnl
  66 pushdef([host_alias], build_alias)dnl
  67 pushdef([host_cpu], build_cpu)dnl
  68 pushdef([host_vendor], build_vendor)dnl
  69 pushdef([host_os], build_os)dnl
  70 pushdef([ac_cv_host], ac_cv_build)dnl
  71 pushdef([ac_cv_host_alias], ac_cv_build_alias)dnl
  72 pushdef([ac_cv_host_cpu], ac_cv_build_cpu)dnl
  73 pushdef([ac_cv_host_vendor], ac_cv_build_vendor)dnl
  74 pushdef([ac_cv_host_os], ac_cv_build_os)dnl
  75 pushdef([ac_tool_prefix], ac_build_tool_prefix)dnl
  76 pushdef([am_cv_CC_dependencies_compiler_type], am_cv_build_CC_dependencies_compiler_type)dnl
  77 pushdef([am__fastdepCC_FALSE], am__fastdepCC_build_FALSE)dnl
  78 pushdef([am__fastdepCC_TRUE], am__fastdepCC_build_TRUE)dnl
  79 pushdef([am_cv_prog_cc_c_o], am_cv_build_prog_cc_c_o)dnl
  80 pushdef([cross_compiling], cross_compiling_build)dnl
  81
  82 cross_compiling_build=no
  83
  84 ac_build_tool_prefix=
  85 AS_IF([test -n "$build"],      [ac_build_tool_prefix="$build-"],
  86       [test -n "$build_alias"],[ac_build_tool_prefix="$build_alias-"])
  87
  88 AC_LANG_PUSH([C])
  89 AC_PROG_CC
  90 _AC_COMPILER_EXEEXT
  91 _AC_COMPILER_OBJEXT
  92 AC_PROG_CPP
  93
  94 dnl Restore the old definitions
  95 dnl
  96 popdef([cross_compiling])dnl
  97 popdef([am_cv_prog_cc_c_o])dnl
  98 popdef([am__fastdepCC_TRUE])dnl
  99 popdef([am__fastdepCC_FALSE])dnl
 100 popdef([am_cv_CC_dependencies_compiler_type])dnl
 101 popdef([ac_tool_prefix])dnl
 102 popdef([ac_cv_host_os])dnl
 103 popdef([ac_cv_host_vendor])dnl
 104 popdef([ac_cv_host_cpu])dnl
 105 popdef([ac_cv_host_alias])dnl
 106 popdef([ac_cv_host])dnl
 107 popdef([host_os])dnl
 108 popdef([host_vendor])dnl
 109 popdef([host_cpu])dnl
 110 popdef([host_alias])dnl
 111 popdef([host])dnl
 112 popdef([OBJEXT])dnl
 113 popdef([LDFLAGS])dnl
 114 popdef([EXEEXT])dnl
 115 popdef([CPPFLAGS])dnl
 116 popdef([CFLAGS])dnl
 117 popdef([GCC])dnl
 118 popdef([CPP])dnl
 119 popdef([CCDEPMODE])dnl
 120 popdef([CC])dnl
 121 popdef([ac_objext])dnl
 122 popdef([ac_exeext])dnl
 123 popdef([ac_cv_objext])dnl
 124 popdef([ac_cv_exeext])dnl
 125 popdef([ac_cv_c_compiler_gnu])dnl
 126 popdef([ac_cv_prog_cc_g])dnl
 127 popdef([ac_cv_prog_cc_cross])dnl
 128 popdef([ac_cv_prog_cc_works])dnl
 129 popdef([ac_cv_prog_cc_c89])dnl
 130 popdef([ac_cv_prog_gcc])dnl
 131 popdef([ac_cv_prog_CPP])dnl
 132
 133 dnl restore global variables ac_ext, ac_cpp, ac_compile,
 134 dnl ac_link, ac_compiler_gnu (dependant on the current
 135 dnl language after popping):
 136 AC_LANG_POP([C])
 137
 138 dnl Finally, set Makefile variables
 139 dnl
 140 AC_SUBST(BUILD_EXEEXT)dnl
 141 AC_SUBST(BUILD_OBJEXT)dnl
 142 AC_SUBST([CFLAGS_FOR_BUILD])dnl
 143 AC_SUBST([CPPFLAGS_FOR_BUILD])dnl
 144 AC_SUBST([LDFLAGS_FOR_BUILD])dnl
 145 ])