net.sockets/socket-methods.lisp

   1 ;;;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp; indent-tabs-mode: nil -*-
   2 ;;;
   3 ;;; socket-methods.lisp --- Various socket methods.
   4 ;;;
   5 ;;; Copyright (C) 2006-2008, Stelian Ionescu  <sionescu@common-lisp.net>
   6 ;;;
   7 ;;; This code is free software; you can redistribute it and/or
   8 ;;; modify it under the terms of the version 2.1 of
   9 ;;; the GNU Lesser General Public License as published by
  10 ;;; the Free Software Foundation, as clarified by the
  11 ;;; preamble found here:
  12 ;;;     http://opensource.franz.com/preamble.html
  13 ;;;
  14 ;;; This program is distributed in the hope that it will be useful,
  15 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU Lesser General
  20 ;;; Public License along with this library; if not, write to the
  21 ;;; Free Software Foundation, Inc., 51 Franklin St, Fifth Floor,
  22 ;;; Boston, MA 02110-1301, USA
  23
  24 (in-package :net.sockets)
  25
  26 (defvar *socket-type-map*
  27   '(((:ipv4  :stream   :active  :default) . socket-stream-internet-active)
  28     ((:ipv6  :stream   :active  :default) . socket-stream-internet-active)
  29     ((:ipv4  :stream   :passive :default) . socket-stream-internet-passive)
  30     ((:ipv6  :stream   :passive :default) . socket-stream-internet-passive)
  31     ((:local :stream   :active  :default) . socket-stream-local-active)
  32     ((:local :stream   :passive :default) . socket-stream-local-passive)
  33     ((:local :datagram :active  :default) . socket-datagram-local-active)
  34     ((:ipv4  :datagram :active  :default) . socket-datagram-internet-active)
  35     ((:ipv6  :datagram :active  :default) . socket-datagram-internet-active)))
  36
  37 ;;; FIXME: should match :default to whatever protocol is the default.
  38 (defun select-socket-class (family type connect protocol)
  39   (or (cdr (assoc (list family type connect protocol) *socket-type-map*
  40                   :test #'equal))
  41       (error "No socket class found !!")))
  42
  43 ;;;; Shared Initialization
  44
  45 (defun translate-make-socket-keywords-to-constants (family type protocol)
  46   (let ((sf (ecase family
  47               (:ipv4  af-inet)
  48               (:ipv6  af-inet6)
  49               (:local af-local)))
  50         (st (ecase type
  51               (:stream   sock-stream)
  52               (:datagram sock-dgram)))
  53         (sp (cond
  54               ((integerp protocol) protocol)
  55               ((eq :default protocol) 0)
  56               (t (lookup-protocol protocol)))))
  57     (values sf st sp)))
  58
  59 (defmethod socket-os-fd ((socket socket))
  60   (fd-of socket))
  61
  62 (defmethod initialize-instance :after ((socket socket) &key
  63                                        file-descriptor family type
  64                                        (protocol :default))
  65   (with-accessors ((fd fd-of) (fam socket-family) (proto socket-protocol))
  66       socket
  67     (setf fd (or file-descriptor
  68                  (multiple-value-call #'%socket
  69                    (translate-make-socket-keywords-to-constants
  70                     family type protocol))))
  71     (setf fam family
  72           proto protocol)))
  73
  74 (defmethod (setf external-format-of) (external-format (socket passive-socket))
  75   (setf (slot-value socket 'external-format)
  76         (babel:ensure-external-format external-format)))
  77
  78 (defmethod initialize-instance :after ((socket passive-socket) &key external-format
  79                                        input-buffer-size output-buffer-size)
  80   ;; Makes CREATE-SOCKET simpler
  81   (declare (ignore input-buffer-size output-buffer-size))
  82   (setf (external-format-of socket) external-format))
  83
  84 (defmethod socket-type ((socket stream-socket))
  85   :stream)
  86
  87 (defmethod socket-type ((socket datagram-socket))
  88   :datagram)
  89
  90 (defun ipv6-socket-p (socket)
  91   "Return T if SOCKET is an AF_INET6 socket."
  92   (eq :ipv6 (socket-family socket)))
  93
  94 ;;;; Printing
  95
  96 (defun sock-fam (socket)
  97   (ecase (socket-family socket)
  98     (:ipv4 "IPv4")
  99     (:ipv6 "IPv6")))
 100
 101 (defmethod print-object ((socket socket-stream-internet-active) stream)
 102   (print-unreadable-object (socket stream :identity t)
 103     (format stream "active ~A stream socket" (sock-fam socket))
 104     (if (socket-connected-p socket)
 105         (multiple-value-bind (host port) (remote-name socket)
 106           (format stream " connected to ~A/~A"
 107                   (address-to-string host) port))
 108         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
 109
 110 (defmethod print-object ((socket socket-stream-internet-passive) stream)
 111   (print-unreadable-object (socket stream :identity t)
 112     (format stream "passive ~A stream socket" (sock-fam socket))
 113     (if (socket-bound-p socket)
 114         (multiple-value-bind (host port) (local-name socket)
 115           (format stream " ~:[bound to~;waiting @~] ~A/~A"
 116                   (socket-listening-p socket)
 117                   (address-to-string host) port))
 118         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 119
 120 (defmethod print-object ((socket socket-stream-local-active) stream)
 121   (print-unreadable-object (socket stream :identity t)
 122     (format stream "active local stream socket")
 123     (if (socket-connected-p socket)
 124         (format stream " connected to ~S"
 125                 (address-to-string (remote-filename socket)))
 126         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
 127
 128 (defmethod print-object ((socket socket-stream-local-passive) stream)
 129   (print-unreadable-object (socket stream :identity t)
 130     (format stream "passive local stream socket")
 131     (if (socket-bound-p socket)
 132         (format stream " ~:[bound to~;waiting @~] ~S"
 133                   (socket-listening-p socket)
 134                   (address-to-string (local-filename socket)))
 135         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 136
 137 (defmethod print-object ((socket socket-datagram-local-active) stream)
 138   (print-unreadable-object (socket stream :identity t)
 139     (format stream "local datagram socket")
 140     (if (socket-connected-p socket)
 141         (format stream " connected to ~S"
 142                 (address-to-string (remote-filename socket)))
 143         (if (fd-of socket)
 144             (format stream " waiting @ ~S" (address-to-string (local-filename socket)))
 145             (format stream ", closed" )))))
 146
 147 (defmethod print-object ((socket socket-datagram-internet-active) stream)
 148   (print-unreadable-object (socket stream :identity t)
 149     (format stream "~A datagram socket" (sock-fam socket))
 150     (if (socket-connected-p socket)
 151         (multiple-value-bind (host port) (remote-name socket)
 152           (format stream " connected to ~A/~A"
 153                   (address-to-string host) port))
 154         (if (fd-of socket)
 155             (multiple-value-bind (host port) (local-name socket)
 156               (format stream " waiting @ ~A/~A"
 157                       (address-to-string host) port))
 158             (format stream ", closed" )))))
 159
 160 ;;;; CLOSE
 161
 162 (defmethod close :around ((socket socket) &key abort)
 163   (declare (ignore abort))
 164   (call-next-method)
 165   (when (fd-of socket)
 166     (nix:close (fd-of socket)))
 167   (setf (fd-of socket) nil
 168         (slot-value socket 'bound) nil)
 169   (values socket))
 170
 171 (defmethod close :around ((socket passive-socket) &key abort)
 172   (declare (ignore abort))
 173   (call-next-method)
 174   (setf (slot-value socket 'listening) nil)
 175   (values socket))
 176
 177 (defmethod close ((socket socket) &key abort)
 178   (declare (ignore socket abort)))
 179
 180 (defmethod socket-open-p ((socket socket))
 181   (when (fd-of socket)
 182     (with-sockaddr-storage-and-socklen (ss size)
 183       (handler-case
 184           (%getsockname (fd-of socket) ss size)
 185         (nix:ebadf () nil)
 186         (socket-connection-reset-error () nil)
 187         (:no-error (_) (declare (ignore _)) t)))))
 188
 189 ;;;; GETSOCKNAME
 190
 191 (defun %local-name (socket)
 192   (with-sockaddr-storage-and-socklen (ss size)
 193     (%getsockname (fd-of socket) ss size)
 194     (sockaddr-storage->sockaddr ss)))
 195
 196 (defmethod local-name ((socket socket))
 197   (%local-name socket))
 198
 199 (defmethod local-host ((socket internet-socket))
 200   (nth-value 0 (%local-name socket)))
 201
 202 (defmethod local-port ((socket internet-socket))
 203   (nth-value 1 (%local-name socket)))
 204
 205 (defmethod local-filename ((socket local-socket))
 206   (%local-name socket))
 207
 208 ;;;; GETPEERNAME
 209
 210 (defun %remote-name (socket)
 211   (with-sockaddr-storage-and-socklen (ss size)
 212     (%getpeername (fd-of socket) ss size)
 213     (sockaddr-storage->sockaddr ss)))
 214
 215 (defmethod remote-name ((socket socket))
 216   (%remote-name socket))
 217
 218 (defmethod remote-host ((socket internet-socket))
 219   (nth-value 0 (%remote-name socket)))
 220
 221 (defmethod remote-port ((socket internet-socket))
 222   (nth-value 1 (%remote-name socket)))
 223
 224 (defmethod remote-filename ((socket local-socket))
 225   (%remote-name socket))
 226
 227 ;;;; BIND
 228
 229 (defmethod bind-address :before ((socket internet-socket) address
 230                                  &key (reuse-address t))
 231   (declare (ignore address))
 232   (when reuse-address
 233     (setf (socket-option socket :reuse-address) t)))
 234
 235 (defun bind-ipv4-address (fd address port)
 236   (with-sockaddr-in (sin address port)
 237     (%bind fd sin size-of-sockaddr-in)))
 238
 239 (defun bind-ipv6-address (fd address port)
 240   (with-sockaddr-in6 (sin6 address port)
 241     (%bind fd sin6 size-of-sockaddr-in6)))
 242
 243 (defmethod bind-address ((socket internet-socket) (address ipv4-address)
 244                          &key (port 0))
 245   (if (ipv6-socket-p socket)
 246       (bind-ipv6-address (fd-of socket)
 247                          (map-ipv4-vector-to-ipv6 (address-name address))
 248                          port)
 249       (bind-ipv4-address (fd-of socket) (address-name address) port))
 250   (values socket))
 251
 252 (defmethod bind-address ((socket internet-socket) (address ipv6-address)
 253                          &key (port 0))
 254   (bind-ipv6-address (fd-of socket) (address-name address) port)
 255   (values socket))
 256
 257 (defmethod bind-address ((socket local-socket) (address local-address) &key)
 258   (with-sockaddr-un (sun (address-name address))
 259     (%bind (fd-of socket) sun size-of-sockaddr-un))
 260   (values socket))
 261
 262 (defmethod bind-address :after ((socket socket) (address address) &key)
 263   (setf (slot-value socket 'bound) t))
 264
 265 ;;;; LISTEN
 266
 267 (defmethod listen-on ((socket passive-socket) &key backlog)
 268   (unless backlog (setf backlog (min *default-backlog-size*
 269                                      +max-backlog-size+)))
 270   (check-type backlog unsigned-byte "a non-negative integer")
 271   (%listen (fd-of socket) backlog)
 272   (setf (slot-value socket 'listening) t)
 273   (values socket))
 274
 275 (defmethod listen-on ((socket active-socket) &key)
 276   (error "You can't listen on active sockets."))
 277
 278 ;;;; ACCEPT
 279
 280 (defmethod accept-connection ((socket active-socket) &key)
 281   (error "You can't accept connections on active sockets."))
 282
 283 (defmethod accept-connection ((socket passive-socket) &key external-format
 284                               input-buffer-size output-buffer-size)
 285   (flet ((make-client-socket (fd)
 286            (make-instance (active-class socket)
 287                           :file-descriptor fd
 288                           :external-format (or external-format
 289                                                (external-format-of socket))
 290                           :input-buffer-size input-buffer-size
 291                           :output-buffer-size output-buffer-size)))
 292     (with-sockaddr-storage-and-socklen (ss size)
 293       (handler-case
 294           (make-client-socket (%accept (fd-of socket) ss size))
 295         (nix:ewouldblock ())))))
 296
 297 ;;;; CONNECT
 298
 299 (defmethod connect :before ((socket active-socket) address &key)
 300   (declare (ignore address))
 301 #+freebsd
 302   (setf (socket-option socket :no-sigpipe) t))
 303
 304 (defun ipv4-connect (fd address port)
 305   (with-sockaddr-in (sin address port)
 306     (%connect fd sin size-of-sockaddr-in)))
 307
 308 (defun ipv6-connect (fd address port)
 309   (with-sockaddr-in6 (sin6 address port)
 310     (%connect fd sin6 size-of-sockaddr-in6)))
 311
 312 (defmethod connect ((socket internet-socket) (address ipv4-address)
 313                     &key (port 0))
 314   (if (ipv6-socket-p socket)
 315       (ipv6-connect (fd-of socket)
 316                     (map-ipv4-vector-to-ipv6 (address-name address))
 317                     port)
 318       (ipv4-connect (fd-of socket) (address-name address) port))
 319   (values socket))
 320
 321 (defmethod connect ((socket internet-socket) (address ipv6-address)
 322                     &key (port 0))
 323   (ipv6-connect (fd-of socket) (address-name address) port)
 324   (values socket))
 325
 326 (defmethod connect ((socket local-socket) (address local-address) &key)
 327   (with-sockaddr-un (sun (address-name address))
 328     (%connect (fd-of socket) sun size-of-sockaddr-un))
 329   (values socket))
 330
 331 (defmethod connect ((socket passive-socket) address &key)
 332   (declare (ignore address))
 333   (error "You cannot connect passive sockets."))
 334
 335 (defmethod socket-connected-p ((socket socket))
 336   (when (fd-of socket)
 337     (with-sockaddr-storage-and-socklen (ss size)
 338       (handler-case
 339           (%getpeername (fd-of socket) ss size)
 340         (socket-not-connected-error () nil)
 341         (:no-error (_) (declare (ignore _)) t)))))
 342
 343 ;;;; DISCONNECT
 344
 345 (defmethod disconnect :before ((socket socket))
 346   (unless (typep socket 'datagram-socket)
 347     (error "You can only disconnect active datagram sockets.")))
 348
 349 (defmethod disconnect ((socket datagram-socket))
 350   (with-foreign-object (sin 'sockaddr-in)
 351     (bzero sin size-of-sockaddr-in)
 352     (setf (foreign-slot-value sin 'sockaddr-in 'addr) af-unspec)
 353     (%connect (fd-of socket) sin size-of-sockaddr-in)))
 354
 355 ;;;; SHUTDOWN
 356
 357 (defmethod shutdown ((socket socket) &key read write)
 358   (assert (or read write) (read write)
 359           "You must select at least one direction to shut down.")
 360   (%shutdown (fd-of socket)
 361              (multiple-value-case ((read write))
 362                ((_   nil) shut-rd)
 363                ((nil _)   shut-wr)
 364                (t         shut-rdwr)))
 365   (values socket))
 366
 367 ;;;; Socket flag definition
 368
 369 (defmacro define-socket-flag (place name value platform)
 370   (let ((val (cond ((or (not platform)
 371                         (featurep platform)) value)
 372                    ((not (featurep platform)) 0))))
 373     `(pushnew (cons ,name ,val) ,place)))
 374
 375 (defmacro define-socket-flags (place &body definitions)
 376   (flet ((dflag (form)
 377            (destructuring-bind (name value &optional platform) form
 378              `(define-socket-flag ,place ,name ,value ,platform))))
 379     `(progn
 380        ,@(mapcar #'dflag definitions))))
 381
 382 ;;;; SENDTO
 383
 384 (defvar *sendto-flags* ())
 385
 386 (define-socket-flags *sendto-flags*
 387   (:dont-route    msg-dontroute)
 388   (:dont-wait     msg-dontwait  (:not :windows))
 389   (:out-of-band   msg-oob)
 390   (:more          msg-more      :linux)
 391   (:confirm       msg-confirm   :linux))
 392
 393 (defun %normalize-send-buffer (buff start end ef)
 394   (check-bounds buff start end)
 395   (etypecase buff
 396     (ub8-sarray (values buff start (- end start)))
 397     (string     (let ((vector (%to-octets buff ef start end)))
 398                   (values vector 0 (length vector))))
 399     (vector     (values (coerce buff 'ub8-sarray)
 400                         start (- end start)))))
 401
 402 (defun %%send-to (fd ss got-peer buffer start end flags ef)
 403   (multiple-value-bind (buff start-offset bufflen)
 404       (%normalize-send-buffer buffer start end ef)
 405     (with-pointer-to-vector-data (buff-sap buff)
 406       (incf-pointer buff-sap start-offset)
 407       (loop
 408          (restart-case
 409              (return-from %%send-to
 410                (%sendto fd buff-sap bufflen flags
 411                         (if got-peer ss (null-pointer))
 412                         (if got-peer (sockaddr-size ss) 0)))
 413            (ignore ()
 414              :report "Ignore this socket condition"
 415              (return-from %%send-to 0))
 416            (continue (&optional (wait 0))
 417              :report "Try to send data again"
 418              (when (plusp wait) (sleep wait))))))))
 419
 420 (defun %inet-send-to (socket buffer start end remote-host remote-port flags)
 421   (with-sockaddr-storage (ss)
 422     (when remote-host
 423       (sockaddr->sockaddr-storage ss (ensure-hostname remote-host)
 424                                   (ensure-numerical-service remote-port)))
 425     (%%send-to (fd-of socket) ss (if remote-host t) buffer start end flags
 426                (external-format-of socket))))
 427
 428 (defun %local-send-to (socket buffer start end remote-filename flags)
 429   (with-sockaddr-storage (ss)
 430     (when remote-filename
 431       (sockaddr->sockaddr-storage ss (ensure-address remote-filename :family :local) 0))
 432     (%%send-to (fd-of socket) ss (if remote-filename t) buffer start end flags
 433                (external-format-of socket))))
 434
 435 (defmethod send-to ((socket internet-socket) buffer &rest args
 436                     &key (start 0) end remote-host (remote-port 0) (ipv6 *ipv6*))
 437   (let ((*ipv6* ipv6))
 438     (%inet-send-to socket buffer start end remote-host remote-port
 439                    (compute-flags *sendto-flags* args))))
 440
 441 (defmethod send-to ((socket local-socket) buffer &rest args
 442                     &key (start 0) end remote-filename)
 443   (%local-send-to socket buffer start end remote-filename
 444                   (compute-flags *sendto-flags* args)))
 445
 446 (define-compiler-macro send-to (&whole form socket buffer &rest args
 447                                 &key (start 0) end remote-host (remote-port 0)
 448                                 remote-filename (ipv6 '*ipv6*) &allow-other-keys)
 449   (let ((flags (compute-flags *sendto-flags* args)))
 450     (cond (flags
 451            (once-only (socket buffer start end remote-host
 452                        remote-port remote-filename flags)
 453              `(etypecase ,socket
 454                 (internet-socket
 455                  (let ((*ipv6* ,ipv6))
 456                    (%inet-send-to ,socket ,buffer ,start ,end
 457                                   ,remote-host ,remote-port ,flags)))
 458                 (local-socket
 459                  (%local-send-to ,socket ,buffer ,start ,end
 460                                  ,remote-filename ,flags)))))
 461           (t form))))
 462
 463 ;;;; RECVFROM
 464
 465 (defvar *recvfrom-flags* ())
 466
 467 (define-socket-flags *recvfrom-flags*
 468   (:out-of-band msg-oob)
 469   (:peek        msg-peek)
 470   (:wait-all    msg-waitall  (:not :windows))
 471   (:dont-wait   msg-dontwait (:not :windows)))
 472
 473 (defun allocate-ub8-buffer-for-string (length ef)
 474   (let* ((units-per-char (babel-encodings:enc-max-units-per-char
 475                           (babel:external-format-encoding ef)))
 476          (length (* units-per-char length)))
 477     (values (make-array length :element-type 'ub8)
 478             0 length)))
 479
 480 (defun %normalize-receive-buffer (buff start end ef)
 481   (etypecase buff
 482     (ub8-sarray (values buff start (- end start)))
 483     (string     (allocate-ub8-buffer-for-string (- end start) ef))))
 484
 485 (defun %%receive-from (fd ss size buffer start end flags ef)
 486   (check-bounds buffer start end)
 487   (multiple-value-bind (buff start-offset bufflen)
 488       (%normalize-receive-buffer buffer start end ef)
 489     (with-pointer-to-vector-data (buff-sap buff)
 490       (incf-pointer buff-sap start-offset)
 491       (loop
 492          (restart-case
 493              (let ((nbytes (%recvfrom fd buff-sap bufflen flags ss size)))
 494                (return-from %%receive-from
 495                  (if (stringp buffer)
 496                      ;; FIXME: convert the octets directly into the buffer
 497                      (let ((str (babel:octets-to-string buff :start 0 :end nbytes
 498                                                         :encoding (babel:external-format-encoding ef)
 499                                                         :errorp nil)))
 500                        (replace buffer str :start1 start :end1 end)
 501                        (- end start))
 502                      nbytes)))
 503            (ignore ()
 504              :report "Ignore this socket condition"
 505              (return-from %%receive-from 0))
 506            (continue (&optional (wait 0))
 507              :report "Try to receive data again"
 508              (when (plusp wait) (sleep wait))))))))
 509
 510 (declaim (inline %receive-from-stream-socket))
 511 (defun %receive-from-stream-socket (socket buffer start end flags)
 512   (with-sockaddr-storage-and-socklen (ss size)
 513     (let ((nelements (%%receive-from (fd-of socket) ss size buffer start end
 514                                      flags (external-format-of socket))))
 515       (values buffer nelements))))
 516
 517 (declaim (inline %receive-from-datagram-socket))
 518 (defun %receive-from-datagram-socket (socket buffer start end flags)
 519   (with-sockaddr-storage-and-socklen (ss size)
 520     (let ((nelements (%%receive-from (fd-of socket) ss size buffer start end
 521                                      flags (external-format-of socket))))
 522       (multiple-value-call #'values buffer nelements
 523                            (sockaddr-storage->sockaddr ss)))))
 524
 525 (defun %receive-from (socket buffer start end size flags)
 526   (unless buffer
 527     (check-type size unsigned-byte "a non-negative integer")
 528     (setf buffer (make-array size :element-type 'ub8)
 529           start 0 end size))
 530   (etypecase socket
 531     (stream-socket (%receive-from-stream-socket socket buffer start end flags))
 532     (datagram-socket (%receive-from-datagram-socket socket buffer start end flags))))
 533
 534 (defmethod receive-from ((socket active-socket) &rest args
 535                          &key buffer size (start 0) end)
 536   (%receive-from socket buffer start end size
 537                  (compute-flags *recvfrom-flags* args)))
 538
 539 (define-compiler-macro receive-from (&whole form socket &rest args
 540                                      &key buffer size (start 0) end &allow-other-keys)
 541   (let ((flags (compute-flags *recvfrom-flags* args)))
 542     (cond (flags `(%receive-from ,socket ,buffer ,start ,end ,size ,flags))
 543           (t form))))