net.sockets/socket-methods.lisp

   1 ;;;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp; indent-tabs-mode: nil -*-
   2 ;;;
   3 ;;; --- Various socket methods.
   4 ;;;
   5
   6 (in-package :net.sockets)
   7
   8 (defvar *socket-type-map*
   9   '(((:ipv4  :stream   :active  :default) . socket-stream-internet-active)
  10     ((:ipv6  :stream   :active  :default) . socket-stream-internet-active)
  11     ((:ipv4  :stream   :passive :default) . socket-stream-internet-passive)
  12     ((:ipv6  :stream   :passive :default) . socket-stream-internet-passive)
  13     ((:local :stream   :active  :default) . socket-stream-local-active)
  14     ((:local :stream   :passive :default) . socket-stream-local-passive)
  15     ((:local :datagram :active  :default) . socket-datagram-local-active)
  16     ((:ipv4  :datagram :active  :default) . socket-datagram-internet-active)
  17     ((:ipv6  :datagram :active  :default) . socket-datagram-internet-active)))
  18
  19 ;;; FIXME: should match :default to whatever protocol is the default.
  20 (defun select-socket-class (address-family type connect protocol)
  21   (or (cdr (assoc (list address-family type connect protocol) *socket-type-map*
  22                   :test #'equal))
  23       (error "No socket class found !!")))
  24
  25 ;;;; Shared Initialization
  26
  27 (defun translate-make-socket-keywords-to-constants (address-family type protocol)
  28   (let ((sf (ecase address-family
  29               (:ipv4  af-inet)
  30               (:ipv6  af-inet6)
  31               (:local af-local)))
  32         (st (ecase type
  33               (:stream   sock-stream)
  34               (:datagram sock-dgram)))
  35         (sp (cond
  36               ((integerp protocol) protocol)
  37               ((eq :default protocol) 0)
  38               (t (lookup-protocol protocol)))))
  39     (values sf st sp)))
  40
  41 (defmethod socket-os-fd ((socket socket))
  42   (fd-of socket))
  43
  44 (defmethod initialize-instance :after ((socket socket) &key
  45                                        file-descriptor address-family type
  46                                        (protocol :default))
  47   (with-accessors ((fd fd-of) (fam socket-address-family) (proto socket-protocol))
  48       socket
  49     (setf fd (or file-descriptor
  50                  (multiple-value-call #'%socket
  51                    (translate-make-socket-keywords-to-constants
  52                     address-family type protocol))))
  53     (setf fam address-family
  54           proto protocol)))
  55
  56 (defmethod (setf external-format-of) (external-format (socket passive-socket))
  57   (setf (slot-value socket 'external-format)
  58         (babel:ensure-external-format external-format)))
  59
  60 (defmethod initialize-instance :after ((socket passive-socket) &key external-format
  61                                        input-buffer-size output-buffer-size)
  62   ;; Makes CREATE-SOCKET simpler
  63   (declare (ignore input-buffer-size output-buffer-size))
  64   (setf (external-format-of socket) external-format))
  65
  66 (defmethod socket-type ((socket stream-socket))
  67   :stream)
  68
  69 (defmethod socket-type ((socket datagram-socket))
  70   :datagram)
  71
  72 (defun ipv6-socket-p (socket)
  73   "Return T if SOCKET is an AF_INET6 socket."
  74   (eq :ipv6 (socket-address-family socket)))
  75
  76 ;;;; Printing
  77
  78 (defun sock-fam (socket)
  79   (ecase (socket-address-family socket)
  80     (:ipv4 "IPv4")
  81     (:ipv6 "IPv6")))
  82
  83 (defmethod print-object ((socket socket-stream-internet-active) stream)
  84   (print-unreadable-object (socket stream :identity t)
  85     (format stream "active ~A stream socket" (sock-fam socket))
  86     (if (socket-connected-p socket)
  87         (multiple-value-bind (host port) (remote-name socket)
  88           (format stream " connected to ~A/~A"
  89                   (address-to-string host) port))
  90         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
  91
  92 (defmethod print-object ((socket socket-stream-internet-passive) stream)
  93   (print-unreadable-object (socket stream :identity t)
  94     (format stream "passive ~A stream socket" (sock-fam socket))
  95     (if (socket-bound-p socket)
  96         (multiple-value-bind (host port) (local-name socket)
  97           (format stream " ~:[bound to~;waiting @~] ~A/~A"
  98                   (socket-listening-p socket)
  99                   (address-to-string host) port))
 100         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 101
 102 (defmethod print-object ((socket socket-stream-local-active) stream)
 103   (print-unreadable-object (socket stream :identity t)
 104     (format stream "active local stream socket")
 105     (if (socket-connected-p socket)
 106         (format stream " connected to ~S"
 107                 (address-to-string (remote-filename socket)))
 108         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
 109
 110 (defmethod print-object ((socket socket-stream-local-passive) stream)
 111   (print-unreadable-object (socket stream :identity t)
 112     (format stream "passive local stream socket")
 113     (if (socket-bound-p socket)
 114         (format stream " ~:[bound to~;waiting @~] ~S"
 115                   (socket-listening-p socket)
 116                   (address-to-string (local-filename socket)))
 117         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 118
 119 (defmethod print-object ((socket socket-datagram-local-active) stream)
 120   (print-unreadable-object (socket stream :identity t)
 121     (format stream "local datagram socket")
 122     (if (socket-connected-p socket)
 123         (format stream " connected to ~S"
 124                 (address-to-string (remote-filename socket)))
 125         (if (fd-of socket)
 126             (format stream " waiting @ ~S" (address-to-string (local-filename socket)))
 127             (format stream ", closed" )))))
 128
 129 (defmethod print-object ((socket socket-datagram-internet-active) stream)
 130   (print-unreadable-object (socket stream :identity t)
 131     (format stream "~A datagram socket" (sock-fam socket))
 132     (if (socket-connected-p socket)
 133         (multiple-value-bind (host port) (remote-name socket)
 134           (format stream " connected to ~A/~A"
 135                   (address-to-string host) port))
 136         (if (fd-of socket)
 137             (multiple-value-bind (host port) (local-name socket)
 138               (format stream " waiting @ ~A/~A"
 139                       (address-to-string host) port))
 140             (format stream ", closed" )))))
 141
 142 ;;;; CLOSE
 143
 144 (defmethod close :around ((socket socket) &key abort)
 145   (declare (ignore abort))
 146   (call-next-method)
 147   (when (fd-of socket)
 148     (nix:close (fd-of socket)))
 149   (setf (fd-of socket) nil
 150         (slot-value socket 'bound) nil)
 151   (values socket))
 152
 153 (defmethod close :around ((socket passive-socket) &key abort)
 154   (declare (ignore abort))
 155   (call-next-method)
 156   (setf (slot-value socket 'listening) nil)
 157   (values socket))
 158
 159 (defmethod close ((socket socket) &key abort)
 160   (declare (ignore socket abort)))
 161
 162 (defmethod socket-open-p ((socket socket))
 163   (when (fd-of socket)
 164     (with-sockaddr-storage-and-socklen (ss size)
 165       (handler-case
 166           (%getsockname (fd-of socket) ss size)
 167         (nix:ebadf () nil)
 168         (socket-connection-reset-error () nil)
 169         (:no-error (_) (declare (ignore _)) t)))))
 170
 171 ;;;; GETSOCKNAME
 172
 173 (defun %local-name (socket)
 174   (with-sockaddr-storage-and-socklen (ss size)
 175     (%getsockname (fd-of socket) ss size)
 176     (sockaddr-storage->sockaddr ss)))
 177
 178 (defmethod local-name ((socket socket))
 179   (%local-name socket))
 180
 181 (defmethod local-host ((socket internet-socket))
 182   (nth-value 0 (%local-name socket)))
 183
 184 (defmethod local-port ((socket internet-socket))
 185   (nth-value 1 (%local-name socket)))
 186
 187 (defmethod local-filename ((socket local-socket))
 188   (%local-name socket))
 189
 190 ;;;; GETPEERNAME
 191
 192 (defun %remote-name (socket)
 193   (with-sockaddr-storage-and-socklen (ss size)
 194     (%getpeername (fd-of socket) ss size)
 195     (sockaddr-storage->sockaddr ss)))
 196
 197 (defmethod remote-name ((socket socket))
 198   (%remote-name socket))
 199
 200 (defmethod remote-host ((socket internet-socket))
 201   (nth-value 0 (%remote-name socket)))
 202
 203 (defmethod remote-port ((socket internet-socket))
 204   (nth-value 1 (%remote-name socket)))
 205
 206 (defmethod remote-filename ((socket local-socket))
 207   (%remote-name socket))
 208
 209 ;;;; BIND
 210
 211 (defmethod bind-address :before ((socket internet-socket) address
 212                                  &key (reuse-address t))
 213   (declare (ignore address))
 214   (when reuse-address
 215     (setf (socket-option socket :reuse-address) t)))
 216
 217 (defun bind-ipv4-address (fd address port)
 218   (with-sockaddr-in (sin address port)
 219     (%bind fd sin size-of-sockaddr-in)))
 220
 221 (defun bind-ipv6-address (fd address port)
 222   (with-sockaddr-in6 (sin6 address port)
 223     (%bind fd sin6 size-of-sockaddr-in6)))
 224
 225 (defmethod bind-address ((socket internet-socket) (address ipv4-address)
 226                          &key (port 0))
 227   (if (ipv6-socket-p socket)
 228       (bind-ipv6-address (fd-of socket)
 229                          (map-ipv4-vector-to-ipv6 (address-name address))
 230                          port)
 231       (bind-ipv4-address (fd-of socket) (address-name address) port))
 232   (values socket))
 233
 234 (defmethod bind-address ((socket internet-socket) (address ipv6-address)
 235                          &key (port 0))
 236   (bind-ipv6-address (fd-of socket) (address-name address) port)
 237   (values socket))
 238
 239 (defmethod bind-address ((socket local-socket) (address local-address) &key)
 240   (with-sockaddr-un (sun (address-name address))
 241     (%bind (fd-of socket) sun size-of-sockaddr-un))
 242   (values socket))
 243
 244 (defmethod bind-address :after ((socket socket) (address address) &key)
 245   (setf (slot-value socket 'bound) t))
 246
 247 ;;;; LISTEN
 248
 249 (defmethod listen-on ((socket passive-socket) &key backlog)
 250   (unless backlog (setf backlog (min *default-backlog-size*
 251                                      +max-backlog-size+)))
 252   (check-type backlog unsigned-byte "a non-negative integer")
 253   (%listen (fd-of socket) backlog)
 254   (setf (slot-value socket 'listening) t)
 255   (values socket))
 256
 257 (defmethod listen-on ((socket active-socket) &key)
 258   (error "You can't listen on active sockets."))
 259
 260 ;;;; ACCEPT
 261
 262 (defmethod accept-connection ((socket active-socket) &key)
 263   (error "You can't accept connections on active sockets."))
 264
 265 (defmethod accept-connection ((socket passive-socket) &key external-format
 266                               input-buffer-size output-buffer-size
 267                               (wait t) (timeout nil))
 268   (flet ((make-client-socket (fd)
 269            (make-instance (active-class socket)
 270                           :address-family (socket-address-family socket)
 271                           :file-descriptor fd
 272                           :external-format (or external-format
 273                                                (external-format-of socket))
 274                           :input-buffer-size input-buffer-size
 275                           :output-buffer-size output-buffer-size)))
 276     (ignore-some-conditions (iomux:poll-timeout)
 277       (when wait (iomux:wait-until-fd-ready (fd-of socket) :input timeout t))
 278       (with-sockaddr-storage-and-socklen (ss size)
 279         (ignore-some-conditions (nix:ewouldblock)
 280           (make-client-socket (%accept (fd-of socket) ss size)))))))
 281
 282 ;;;; CONNECT
 283
 284 (defun ipv4-connect (fd address port)
 285   (with-sockaddr-in (sin address port)
 286     (%connect fd sin size-of-sockaddr-in)))
 287
 288 (defun ipv6-connect (fd address port)
 289   (with-sockaddr-in6 (sin6 address port)
 290     (%connect fd sin6 size-of-sockaddr-in6)))
 291
 292 (defun call-with-socket-to-wait-connect (socket thunk wait timeout)
 293   (handler-case
 294       (funcall thunk)
 295     (nix:ewouldblock (err)
 296       (cond
 297         (wait
 298          (iomux:wait-until-fd-ready (fd-of socket) :output timeout t)
 299          (let ((errcode (socket-option socket :error)))
 300            (unless (zerop errcode)
 301              (signal-socket-error errcode))))
 302         (t (error err))))))
 303
 304 (defmacro with-socket-to-wait-connect ((socket wait timeout) &body body)
 305   `(call-with-socket-to-wait-connect ,socket (lambda () ,@body) ,wait ,timeout))
 306
 307 (defmethod connect ((socket internet-socket) (address inet-address)
 308                     &key (port 0) (wait t) (timeout nil))
 309   (let ((name (address-name address)))
 310     (with-socket-to-wait-connect (socket wait timeout)
 311       (cond
 312         ((ipv6-socket-p socket)
 313          (when (ipv4-address-p address)
 314            (setf name (map-ipv4-vector-to-ipv6 name)))
 315          (ipv6-connect (fd-of socket) name port))
 316         (t (ipv4-connect (fd-of socket) name port)))))
 317   (values socket))
 318
 319 (defmethod connect ((socket local-socket) (address local-address) &key)
 320   (with-sockaddr-un (sun (address-name address))
 321     (%connect (fd-of socket) sun size-of-sockaddr-un))
 322   (values socket))
 323
 324 (defmethod connect ((socket passive-socket) address &key)
 325   (declare (ignore address))
 326   (error "You cannot connect passive sockets."))
 327
 328 (defmethod socket-connected-p ((socket socket))
 329   (when (fd-of socket)
 330     (with-sockaddr-storage-and-socklen (ss size)
 331       (handler-case
 332           (%getpeername (fd-of socket) ss size)
 333         (socket-not-connected-error () nil)
 334         (:no-error (_) (declare (ignore _)) t)))))
 335
 336 ;;;; DISCONNECT
 337
 338 (defmethod disconnect :before ((socket socket))
 339   (unless (typep socket 'datagram-socket)
 340     (error "You can only disconnect active datagram sockets.")))
 341
 342 (defmethod disconnect ((socket datagram-socket))
 343   (with-foreign-object (sin 'sockaddr-in)
 344     (bzero sin size-of-sockaddr-in)
 345     (setf (foreign-slot-value sin 'sockaddr-in 'addr) af-unspec)
 346     (%connect (fd-of socket) sin size-of-sockaddr-in)
 347     (values socket)))
 348
 349 ;;;; SHUTDOWN
 350
 351 (defmethod shutdown ((socket socket) &key read write)
 352   (assert (or read write) (read write)
 353           "You must select at least one direction to shut down.")
 354   (%shutdown (fd-of socket)
 355              (multiple-value-case ((read write))
 356                ((*   nil) shut-rd)
 357                ((nil *)   shut-wr)
 358                (t         shut-rdwr)))
 359   (values socket))
 360
 361 ;;;; Socket flag definition
 362
 363 (defmacro define-socket-flag (place name value platform)
 364   (let ((val (cond ((or (not platform)
 365                         (featurep platform)) value)
 366                    ((not (featurep platform)) 0))))
 367     `(pushnew (cons ,name ,val) ,place)))
 368
 369 (defmacro define-socket-flags (place &body definitions)
 370   (flet ((dflag (form)
 371            (destructuring-bind (name value &optional platform) form
 372              `(define-socket-flag ,place ,name ,value ,platform))))
 373     `(progn
 374        ,@(mapcar #'dflag definitions))))
 375
 376 ;;;; SENDTO
 377
 378 (defvar *sendto-flags* ())
 379
 380 (define-socket-flags *sendto-flags*
 381   (:dont-route    msg-dontroute)
 382   (:dont-wait     msg-dontwait  (:not :windows))
 383   (:out-of-band   msg-oob)
 384   (:more          msg-more      :linux)
 385   (:confirm       msg-confirm   :linux))
 386
 387 (defun %normalize-send-buffer (buffer start end)
 388   (check-bounds buffer start end)
 389   (etypecase buffer
 390     (ub8-sarray
 391      (values buffer start (- end start)))
 392     ((or ub8-vector (vector t))
 393      (values (coerce buffer 'ub8-sarray)
 394              start (- end start)))))
 395
 396 (defun %%send-to (fd ss got-peer buffer start end flags)
 397   (multiple-value-bind (buff start-offset bufflen)
 398       (%normalize-send-buffer buffer start end)
 399     (with-pointer-to-vector-data (buff-sap buff)
 400       (incf-pointer buff-sap start-offset)
 401       (loop
 402          (restart-case
 403              (return*
 404               (%sendto fd buff-sap bufflen flags
 405                        (if got-peer ss (null-pointer))
 406                        (if got-peer (sockaddr-size ss) 0)))
 407            (ignore ()
 408              :report "Ignore this socket condition"
 409              (return* 0))
 410            (continue (&optional (wait 0))
 411              :report "Try to send data again"
 412              (when (plusp wait) (sleep wait))))))))
 413
 414 (defun %inet-send-to (socket buffer start end remote-host remote-port flags)
 415   (with-sockaddr-storage (ss)
 416     (when remote-host
 417       (sockaddr->sockaddr-storage ss (ensure-hostname remote-host)
 418                                   (ensure-numerical-service remote-port)))
 419     (%%send-to (fd-of socket) ss (if remote-host t) buffer start end flags)))
 420
 421 (defun %local-send-to (socket buffer start end remote-filename flags)
 422   (with-sockaddr-storage (ss)
 423     (when remote-filename
 424       (sockaddr->sockaddr-storage ss (ensure-address remote-filename :family :local) 0))
 425     (%%send-to (fd-of socket) ss (if remote-filename t) buffer start end flags)))
 426
 427 (defmethod send-to ((socket internet-socket) buffer &rest args
 428                     &key (start 0) end remote-host (remote-port 0) (ipv6 *ipv6*))
 429   (let ((*ipv6* ipv6))
 430     (%inet-send-to socket buffer start end remote-host remote-port
 431                    (compute-flags *sendto-flags* args))))
 432
 433 (defmethod send-to ((socket local-socket) buffer &rest args
 434                     &key (start 0) end remote-filename)
 435   (%local-send-to socket buffer start end remote-filename
 436                   (compute-flags *sendto-flags* args)))
 437
 438 (define-compiler-macro send-to (&whole form socket buffer &rest args
 439                                 &key (start 0) end remote-host (remote-port 0)
 440                                 remote-filename (ipv6 '*ipv6*) &allow-other-keys)
 441   (let ((flags (compute-flags *sendto-flags* args)))
 442     (cond (flags
 443            (once-only (socket buffer start end remote-host
 444                        remote-port remote-filename flags)
 445              `(etypecase ,socket
 446                 (internet-socket
 447                  (let ((*ipv6* ,ipv6))
 448                    (%inet-send-to ,socket ,buffer ,start ,end
 449                                   ,remote-host ,remote-port ,flags)))
 450                 (local-socket
 451                  (%local-send-to ,socket ,buffer ,start ,end
 452                                  ,remote-filename ,flags)))))
 453           (t form))))
 454
 455 ;;;; RECVFROM
 456
 457 (defvar *recvfrom-flags* ())
 458
 459 (define-socket-flags *recvfrom-flags*
 460   (:out-of-band msg-oob)
 461   (:peek        msg-peek)
 462   (:wait-all    msg-waitall  (:not :windows))
 463   (:dont-wait   msg-dontwait (:not :windows)))
 464
 465 (defun %%receive-from (fd ss size buffer start length flags)
 466   (with-pointer-to-vector-data (buff-sap buffer)
 467     (incf-pointer buff-sap start)
 468     (loop
 469        (restart-case
 470            (return* (%recvfrom fd buff-sap length flags ss size))
 471          (ignore ()
 472            :report "Ignore this socket condition"
 473            (return* 0))
 474          (continue (&optional (wait 0))
 475            :report "Try to receive data again"
 476            (when (plusp wait) (sleep wait)))))))
 477
 478 (defun %receive-from (socket buffer start end flags)
 479   (check-bounds buffer start end)
 480   (with-sockaddr-storage-and-socklen (ss size)
 481     (flet ((%do-recvfrom (buff start length)
 482              (%%receive-from (fd-of socket) ss size buff start length flags)))
 483       (let (nbytes)
 484         (etypecase buffer
 485           (ub8-sarray
 486            (setf nbytes (%do-recvfrom buffer start (- end start))))
 487           ((or ub8-vector (vector t))
 488            (let ((tmpbuff (make-array (- end start) :element-type 'ub8)))
 489              (setf nbytes (%do-recvfrom tmpbuff 0 (- end start)))
 490              (replace buffer tmpbuff :start1 start :end2 end :start2 0 :end2 nbytes))))
 491         (etypecase socket
 492           (stream-socket
 493            (values buffer nbytes))
 494           (datagram-socket
 495            (multiple-value-call #'values buffer nbytes
 496                                 (sockaddr-storage->sockaddr ss))))))))
 497
 498 (defmethod receive-from ((socket active-socket) &rest args
 499                          &key buffer size (start 0) end)
 500   (let ((flags (compute-flags *recvfrom-flags* args)))
 501     (cond
 502       (buffer
 503        (%receive-from socket buffer start end flags))
 504       (t
 505        (check-type size unsigned-byte "a non-negative integer")
 506        (%receive-from socket (make-array size :element-type 'ub8) 0 size flags)))))
 507
 508 (define-compiler-macro receive-from (&whole form socket &rest args
 509                                      &key buffer size (start 0) end &allow-other-keys)
 510   (let ((flags (compute-flags *recvfrom-flags* args)))
 511     (cond
 512       (flags
 513        (if buffer
 514            `(%receive-from ,socket ,buffer ,start ,end ,flags)
 515            (with-gensyms (buffer-size)
 516              `(let ((,buffer-size ,size))
 517                 (check-type ,buffer-size unsigned-byte "a non-negative integer")
 518                 (%receive-from ,socket (make-array ,buffer-size :element-type 'ub8)
 519                                0 nil ,flags)))))
 520       (t
 521        form))))