5261 libm should stop using synonyms.h
[illumos-gate.git] / usr / src / lib / libm / i386 / src / exp10l.s
blobe15b129a667ff4a1ffe3c11e1644162147cb1b5f
1 /*
2 * CDDL HEADER START
4 * The contents of this file are subject to the terms of the
5 * Common Development and Distribution License (the "License").
6 * You may not use this file except in compliance with the License.
8 * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
9 * or http://www.opensolaris.org/os/licensing.
10 * See the License for the specific language governing permissions
11 * and limitations under the License.
13 * When distributing Covered Code, include this CDDL HEADER in each
14 * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
15 * If applicable, add the following below this CDDL HEADER, with the
16 * fields enclosed by brackets "[]" replaced with your own identifying
17 * information: Portions Copyright [yyyy] [name of copyright owner]
19 * CDDL HEADER END
22 * Copyright 2011 Nexenta Systems, Inc. All rights reserved.
25 * Copyright 2006 Sun Microsystems, Inc. All rights reserved.
26 * Use is subject to license terms.
29 .file "exp10l.s"
31 #include "libm.h"
33 .data
34 .align 4
35 lt2_hi: .long 0xfbd00000, 0x9a209a84, 0x00003ffd
36 lt2_lo: .long 0x653f4837, 0x8677076a, 0x0000bfc9
38 ENTRY(exp10l)
39 movl 12(%esp),%ecx / cx <--sign&bexp(x)
40 andl $0x00007fff,%ecx / ecx <-- zero_xtnd(bexp(x))
41 cmpl $0x00003ffd,%ecx / Is |x| < log10(2)?
42 jb .shortcut / If so, take a shortcut.
43 je .check_tail / maybe |x| only slightly < log10(2)
44 cmpl $0x00007fff,%ecx / bexp(|x|) = bexp(INF)?
45 je .not_finite / if so, x is not finite
46 cmpl $0x0000400e,%ecx / |x| < 32768 = 2^15?
47 jb .finite_non_special / if so, proceed with argument reduction
48 fldt 4(%esp) / x
49 fld1 / 1, x
50 jmp 1f
51 .finite_non_special: / Here, log10(2) < |x| < 2^15
52 fldt 4(%esp) / x
53 fld %st(0) / x, x
54 fldl2t / log2(10), x, x
55 fmulp / z := x*log2(10), x
56 frndint / [z], x
57 fst %st(2) / [z], x, [z]
58 PIC_SETUP(1)
59 fldt PIC_L(lt2_hi) / lt2_hi, [z], x, [z]
60 fmulp / [z]*lt2_hi, x, [z]
61 fsubrp %st,%st(1) / x-[z]*lt2_hi, [z]
62 fldt PIC_L(lt2_lo) / lt2_lo, x-[z]*lt2_hi, [z]
63 PIC_WRAPUP
64 fmul %st(2),%st / [z]*lt2_lo, x-[z]*lt2_hi, [z]
65 fsubrp %st,%st(1) / r := x-[z]*log10(2), [z]
66 fldl2t / log2(10), r, [z]
67 fmulp / f := r*log2(10), [z]
68 f2xm1 / 2^f-1,[z]
69 fld1 / 1, 2^f-1, [z]
70 faddp %st,%st(1) / 2^f, [z]
72 fscale / 10^x, [z]
73 fstp %st(1)
74 ret
76 .check_tail:
77 movl 8(%esp),%ecx / ecx <-- hi_32(sgnfcnd(x))
78 cmpl $0x9a209a84,%ecx / Is |x| < log10(2)?
79 ja .finite_non_special
80 jb .shortcut
81 movl 4(%esp),%edx / edx <-- lo_32(sgnfcnd(x))
82 cmpl $0xfbcff798,%edx / Is |x| slightly > log10(2)?
83 ja .finite_non_special / branch if |x| slightly > log10(2)
84 .shortcut:
85 / Here, |x| < log10(2), so |z| = |x/log10(2)| < 1
86 / whence z is in f2xm1's domain.
87 fldt 4(%esp) / x
88 fldl2t / log2(10), x
89 fmulp / z := x*log2(10)
90 f2xm1 / 2^z-1
91 fld1 / 1, 2^z-1
92 faddp %st,%st(1) / 10^x
93 ret
95 .not_finite:
96 movl 8(%esp),%ecx / ecx <-- hi_32(sgnfcnd(x))
97 cmpl $0x80000000,%ecx / hi_32(sgnfcnd(x)) = hi_32(sgnfcnd(INF))?
98 jne .NaN_or_pinf / if not, x is NaN or unsupp.
99 movl 4(%esp),%edx / edx <-- lo_32(sgnfcnd(x))
100 cmpl $0,%edx / lo_32(sgnfcnd(x)) = 0?
101 jne .NaN_or_pinf / if not, x is NaN
102 movl 12(%esp),%eax / ax <-- sign&bexp((x))
103 andl $0x00008000,%eax / here, x is infinite, but +/-?
104 jz .NaN_or_pinf / branch if x = +INF
105 fldz / Here, x = -inf, so return 0
108 .NaN_or_pinf:
109 / Here, x = NaN or +inf, so load x and return immediately.
110 fldt 4(%esp)
112 .align 4
113 SET_SIZE(exp10l)