sockets/conditions.lisp

   1 ;; -*- Mode: Lisp; Syntax: ANSI-Common-Lisp -*-
   2
   3 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   4 ;   Copyright (C) 2006 by Stelian Ionescu                                 ;
   5 ;                                                                         ;
   6 ;   This program is free software; you can redistribute it and/or modify  ;
   7 ;   it under the terms of the GNU General Public License as published by  ;
   8 ;   the Free Software Foundation; either version 2 of the License, or     ;
   9 ;   (at your option) any later version.                                   ;
  10 ;                                                                         ;
  11 ;   This program is distributed in the hope that it will be useful,       ;
  12 ;   but WITHOUT ANY WARRANTY; without even the implied warranty of        ;
  13 ;   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         ;
  14 ;   GNU General Public License for more details.                          ;
  15 ;                                                                         ;
  16 ;   You should have received a copy of the GNU General Public License     ;
  17 ;   along with this program; if not, write to the                         ;
  18 ;   Free Software Foundation, Inc.,                                       ;
  19 ;   51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA              ;
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21
  22 ;; (declaim (optimize (speed 2) (safety 2) (space 1) (debug 2)))
  23 (declaim (optimize (speed 0) (safety 2) (space 0) (debug 2)))
  24
  25 (in-package #:net.sockets)
  26
  27 (defmethod error-code ((err system-error))
  28   (et:system-error-code err))
  29
  30 (defmethod error-identifier ((err system-error))
  31   (et:system-error-identifier err))
  32
  33 (defmethod error-message ((err system-error))
  34   (et:message err))
  35
  36 (defun print-message-if-not-null (condition stream &optional (eof-place :before))
  37   (declare (type stream stream))
  38   (let ((msg (error-message condition)))
  39     (when msg
  40       (when (eql eof-place :before)
  41         (fresh-line stream))
  42       (format stream "~a" msg)
  43       (when (eql eof-place :after)
  44         (fresh-line stream)))))
  45
  46 (define-condition invalid-argument (system-error)
  47   ((argument :initarg :argument :reader invalid-argument))
  48   (:report (lambda (condition stream)
  49              (declare (type stream stream))
  50              (format stream "Invalid argument: ~a"
  51                      (invalid-argument condition))
  52              (print-message-if-not-null condition stream)))
  53   (:documentation "Signaled when one or more of a function's arguments are considered
  54 not valid(wrong type or good type but not within a certain range of
  55 values, et caetera)."))
  56
  57 ;;;;;;;;;;;;;;;;;;;;;;;
  58 ;;;  SOCKET ERRORS  ;;;
  59 ;;;;;;;;;;;;;;;;;;;;;;;
  60
  61 (defparameter *socket-error-map* nil)
  62
  63 (define-condition socket-error (unix-error) ())
  64
  65 (defmacro define-socket-error (name identifier &optional documentation)
  66   `(progn
  67      (export ',name)
  68      (push (cons ,identifier ',name) *socket-error-map*)
  69      (define-condition ,name (socket-error) ()
  70        (:default-initargs :code (unixerr-value ,identifier)
  71                           :identifier ,identifier)
  72        (:documentation ,documentation))))
  73
  74 (define-socket-error socket-address-in-use-error          :eaddrinuse)
  75 (define-socket-error socket-address-not-available-error   :eaddrnotavail)
  76 (define-socket-error socket-network-down-error            :enetdown)
  77 (define-socket-error socket-network-reset-error           :enetreset)
  78 (define-socket-error socket-network-unreachable-error     :enetunreach)
  79 (define-socket-error socket-no-network-error              :enonet)
  80 (define-socket-error socket-connection-aborted-error      :econnaborted)
  81 (define-socket-error socket-connection-reset-error        :econnreset)
  82 (define-socket-error socket-connection-refused-error      :econnrefused)
  83 (define-socket-error socket-endpoint-shutdown-error       :eshutdown)
  84 (define-socket-error socket-connection-timeout-error      :etimedout)
  85 (define-socket-error socket-no-buffer-space-error         :enobufs)
  86 (define-socket-error socket-host-down-error               :ehostdown)
  87 (define-socket-error socket-host-unreachable-error        :ehostunreach)
  88 (define-socket-error socket-already-connected-error       :eisconn)
  89 (define-socket-error socket-not-connected-error           :enotconn)
  90 (define-socket-error socket-option-not-supported-error    :enoprotoopt)
  91 (define-socket-error socket-operation-not-supported-error :eopnotsupp)
  92
  93 (defun socket-error (unix-error)
  94   (let* ((id (error-identifier unix-error))
  95          (condition (cdr (assoc id *socket-error-map*))))
  96     (if condition
  97         (error condition)
  98         (error unix-error))))
  99
 100 (defmacro with-socket-error-filter (&body body)
 101   `(handler-case
 102        (progn ,@body)
 103      (unix-error (err)
 104        (socket-error err))))