usr/src/lib/libm/i386/src/hypotf.s

   1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28
  29         .file "hypotf.s"
  30
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(hypotf,function)
  33 #include "libm_protos.h"
  34
  35         ENTRY(hypotf)
  36         movl    4(%esp),%eax            / eax <-- x
  37         andl    $0x7fffffff,%eax        / eax <-- |x|
  38         jz      .return_abs_y           / if x = +/-0, return |y|
  39         subl    $0x7f800000,%eax        / eax <-- |x| - INF
  40         jz      .return_abs_x           / if x = +/-INF, return |x|
  41         movl    8(%esp),%eax            / eax <-- y
  42         andl    $0x7fffffff,%eax        / eax <-- |y|
  43         jz      .return_abs_x           / if y = +/-0, return |x|
  44         subl    $0x7f800000,%eax        / eax <-- |y| - INF
  45 .return_abs_y:
  46         flds    8(%esp)                 / y
  47         jz      .take_abs               / if y = +/-INF, return |y|
  48         fmul    %st(0),%st              / y*y
  49         flds    4(%esp)                 / x,y*y
  50         fmul    %st(0),%st              / x*x,y*y
  51         faddp   %st,%st(1)              / x*x+y*y
  52         fsqrt                           / sqrt(x*x+y*y)
  53         subl    $4,%esp
  54         fstps   (%esp)                  / round to single
  55         flds    (%esp)
  56         fwait
  57         addl    $4,%esp
  58         ret
  59
  60 .return_abs_x:
  61         / returns |x|
  62         flds    4(%esp)
  63 .take_abs:
  64         fabs
  65         ret
  66         .align  4
  67         SET_SIZE(hypotf)