usr/src/lib/libm/amd64/src/ieee_funcl.s

   1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28
  29         .file "ieee_funcl.s"
  30
  31 #include "libm.h"
  32
  33         ENTRY(isinfl)
  34         movl    16(%rsp),%eax           / ax <-- sign and bexp of x
  35         notl    %eax
  36         andq    $0x7fff,%rax
  37         jz      .L6
  38         movq    $0,%rax
  39 .not_inf:
  40         ret
  41
  42 .L6:                                    / here, (eax) = 0.0
  43         movl    12(%rsp),%ecx
  44         xorl    $0x80000000,%ecx        / handle unsupported implicitly
  45         orl     8(%rsp), %ecx
  46         jnz     .not_inf
  47         movq    $1,%rax
  48         ret
  49         .align  16
  50         SET_SIZE(isinfl)
  51
  52         ENTRY(isnormall)
  53                                         / TRUE iff (x is finite, but
  54                                         /           neither subnormal nor zero)
  55                                         /      iff (msb(sgnfcnd(x) /= 0
  56                                         /           &  0 < bexp(x) < 0x7fff)
  57         movl    12(%rsp),%eax           / eax <-- hi_32(sgnfcnd(x))
  58         andl    $-0x80000000,%eax       / eax[31]  <-- msb(sgnfcnd(x)),
  59                                         / rest_of(eax) <-- 0
  60         jz      .L8                     / jump iff msb(sgnfcnd(x)) = 0
  61         movl    16(%rsp),%eax           / ax <-- sign and bexp of x
  62         notl    %eax                    / ax[0..14] <-- not(bexp(x))
  63         andq    $0x7fff,%rax            / eax  <-- zero_xtnd(not(bexp(x)))
  64         jz      .L8                     / jump  iff bexp(x) = 0x7fff or 0
  65         xorq    $0x7fff,%rax            / treat pseudo-denormal as subnormal
  66         jz      .L8
  67         movq    $1,%rax
  68 .L8:
  69         ret
  70         .align  16
  71         SET_SIZE(isnormall)
  72
  73         ENTRY(issubnormall)
  74                                         / TRUE iff (bexp(x) = 0 &
  75                                         / msb(sgnfcnd(x)) = 0 & frac(x) /= 0)
  76         movl    12(%rsp),%eax           / eax <-- hi_32(sgnfcnd(x))
  77         testl   $0x80000000,%eax        / eax[31] = msb(sgnfcnd(x));
  78                                         / set ZF if it's 0.
  79         jz      .may_be_subnorm         / jump iff msb(sgnfcnd(x)) = 0
  80 .not_subnorm:
  81         movq    $0,%rax
  82         ret
  83 .may_be_subnorm:
  84         testl   $0x7fff,16(%rsp)        / set ZF iff bexp(x)  = 0
  85         jnz     .not_subnorm            / jump   iff bexp(x) /= 0
  86         orl     8(%rsp),%eax            / (eax) = 0 iff sgnfcnd(x) = 0
  87         jz      .not_subnorm
  88         movq    $1,%rax
  89         ret
  90         .align  16
  91         SET_SIZE(issubnormall)
  92
  93         ENTRY(iszerol)
  94         movl    16(%rsp),%eax           / ax <-- sign and bexp of x
  95         andl    $0x7fff,%eax            / eax <-- zero_xtnd(bexp(x))
  96         jz      .may_be_zero            / jump iff bexp(x) = 0
  97 .not_zero:
  98         movq    $0,%rax
  99         ret
 100 .may_be_zero:                           / here, (eax) = 0
 101         orl     12(%rsp),%eax           / is hi_32(sgnfcnd(x)) = 0?
 102         jnz     .not_zero               / jump iff hi_32(sgnfcnd(x)) /= 0
 103         orl     8(%rsp),%eax            / is lo_32(sgnfcnd(x)) = 0?
 104         jnz     .not_zero               / jump iff lo_32(sgnfcnd(x)) /= 0
 105         movq    $1,%rax
 106         ret
 107         .align  16
 108         SET_SIZE(iszerol)
 109
 110         ENTRY(signbitl)
 111         movl    16(%rsp),%eax           / eax[15] <-- sign_bit(x)
 112         shrl    $15,%eax                / eax <-- zero_xtnd(sign_bit(x))
 113         andq    $1,%rax
 114         ret
 115         .align  16
 116         SET_SIZE(signbitl)